1c467bffffe618200def31383b88b60283d2a4ef
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [17])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 use_libdns=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(tools, yes)
130 GNUPG_BUILD_PROGRAM(doc, yes)
131 GNUPG_BUILD_PROGRAM(symcryptrun, no)
132 # We use gpgtar to unpack test data, hence we always build it.  If the
133 # user opts out, we simply don't install it.
134 GNUPG_BUILD_PROGRAM(gpgtar, yes)
135 GNUPG_BUILD_PROGRAM(wks-tools, no)
136
137 AC_SUBST(PACKAGE)
138 AC_SUBST(PACKAGE_GT)
139 AC_SUBST(VERSION)
140 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
142                                 [Name of this package for gettext])
143 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
144 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
145                                         [Bug report address])
146 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
147                                        [Required version of Libgcrypt])
148 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
149                                        [Required version of Libksba])
150 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
151                                        [Required version of NTBTLS])
152
153
154
155 # The default is to use the modules from this package and the few
156 # other packages in a standard place; i.e where this package gets
157 # installed.  With these options it is possible to override these
158 # ${prefix} depended values with fixed paths, which can't be replaced
159 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
160 AC_ARG_WITH(agent-pgm,
161     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
162           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
163 AC_SUBST(GNUPG_AGENT_PGM)
164 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
165 show_gnupg_agent_pgm="(default)"
166 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
167
168 AC_ARG_WITH(pinentry-pgm,
169     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
170           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
171 AC_SUBST(GNUPG_PINENTRY_PGM)
172 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
173 show_gnupg_pinentry_pgm="(default)"
174 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
175
176
177 AC_ARG_WITH(scdaemon-pgm,
178     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
179           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
180 AC_SUBST(GNUPG_SCDAEMON_PGM)
181 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
182 show_gnupg_scdaemon_pgm="(default)"
183 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
184
185
186 AC_ARG_WITH(dirmngr-pgm,
187     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
188           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
189 AC_SUBST(GNUPG_DIRMNGR_PGM)
190 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
191 show_gnupg_dirmngr_pgm="(default)"
192 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
193
194 AC_ARG_WITH(protect-tool-pgm,
195     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
196           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
197 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
198 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
199 show_gnupg_protect_tool_pgm="(default)"
200 test -n "$GNUPG_PROTECT_TOOL_PGM" \
201       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
202
203 AC_ARG_WITH(dirmngr-ldap-pgm,
204     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
205           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
206 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
207 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
208 show_gnupg_dirmngr_ldap_pgm="(default)"
209 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
210       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
211
212 #
213 # On some platforms gpg2 is usually installed as gpg without using a
214 # symlink.  For correct operation of gpgconf it needs to know the
215 # installed name of gpg.  This option sets "gpg2"'s installed name to
216 # just "gpg".  Note that it might be required to rename gpg2 to gpg
217 # manually after the build process.
218 #
219 AC_ARG_ENABLE(gpg2-is-gpg,
220     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
221     gpg2_is_gpg=$enableval)
222 if test "$gpg2_is_gpg" != "yes"; then
223    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
224 fi
225 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
226
227
228 # SELinux support includes tracking of sensitive files to avoid
229 # leaking their contents through processing these files by gpg itself
230 AC_MSG_CHECKING([whether SELinux support is requested])
231 AC_ARG_ENABLE(selinux-support,
232               AC_HELP_STRING([--enable-selinux-support],
233                              [enable SELinux support]),
234               selinux_support=$enableval, selinux_support=no)
235 AC_MSG_RESULT($selinux_support)
236
237
238 AC_MSG_CHECKING([whether to allocate extra secure memory])
239 AC_ARG_ENABLE(large-secmem,
240               AC_HELP_STRING([--enable-large-secmem],
241                              [allocate extra secure memory]),
242               large_secmem=$enableval, large_secmem=no)
243 AC_MSG_RESULT($large_secmem)
244 if test "$large_secmem" = yes ; then
245    SECMEM_BUFFER_SIZE=65536
246 else
247    SECMEM_BUFFER_SIZE=32768
248 fi
249 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
250                    [Size of secure memory buffer])
251
252 AC_MSG_CHECKING([whether to enable trust models])
253 AC_ARG_ENABLE(trust-models,
254               AC_HELP_STRING([--disable-trust-models],
255                              [disable all trust models except "always"]),
256               use_trust_models=$enableval)
257 AC_MSG_RESULT($use_trust_models)
258 if test "$use_trust_models" = no ; then
259     AC_DEFINE(NO_TRUST_MODELS, 1,
260              [Define to include only trust-model always])
261 fi
262
263 AC_MSG_CHECKING([whether to enable TOFU])
264 AC_ARG_ENABLE(tofu,
265                 AC_HELP_STRING([--disable-tofu],
266                                [disable the TOFU trust model]),
267               use_tofu=$enableval, use_tofu=$use_trust_models)
268 AC_MSG_RESULT($use_tofu)
269 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
270     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
271 fi
272
273 AC_MSG_CHECKING([whether to enable libdns])
274 AC_ARG_ENABLE(libdns,
275                 AC_HELP_STRING([--disable-libdns],
276                                [do not build with libdns support]),
277               use_libdns=$enableval, use_libdns=yes)
278 AC_MSG_RESULT($use_libdns)
279 if test x"$use_libdns" = xyes ; then
280     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
281 fi
282 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
283
284
285 #
286 # Options to disable algorithm
287 #
288
289 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
290 # Elgamal is a MUST algorithm
291 # DSA is a MUST algorithm
292 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
293 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
294 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
295
296 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
297 # 3DES is a MUST algorithm
298 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
299 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
300 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
301 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
302 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
303 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
307
308 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
309 # SHA1 is a MUST algorithm
310 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
311 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
312 # SHA256 is a MUST algorithm for GnuPG.
313 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
314 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
315
316
317 # Allow disabling of zip support.
318 # This is in general not a good idea because according to rfc4880 OpenPGP
319 # implementations SHOULD support ZLIB.
320 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
321 AC_ARG_ENABLE(zip,
322    AC_HELP_STRING([--disable-zip],
323                   [disable the ZIP and ZLIB compression algorithm]),
324    use_zip=$enableval)
325 AC_MSG_RESULT($use_zip)
326
327 # Allow disabling of bzib2 support.
328 # It is defined only after we confirm the library is available later
329 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
330 AC_ARG_ENABLE(bzip2,
331    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
332    use_bzip2=$enableval)
333 AC_MSG_RESULT($use_bzip2)
334
335 # Configure option to allow or disallow execution of external
336 # programs, like a photo viewer.
337 AC_MSG_CHECKING([whether to enable external program execution])
338 AC_ARG_ENABLE(exec,
339     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
340     use_exec=$enableval)
341 AC_MSG_RESULT($use_exec)
342 if test "$use_exec" = no ; then
343     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
344 fi
345
346 if test "$use_exec" = yes ; then
347   AC_MSG_CHECKING([whether to enable photo ID viewing])
348   AC_ARG_ENABLE(photo-viewers,
349       [  --disable-photo-viewers disable photo ID viewers],
350       [if test "$enableval" = no ; then
351          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
352       fi],enableval=yes)
353   gnupg_cv_enable_photo_viewers=$enableval
354   AC_MSG_RESULT($enableval)
355
356   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
357     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
358     AC_ARG_WITH(photo-viewer,
359         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
360         [if test "$withval" = yes ; then
361            withval=no
362         elif test "$withval" != no ; then
363            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
364                             [if set, restrict photo-viewer to this])
365         fi],withval=no)
366     AC_MSG_RESULT($withval)
367   fi
368 fi
369
370
371 #
372 # Check for the key/uid cache size.  This can't be zero, but can be
373 # pretty small on embedded systems.  This is used for the gpg part.
374 #
375 AC_MSG_CHECKING([for the size of the key and uid cache])
376 AC_ARG_ENABLE(key-cache,
377         AC_HELP_STRING([--enable-key-cache=SIZE],
378                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
379 if test "$enableval" = "no"; then
380    enableval=5
381 elif test "$enableval" = "yes" || test "$enableval" = ""; then
382    enableval=4096
383 fi
384 changequote(,)dnl
385 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
386 changequote([,])dnl
387 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
388    AC_MSG_ERROR([invalid key-cache size])
389 fi
390 AC_MSG_RESULT($key_cache_size)
391 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
392                   [Size of the key and UID caches])
393
394
395
396 #
397 # Check whether we want to use Linux capabilities
398 #
399 AC_MSG_CHECKING([whether use of capabilities is requested])
400 AC_ARG_WITH(capabilities,
401     [  --with-capabilities     use linux capabilities [default=no]],
402 [use_capabilities="$withval"],[use_capabilities=no])
403 AC_MSG_RESULT($use_capabilities)
404
405 #
406 # Check whether to disable the card support
407 AC_MSG_CHECKING([whether smartcard support is requested])
408 AC_ARG_ENABLE(card-support,
409               AC_HELP_STRING([--disable-card-support],
410                              [disable smartcard support]),
411               card_support=$enableval)
412 AC_MSG_RESULT($card_support)
413 if test "$card_support" = yes ; then
414   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
415 else
416   build_scdaemon=no
417 fi
418
419 #
420 # Allow disabling of internal CCID support.
421 # It is defined only after we confirm the library is available later
422 #
423 AC_MSG_CHECKING([whether to enable the internal CCID driver])
424 AC_ARG_ENABLE(ccid-driver,
425               AC_HELP_STRING([--disable-ccid-driver],
426                              [disable the internal CCID driver]),
427               use_ccid_driver=$enableval)
428 AC_MSG_RESULT($use_ccid_driver)
429
430 AC_MSG_CHECKING([whether to auto start dirmngr])
431 AC_ARG_ENABLE(dirmngr-auto-start,
432               AC_HELP_STRING([--disable-dirmngr-auto-start],
433                              [disable auto starting of the dirmngr]),
434               dirmngr_auto_start=$enableval)
435 AC_MSG_RESULT($dirmngr_auto_start)
436 if test "$dirmngr_auto_start" = yes ; then
437     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
438               [Define to enable auto starting of the dirmngr])
439 fi
440
441
442 #
443 # To avoid double inclusion of config.h which might happen at some
444 # places, we add the usual double inclusion protection at the top of
445 # config.h.
446 #
447 AH_TOP([
448 #ifndef GNUPG_CONFIG_H_INCLUDED
449 #define GNUPG_CONFIG_H_INCLUDED
450 ])
451
452 #
453 # Stuff which goes at the bottom of config.h.
454 #
455 AH_BOTTOM([
456 /* This is the major version number of GnuPG so that
457    source included files can test for this.  Note, that
458    we use 2 here even for GnuPG 1.9.x. */
459 #define GNUPG_MAJOR_VERSION 2
460
461 /* Now to separate file name parts.
462    Please note that the string version must not contain more
463    than one character because the code assumes strlen()==1 */
464 #ifdef HAVE_DOSISH_SYSTEM
465 #define DIRSEP_C '\\'
466 #define DIRSEP_S "\\"
467 #define EXTSEP_C '.'
468 #define EXTSEP_S "."
469 #define PATHSEP_C ';'
470 #define PATHSEP_S ";"
471 #define EXEEXT_S ".exe"
472 #else
473 #define DIRSEP_C '/'
474 #define DIRSEP_S "/"
475 #define EXTSEP_C '.'
476 #define EXTSEP_S "."
477 #define PATHSEP_C ':'
478 #define PATHSEP_S ":"
479 #define EXEEXT_S ""
480 #endif
481
482 /* This is the same as VERSION, but should be overridden if the
483    platform cannot handle things like dots '.' in filenames. Set
484    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
485    uses for dots and dashes. */
486 #define SAFE_VERSION VERSION
487 #define SAFE_VERSION_DOT  '.'
488 #define SAFE_VERSION_DASH '-'
489
490 /* Some global constants. */
491 #ifdef HAVE_DOSISH_SYSTEM
492 # ifdef HAVE_DRIVE_LETTERS
493 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
494 # else
495 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
496 # endif
497 #elif defined(__VMS)
498 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
499 #else
500 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
501 #endif
502 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
503 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
504
505 /* For some systems (DOS currently), we hardcode the path here.  For
506    POSIX systems the values are constructed by the Makefiles, so that
507    the values may be overridden by the make invocations; this is to
508    comply with the GNU coding standards.  Note that these values are
509    only defaults.  */
510 #ifdef HAVE_DOSISH_SYSTEM
511 # ifdef HAVE_DRIVE_LETTERS
512 #  define GNUPG_BINDIR      "c:\\gnupg"
513 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
514 #  define GNUPG_LIBDIR      "c:\\gnupg"
515 #  define GNUPG_DATADIR     "c:\\gnupg"
516 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
517 # else
518 #  define GNUPG_BINDIR      "\\gnupg"
519 #  define GNUPG_LIBEXECDIR  "\\gnupg"
520 #  define GNUPG_LIBDIR      "\\gnupg"
521 #  define GNUPG_DATADIR     "\\gnupg"
522 #  define GNUPG_SYSCONFDIR  "\\gnupg"
523 # endif
524 #endif
525
526 /* Derive some other constants. */
527 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
528 #define EXEC_TEMPFILE_ONLY
529 #endif
530
531
532 /* We didn't define endianness above, so get it from OS macros.  This
533    is intended for making fat binary builds on OS X. */
534 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
535 #if defined(__BIG_ENDIAN__)
536 #define BIG_ENDIAN_HOST 1
537 #elif defined(__LITTLE_ENDIAN__)
538 #define LITTLE_ENDIAN_HOST 1
539 #else
540 #error "No endianness found"
541 #endif
542 #endif
543
544
545 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
546    ldap_start_tls_s because that is the actual symbol used in the
547    library.  winldap.h redefines it to our commonly used value,
548    thus we define our usual macro here.  */
549 #ifdef HAVE_LDAP_START_TLS_SA
550 # ifndef HAVE_LDAP_START_TLS_S
551 #  define HAVE_LDAP_START_TLS_S 1
552 # endif
553 #endif
554
555 /* Provide the es_ macro for estream.  */
556 #define GPGRT_ENABLE_ES_MACROS 1
557
558 /* Tell libgcrypt not to use its own libgpg-error implementation. */
559 #define USE_LIBGPG_ERROR 1
560
561 /* Tell Libgcrypt not to include deprecated definitions.  */
562 #define GCRYPT_NO_DEPRECATED 1
563
564 /* Our HTTP code is used in estream mode.  */
565 #define HTTP_USE_ESTREAM 1
566
567 /* Under W32 we do an explicit socket initialization, thus we need to
568    avoid the on-demand initialization which would also install an atexit
569    handler.  */
570 #define HTTP_NO_WSASTARTUP
571
572 /* Under Windows we use the gettext code from libgpg-error.  */
573 #define GPG_ERR_ENABLE_GETTEXT_MACROS
574
575 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
576 #define GPG_ERR_ENABLE_ERRNO_MACROS
577
578 #endif /*GNUPG_CONFIG_H_INCLUDED*/
579 ])
580
581
582 AM_MAINTAINER_MODE
583 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
584
585 # Checks for programs.
586 AC_MSG_NOTICE([checking for programs])
587 AC_PROG_MAKE_SET
588 AM_SANITY_CHECK
589 missing_dir=`cd $ac_aux_dir && pwd`
590 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
591 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
592 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
593 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
594 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
595 AM_SILENT_RULES
596 AC_PROG_AWK
597 AC_PROG_CC
598 AC_PROG_CPP
599 AM_PROG_CC_C_O
600 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
601   AC_MSG_ERROR([[No C-89 compiler found]])
602 fi
603 AC_PROG_INSTALL
604 AC_PROG_LN_S
605 AC_PROG_RANLIB
606 AC_CHECK_TOOL(AR, ar, :)
607 AC_PATH_PROG(PERL,"perl")
608 AC_CHECK_TOOL(WINDRES, windres, :)
609 AC_ISC_POSIX
610 AC_SYS_LARGEFILE
611 GNUPG_CHECK_USTAR
612
613
614 # We need to compile and run a program on the build machine.  A
615 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
616 # the AC archive is broken for autoconf 2.57.  Given that there is no
617 # newer version of that macro, we assume that it is also broken for
618 # autoconf 2.61 and thus we use a simple but usually sufficient
619 # approach.
620 AC_MSG_CHECKING(for cc for build)
621 if test "$cross_compiling" = "yes"; then
622   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
623 else
624   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
625 fi
626 AC_MSG_RESULT($CC_FOR_BUILD)
627 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
628
629 # We need to call this macro because other pkg-config macros are
630 # not always used.
631 PKG_PROG_PKG_CONFIG
632
633
634 try_gettext=yes
635 require_iconv=yes
636 have_dosish_system=no
637 have_w32_system=no
638 have_w32ce_system=no
639 have_android_system=no
640 use_simple_gettext=no
641 use_ldapwrapper=yes
642 mmap_needed=yes
643 case "${host}" in
644     *-mingw32*)
645         # special stuff for Windoze NT
646         ac_cv_have_dev_random=no
647         AC_DEFINE(USE_ONLY_8DOT3,1,
648                   [Set this to limit filenames to the 8.3 format])
649         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
650                   [Because the Unix gettext has too much overhead on
651                    MingW32 systems and these systems lack Posix functions,
652                    we use a simplified version of gettext])
653         have_dosish_system=yes
654         have_w32_system=yes
655         require_iconv=no
656         use_ldapwrapper=no  # Fixme: Do this only for CE.
657         case "${host}" in
658           *-mingw32ce*)
659             have_w32ce_system=yes
660             ;;
661           *)
662             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
663                       [Defined if the OS supports drive letters.])
664             ;;
665         esac
666         try_gettext="no"
667         use_simple_gettext=yes
668         mmap_needed=no
669         ;;
670     i?86-emx-os2 | i?86-*-os2*emx )
671         # OS/2 with the EMX environment
672         ac_cv_have_dev_random=no
673         AC_DEFINE(HAVE_DRIVE_LETTERS)
674         have_dosish_system=yes
675         try_gettext="no"
676         ;;
677
678     i?86-*-msdosdjgpp*)
679         # DOS with the DJGPP environment
680         ac_cv_have_dev_random=no
681         AC_DEFINE(HAVE_DRIVE_LETTERS)
682         have_dosish_system=yes
683         try_gettext="no"
684         ;;
685
686     *-*-hpux*)
687         if test -z "$GCC" ; then
688             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
689         fi
690         ;;
691     *-dec-osf4*)
692         if test -z "$GCC" ; then
693             # Suppress all warnings
694             # to get rid of the unsigned/signed char mismatch warnings.
695             CFLAGS="-w $CFLAGS"
696         fi
697         ;;
698     *-dec-osf5*)
699         if test -z "$GCC" ; then
700             # Use the newer compiler `-msg_disable ptrmismatch1' to
701             # get rid of the unsigned/signed char mismatch warnings.
702             # Using this may hide other pointer mismatch warnings, but
703             # it at least lets other warning classes through
704             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
705         fi
706         ;;
707     m68k-atari-mint)
708         ;;
709     *-linux-android*)
710         have_android_system=yes
711         # Android is fully utf-8 and we do not want to use iconv to
712         # keeps things simple
713         require_iconv=no
714         ;;
715     *)
716        ;;
717 esac
718
719 if test "$have_dosish_system" = yes; then
720    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
721              [Defined if we run on some of the PCDOS like systems
722               (DOS, Windoze. OS/2) with special properties like
723               no file modes, case insensitive file names and preferred
724               use of backslashes as directory name separators.])
725 fi
726 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
727
728 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
729
730 if test "$have_w32_system" = yes; then
731    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
732    if test "$have_w32ce_system" = yes; then
733       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
734    fi
735 fi
736 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
737 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
738
739 if test "$have_android_system" = yes; then
740    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
741 fi
742 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
743
744
745 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
746 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
747
748
749 #
750 # Checks for libraries.
751 #
752 AC_MSG_NOTICE([checking for libraries])
753
754
755 #
756 # libgpg-error is a library with error codes shared between GnuPG
757 # related projects.
758 #
759 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
760                   have_gpg_error=yes,have_gpg_error=no)
761
762
763 #
764 # Libgcrypt is our generic crypto library
765 #
766 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
767         have_libgcrypt=yes,have_libgcrypt=no)
768
769
770 #
771 # libassuan is used for IPC
772 #
773 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
774                   have_libassuan=yes,have_libassuan=no)
775 if test "$have_libassuan" = "yes"; then
776   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
777                      [version of the libassuan library])
778   show_tor_support="only .onion"
779 fi
780
781
782 #
783 # libksba is our X.509 support library
784 #
785 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
786
787
788 #
789 # libusb allows us to use the integrated CCID smartcard reader driver.
790 #
791 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
792 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
793    case "${host}" in
794      *-mingw32*)
795        LIBUSB_NAME=
796        LIBUSB_LIBS=
797        LIBUSB_CPPFLAGS=
798        ;;
799      *-*-darwin*)
800        LIBUSB_NAME=usb-1.0
801        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
802        ;;
803      *-*-freebsd*)
804        # FreeBSD has a native 1.0 compatible library by -lusb.
805        LIBUSB_NAME=usb
806        LIBUSB_LIBS=
807        ;;
808      *)
809        LIBUSB_NAME=usb-1.0
810        LIBUSB_LIBS=
811        ;;
812    esac
813 fi
814 if test x"$LIBUSB_NAME" != x ; then
815    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
816                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
817                   have_libusb=yes ])
818    AC_MSG_CHECKING([libusb include dir])
819    usb_incdir_found="no"
820    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
821      _libusb_save_cppflags=$CPPFLAGS
822      if test -n "${_incdir}"; then
823        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
824      fi
825      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
826      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
827      CPPFLAGS=${_libusb_save_cppflags}
828      if test "$usb_incdir_found" = "yes"; then
829        break
830      fi
831    done
832    if test "$usb_incdir_found" = "yes"; then
833      AC_MSG_RESULT([${usb_incdir}])
834    else
835      AC_MSG_RESULT([not found])
836      usb_incdir=""
837      have_libusb=no
838      if test "$use_ccid_driver" != yes; then
839        use_ccid_driver=no
840      fi
841      LIBUSB_LIBS=""
842    fi
843
844    if test "$have_libusb" = yes; then
845      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
846    fi
847    if test x"$usb_incdir" = x; then
848      LIBUSB_CPPFLAGS=""
849    else
850      LIBUSB_CPPFLAGS="-I${usb_incdir}"
851    fi
852 fi
853 AC_SUBST(LIBUSB_LIBS)
854 AC_SUBST(LIBUSB_CPPFLAGS)
855
856 #
857 # Check wether it is necessary to link against libdl.
858 # (For example to load libpcsclite)
859 #
860 gnupg_dlopen_save_libs="$LIBS"
861 LIBS=""
862 AC_SEARCH_LIBS(dlopen, c dl,,,)
863 DL_LIBS=$LIBS
864 AC_SUBST(DL_LIBS)
865 LIBS="$gnupg_dlopen_save_libs"
866
867
868 # Checks for g10
869
870 AC_ARG_ENABLE(sqlite,
871                 AC_HELP_STRING([--disable-sqlite],
872                                [disable the use of SQLITE]),
873               try_sqlite=$enableval, try_sqlite=yes)
874
875 if test x"$use_tofu" = xyes ; then
876   if test x"$try_sqlite" = xyes ; then
877     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
878                                  [have_sqlite=yes],
879                                  [have_sqlite=no])
880   fi
881   if test "$have_sqlite" = "yes"; then
882     :
883     AC_SUBST([SQLITE3_CFLAGS])
884     AC_SUBST([SQLITE3_LIBS])
885   else
886     use_tofu=no
887     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
888     AC_MSG_WARN([[
889 ***
890 *** Building without SQLite support - TOFU disabled
891 ***
892 *** $tmp]])
893   fi
894 fi
895
896 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
897
898 if test x"$use_tofu" = xyes ; then
899     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
900 fi
901
902
903 # Checks for g13
904
905 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
906 AC_DEFINE_UNQUOTED(ENCFS,
907         "${ENCFS}", [defines the filename of the encfs program])
908
909 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
910 AC_DEFINE_UNQUOTED(FUSERMOUNT,
911         "${FUSERMOUNT}", [defines the filename of the fusermount program])
912
913
914 # Checks for dirmngr
915
916
917 #
918 # Checks for symcryptrun:
919 #
920
921 # libutil has openpty() and login_tty().
922 AC_CHECK_LIB(util, openpty,
923               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
924                 AC_DEFINE(HAVE_LIBUTIL,1,
925                          [defined if libutil is available])
926              ])
927 AC_SUBST(LIBUTIL_LIBS)
928
929 # shred is used to clean temporary plain text files.
930 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
931 AC_DEFINE_UNQUOTED(SHRED,
932         "${SHRED}", [defines the filename of the shred program])
933
934
935 #
936 # Check whether the nPth library is available
937 #
938 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
939 if test "$have_npth" = "yes"; then
940   AC_DEFINE(HAVE_NPTH, 1,
941               [Defined if the New Portable Thread Library is available])
942   AC_DEFINE(USE_NPTH, 1,
943               [Defined if support for nPth is requested and nPth is available])
944 else
945   AC_MSG_WARN([[
946 ***
947 *** To support concurrent access for example in gpg-agent and the SCdaemon
948 *** we need the support of the New Portable Threads Library.
949 ***]])
950 fi
951
952
953 #
954 # NTBTLS is our TLS library.  If it is not available fallback to
955 # GNUTLS.
956 #
957 AC_ARG_ENABLE(ntbtls,
958               AC_HELP_STRING([--disable-ntbtls],
959                              [disable the use of NTBTLS as TLS library]),
960               try_ntbtls=$enableval, try_ntbtls=yes)
961 if test x"$try_ntbtls" = xyes ; then
962   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
963                  [have_ntbtls=yes],[have_ntbtls=no])
964 fi
965 if test "$have_ntbtls" = yes ; then
966    use_tls_library=ntbtls
967    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
968 else
969   AC_ARG_ENABLE(gnutls,
970                 AC_HELP_STRING([--disable-gnutls],
971                                [disable GNUTLS as fallback TLS library]),
972                 try_gnutls=$enableval, try_gnutls=yes)
973   if test x"$try_gnutls" = xyes ; then
974     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
975                                    [have_gnutls=yes],
976                                    [have_gnutls=no])
977   fi
978   if test "$have_gnutls" = "yes"; then
979     AC_SUBST([LIBGNUTLS_CFLAGS])
980     AC_SUBST([LIBGNUTLS_LIBS])
981     use_tls_library=gnutls
982     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
983   else
984     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
985     AC_MSG_WARN([[
986 ***
987 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
988 ***
989 *** $tmp]])
990   fi
991 fi
992
993
994 AC_MSG_NOTICE([checking for networking options])
995
996 #
997 # Must check for network library requirements before doing link tests
998 # for ldap, for example. If ldap libs are static (or dynamic and without
999 # ELF runtime link paths), then link will fail and LDAP support won't
1000 # be detected.
1001 #
1002 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1003         [NETLIBS="-lnsl $NETLIBS"]))
1004 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1005         [NETLIBS="-lsocket $NETLIBS"]))
1006
1007
1008 #
1009 # Check standard resolver functions.
1010 #
1011 if test "$build_dirmngr" = "yes"; then
1012   _dns_save_libs=$LIBS
1013   LIBS=""
1014
1015   # Find the system resolver which can always be enabled with
1016   # the dirmngr option --standard-resolver.
1017
1018   # the double underscore thing is a glibc-ism?
1019   AC_SEARCH_LIBS(res_query,resolv bind,,
1020                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1021   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1022                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1023
1024   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1025   # and for some reason fools us into believing we don't need
1026   # -lresolv even if we do.  Since the test program checking for the
1027   # symbol does not include <resolv.h>, we need to check for the
1028   # renamed symbol explicitly.
1029   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1030       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1031           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1032
1033   if test x"$have_resolver" != xno ; then
1034
1035       # Make sure that the BIND 4 resolver interface is workable before
1036       # enabling any code that calls it.  At some point I'll rewrite the
1037       # code to use the BIND 8 resolver API.
1038       # We might also want to use libdns instead.
1039
1040     AC_MSG_CHECKING([whether the resolver is usable])
1041     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1042 #include <netinet/in.h>
1043 #include <arpa/nameser.h>
1044 #include <resolv.h>]],
1045 [[unsigned char answer[PACKETSZ];
1046   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1047   dn_skipname(0,0);
1048   dn_expand(0,0,0,0,0);
1049 ]])],have_resolver=yes,have_resolver=no)
1050     AC_MSG_RESULT($have_resolver)
1051
1052     # This is Apple-specific and somewhat bizarre as they changed the
1053     # define in bind 8 for some reason.
1054
1055     if test x"$have_resolver" != xyes ; then
1056       AC_MSG_CHECKING(
1057            [whether I can make the resolver usable with BIND_8_COMPAT])
1058       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1059 #include <sys/types.h>
1060 #include <netinet/in.h>
1061 #include <arpa/nameser.h>
1062 #include <resolv.h>]],
1063 [[unsigned char answer[PACKETSZ];
1064   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1065   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1066 ]])],[have_resolver=yes ; need_compat=yes])
1067       AC_MSG_RESULT($have_resolver)
1068     fi
1069   fi
1070
1071   if test x"$have_resolver" = xyes ; then
1072     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1073     DNSLIBS="$DNSLIBS $LIBS"
1074     if test x"$need_compat" = xyes ; then
1075       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1076     fi
1077     if test "$use_libdns" = yes; then
1078      show_tor_support=yes
1079     fi
1080   elif test "$use_libdns" = yes; then
1081     show_tor_support=yes
1082   else
1083     AC_MSG_WARN([[
1084 ***
1085 *** The system's DNS resolver is not usable.
1086 *** Dirmngr functionality is limited.
1087 ***]])
1088     show_tor_support="${show_tor_support} (no system resolver)"
1089   fi
1090
1091   LIBS=$_dns_save_libs
1092 fi
1093
1094 AC_SUBST(DNSLIBS)
1095
1096
1097 #
1098 # Check for LDAP
1099 #
1100 # Note that running the check changes the variable
1101 # gnupg_have_ldap from "n/a" to "no" or "yes".
1102
1103 AC_ARG_ENABLE(ldap,
1104     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1105     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1106
1107 if test "$gnupg_have_ldap" != "no" ; then
1108   if test "$build_dirmngr" = "yes" ; then
1109      GNUPG_CHECK_LDAP($NETLIBS)
1110      AC_CHECK_LIB(lber, ber_free,
1111                   [ LBER_LIBS="$LBER_LIBS -llber"
1112                     AC_DEFINE(HAVE_LBER,1,
1113                              [defined if liblber is available])
1114                     have_lber=yes
1115                  ])
1116   fi
1117 fi
1118 AC_SUBST(LBER_LIBS)
1119 if test "$gnupg_have_ldap" = "no"; then
1120     AC_MSG_WARN([[
1121 ***
1122 *** Building without LDAP support.
1123 *** No CRL access or X.509 certificate search available.
1124 ***]])
1125 fi
1126
1127 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1128 if test "$gnupg_have_ldap" = yes ; then
1129   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1130 else
1131  use_ldapwrapper=no
1132 fi
1133
1134 if test "$use_ldapwrapper" = yes; then
1135    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1136 fi
1137 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1138
1139
1140
1141
1142 #
1143 # Check for sendmail
1144 #
1145 # This isn't necessarily sendmail itself, but anything that gives a
1146 # sendmail-ish interface to the outside world.  That includes Exim,
1147 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1148 AC_ARG_WITH(mailprog,
1149       AC_HELP_STRING([--with-mailprog=NAME],
1150                      [use "NAME -t" for mail transport]),
1151              ,with_mailprog=yes)
1152 if test x"$with_mailprog" = xyes ; then
1153     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1154 elif test x"$with_mailprog" != xno ; then
1155     AC_MSG_CHECKING([for a mail transport program])
1156     AC_SUBST(SENDMAIL,$with_mailprog)
1157     AC_MSG_RESULT($with_mailprog)
1158 fi
1159
1160
1161 #
1162 # Construct a printable name of the OS
1163 #
1164 case "${host}" in
1165     *-mingw32ce*)
1166         PRINTABLE_OS_NAME="W32CE"
1167         ;;
1168     *-mingw32*)
1169         PRINTABLE_OS_NAME="MingW32"
1170         ;;
1171     *-*-cygwin*)
1172         PRINTABLE_OS_NAME="Cygwin"
1173         ;;
1174     i?86-emx-os2 | i?86-*-os2*emx )
1175         PRINTABLE_OS_NAME="OS/2"
1176         ;;
1177     i?86-*-msdosdjgpp*)
1178         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1179         try_dynload=no
1180         ;;
1181     *-linux*)
1182         PRINTABLE_OS_NAME="GNU/Linux"
1183         ;;
1184     *)
1185         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1186         ;;
1187 esac
1188 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1189                    [A human readable text with the name of the OS])
1190
1191
1192 #
1193 # Checking for iconv
1194 #
1195 if test "$require_iconv" = yes; then
1196   AM_ICONV
1197 else
1198   LIBICONV=
1199   LTLIBICONV=
1200   AC_SUBST(LIBICONV)
1201   AC_SUBST(LTLIBICONV)
1202 fi
1203
1204
1205 #
1206 # Check for gettext
1207 #
1208 # This is "GNU gnupg" - The project-id script from gettext
1209 #                       needs this string
1210 #
1211 AC_MSG_NOTICE([checking for gettext])
1212 AM_PO_SUBDIRS
1213 AM_GNU_GETTEXT_VERSION([0.17])
1214 if test "$try_gettext" = yes; then
1215   AM_GNU_GETTEXT([external],[need-ngettext])
1216
1217   # gettext requires some extra checks.  These really should be part of
1218   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1219   # function checks to here.
1220
1221   AC_CHECK_FUNCS(strchr)
1222 else
1223   USE_NLS=no
1224   USE_INCLUDED_LIBINTL=no
1225   BUILD_INCLUDED_LIBINTL=no
1226   POSUB=po
1227   AC_SUBST(USE_NLS)
1228   AC_SUBST(USE_INCLUDED_LIBINTL)
1229   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1230   AC_SUBST(POSUB)
1231 fi
1232
1233 # We use HAVE_LANGINFO_CODESET in a couple of places.
1234 AM_LANGINFO_CODESET
1235
1236 # Checks required for our use of locales
1237 gt_LC_MESSAGES
1238
1239
1240 #
1241 # SELinux support
1242 #
1243 if test "$selinux_support" = yes ; then
1244   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1245 fi
1246
1247
1248 #
1249 # Checks for header files.
1250 #
1251 AC_MSG_NOTICE([checking for header files])
1252 AC_HEADER_STDC
1253 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1254                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1255                   signal.h])
1256 AC_HEADER_TIME
1257
1258
1259 #
1260 # Checks for typedefs, structures, and compiler characteristics.
1261 #
1262 AC_MSG_NOTICE([checking for system characteristics])
1263 AC_C_CONST
1264 AC_C_INLINE
1265 AC_C_VOLATILE
1266 AC_TYPE_SIZE_T
1267 AC_TYPE_MODE_T
1268 AC_TYPE_SIGNAL
1269 AC_DECL_SYS_SIGLIST
1270
1271 gl_HEADER_SYS_SOCKET
1272 gl_TYPE_SOCKLEN_T
1273
1274 AC_SEARCH_LIBS([inet_addr], [nsl])
1275
1276 AC_ARG_ENABLE(endian-check,
1277               AC_HELP_STRING([--disable-endian-check],
1278               [disable the endian check and trust the OS provided macros]),
1279               endiancheck=$enableval,endiancheck=yes)
1280
1281 if test x"$endiancheck" = xyes ; then
1282   GNUPG_CHECK_ENDIAN
1283 fi
1284
1285 # fixme: we should get rid of the byte type
1286 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1287 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1288 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1289 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1290 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1291
1292 AC_CHECK_SIZEOF(unsigned short)
1293 AC_CHECK_SIZEOF(unsigned int)
1294 AC_CHECK_SIZEOF(unsigned long)
1295 AC_CHECK_SIZEOF(unsigned long long)
1296 AC_HEADER_TIME
1297 AC_CHECK_SIZEOF(time_t,,[[
1298 #include <stdio.h>
1299 #if TIME_WITH_SYS_TIME
1300 # include <sys/time.h>
1301 # include <time.h>
1302 #else
1303 # if HAVE_SYS_TIME_H
1304 #  include <sys/time.h>
1305 # else
1306 #  include <time.h>
1307 # endif
1308 #endif
1309 ]])
1310 GNUPG_TIME_T_UNSIGNED
1311
1312
1313 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1314    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1315    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1316     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1317 fi
1318
1319
1320 #
1321 # Checks for library functions.
1322 #
1323 AC_MSG_NOTICE([checking for library functions])
1324 AC_CHECK_DECLS(getpagesize)
1325 AC_FUNC_FSEEKO
1326 AC_FUNC_VPRINTF
1327 AC_FUNC_FORK
1328 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1329 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1330 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1331 AC_CHECK_FUNCS([canonicalize_file_name])
1332 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1333 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1334 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1335 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1336 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1337                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1338                 flockfile funlockfile getpwnam getpwuid \
1339                 getenv inet_pton strpbrk])
1340
1341 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1342 # Given that we use nanosleep only as an optimization over a select
1343 # based wait function we want it only if it is available in libc.
1344 _save_libs="$LIBS"
1345 AC_SEARCH_LIBS([nanosleep], [],
1346                [AC_DEFINE(HAVE_NANOSLEEP,1,
1347                 [Define to 1 if you have the `nanosleep' function in libc.])])
1348 LIBS="$_save_libs"
1349
1350
1351 # See whether libc supports the Linux inotify interface
1352 case "${host}" in
1353     *-*-linux*)
1354         AC_CHECK_FUNCS([inotify_init])
1355         ;;
1356 esac
1357
1358
1359 if test "$have_android_system" = yes; then
1360    # On Android ttyname is a stub but prints an error message.
1361    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1362              [Defined if ttyname does not work properly])
1363 fi
1364
1365 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1366
1367 # Dirmngr requires mmap on Unix systems.
1368 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1369   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1370 fi
1371
1372 #
1373 # W32 specific test
1374 #
1375 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1376
1377 #
1378 # Sanity check regex.  Tests adapted from mutt.
1379 #
1380 AC_MSG_CHECKING([whether regular expression support is requested])
1381 AC_ARG_ENABLE(regex,
1382   AC_HELP_STRING([--disable-regex],
1383     [do not handle regular expressions in trust signatures]),
1384   use_regex=$enableval, use_regex=yes)
1385 AC_MSG_RESULT($use_regex)
1386
1387 if test "$use_regex" = yes ; then
1388   _cppflags="${CPPFLAGS}"
1389   _ldflags="${LDFLAGS}"
1390   AC_ARG_WITH(regex,
1391      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1392       [
1393       if test -d "$withval" ; then
1394         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1395         LDFLAGS="${LDFLAGS} -L$withval/lib"
1396       fi
1397       ],withval="")
1398
1399   # Does the system have regex functions at all?
1400   AC_SEARCH_LIBS([regcomp], [regex])
1401   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1402
1403   if test $gnupg_cv_have_regex = no; then
1404     use_regex=no
1405   else
1406     if test x"$cross_compiling" = xyes; then
1407       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1408     else
1409       AC_CACHE_CHECK([whether your system's regexp library is broken],
1410        [gnupg_cv_regex_broken],
1411        AC_TRY_RUN([
1412 #include <unistd.h>
1413 #include <regex.h>
1414 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1415        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1416
1417       if test $gnupg_cv_regex_broken = yes; then
1418         AC_MSG_WARN([your regex is broken - disabling regex use])
1419         use_regex=no
1420       fi
1421     fi
1422   fi
1423   CPPFLAGS="${_cppflags}"
1424   LDFLAGS="${_ldflags}"
1425 fi
1426
1427 if test "$use_regex" != yes ; then
1428   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1429 fi
1430 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1431
1432
1433
1434 #
1435 # Do we have zlib? Must do it here because Solaris failed
1436 # when compiling a conftest (due to the "-lz" from LIBS).
1437 # Note that we combine zlib and bzlib2 in ZLIBS.
1438 #
1439 if test "$use_zip" = yes ; then
1440   _cppflags="${CPPFLAGS}"
1441   _ldflags="${LDFLAGS}"
1442   AC_ARG_WITH(zlib,
1443     [  --with-zlib=DIR         use libz in DIR],[
1444       if test -d "$withval"; then
1445         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1446         LDFLAGS="${LDFLAGS} -L$withval/lib"
1447       fi
1448     ])
1449
1450   AC_CHECK_HEADER(zlib.h,
1451      AC_CHECK_LIB(z, deflateInit2_,
1452        [
1453        ZLIBS="-lz"
1454        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1455        ],
1456        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1457        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1458 fi
1459
1460
1461 #
1462 # Check whether we can support bzip2
1463 #
1464 if test "$use_bzip2" = yes ; then
1465   _cppflags="${CPPFLAGS}"
1466   _ldflags="${LDFLAGS}"
1467   AC_ARG_WITH(bzip2,
1468      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1469       [
1470       if test -d "$withval" ; then
1471         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1472         LDFLAGS="${LDFLAGS} -L$withval/lib"
1473       fi
1474       ],withval="")
1475
1476   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1477   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1478   # woefully out of date.
1479   if test "$withval" != no ; then
1480      AC_CHECK_HEADER(bzlib.h,
1481         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1482           [
1483           have_bz2=yes
1484           ZLIBS="$ZLIBS -lbz2"
1485           AC_DEFINE(HAVE_BZIP2,1,
1486                   [Defined if the bz2 compression library is available])
1487           ],
1488           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1489           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1490   fi
1491 fi
1492 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1493 AC_SUBST(ZLIBS)
1494
1495
1496 # Check for readline support
1497 GNUPG_CHECK_READLINE
1498
1499
1500 if test "$development_version" = yes; then
1501     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1502             [Defined if this is not a regular release])
1503 fi
1504
1505 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1506
1507 GNUPG_CHECK_GNUMAKE
1508
1509 # Add some extra libs here so that previous tests don't fail for
1510 # mysterious reasons - the final link step should bail out.
1511 # W32SOCKLIBS is also defined so that if can be used for tools not
1512 # requiring any network stuff but linking to code in libcommon which
1513 # tracks in winsock stuff (e.g. init_common_subsystems).
1514 if test "$have_w32_system" = yes; then
1515    if test "$have_w32ce_system" = yes; then
1516      W32SOCKLIBS="-lws2"
1517    else
1518      W32SOCKLIBS="-lws2_32"
1519    fi
1520    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1521 fi
1522
1523 AC_SUBST(NETLIBS)
1524 AC_SUBST(W32SOCKLIBS)
1525
1526 #
1527 # Setup gcc specific options
1528 #
1529 USE_C99_CFLAGS=
1530 AC_MSG_NOTICE([checking for cc features])
1531 if test "$GCC" = yes; then
1532     mycflags=
1533     mycflags_save=$CFLAGS
1534
1535     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1536     # options.  This is the case for gcc >= 4.6
1537     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1538     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1539 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1540 #kickerror
1541 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1542     AC_MSG_RESULT($_gcc_silent_wno)
1543
1544     # Note that it is okay to use CFLAGS here because these are just
1545     # warning options and the user should have a chance of overriding
1546     # them.
1547     if test "$USE_MAINTAINER_MODE" = "yes"; then
1548         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1549         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1550         if test x"$_gcc_silent_wno" = xyes ; then
1551           _gcc_wopt=yes
1552         else
1553           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1554           CFLAGS="-Wno-missing-field-initializers"
1555           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1556                             [_gcc_wopt=yes],[_gcc_wopt=no])
1557           AC_MSG_RESULT($_gcc_wopt)
1558         fi
1559         if test x"$_gcc_wopt" = xyes ; then
1560           mycflags="$mycflags -W -Wno-sign-compare"
1561           mycflags="$mycflags -Wno-missing-field-initializers"
1562         fi
1563
1564         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1565         CFLAGS="-Wdeclaration-after-statement"
1566         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1567         AC_MSG_RESULT($_gcc_wopt)
1568         if test x"$_gcc_wopt" = xyes ; then
1569           mycflags="$mycflags -Wdeclaration-after-statement"
1570         fi
1571     else
1572         mycflags="$mycflags -Wall"
1573     fi
1574
1575     if test x"$_gcc_silent_wno" = xyes ; then
1576       _gcc_psign=yes
1577     else
1578       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1579       CFLAGS="-Wno-pointer-sign"
1580       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1581                         [_gcc_psign=yes],[_gcc_psign=no])
1582       AC_MSG_RESULT($_gcc_psign)
1583     fi
1584     if test x"$_gcc_psign" = xyes ; then
1585        mycflags="$mycflags -Wno-pointer-sign"
1586     fi
1587
1588     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1589     CFLAGS="-Wpointer-arith"
1590     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1591     AC_MSG_RESULT($_gcc_psign)
1592     if test x"$_gcc_psign" = xyes ; then
1593        mycflags="$mycflags -Wpointer-arith"
1594     fi
1595
1596     CFLAGS="$mycflags $mycflags_save"
1597     if test "$use_libdns" = yes; then
1598        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1599        USE_C99_CFLAGS="-std=gnu99"
1600     fi
1601 fi
1602
1603 AC_SUBST(USE_C99_CFLAGS)
1604
1605
1606 #
1607 # This is handy for debugging so the compiler doesn't rearrange
1608 # things and eliminate variables.
1609 #
1610 AC_ARG_ENABLE(optimization,
1611    AC_HELP_STRING([--disable-optimization],
1612                   [disable compiler optimization]),
1613                   [if test $enableval = no ; then
1614                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1615                    fi])
1616
1617 #
1618 # Add user CFLAGS.
1619 #
1620 CFLAGS="$CFLAGS $CFLAGS_orig"
1621
1622 #
1623 # Decide what to build
1624 #
1625
1626 build_scdaemon_extra=""
1627 if test "$build_scdaemon" = "yes"; then
1628   if test $have_libusb = no; then
1629      build_scdaemon_extra="without internal CCID driver"
1630   fi
1631   if test -n "$build_scdaemon_extra"; then
1632      build_scdaemon_extra="(${build_scdaemon_extra})"
1633   fi
1634 fi
1635
1636
1637 #
1638 # Set variables for use by automake makefiles.
1639 #
1640 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1641 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1642 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1643 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1644 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1645 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1646 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1647 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1648 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1649 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1650 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1651
1652 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1653 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1654 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1655
1656 #
1657 # Set some defines for use gpgconf.
1658 #
1659 if test "$build_gpg" = yes ; then
1660     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1661 fi
1662 if test "$build_gpgsm" = yes ; then
1663     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1664 fi
1665 if test "$build_agent" = yes ; then
1666     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1667 fi
1668 if test "$build_scdaemon" = yes ; then
1669     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1670 fi
1671 if test "$build_dirmngr" = yes ; then
1672     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1673 fi
1674 if test "$build_g13" = yes ; then
1675     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1676 fi
1677
1678
1679 #
1680 # Define Name strings
1681 #
1682 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1683
1684 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1685 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1686
1687 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1688 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1689
1690 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1691 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1692                                         [The displayed name of gpg-agent])
1693
1694 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1695 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1696                                        [The displayed name of scdaemon])
1697
1698 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1699 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1700                                       [The displayed name of dirmngr])
1701
1702 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1703 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1704
1705 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1706 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1707                                       [The displayed name of gpgconf])
1708
1709 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1710
1711 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1712                    [The name of the agent socket])
1713 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1714                    [The name of the agent socket for remote access])
1715 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1716                    [The name of the agent socket for browsers])
1717 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1718                    [The name of the agent socket for ssh])
1719 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1720                    [The name of the dirmngr info envvar])
1721 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1722                    [The name of the SCdaemon socket])
1723 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1724                    [The name of the dirmngr socket])
1725 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1726                    "hkps://hkps.pool.sks-keyservers.net",
1727       [The default keyserver for dirmngr to use, if none is explicitly given])
1728
1729 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1730
1731 if test "$have_w32_system" = yes; then
1732   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1733                      [The directory part of the W32 registry keys])
1734 fi
1735
1736
1737 #
1738 # Provide information about the build.
1739 #
1740 BUILD_REVISION="mym4_revision"
1741 AC_SUBST(BUILD_REVISION)
1742 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1743                    [GIT commit id revision used to build this package])
1744
1745 changequote(,)dnl
1746 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1747 changequote([,])dnl
1748 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1749 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1750 AC_SUBST(BUILD_VERSION)
1751 AC_SUBST(BUILD_FILEVERSION)
1752
1753 AC_ARG_ENABLE([build-timestamp],
1754   AC_HELP_STRING([--enable-build-timestamp],
1755                  [set an explicit build timestamp for reproducibility.
1756                   (default is the current time in ISO-8601 format)]),
1757      [if test "$enableval" = "yes"; then
1758         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1759       else
1760         BUILD_TIMESTAMP="$enableval"
1761       fi
1762       BUILD_HOSTNAME="$ac_hostname"],
1763      [BUILD_TIMESTAMP="<none>"
1764       BUILD_HOSTNAME="<anon>"])
1765 AC_SUBST(BUILD_TIMESTAMP)
1766 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1767                    [The time this package was configured for a build])
1768 AC_SUBST(BUILD_HOSTNAME)
1769
1770
1771 #
1772 # Print errors here so that they are visible all
1773 # together and the user can acquire them all together.
1774 #
1775 die=no
1776 if test "$have_gpg_error" = "no"; then
1777    die=yes
1778    AC_MSG_NOTICE([[
1779 ***
1780 *** You need libgpg-error to build this program.
1781 **  This library is for example available at
1782 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1783 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1784 ***]])
1785 fi
1786 if test "$have_libgcrypt" = "no"; then
1787    die=yes
1788    AC_MSG_NOTICE([[
1789 ***
1790 *** You need libgcrypt to build this program.
1791 **  This library is for example available at
1792 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1793 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1794 ***]])
1795 fi
1796 if test "$have_libassuan" = "no"; then
1797    die=yes
1798    AC_MSG_NOTICE([[
1799 ***
1800 *** You need libassuan to build this program.
1801 *** This library is for example available at
1802 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1803 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1804 ***]])
1805 fi
1806 if test "$have_ksba" = "no"; then
1807     die=yes
1808     AC_MSG_NOTICE([[
1809 ***
1810 *** You need libksba to build this program.
1811 *** This library is for example available at
1812 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1813 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1814 ***]])
1815 fi
1816 if test "$gnupg_have_ldap" = yes; then
1817   if test "$have_w32ce_system" = yes; then
1818     AC_MSG_NOTICE([[
1819 *** Note that CeGCC might be broken, a package fixing this is:
1820 ***    http://files.kolab.org/local/windows-ce/
1821 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1822 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1823 ***]])
1824    fi
1825 fi
1826 if test "$have_npth" = "no"; then
1827     die=yes
1828     AC_MSG_NOTICE([[
1829 ***
1830 *** It is now required to build with support for the
1831 *** New Portable Threads Library (nPth). Please install this
1832 *** library first.  The library is for example available at
1833 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1834 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1835 ***]])
1836 fi
1837
1838 if test "$require_iconv" = yes; then
1839   if test "$am_func_iconv" != yes; then
1840     die=yes
1841     AC_MSG_NOTICE([[
1842 ***
1843 *** The system does not provide a working iconv function.  Please
1844 *** install a suitable library; for example GNU Libiconv which is
1845 *** available at:
1846 ***   http://ftp.gnu.org/gnu/libiconv/
1847 ***]])
1848   fi
1849 fi
1850
1851 if test "$use_ccid_driver" = yes; then
1852   if test "$have_libusb" != yes; then
1853     die=yes
1854     AC_MSG_NOTICE([[
1855 ***
1856 *** You need libusb to build the internal ccid driver.  Please
1857 *** install a libusb suitable for your system.
1858 ***]])
1859   fi
1860 fi
1861
1862 if test "$die" = "yes"; then
1863     AC_MSG_ERROR([[
1864 ***
1865 *** Required libraries not found. Please consult the above messages
1866 *** and install them before running configure again.
1867 ***]])
1868 fi
1869
1870
1871
1872 AC_CONFIG_FILES([ m4/Makefile
1873 Makefile
1874 po/Makefile.in
1875 common/Makefile
1876 common/w32info-rc.h
1877 kbx/Makefile
1878 g10/Makefile
1879 sm/Makefile
1880 agent/Makefile
1881 scd/Makefile
1882 g13/Makefile
1883 dirmngr/Makefile
1884 tools/gpg-zip
1885 tools/Makefile
1886 doc/Makefile
1887 tests/Makefile
1888 tests/gpgscm/Makefile
1889 tests/openpgp/Makefile
1890 tests/migrations/Makefile
1891 tests/gpgme/Makefile
1892 tests/pkits/Makefile
1893 g10/gpg.w32-manifest
1894 ])
1895
1896
1897 AC_OUTPUT
1898
1899
1900 echo "
1901         GnuPG v${VERSION} has been configured as follows:
1902
1903         Revision:  mym4_revision  (mym4_revision_dec)
1904         Platform:  $PRINTABLE_OS_NAME ($host)
1905
1906         OpenPGP:   $build_gpg
1907         S/MIME:    $build_gpgsm
1908         Agent:     $build_agent
1909         Smartcard: $build_scdaemon $build_scdaemon_extra
1910         G13:       $build_g13
1911         Dirmngr:   $build_dirmngr
1912         Gpgtar:    $build_gpgtar
1913         WKS tools: $build_wks_tools
1914
1915         Protect tool:      $show_gnupg_protect_tool_pgm
1916         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1917         Default agent:     $show_gnupg_agent_pgm
1918         Default pinentry:  $show_gnupg_pinentry_pgm
1919         Default scdaemon:  $show_gnupg_scdaemon_pgm
1920         Default dirmngr:   $show_gnupg_dirmngr_pgm
1921
1922         Dirmngr auto start:  $dirmngr_auto_start
1923         Readline support:    $gnupg_cv_have_readline
1924         LDAP support:        $gnupg_have_ldap
1925         TLS support:         $use_tls_library
1926         TOFU support:        $use_tofu
1927         Tor support:         $show_tor_support
1928 "
1929 if test x"$use_regex" != xyes ; then
1930 echo "
1931         Warning: No regular expression support available.
1932                  OpenPGP trust signatures won't work.
1933                  gpg-check-pattern will not be built.
1934 "
1935 fi
1936 if test "x${gpg_config_script_warn}" != x; then
1937 cat <<G10EOF
1938         Warning: Mismatches between the target platform and the
1939                  to be used libraries have been detected for:
1940                   ${gpg_config_script_warn}
1941                  Please check above for more warning messages.
1942
1943 G10EOF
1944 fi