02b0db305f4e851f8ef94fd4036647271ac9c790
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.52)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.3, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 ALL_LINGUAS="de"
35
36 AC_CONFIG_AUX_DIR(scripts)
37 AC_CONFIG_SRCDIR(g10/g10.c)
38 AC_CANONICAL_TARGET()
39 AM_INIT_AUTOMAKE
40 AM_CONFIG_HEADER(config.h)
41
42 AC_GNU_SOURCE
43
44 dnl
45 dnl  Check for random module options
46 dnl
47 AC_MSG_CHECKING([which random module to use])
48 AC_ARG_ENABLE(static-rnd,
49     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
50 [use_static_rnd=$enableval], [use_static_rnd=default] )
51
52 if test "$use_static_rnd" = no; then
53     use_static_rnd=default
54 fi
55
56 case "$use_static_rnd" in
57     egd | linux | unix | default )
58       AC_MSG_RESULT($use_static_rnd)
59       ;;
60     auto )
61       AC_MSG_RESULT(automagically selected at runtime)
62       ;;
63     * )
64       AC_MSG_RESULT(invalid argument)
65       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
66       ;;
67 esac
68
69 AC_ARG_WITH(egd-socket,
70     [  --with-egd-socket=NAME  use NAME for the EGD socket],
71             egd_socket_name="$withval", egd_socket_name="" )
72 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
73                    [Define if you don't want the default EGD socket name.
74                     For details see cipher/rndegd.c])
75
76
77 dnl
78 dnl See whether the user wants to disable checking for /dev/random
79
80 AC_MSG_CHECKING([whether use of /dev/random is requested])
81 AC_ARG_ENABLE(dev-random,
82 [  --disable-dev-random    disable the use of dev random],
83     try_dev_random=$enableval, try_dev_random=yes)
84 AC_MSG_RESULT($try_dev_random)
85
86
87 dnl
88 dnl  Check other options
89 dnl
90
91 AC_MSG_CHECKING([whether assembler modules are requested])
92 AC_ARG_ENABLE(asm,
93 [  --disable-asm           do not use assembler modules],
94      try_asm_modules=$enableval, try_asm_modules=yes)
95 AC_MSG_RESULT($try_asm_modules)
96
97 AC_MSG_CHECKING([whether memory guard is requested])
98 AC_ARG_ENABLE(m-guard,
99     [  --enable-m-guard        enable memory guard facility],
100     use_m_guard=$enableval, use_m_guard=no)
101 AC_MSG_RESULT($use_m_guard)
102 if test "$use_m_guard" = yes ; then
103     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
104 fi
105
106 AC_MSG_CHECKING([whether OpenPGP card support is requested])
107 AC_ARG_ENABLE(card-support,
108     [  --enable-card-support   enable OpenPGP card support],
109     card_support=$enableval, card_support=no)
110 AC_MSG_RESULT($card_support)
111 if test "$card_support" = yes ; then
112     AC_DEFINE(ENABLE_CARD_SUPPORT,1,
113              [Define to include the OpenPGP card support])
114 fi
115 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
116
117 dnl See if we are disabling any algorithms or features for a smaller
118 dnl binary
119
120 try_dynload=no
121
122 use_idea=yes
123 use_cast5=yes
124 use_blowfish=yes
125 use_aes=yes
126 use_twofish=yes
127 use_sha256=yes
128 use_sha512=yes
129 use_exec=yes
130
131 AC_ARG_ENABLE(minimal,
132    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
133    use_idea=no
134    use_cast5=no
135    use_blowfish=no
136    use_aes=no
137    use_twofish=no
138    use_sha256=no
139    use_sha512=no
140    use_exec=no)
141
142 AC_MSG_CHECKING([whether to enable the IDEA cipher])
143 AC_ARG_ENABLE(idea,
144    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
145    use_idea=$enableval)
146 AC_MSG_RESULT($use_idea)
147 if test x"$use_idea" = xyes ; then
148    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
149
150 # We don't need idea but some people claim that they need it for
151 # research etc., so we allow to place an idea source code into the
152 # cipher directory and statically link it if available, otherwise we
153 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
154
155    AC_MSG_CHECKING([for idea cipher module])
156    tmp=""
157    if test -f $srcdir/cipher/idea.c; then 
158       IDEA_O=idea.o
159       tmp=idea
160    else
161       IDEA_O=idea-stub.o
162       tmp=no
163       try_dynload=yes
164    fi
165    AC_SUBST(IDEA_O)
166    AC_MSG_RESULT($tmp)
167 fi
168
169 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
170 AC_ARG_ENABLE(cast5,
171    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
172    use_cast5=$enableval)
173 AC_MSG_RESULT($use_cast5)
174 if test x"$use_cast5" = xyes ; then
175    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
176 fi
177
178 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
179 AC_ARG_ENABLE(blowfish,
180    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
181    use_blowfish=$enableval)
182 AC_MSG_RESULT($use_blowfish)
183 if test x"$use_blowfish" = xyes ; then
184    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
185 fi
186
187 AC_MSG_CHECKING([whether to enable the AES ciphers])
188 AC_ARG_ENABLE(aes,
189    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
190    use_aes=$enableval)
191 AC_MSG_RESULT($use_aes)
192 if test x"$use_aes" = xyes ; then
193    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
194 fi
195
196 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
197 AC_ARG_ENABLE(twofish,
198    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
199    use_twofish=$enableval)
200 AC_MSG_RESULT($use_twofish)
201 if test x"$use_twofish" = xyes ; then
202    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
203 fi
204
205 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
206 AC_ARG_ENABLE(sha256,
207    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
208    use_sha256=$enableval)
209 AC_MSG_RESULT($use_sha256)
210 if test x"$use_sha256" = xyes ; then
211    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
212 fi
213
214 dnl SHA512 is defined only after we confirm 64-bit support later
215 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
216 AC_ARG_ENABLE(sha512,
217    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
218    use_sha512=$enableval)
219 AC_MSG_RESULT($use_sha512)
220
221 AC_MSG_CHECKING([whether to enable external program execution])
222 AC_ARG_ENABLE(exec,
223     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
224     use_exec=$enableval)
225 AC_MSG_RESULT($use_exec)
226 if test "$use_exec" = no ; then
227     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
228 fi
229
230 if test "$use_exec" = yes ; then
231   AC_MSG_CHECKING([whether to enable photo ID viewing])
232   AC_ARG_ENABLE(photo-viewers,
233       [  --disable-photo-viewers disable photo ID viewers],
234       [if test "$enableval" = no ; then
235          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
236       fi],enableval=yes)
237   gnupg_cv_enable_photo_viewers=$enableval
238   AC_MSG_RESULT($enableval)
239
240   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
241     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
242     AC_ARG_WITH(photo-viewer,
243         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
244         [if test "$withval" = yes ; then
245            withval=no
246         elif test "$withval" != no ; then
247            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
248                             [if set, restrict photo-viewer to this])
249         fi],withval=no)
250     AC_MSG_RESULT($withval)
251   fi
252
253   AC_MSG_CHECKING([whether to enable external keyserver helpers])
254   AC_ARG_ENABLE(keyserver-helpers,
255       [  --disable-keyserver-helpers  disable all external keyserver support],
256       [if test "$enableval" = no ; then
257          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
258                   [define to disable keyserver helpers])
259       fi],enableval=yes)
260   gnupg_cv_enable_keyserver_helpers=$enableval
261   AC_MSG_RESULT($enableval)
262
263   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
264     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
265     AC_ARG_ENABLE(ldap,
266     [  --disable-ldap          disable LDAP keyserver interface],
267         try_ldap=$enableval, try_ldap=yes)
268     AC_MSG_RESULT($try_ldap)
269
270     AC_MSG_CHECKING([whether HKP keyserver support is requested])
271     AC_ARG_ENABLE(hkp,
272     [  --disable-hkp           disable HKP keyserver interface],
273         try_hkp=$enableval, try_hkp=yes)
274     AC_MSG_RESULT($try_hkp)
275
276     AC_MSG_CHECKING([whether email keyserver support is requested])
277     AC_ARG_ENABLE(mailto,
278     [  --disable-mailto        disable email keyserver interface],
279         try_mailto=$enableval, try_mailto=yes)
280     AC_MSG_RESULT($try_mailto)
281     fi
282
283     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
284     AC_ARG_ENABLE(keyserver-path,
285         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
286         [if test "$enableval" = no ; then
287          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
288         fi],enableval=yes)
289     AC_MSG_RESULT($enableval)
290   fi
291
292 AC_MSG_CHECKING([whether the included zlib is requested])
293 AC_ARG_WITH(included-zlib,
294     [  --with-included-zlib    use the zlib code included here],
295 [g10_force_zlib=yes], [g10_force_zlib=no] )
296 AC_MSG_RESULT($g10_force_zlib)
297
298 dnl
299 dnl Check whether we want to use Linux capabilities
300 dnl
301 AC_MSG_CHECKING([whether use of capabilities is requested])
302 AC_ARG_WITH(capabilities,
303     [  --with-capabilities     use linux capabilities [default=no]],
304 [use_capabilities="$withval"],[use_capabilities=no])
305 AC_MSG_RESULT($use_capabilities)
306
307
308 AH_BOTTOM([
309 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
310 #define EXEC_TEMPFILE_ONLY
311 #endif
312
313 /* This is the major version number of GnuPG so that
314    source included files can test for this. */
315 #define GNUPG_MAJOR_VERSION 1
316
317 #include "g10defs.h"
318 ])
319
320
321 AM_MAINTAINER_MODE
322
323 dnl Checks for programs.
324
325 AC_PROG_MAKE_SET
326 AM_SANITY_CHECK
327 missing_dir=`cd $ac_aux_dir && pwd`
328 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
329 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
330 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
331 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
332 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
333 AC_PROG_CC
334 AC_PROG_CPP
335 AC_PROG_RANLIB
336 AC_CHECK_TOOL(AR, ar, :)
337 AC_PATH_PROG(PERL,"perl")
338 AC_ISC_POSIX
339 AC_SYS_LARGEFILE
340 AC_PROG_INSTALL
341 AC_PROG_AWK
342 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
343 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
344 GNUPG_CHECK_FAQPROG
345 GNUPG_CHECK_DOCBOOK_TO_TEXI
346
347 MPI_OPT_FLAGS=""
348
349
350 try_gettext=yes
351 have_dosish_system=no
352 case "${target}" in
353     *-*-mingw32*)
354         # special stuff for Windoze NT
355         ac_cv_have_dev_random=no
356         AC_DEFINE(USE_ONLY_8DOT3,1,
357                   [set this to limit filenames to the 8.3 format])
358         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
359                   [defined if we must run on a stupid file system])
360         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
361                   [because the Unix gettext has too much overhead on
362                    MingW32 systems and these systems lack Posix functions,
363                    we use a simplified version of gettext])
364         have_dosish_system=yes
365         try_gettext="no"
366         ;;
367     i?86-emx-os2 | i?86-*-os2*emx )
368         # OS/2 with the EMX environment
369         ac_cv_have_dev_random=no
370         AC_DEFINE(HAVE_DRIVE_LETTERS)
371         have_dosish_system=yes
372         try_gettext="no"
373         ;;
374
375     i?86-*-msdosdjgpp*)
376         # DOS with the DJGPP environment
377         ac_cv_have_dev_random=no
378         AC_DEFINE(HAVE_DRIVE_LETTERS)
379         have_dosish_system=yes
380         try_gettext="no"
381         ;;
382
383     *-*-freebsd*)
384        # FreeBSD
385        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
386        LDFLAGS="$LDFLAGS -L/usr/local/lib"
387        ;;
388
389     *-*-hpux*)
390         if test -z "$GCC" ; then
391             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
392         fi
393         ;;
394     *-dec-osf4*)
395         if test -z "$GCC" ; then
396             # Suppress all warnings
397             # to get rid of the unsigned/signed char mismatch warnings.
398             CFLAGS="$CFLAGS -w"
399         fi
400         ;;
401     *-dec-osf5*)
402         if test -z "$GCC" ; then
403             # Use the newer compiler `-msg_disable ptrmismatch' to
404             # get rid of the unsigned/signed char mismatch warnings.
405             # Using this may hide other pointer mismatch warnings, but
406             # it at least lets other warning classes through
407             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
408         fi
409         ;;
410     m68k-atari-mint)
411         ;;
412     *)
413        ;;
414 esac
415
416 if test "$have_dosish_system" = yes; then
417    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
418              [defined if we run on some of the PCDOS like systems 
419               (DOS, Windoze. OS/2) with special properties like
420               no file modes])
421 fi
422 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
423
424 AC_SUBST(MPI_OPT_FLAGS)
425 GNUPG_SYS_SYMBOL_UNDERSCORE
426
427 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
428 if test "$try_hkp" = yes ; then
429   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
430 fi
431
432 dnl Must check for network library requirements before doing link tests
433 dnl for ldap, for example. If ldap libs are static (or dynamic and without
434 dnl ELF runtime link paths), then link will fail and LDAP support won't
435 dnl be detected.
436
437 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
438         [NETLIBS="-lnsl $NETLIBS"]))
439 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
440         [NETLIBS="-lsocket $NETLIBS"]))
441
442 dnl Now try for the resolver functions so we can use DNS SRV
443
444 AC_ARG_ENABLE(dns-srv,
445    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
446    use_dns_srv=$enableval,use_dns_srv=yes)
447
448 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
449   _srv_save_libs=$LIBS
450   LIBS=""
451   # the double underscore thing is a glibc-ism?
452   AC_SEARCH_LIBS(res_query,resolv bind,,
453                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
454   AC_SEARCH_LIBS(dn_expand,resolv bind,,
455                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
456   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
457                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
458
459   if test x"$use_dns_srv" = xyes ; then
460      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
461      SRVLIBS=$LIBS
462   else
463      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
464   fi
465   LIBS=$_srv_save_libs
466 fi
467
468 AC_SUBST(SRVLIBS)
469
470 # Try and link a LDAP test program to weed out unusable LDAP
471 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
472 # general is terrible with creating weird dependencies.  If all else
473 # fails, the user can play guess-the-dependency by using something
474 # like ./configure LDAPLIBS="-Lfoo -lbar"
475
476 if test "$try_ldap" = yes ; then
477   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
478     _ldap_save_libs=$LIBS
479     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
480
481     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
482     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
483                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
484     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
485
486     if test $gnupg_cv_func_ldap_init = no; then
487       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
488       AC_TRY_LINK([#include <lber.h>
489 #include <ldap.h>],[ldap_open("foobar",1234);],
490          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
491       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
492     fi
493
494     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
495        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
496     fi
497
498     if test "$gnupg_cv_func_ldap_init" = yes || \
499         test "$gnupg_cv_func_ldaplber_init" = yes ; then
500        LDAPLIBS=$MY_LDAPLIBS
501        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
502
503        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
504
505        if test "$gnupg_cv_func_ldap_init" = yes ; then
506           AC_TRY_LINK([#include <ldap.h>],
507              [ldap_get_option((void *)0,0,(void *)0);],
508              [gnupg_cv_func_ldap_get_option=yes],
509              [gnupg_cv_func_ldap_get_option=no])
510         else
511           AC_TRY_LINK([#include <lber.h>
512 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
513              [gnupg_cv_func_ldap_get_option=yes],
514              [gnupg_cv_func_ldap_get_option=no])
515        fi
516
517        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
518
519        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
520           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
521        else
522           AC_MSG_CHECKING([whether LDAP supports ld_errno])
523
524           if test "$gnupg_cv_func_ldap_init" = yes ; then
525             AC_TRY_COMPILE([#include <ldap.h>],
526                [LDAP *ldap; ldap->ld_errno;],
527                [gnupg_cv_func_ldap_ld_errno=yes],
528                [gnupg_cv_func_ldap_ld_errno=no])
529            else
530             AC_TRY_LINK([#include <lber.h>
531 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
532                [gnupg_cv_func_ldap_ld_errno=yes],
533                [gnupg_cv_func_ldap_ld_errno=no])
534           fi
535
536           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
537
538           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
539              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
540           fi
541        fi
542     fi
543
544     LIBS=$_ldap_save_libs
545
546     if test "$GPGKEYS_LDAP" != "" ; then break; fi
547   done
548 fi
549
550 AC_SUBST(GPGKEYS_LDAP)
551 AC_SUBST(LDAPLIBS)
552
553 dnl This isn't necessarily sendmail itself, but anything that gives a
554 dnl sendmail-ish interface to the outside world.  That includes qmail,
555 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
556
557 if test "$try_mailto" = yes ; then
558   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
559
560   if test "$with_mailprog" = yes ; then
561     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
562     if test "$ac_cv_path_SENDMAIL" ; then
563       GPGKEYS_MAILTO="gpgkeys_mailto"
564     fi
565   elif test "$with_mailprog" != no ; then
566     AC_MSG_CHECKING([for a mail transport program])
567     AC_SUBST(SENDMAIL,$with_mailprog)
568     AC_MSG_RESULT($with_mailprog)
569     GPGKEYS_MAILTO="gpgkeys_mailto"
570   fi
571 fi
572
573 AC_SUBST(GPGKEYS_MAILTO)
574
575 case "${target}" in
576     *-*-mingw32*)
577         PRINTABLE_OS_NAME="MingW32"
578         ;;
579     *-*-cygwin*)
580         PRINTABLE_OS_NAME="Cygwin"
581         ;;
582     i?86-emx-os2 | i?86-*-os2*emx )
583         PRINTABLE_OS_NAME="OS/2"
584         ;;
585     i?86-*-msdosdjgpp*)
586         PRINTABLE_OS_NAME="MSDOS/DJGPP"
587         try_dynload=no
588         ;;
589     *-linux*)
590         PRINTABLE_OS_NAME="GNU/Linux"
591         ;;
592 dnl let that after linux to avoid gnu-linux problems
593     *-gnu*)
594         PRINTABLE_OS_NAME="GNU/Hurd"
595         ;;
596     *)
597         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
598         ;;
599 esac
600 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
601                    [A human readable text with the name of the OS])
602
603
604 #
605 # 1. Set names of random devices
606 #
607 NAME_OF_DEV_RANDOM="/dev/random"
608 NAME_OF_DEV_URANDOM="/dev/urandom"
609 case "${target}" in
610     *-openbsd*)
611         NAME_OF_DEV_RANDOM="/dev/srandom"
612         NAME_OF_DEV_URANDOM="/dev/urandom"
613         ;;
614 esac
615 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
616                    [defined to the name of the strong random device])
617 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
618                    [defined to the name of the weaker random device])
619 AC_SUBST(MPI_OPT_FLAGS)
620
621
622 dnl Checks for libraries.
623
624 if test "$try_gettext" = yes; then
625   AM_GNU_GETTEXT(,[need-ngettext])
626
627   # gettext requires some extra checks.  These really should be part of
628   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
629   # function checks to here.
630
631   AC_CHECK_FUNCS(strchr)
632 else
633   USE_NLS=no
634   USE_INCLUDED_LIBINTL=no
635   BUILD_INCLUDED_LIBINTL=no
636   AC_SUBST(USE_NLS)
637   AC_SUBST(USE_INCLUDED_LIBINTL)
638   AC_SUBST(BUILD_INCLUDED_LIBINTL)
639 fi
640
641 if test "$try_dynload" = yes ; then
642   AC_CHECK_FUNC(dlopen,,AC_CHECK_LIB(dl,dlopen,found_dlopen=yes))
643   if test x"$found_dlopen" = "xyes" ; then
644     AC_DEFINE(USE_DYNAMIC_LINKING,1,[define to enable the use of extensions])
645     AC_DEFINE(HAVE_DL_DLOPEN,1,
646               [Defined when the dlopen function family is available])
647     AC_SUBST(DLLIBS,"-ldl")
648   fi
649 else
650   AC_MSG_CHECKING(for dynamic loading)
651   AC_MSG_RESULT(has been disabled)
652 fi
653
654
655 dnl Checks for header files.
656 AC_HEADER_STDC
657 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
658
659 dnl Checks for typedefs, structures, and compiler characteristics.
660 AC_C_CONST
661 AC_C_INLINE
662 AC_C_VOLATILE
663 AC_TYPE_SIZE_T
664 AC_TYPE_MODE_T
665 AC_TYPE_SIGNAL
666 AC_DECL_SYS_SIGLIST
667
668 GNUPG_CHECK_ENDIAN
669
670 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
671 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
672 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
673 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
674 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
675
676 AC_CHECK_SIZEOF(unsigned short)
677 AC_CHECK_SIZEOF(unsigned int)
678 AC_CHECK_SIZEOF(unsigned long)
679 AC_CHECK_SIZEOF(unsigned long long)
680
681 # Ensure that we have UINT64_C before we bother to check for uint64_t
682 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
683    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
684 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
685
686 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
687    AC_CHECK_SIZEOF(uint64_t)
688 fi
689
690 if test "$ac_cv_sizeof_unsigned_short" = "0" \
691    || test "$ac_cv_sizeof_unsigned_int" = "0" \
692    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
693     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
694 fi
695
696 dnl Do we have any 64-bit data types?
697 if test "$ac_cv_sizeof_unsigned_int" != "8" \
698    && test "$ac_cv_sizeof_unsigned_long" != "8" \
699    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
700    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
701     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
702 else
703   if test x"$use_sha512" = xyes ; then
704      AC_SUBST(SHA512_O,sha512.o)
705      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
706   fi
707 fi
708
709 dnl Checks for library functions.
710 AC_FUNC_FSEEKO
711 AC_FUNC_VPRINTF
712 AC_FUNC_FORK
713 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
714 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
715 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
716 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
717 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
718 AC_REPLACE_FUNCS(mkdtemp)
719 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
720
721 # See if getopt is in libiberty.  This is of course not optimal since
722 # it might be somewhere other than libiberty, but does cover the
723 # mingw32 case.
724
725 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
726
727 #
728 # check for gethrtime and run a testprogram to see whether
729 # it is broken.  It has been reported that some Solaris and HP UX systems 
730 # raise an SIGILL
731 #
732 AC_CACHE_CHECK([for gethrtime], 
733                [gnupg_cv_func_gethrtime],
734                [AC_TRY_LINK([#include <sys/times.h>],[
735                    hrtime_t tv;
736                    tv = gethrtime();
737                  ],
738                  [gnupg_cv_func_gethrtime=yes],
739                  [gnupg_cv_func_gethrtime=no])
740                ])
741 if test $gnupg_cv_func_gethrtime = yes; then
742      AC_DEFINE([HAVE_GETHRTIME], 1,
743                [Define if you have the `gethrtime(2)' function.])
744      AC_CACHE_CHECK([whether gethrtime is broken], 
745                [gnupg_cv_func_broken_gethrtime],
746                [AC_TRY_RUN([
747                    #include <sys/times.h>
748                    int main () {
749                    hrtime_t tv;
750                    tv = gethrtime(); 
751                  }
752                  ],
753                  [gnupg_cv_func_broken_gethrtime=no],
754                  [gnupg_cv_func_broken_gethrtime=yes],
755                  [gnupg_cv_func_broken_gethrtime=assume-no])
756                 ])
757     if test $gnupg_cv_func_broken_gethrtime = yes; then
758       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
759       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
760     fi
761 fi
762      
763
764 GNUPG_CHECK_MLOCK
765 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
766
767 dnl
768 dnl Check whether we can use Linux capabilities as requested
769 dnl
770 if test "$use_capabilities" = "yes" ; then
771 use_capabilities=no
772 AC_CHECK_HEADERS(sys/capability.h)
773 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
774   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
775   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
776      AC_DEFINE(USE_CAPABILITIES,1,
777                [define if capabilities should be used])
778      AC_SUBST(CAPLIBS,"-lcap")
779      use_capabilities=yes
780   fi
781 fi
782 if test "$use_capabilities" = "no" ; then
783     AC_MSG_WARN([[
784 ***
785 *** The use of capabilities on this system is not possible.
786 *** You need a recent Linux kernel and some patches:
787 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
788 ***   fcap-module-990613.tar.gz     (kernel module)
789 ***   libcap-1.92.tar.gz            (user mode library and utilities)
790 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
791 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
792 ***]])
793 fi
794 fi
795
796
797 GNUPG_CHECK_IPC
798 if test "$ac_cv_header_sys_shm_h" = "yes"; then
799   AC_DEFINE(USE_SHM_COPROCESSING,1,
800             [define if the shared memory interface should be made available])
801 fi
802
803 dnl
804 dnl check whether we have a random device
805 dnl
806 if test "$try_dev_random" = yes ; then
807     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
808     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
809       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
810     if test "$ac_cv_have_dev_random" = yes; then
811         AC_DEFINE(HAVE_DEV_RANDOM,1,
812                  [defined if the system supports a random device] )
813     fi
814 else
815     AC_MSG_CHECKING(for random device)
816     ac_cv_have_dev_random=no
817     AC_MSG_RESULT(has been disabled)
818 fi
819
820
821 dnl
822 dnl Figure out the default random module.
823 dnl
824 random_modules=""
825 if test "$use_static_rnd" = default; then
826      if test "$ac_cv_have_dev_random" = yes; then
827         random_modules="rndlinux"
828      else
829          case "${target}" in
830             *-*-mingw32*|*-*-cygwin*)
831                 random_modules="rndw32"
832                 ;;
833             i?86-emx-os2|i?86-*-os2*emx)
834                 random_modules="rndos2"
835                 ;;
836             m68k-atari-mint)
837                 random_modules="rndatari"
838                 ;;
839             i?86-*-msdosdjgpp*)
840                 :
841                 ;;
842             *)
843                 random_modules="rndlinux rndegd rndunix"
844                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
845                           [Allow to select random modules at runtime.])
846                 ;;
847          esac
848      fi
849 else
850   if test "$use_static_rnd" = auto; then
851      random_modules="rndlinux rndegd rndunix"
852      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
853   else
854      random_modules="rnd$use_static_rnd";
855   fi
856 fi
857
858 if test -z "$random_modules"; then
859    AC_MSG_ERROR(no random module available)
860 fi
861 print_egd_warning=no
862 for rndmod in $random_modules "" ; do
863   case "$rndmod" in
864     rndlinux)
865          AC_DEFINE(USE_RNDLINUX,1, 
866                   [Defined if the /dev/random based RNG should be used.])
867          ;;
868     rndunix)
869          AC_DEFINE(USE_RNDUNIX,1, 
870                   [Defined if the default Unix RNG should be used.])
871          print_egd_warning=yes
872           ;;
873     rndegd)
874          AC_DEFINE(USE_RNDEGD,1, 
875                   [Defined if the EGD based RNG should be used.])
876          ;;
877     rndw32)
878          AC_DEFINE(USE_RNDW32,1, 
879                   [Defined if the Windows specific RNG should be used.])
880         ;;
881    esac
882 done
883
884 dnl setup assembler stuff
885 AC_MSG_CHECKING(for mpi assembler functions)
886 if test -f $srcdir/mpi/config.links ; then
887     . $srcdir/mpi/config.links
888     AC_CONFIG_LINKS("$mpi_ln_list")
889     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
890     ac_cv_mpi_sflags="$mpi_sflags"
891     ac_cv_mpi_config_done="yes"
892     AC_MSG_RESULT(done)
893 else
894     AC_MSG_RESULT(failed)
895     AC_MSG_ERROR([mpi/config.links missing!])
896 fi
897 MPI_EXTRA_ASM_OBJS=""
898 show_extraasm=""
899 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
900 for i in $ac_cv_mpi_extra_asm_modules; do
901     show_extraasm="$show_extraasm $i"
902     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
903 done
904 fi
905 AC_SUBST(MPI_EXTRA_ASM_OBJS)
906 MPI_SFLAGS="$ac_cv_mpi_sflags"
907 AC_SUBST(MPI_SFLAGS)
908
909 # Sanity check regex.  Tests adapted from mutt.
910
911 AC_MSG_CHECKING([whether regular expression support is requested])
912 AC_ARG_ENABLE(regex,
913 [  --disable-regex         do not handle regular expressions in trust sigs],
914      use_regex=$enableval, use_regex=yes)
915 AC_MSG_RESULT($use_regex)
916
917 if test "$use_regex" = yes ; then
918   AC_MSG_CHECKING([whether the included regex lib is requested])
919   AC_ARG_WITH(included-regex,
920       [  --with-included-regex   use the included GNU regex library],
921       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
922   AC_MSG_RESULT($gnupg_cv_included_regex)
923
924   if test $gnupg_cv_included_regex = no ; then
925      # Does the system have regex functions at all?
926      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
927                            gnupg_cv_included_regex=yes)
928   fi
929
930   if test $gnupg_cv_included_regex = no ; then
931      AC_CACHE_CHECK([whether your system's regexp library is broken],
932        [gnupg_cv_regex_broken],
933        AC_TRY_RUN([
934 #include <unistd.h>
935 #include <regex.h>
936 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
937        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
938
939      if test $gnupg_cv_regex_broken = yes ; then
940       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
941       gnupg_cv_included_regex=yes
942      fi
943   fi
944
945   if test $gnupg_cv_included_regex = yes; then
946      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
947      AC_SUBST(REGEX_O,regex.o)
948   fi
949 else
950
951   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
952 fi
953
954 dnl Do we have zlib? Must do it here because Solaris failed
955 dnl when compiling a conftest (due to the "-lz" from LIBS).
956 use_local_zlib=yes
957 if test "$g10_force_zlib" = "yes"; then
958   :
959 else
960   _cppflags="${CPPFLAGS}"
961   _ldflags="${LDFLAGS}"
962
963   AC_ARG_WITH(zlib,
964   [  --with-zlib=DIR         use libz in DIR],[
965     if test -d "$withval"; then
966       CPPFLAGS="${CPPFLAGS} -I$withval/include"
967       LDFLAGS="${LDFLAGS} -L$withval/lib"
968     fi
969   ])
970
971   AC_CHECK_HEADER(zlib.h,
972       AC_CHECK_LIB(z, deflateInit2_,
973        use_local_zlib=no
974        ZLIBS="-lz",
975        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
976        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
977 fi
978
979 if test "$use_local_zlib" = yes ; then
980     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
981     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
982     ZLIBS="../zlib/libzlib.a"
983 else
984     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
985 fi
986 AC_SUBST(ZLIBS)
987
988
989 #
990 # libusb allows us to use the integrated CCID smartcard reader driver.
991 #
992 # Note, that we need the CVS (unstable) version. 
993 #
994 LIBUSB_LIBS=""
995 if test "$card_support" = yes; then
996     AC_CHECK_LIB(usb, usb_find_device,
997                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
998                    AC_DEFINE(HAVE_LIBUSB,1,
999                    [defined if libusb is available])
1000                  ])
1001 fi
1002 AC_SUBST(LIBUSB_LIBS)
1003
1004
1005
1006 # Allow users to append something to the version string without
1007 # flagging it as development version.  The user version parts is
1008 # considered everything after a dash. 
1009 if test "$development_version" != yes; then
1010   changequote(,)dnl
1011   tmp_pat='[a-zA-Z]'
1012   changequote([,])dnl
1013   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1014     development_version=yes
1015   fi
1016 fi
1017 if test "$development_version" = yes; then
1018     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1019             [Defined if this is not a regular release])
1020 fi
1021
1022 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1023
1024 GNUPG_CHECK_GNUMAKE
1025
1026 # add some extra libs here so that previous tests don't fail for
1027 # mysterious reasons - the final link step should bail out. 
1028 case "${target}" in
1029     *-*-mingw32*)
1030 dnl      NETLIBS="$NETLIBS -lwsock32"
1031         W32LIBS="-lwsock32"
1032         ;;
1033     *)
1034        ;;
1035 esac
1036
1037 AC_SUBST(NETLIBS)
1038 AC_SUBST(W32LIBS)
1039
1040 if test "$GCC" = yes; then
1041     if test "$USE_MAINTAINER_MODE" = "yes"; then
1042         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1043     else
1044         CFLAGS="$CFLAGS -Wall"
1045     fi
1046 fi
1047
1048
1049 if test "$print_egd_warning" = yes; then
1050   AC_MSG_WARN([[
1051 ***
1052 *** The performance of the UNIX random gatherer module is not very good
1053 *** and it does not keep the entropy pool over multiple invocations of
1054 *** GnuPG.  The suggested way to overcome this problem is to use the
1055 ***
1056 ***               Entropy Gathering Daemon (EGD)
1057 ***
1058 *** which provides a entropy source for the whole system.  It is written
1059 *** in Perl and available at the GnuPG FTP servers.  For more information
1060 *** consult the GnuPG webpages:
1061 ***
1062 ***           http://www.gnupg.org/download/#EGD
1063 ***
1064 *** You may want to run ./configure with --enable-static-rnd=egd or
1065 *** --enable-static-rnd=auto to use it.
1066 ***]])
1067 fi
1068
1069 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1070
1071 AC_CONFIG_COMMANDS(g10defs.h,[[
1072 cat >g10defs.tmp <<G10EOF
1073 /* Generated automatically by configure */
1074 #ifdef HAVE_DRIVE_LETTERS
1075 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1076 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1077 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1078 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1079 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1080 #else
1081 #define G10_LOCALEDIR     "${datadir}/locale"
1082 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1083 #define GNUPG_DATADIR     "${datadir}/gnupg"
1084 #ifdef __VMS
1085 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1086 #else
1087 #define GNUPG_HOMEDIR "~/.gnupg" 
1088 #endif
1089 #endif
1090 /* those are here to be redefined by handcrafted g10defs.h.
1091    Please note that the string version must not contain more
1092    than one character because the using code assumes strlen()==1 */
1093 #ifdef HAVE_DOSISH_SYSTEM
1094 #define DIRSEP_C '\\\\'
1095 #define EXTSEP_C '.'
1096 #define DIRSEP_S "\\\\"
1097 #define EXTSEP_S "."
1098 #else
1099 #define DIRSEP_C '/'
1100 #define EXTSEP_C '.'
1101 #define DIRSEP_S "/"
1102 #define EXTSEP_S "."
1103 #endif
1104 /* This is the same as VERSION, but should be overridden if the
1105    platform cannot handle things like dots '.' in filenames. */
1106 #define SAFE_VERSION VERSION
1107 G10EOF
1108 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1109 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1110     echo "g10defs.h is unchanged"
1111     rm -f g10defs.tmp
1112 else
1113     rm -f g10defs.h
1114     mv g10defs.tmp g10defs.h
1115     echo "g10defs.h created"
1116 fi
1117 ]],[[
1118 prefix=$prefix
1119 exec_prefix=$exec_prefix
1120 libdir=$libdir
1121 libexecdir=$libexecdir
1122 datadir=$datadir
1123 DATADIRNAME=$DATADIRNAME
1124 ]])
1125
1126
1127 AC_CONFIG_FILES([
1128 Makefile
1129 intl/Makefile
1130 po/Makefile.in
1131 util/Makefile
1132 mpi/Makefile
1133 cipher/Makefile
1134 g10/Makefile
1135 keyserver/Makefile
1136 keyserver/gpgkeys_mailto
1137 keyserver/gpgkeys_test
1138 doc/Makefile
1139 tools/Makefile
1140 zlib/Makefile
1141 checks/Makefile
1142 ])
1143 AC_OUTPUT
1144
1145 # Give some feedback
1146 echo
1147 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1148 if test -n "$show_extraasm"; then
1149   echo "  Extra cpu specific functions:$show_extraasm"
1150 fi
1151 echo