Fixed last yat2m change.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.0
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.0.10])
28 m4_define([my_issvn], [yes])
29
30
31 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
32             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q;}')]))
33 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
34         [bug-gnupg@gnupg.org])
35 # Set development_version to yes if the minor number is odd or you
36 # feel that the default check for a development version is not
37 # sufficient.
38 development_version=no
39
40 NEED_GPG_ERROR_VERSION=1.4
41
42 NEED_LIBGCRYPT_API=1
43 NEED_LIBGCRYPT_VERSION=1.2.2
44
45 NEED_LIBASSUAN_API=1
46 NEED_LIBASSUAN_VERSION=1.0.4
47
48 NEED_KSBA_API=1
49 NEED_KSBA_VERSION=1.0.2
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
60 AC_CANONICAL_HOST
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71 have_libusb=no
72
73 use_bzip2=yes
74 use_exec=yes
75 disable_keyserver_path=no
76 use_camellia=no
77
78
79 GNUPG_BUILD_PROGRAM(gpg, yes)
80 GNUPG_BUILD_PROGRAM(gpgsm, yes)
81 GNUPG_BUILD_PROGRAM(agent, yes)
82 GNUPG_BUILD_PROGRAM(scdaemon, yes)
83 GNUPG_BUILD_PROGRAM(tools, yes)
84 GNUPG_BUILD_PROGRAM(doc, yes)
85 GNUPG_BUILD_PROGRAM(symcryptrun, no)
86
87 AC_SUBST(PACKAGE)
88 AC_SUBST(PACKAGE_GT)
89 AC_SUBST(VERSION)
90 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
91 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
92                                 [Name of this package for gettext])
93 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
94 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
95                                         [Bug report address])
96 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
97                                        [Required version of Libgcrypt])
98 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
99                                        [Required version of Libksba])
100
101
102
103 # The default is to use the modules from this package and the few
104 # other packages in a standard place; i.e where this package gets
105 # installed.  With these options it is possible to override these
106 # ${prefix} depended values with fixed paths, which can't be replaced
107 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
108 AC_ARG_WITH(agent-pgm,
109     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
110           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
111 AC_SUBST(GNUPG_AGENT_PGM)
112 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
113 show_gnupg_agent_pgm="(default)"
114 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
115
116 AC_ARG_WITH(pinentry-pgm,
117     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
118           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
119 AC_SUBST(GNUPG_PINENTRY_PGM)
120 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
121 show_gnupg_pinentry_pgm="(default)"
122 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
123
124
125 AC_ARG_WITH(scdaemon-pgm,
126     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
127           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
128 AC_SUBST(GNUPG_SCDAEMON_PGM)
129 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
130 show_gnupg_scdaemon_pgm="(default)"
131 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
132
133
134 AC_ARG_WITH(dirmngr-pgm,
135     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
136           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
137 AC_SUBST(GNUPG_DIRMNGR_PGM)
138 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
139 show_gnupg_dirmngr_pgm="(default)"
140 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
141
142 AC_ARG_WITH(protect-tool-pgm,
143     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
144           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
145 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
146 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
147 show_gnupg_protect_tool_pgm="(default)"
148 test -n "$GNUPG_PROTECT_TOOL_PGM" \
149       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
150
151
152 # Some folks want to use only the agent from this packet.  Make it
153 # easier for them by providing the configure option
154 # --enable-only-agent.
155 AC_ARG_ENABLE(agent-only,
156     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
157     build_agent_only=$enableval)
158
159 # SELinux support includes tracking of sensitive files to avoid
160 # leaking their contents through processing these files by gpg itself
161 AC_MSG_CHECKING([whether SELinux support is requested])
162 AC_ARG_ENABLE(selinux-support,
163               AC_HELP_STRING([--enable-selinux-support],
164                              [enable SELinux support]),
165               selinux_support=$enableval, selinux_support=no)
166 AC_MSG_RESULT($selinux_support)
167
168 # Allow disabling of bzib2 support.
169 # It is defined only after we confirm the library is available later
170 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
171 AC_ARG_ENABLE(bzip2,
172    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
173    use_bzip2=$enableval)
174 AC_MSG_RESULT($use_bzip2)
175
176 # Check whether testing support for Camellia has been requested
177 AC_MSG_CHECKING([whether to enable the CAMELLIA cipher for gpg])
178 AC_ARG_ENABLE(camellia,
179    AC_HELP_STRING([--enable-camellia],[enable the CAMELLIA cipher for gpg]),
180    use_camellia=$enableval)
181 AC_MSG_RESULT($use_camellia)
182 if test x"$use_camellia" = xyes ; then
183    AC_DEFINE(USE_CAMELLIA,1,[Define to include the CAMELLIA cipher into gpg])
184    AC_MSG_WARN([[
185 ***
186 *** The Camellia cipher for gpg is for testing only and 
187 *** is NOT for production use!
188 ***]])
189 fi
190
191
192 # Configure option to allow or disallow execution of external
193 # programs, like a photo viewer.
194 AC_MSG_CHECKING([whether to enable external program execution])
195 AC_ARG_ENABLE(exec,
196     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
197     use_exec=$enableval)
198 AC_MSG_RESULT($use_exec)
199 if test "$use_exec" = no ; then
200     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
201 fi
202
203 if test "$use_exec" = yes ; then
204   AC_MSG_CHECKING([whether to enable photo ID viewing])
205   AC_ARG_ENABLE(photo-viewers,
206       [  --disable-photo-viewers disable photo ID viewers],
207       [if test "$enableval" = no ; then
208          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
209       fi],enableval=yes)
210   gnupg_cv_enable_photo_viewers=$enableval
211   AC_MSG_RESULT($enableval)
212
213   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
214     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
215     AC_ARG_WITH(photo-viewer,
216         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
217         [if test "$withval" = yes ; then
218            withval=no
219         elif test "$withval" != no ; then
220            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
221                             [if set, restrict photo-viewer to this])
222         fi],withval=no)
223     AC_MSG_RESULT($withval)
224   fi
225
226   AC_MSG_CHECKING([whether to enable external keyserver helpers])
227   AC_ARG_ENABLE(keyserver-helpers,
228       [  --disable-keyserver-helpers  disable all external keyserver support],
229       [if test "$enableval" = no ; then
230          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
231                   [define to disable keyserver helpers])
232       fi],enableval=yes)
233   gnupg_cv_enable_keyserver_helpers=$enableval
234   AC_MSG_RESULT($enableval)
235
236   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
237     # LDAP is defined only after we confirm the library is available later
238     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
239     AC_ARG_ENABLE(ldap,
240       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
241       try_ldap=$enableval, try_ldap=yes)
242     AC_MSG_RESULT($try_ldap)
243
244     AC_MSG_CHECKING([whether HKP keyserver support is requested])
245     AC_ARG_ENABLE(hkp,
246       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
247       try_hkp=$enableval, try_hkp=yes)
248     AC_MSG_RESULT($try_hkp)
249
250     AC_MSG_CHECKING([whether finger key fetching support is requested])
251     AC_ARG_ENABLE(finger,
252       AC_HELP_STRING([--disable-finger],
253         [disable finger key fetching interface only]),
254       try_finger=$enableval, try_finger=yes)
255     AC_MSG_RESULT($try_finger)
256
257     AC_MSG_CHECKING([whether generic object key fetching support is requested])
258     AC_ARG_ENABLE(generic,
259       AC_HELP_STRING([--disable-generic],
260         [disable generic object key fetching interface only]),
261       try_generic=$enableval, try_generic=yes)
262     AC_MSG_RESULT($try_generic)
263
264     AC_MSG_CHECKING([whether email keyserver support is requested])
265     AC_ARG_ENABLE(mailto,
266       AC_HELP_STRING([--enable-mailto],
267         [enable email keyserver interface only]),
268       try_mailto=$enableval, try_mailto=no)
269     AC_MSG_RESULT($try_mailto)
270     fi
271
272     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
273     AC_ARG_ENABLE(keyserver-path,
274       AC_HELP_STRING([--disable-keyserver-path],
275         [disable the exec-path option for keyserver helpers]),
276       [if test "$enableval" = no ; then
277          disable_keyserver_path=yes
278       fi],enableval=yes)
279     AC_MSG_RESULT($enableval)
280   fi
281
282
283 #
284 # Check for the key/uid cache size.  This can't be zero, but can be
285 # pretty small on embedded systems.  This is used for the gpg part.
286 #
287 AC_MSG_CHECKING([for the size of the key and uid cache])
288 AC_ARG_ENABLE(key-cache,
289         AC_HELP_STRING([--enable-key-cache=SIZE],
290                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
291 if test "$enableval" = "no"; then
292    enableval=5
293 elif test "$enableval" = "yes" || test "$enableval" = ""; then
294    enableval=4096
295 fi
296 changequote(,)dnl
297 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
298 changequote([,])dnl
299 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
300    AC_MSG_ERROR([invalid key-cache size])
301 fi
302 AC_MSG_RESULT($key_cache_size)
303 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
304                   [Size of the key and UID caches])
305
306
307
308 #
309 # Check whether we want to use Linux capabilities
310 #
311 AC_MSG_CHECKING([whether use of capabilities is requested])
312 AC_ARG_WITH(capabilities,
313     [  --with-capabilities     use linux capabilities [default=no]],
314 [use_capabilities="$withval"],[use_capabilities=no])
315 AC_MSG_RESULT($use_capabilities)
316
317 #
318 # To avoid double inclusion of config.h which might happen at some
319 # places, we add the usual double inclusion protection at the top of
320 # config.h.
321 #
322 AH_TOP([
323 #ifndef GNUPG_CONFIG_H_INCLUDED
324 #define GNUPG_CONFIG_H_INCLUDED
325 ])
326
327 #
328 # Stuff which goes at the bottom of config.h.
329 #
330 AH_BOTTOM([
331 /* This is the major version number of GnuPG so that
332    source included files can test for this.  Note, that
333    we use 2 here even for GnuPG 1.9.x. */
334 #define GNUPG_MAJOR_VERSION 2
335
336 /* Now to separate file name parts.
337    Please note that the string version must not contain more
338    than one character because the code assumes strlen()==1 */
339 #ifdef HAVE_DOSISH_SYSTEM
340 #define DIRSEP_C '\\'
341 #define DIRSEP_S "\\"
342 #define EXTSEP_C '.'
343 #define EXTSEP_S "."
344 #define PATHSEP_C ';'
345 #define PATHSEP_S ";"
346 #define EXEEXT_S ".exe"
347 #else
348 #define DIRSEP_C '/'
349 #define DIRSEP_S "/"
350 #define EXTSEP_C '.'
351 #define EXTSEP_S "."
352 #define PATHSEP_C ':'
353 #define PATHSEP_S ":"
354 #define EXEEXT_S ""
355 #endif
356
357 /* This is the same as VERSION, but should be overridden if the
358    platform cannot handle things like dots '.' in filenames. Set
359    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
360    uses for dots and dashes. */
361 #define SAFE_VERSION VERSION
362 #define SAFE_VERSION_DOT  '.'
363 #define SAFE_VERSION_DASH '-'
364
365 /* Some global constants. */
366 #ifdef HAVE_DRIVE_LETTERS
367 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
368 #elif defined(__VMS)
369 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
370 #else
371 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
372 #endif 
373 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
374
375 /* For some systems (DOS currently), we hardcode the path here.  For
376    POSIX systems the values are constructed by the Makefiles, so that
377    the values may be overridden by the make invocations; this is to
378    comply with the GNU coding standards. */
379 #ifdef HAVE_DRIVE_LETTERS
380  /* FIXME: We need to use a function to determine these values depending 
381     on the actual installation directory. */
382 #define GNUPG_BINDIR      "c:\\gnupg"
383 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
384 #define GNUPG_LIBDIR      "c:\\gnupg"
385 #define GNUPG_DATADIR     "c:\\gnupg"
386 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
387 #endif
388
389 /* Derive some other constants. */
390 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
391 #define EXEC_TEMPFILE_ONLY
392 #endif
393
394
395 /* We didn't define endianness above, so get it from OS macros.  This
396    is intended for making fat binary builds on OS X. */
397 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
398 #if defined(__BIG_ENDIAN__)
399 #define BIG_ENDIAN_HOST 1
400 #elif defined(__LITTLE_ENDIAN__)
401 #define LITTLE_ENDIAN_HOST 1
402 #else
403 #error "No endianness found"
404 #endif
405 #endif
406
407
408 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
409    ldap_start_tls_s because that is the actual symbol used in the
410    library.  winldap.h redefines it to our commonly used value,
411    thus we define our usual macro here.  */
412 #ifdef HAVE_LDAP_START_TLS_SA
413 # ifndef HAVE_LDAP_START_TLS_S
414 #  define HAVE_LDAP_START_TLS_S 1
415 # endif
416 #endif
417
418
419 /* Tell libgcrypt not to use its own libgpg-error implementation. */
420 #define USE_LIBGPG_ERROR 1
421
422 /* We use jnlib, so tell other modules about it.  */
423 #define HAVE_JNLIB_LOGGING 1
424
425 /* Our HTTP code is used in estream mode.  */
426 #define HTTP_USE_ESTREAM 1
427
428 /* Under W32 we do an explicit socket initialization, thus we need to
429    avoid the on-demand initialization which would also install an atexit
430    handler.  */
431 #define HTTP_NO_WSASTARTUP
432
433 /* We always include support for the OpenPGP card.  */
434 #define ENABLE_CARD_SUPPORT 1
435
436 /* We don't want the old assuan codes anymore. */
437 #define _ASSUAN_ONLY_GPG_ERRORS 1
438
439 /* We explicitly need to disable PTH's soft mapping as Debian
440    currently enables it by default for no reason. */
441 #define PTH_SYSCALL_SOFT 0
442
443 /* We want to use the libgcrypt provided memory allocation for
444    asprintf.  */
445 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
446 #define _ESTREAM_PRINTF_FREE          gcry_free
447 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
448
449 #endif /*GNUPG_CONFIG_H_INCLUDED*/
450 ])
451
452
453 AM_MAINTAINER_MODE
454
455 # Checks for programs.
456 AC_MSG_NOTICE([checking for programs])
457 AC_PROG_MAKE_SET
458 AM_SANITY_CHECK
459 missing_dir=`cd $ac_aux_dir && pwd`
460 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
461 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
462 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
463 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
464 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
465 AC_PROG_AWK
466 AC_PROG_CC
467 AC_PROG_CPP
468 AM_PROG_CC_C_O
469 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
470   AC_MSG_ERROR([[No C-89 compiler found]])
471 fi
472 AC_PROG_INSTALL
473 AC_PROG_LN_S
474 AC_PROG_RANLIB
475 AC_CHECK_TOOL(AR, ar, :)
476 AC_PATH_PROG(PERL,"perl")
477 AC_CHECK_TOOL(WINDRES, windres, :)
478 AC_ISC_POSIX
479 gl_EARLY
480 AC_SYS_LARGEFILE
481 GNUPG_CHECK_FAQPROG
482 GNUPG_CHECK_USTAR
483
484 # We need to compile and run a program on the build machine.  A
485 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
486 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
487 # newer version of that macro, we assume that it is also broken for
488 # autoconf 2.61 and thus we use a simple but usually sufficient
489 # approach.
490 AC_MSG_CHECKING(for cc for build)
491 if test "$cross_compiling" = "yes"; then
492   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
493 else
494   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
495 fi
496 AC_MSG_RESULT($CC_FOR_BUILD)
497 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
498
499
500
501 try_gettext=yes
502 have_dosish_system=no
503 have_w32_system=no
504 use_simple_gettext=no
505 case "${host}" in
506     *-mingw32*)
507         # special stuff for Windoze NT
508         ac_cv_have_dev_random=no
509         AC_DEFINE(USE_ONLY_8DOT3,1,
510                   [set this to limit filenames to the 8.3 format])
511         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
512                   [defined if we must run on a stupid file system])
513         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
514                   [because the Unix gettext has too much overhead on
515                    MingW32 systems and these systems lack Posix functions,
516                    we use a simplified version of gettext])
517         disable_keyserver_path=yes
518         have_dosish_system=yes
519         have_w32_system=yes
520         try_gettext="no"
521         use_simple_gettext=yes
522         ;;
523     i?86-emx-os2 | i?86-*-os2*emx )
524         # OS/2 with the EMX environment
525         ac_cv_have_dev_random=no
526         AC_DEFINE(HAVE_DRIVE_LETTERS)
527         have_dosish_system=yes
528         try_gettext="no"
529         ;;
530
531     i?86-*-msdosdjgpp*)
532         # DOS with the DJGPP environment
533         ac_cv_have_dev_random=no
534         AC_DEFINE(HAVE_DRIVE_LETTERS)
535         have_dosish_system=yes
536         try_gettext="no"
537         ;;
538
539     *-*-freebsd*)
540        # FreeBSD
541        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
542        LDFLAGS="$LDFLAGS -L/usr/local/lib"
543        ;;
544
545     *-*-hpux*)
546         if test -z "$GCC" ; then
547             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
548         fi
549         ;;
550     *-dec-osf4*)
551         if test -z "$GCC" ; then
552             # Suppress all warnings
553             # to get rid of the unsigned/signed char mismatch warnings.
554             CFLAGS="$CFLAGS -w"
555         fi
556         ;;
557     *-dec-osf5*)
558         if test -z "$GCC" ; then
559             # Use the newer compiler `-msg_disable ptrmismatch1' to
560             # get rid of the unsigned/signed char mismatch warnings.
561             # Using this may hide other pointer mismatch warnings, but
562             # it at least lets other warning classes through
563             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
564         fi
565         ;;
566     m68k-atari-mint)
567         ;;
568     *)
569        ;;
570 esac
571
572 if test "$have_dosish_system" = yes; then
573    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
574              [Defined if we run on some of the PCDOS like systems 
575               (DOS, Windoze. OS/2) with special properties like
576               no file modes])
577 fi
578 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
579
580 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
581
582 if test "$have_w32_system" = yes; then
583    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
584 fi
585 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
586
587 if test "$disable_keyserver_path" = yes; then
588     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
589               [Defined to disable exec-path for keyserver helpers])
590 fi
591
592 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
593 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
594
595 if test x"$try_hkp" = xyes ; then
596   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
597 fi
598
599 if test x"$try_finger" = xyes ; then
600   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
601 fi
602
603
604
605 #
606 # Checks for libraries.
607 #
608 AC_MSG_NOTICE([checking for libraries])
609
610
611 #
612 # libgpg-error is a library with error codes shared between GnuPG
613 # related projects.
614 #
615 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
616                   have_gpg_error=yes,have_gpg_error=no)
617
618
619 #
620 # Libgcrypt is our generic crypto library
621 #
622 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
623         have_libgcrypt=yes,have_libgcrypt=no)
624
625
626 #
627 # libassuan is used for IPC
628 #
629 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
630                   have_libassuan=yes,have_libassuan=no)
631 if test "$have_libassuan" = "yes"; then
632   have_libassuan=no
633   AM_PATH_LIBASSUAN_PTH("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
634                         have_libassuan=yes,have_libassuan=no)
635   AM_CHECK_LIBASSUAN("$NEED_LIBASSUAN_API:1.0.1",
636        [AC_DEFINE(HAVE_ASSUAN_SET_IO_MONITOR, 1,
637          [Define to 1 if you have the `assuan_set_io_monitor' function.])],)  
638   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
639             [version of the libbassuan library])
640 fi
641
642
643
644 #
645 # libksba is our X.509 support library
646 #
647 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
648
649
650 #
651 # libusb allows us to use the integrated CCID smartcard reader driver.
652 #
653 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
654 AC_CHECK_LIB(usb, usb_bulk_write,
655               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
656                 AC_DEFINE(HAVE_LIBUSB,1,
657                          [defined if libusb is available])
658                 have_libusb=yes
659              ])
660 AC_SUBST(LIBUSB_LIBS)
661 AC_CHECK_FUNCS(usb_create_match)
662
663 #
664 # Check wether it is necessary to link against libdl.
665 #
666 gnupg_dlopen_save_libs="$LIBS"
667 LIBS=""
668 AC_SEARCH_LIBS(dlopen, c dl,,,)
669 DL_LIBS=$LIBS
670 AC_SUBST(DL_LIBS)
671 LIBS="$gnupg_dlopen_save_libs"
672
673 #
674 # Checks for symcryptrun:
675 #
676
677 # libutil has openpty() and login_tty().
678 AC_CHECK_LIB(util, openpty,
679               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
680                 AC_DEFINE(HAVE_LIBUTIL,1,
681                          [defined if libutil is available])
682              ])
683 AC_SUBST(LIBUTIL_LIBS)
684
685 # shred is used to clean temporary plain text files.
686 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
687 AC_DEFINE_UNQUOTED(SHRED,
688         "${SHRED}", [defines the filename of the shred program])
689
690
691
692 #
693 # Check whether the GNU Pth library is available
694 # Note, that we include a Pth emulation for W32.
695 #
696 GNUPG_PATH_PTH
697 if test "$have_pth" = "yes"; then
698   AC_DEFINE(USE_GNU_PTH, 1,
699               [Defined if the GNU Portable Thread Library should be used])
700 else
701   AC_MSG_WARN([[
702 ***
703 *** To support concurrent access to the gpg-agent and the SCdaemon
704 *** we need the support of the GNU Portable Threads Library.
705 *** Download it from ftp://ftp.gnu.org/gnu/pth/
706 *** On a Debian GNU/Linux system you might want to try 
707 ***   apt-get install libpth-dev
708 ***]])
709 fi
710
711
712 AC_MSG_NOTICE([checking for networking options])
713
714 #
715 # Must check for network library requirements before doing link tests
716 # for ldap, for example. If ldap libs are static (or dynamic and without
717 # ELF runtime link paths), then link will fail and LDAP support won't
718 # be detected.
719 #
720 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
721         [NETLIBS="-lnsl $NETLIBS"]))
722 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
723         [NETLIBS="-lsocket $NETLIBS"]))
724
725 #
726 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
727 #
728 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
729   AC_ARG_ENABLE(dns-srv,
730      AC_HELP_STRING([--disable-dns-srv],
731                     [disable the use of DNS SRV in HKP and HTTP]),
732                 use_dns_srv=$enableval,use_dns_srv=yes)
733 fi
734
735 AC_ARG_ENABLE(dns-pka,
736    AC_HELP_STRING([--disable-dns-pka],
737         [disable the use of PKA records in DNS]),
738    use_dns_pka=$enableval,use_dns_pka=yes)
739
740 AC_ARG_ENABLE(dns-cert,
741    AC_HELP_STRING([--disable-dns-cert],
742         [disable the use of CERT records in DNS]),
743    use_dns_cert=$enableval,use_dns_cert=yes)
744
745 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
746    || test x"$use_dns_cert" = xyes; then
747   _dns_save_libs=$LIBS
748   LIBS=""
749   # the double underscore thing is a glibc-ism?
750   AC_SEARCH_LIBS(res_query,resolv bind,,
751                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
752   AC_SEARCH_LIBS(dn_expand,resolv bind,,
753                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
754   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
755                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
756
757   if test x"$have_resolver" != xno ; then
758
759     # Make sure that the BIND 4 resolver interface is workable before
760     # enabling any code that calls it.  At some point I'll rewrite the
761     # code to use the BIND 8 resolver API.
762
763     AC_MSG_CHECKING([whether the resolver is usable])
764     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
765 #include <netinet/in.h>
766 #include <arpa/nameser.h>
767 #include <resolv.h>],
768 [[unsigned char answer[PACKETSZ];
769   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
770   dn_skipname(0,0); 
771   dn_expand(0,0,0,0,0);
772 ]])],have_resolver=yes,have_resolver=no)
773     AC_MSG_RESULT($have_resolver)
774
775     # This is Apple-specific and somewhat bizarre as they changed the
776     # define in bind 8 for some reason.
777
778     if test x"$have_resolver" != xyes ; then
779        AC_MSG_CHECKING(
780              [whether I can make the resolver usable with BIND_8_COMPAT])
781        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
782 #include <sys/types.h>
783 #include <netinet/in.h>
784 #include <arpa/nameser.h>
785 #include <resolv.h>],
786 [[unsigned char answer[PACKETSZ];
787   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
788   dn_skipname(0,0); dn_expand(0,0,0,0,0);
789 ]])],[have_resolver=yes ; need_compat=yes])
790        AC_MSG_RESULT($have_resolver)
791     fi
792   fi
793
794   if test x"$have_resolver" = xyes ; then
795      DNSLIBS=$LIBS
796
797      if test x"$use_dns_srv" = xyes ; then
798         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
799      fi
800
801      if test x"$use_dns_pka" = xyes ; then
802         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
803      fi
804
805      if test x"$use_dns_cert" = xyes ; then
806         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
807      fi
808
809      if test x"$need_compat" = xyes ; then
810         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
811      fi
812   else
813      use_dns_srv=no
814      use_dns_pka=no
815      use_dns_cert=no
816   fi
817
818   LIBS=$_dns_save_libs
819 fi
820
821 AC_SUBST(DNSLIBS)
822
823 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
824
825 #
826 # Check for LDAP
827 #
828 if test "$try_ldap" = yes ; then
829    GNUPG_CHECK_LDAP($NETLIBS)
830 fi
831
832 #
833 # Check for curl.  We fake the curl API if libcurl isn't installed.
834 # We require 7.10 or later as we use curl_version_info().
835 #
836 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
837 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
838
839 # Generic, for us, means curl
840
841 if test x"$try_generic" = xyes ; then
842    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
843 fi
844
845 #
846 # Check for sendmail
847 #
848 # This isn't necessarily sendmail itself, but anything that gives a
849 # sendmail-ish interface to the outside world.  That includes Exim,
850 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
851 if test "$try_mailto" = yes ; then
852   AC_ARG_WITH(mailprog,
853       AC_HELP_STRING([--with-mailprog=NAME],
854                      [use "NAME -t" for mail transport]),
855              ,with_mailprog=yes)
856
857   if test x"$with_mailprog" = xyes ; then
858     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
859     if test "$ac_cv_path_SENDMAIL" ; then
860       GPGKEYS_MAILTO="gpg2keys_mailto"
861     fi
862   elif test x"$with_mailprog" != xno ; then
863     AC_MSG_CHECKING([for a mail transport program])
864     AC_SUBST(SENDMAIL,$with_mailprog)
865     AC_MSG_RESULT($with_mailprog)
866     GPGKEYS_MAILTO="gpg2keys_mailto"
867   fi
868 fi
869
870 AC_SUBST(GPGKEYS_MAILTO)
871
872 #
873 # Construct a printable name of the OS
874 #
875 case "${host}" in
876     *-mingw32*)
877         PRINTABLE_OS_NAME="MingW32"
878         ;;
879     *-*-cygwin*)
880         PRINTABLE_OS_NAME="Cygwin"
881         ;;
882     i?86-emx-os2 | i?86-*-os2*emx )
883         PRINTABLE_OS_NAME="OS/2"
884         ;;
885     i?86-*-msdosdjgpp*)
886         PRINTABLE_OS_NAME="MSDOS/DJGPP"
887         try_dynload=no
888         ;;
889     *-linux*)
890         PRINTABLE_OS_NAME="GNU/Linux"
891         ;;
892     *)
893         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
894         ;;
895 esac
896 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
897                    [A human readable text with the name of the OS])
898
899
900 #
901 # Checking for iconv
902 #
903 AM_ICONV
904
905
906 #
907 # Check for gettext
908 #
909 AC_MSG_NOTICE([checking for gettext])
910 AM_PO_SUBDIRS
911 AM_GNU_GETTEXT_VERSION([0.17])
912 if test "$try_gettext" = yes; then
913   AM_GNU_GETTEXT([external],[need-ngettext])
914
915   # gettext requires some extra checks.  These really should be part of
916   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
917   # function checks to here.
918
919   AC_CHECK_FUNCS(strchr)
920 else
921   USE_NLS=no
922   USE_INCLUDED_LIBINTL=no
923   BUILD_INCLUDED_LIBINTL=no
924   POSUB=po
925   AC_SUBST(USE_NLS)
926   AC_SUBST(USE_INCLUDED_LIBINTL)
927   AC_SUBST(BUILD_INCLUDED_LIBINTL)
928   AC_SUBST(POSUB)
929 fi
930
931 # We use HAVE_LANGINFO_CODESET in a couple of places.
932 AM_LANGINFO_CODESET
933
934 # Checks required for our use locales
935 gt_LC_MESSAGES
936
937
938 #
939 # SELinux support
940 #
941 if test "$selinux_support" = yes ; then
942   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
943 fi
944
945
946 #
947 # Checks for header files.
948 #
949 AC_MSG_NOTICE([checking for header files])
950 AC_HEADER_STDC
951 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
952 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
953 AC_HEADER_TIME
954
955
956 #
957 # Checks for typedefs, structures, and compiler characteristics.
958 #
959 AC_MSG_NOTICE([checking for system characteristics])
960 AC_C_CONST
961 AC_C_INLINE
962 AC_C_VOLATILE
963 AC_TYPE_SIZE_T
964 AC_TYPE_MODE_T
965 AC_TYPE_SIGNAL
966 AC_DECL_SYS_SIGLIST
967
968 AC_ARG_ENABLE(endian-check,
969               AC_HELP_STRING([--disable-endian-check],
970               [disable the endian check and trust the OS provided macros]),
971               endiancheck=$enableval,endiancheck=yes)
972
973 if test x"$endiancheck" = xyes ; then
974   GNUPG_CHECK_ENDIAN
975 fi
976
977 # fixme: we should get rid of the byte type
978 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
979 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
980 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
981 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
982 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
983
984 AC_CHECK_SIZEOF(unsigned short)
985 AC_CHECK_SIZEOF(unsigned int)
986 AC_CHECK_SIZEOF(unsigned long)
987 AC_CHECK_SIZEOF(unsigned long long)
988 AC_CHECK_SIZEOF(time_t,,[[
989 #include <stdio.h>
990 #if TIME_WITH_SYS_TIME
991 # include <sys/time.h>
992 # include <time.h>
993 #else
994 # if HAVE_SYS_TIME_H
995 #  include <sys/time.h>
996 # else
997 #  include <time.h>
998 # endif
999 #endif
1000 ]])
1001
1002
1003 # Ensure that we have UINT64_C before we bother to check for uint64_t
1004 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1005 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1006    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1007        uint64_t foo=UINT64_C(42);]),
1008      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1009 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1010    AC_CHECK_SIZEOF(uint64_t)
1011 fi
1012
1013 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1014    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1015    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1016     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1017 fi
1018
1019
1020 #
1021 # Checks for library functions.
1022 #
1023 AC_MSG_NOTICE([checking for library functions])
1024 AC_CHECK_DECLS(getpagesize)
1025 AC_FUNC_FSEEKO
1026 AC_FUNC_VPRINTF
1027 AC_FUNC_FORK
1028 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1029 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1030 AC_CHECK_FUNCS([unsetenv getpwnam getpwuid fcntl ftruncate])
1031 AC_CHECK_FUNCS([gettimeofday getrusage setrlimit clock_gettime])
1032 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1033 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1034 AC_CHECK_FUNCS([ttyname rand ftello])
1035
1036 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1037
1038 #
1039 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1040 #
1041 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1042 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1043 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen])
1044
1045 #
1046 # gnulib checks
1047 #
1048 gl_SOURCE_BASE([gl])
1049 gl_M4_BASE([gl/m4])
1050 gl_MODULES([setenv mkdtemp xsize strpbrk])
1051 gl_INIT
1052
1053
1054 #
1055 # W32 specific test
1056 #
1057 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1058
1059 #
1060 # Sanity check regex.  Tests adapted from mutt.
1061 #
1062 AC_MSG_CHECKING([whether regular expression support is requested])
1063 AC_ARG_ENABLE(regex,
1064   AC_HELP_STRING([--disable-regex],
1065     [do not handle regular expressions in trust signatures]),
1066   use_regex=$enableval, use_regex=yes)
1067 AC_MSG_RESULT($use_regex)
1068
1069 if test "$use_regex" = yes ; then
1070   _cppflags="${CPPFLAGS}"
1071   _ldflags="${LDFLAGS}"
1072   AC_ARG_WITH(regex,
1073      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1074       [
1075       if test -d "$withval" ; then
1076         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1077         LDFLAGS="${LDFLAGS} -L$withval/lib"
1078       fi
1079       ],withval="")     
1080
1081   # Does the system have regex functions at all?
1082   AC_SEARCH_LIBS([regcomp], [regex])
1083   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1084
1085   if test $gnupg_cv_have_regex = no; then
1086     use_regex=no
1087   else
1088     if test x"$cross_compiling" = xyes; then
1089       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1090     else
1091       AC_CACHE_CHECK([whether your system's regexp library is broken],
1092        [gnupg_cv_regex_broken],
1093        AC_TRY_RUN([
1094 #include <unistd.h>
1095 #include <regex.h>
1096 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1097        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1098
1099       if test $gnupg_cv_regex_broken = yes; then
1100         AC_MSG_WARN([your regex is broken - disabling regex use])
1101         use_regex=no
1102       fi
1103     fi
1104   fi
1105   CPPFLAGS="${_cppflags}"
1106   LDFLAGS="${_ldflags}"
1107 fi
1108
1109 if test "$use_regex" != yes ; then
1110   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1111 fi
1112 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1113
1114
1115
1116 #
1117 # Do we have zlib? Must do it here because Solaris failed
1118 # when compiling a conftest (due to the "-lz" from LIBS).
1119 # Note that we combine zlib and bzlib2 in ZLIBS.
1120 #
1121 _cppflags="${CPPFLAGS}"
1122 _ldflags="${LDFLAGS}"
1123 AC_ARG_WITH(zlib,
1124   [  --with-zlib=DIR         use libz in DIR],[
1125     if test -d "$withval"; then
1126       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1127       LDFLAGS="${LDFLAGS} -L$withval/lib"
1128     fi
1129   ])
1130
1131 AC_CHECK_HEADER(zlib.h,
1132       AC_CHECK_LIB(z, deflateInit2_,
1133        ZLIBS="-lz",
1134        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1135        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1136
1137 #
1138 # Check whether we can support bzip2
1139
1140 if test "$use_bzip2" = yes ; then
1141   _cppflags="${CPPFLAGS}"
1142   _ldflags="${LDFLAGS}"
1143   AC_ARG_WITH(bzip2,
1144      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1145       [
1146       if test -d "$withval" ; then
1147         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1148         LDFLAGS="${LDFLAGS} -L$withval/lib"
1149       fi
1150       ],withval="")
1151
1152   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1153   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1154   # woefully out of date.
1155   if test "$withval" != no ; then
1156      AC_CHECK_HEADER(bzlib.h,
1157         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1158           [
1159           have_bz2=yes
1160           ZLIBS="$ZLIBS -lbz2"
1161           AC_DEFINE(HAVE_BZIP2,1,
1162                   [Defined if the bz2 compression library is available])
1163           ],
1164           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1165           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1166   fi
1167 fi
1168 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1169 AC_SUBST(ZLIBS)
1170
1171
1172 # Check for readline support
1173 GNUPG_CHECK_READLINE
1174
1175 #
1176 # Allow users to append something to the version string without
1177 # flagging it as development version.  The user version parts is
1178 # considered everything after a dash. 
1179 #
1180 if test "$development_version" != yes; then
1181   changequote(,)dnl
1182   tmp_pat='[a-zA-Z]'
1183   changequote([,])dnl
1184   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1185     development_version=yes
1186   fi
1187 fi
1188 if test "$development_version" = yes; then
1189     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1190             [Defined if this is not a regular release])
1191 fi
1192
1193 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1194
1195 GNUPG_CHECK_GNUMAKE
1196
1197 # Add some extra libs here so that previous tests don't fail for
1198 # mysterious reasons - the final link step should bail out.
1199 # W32SOCKLIBS is also defined so that if can be used for tools not
1200 # requiring any network stuff but linking to code in libcommon which
1201 # tracks in winsock stuff (e.g. init_common_subsystems.
1202 if test "$have_w32_system" = yes; then
1203    W32SOCKLIBS="-lws2_32"
1204    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1205 fi
1206
1207 AC_SUBST(NETLIBS)
1208 AC_SUBST(W32SOCKLIBS)
1209
1210 #
1211 # Setup gcc specific options
1212 #
1213 AC_MSG_NOTICE([checking for cc features])
1214 if test "$GCC" = yes; then
1215     # Note that it is okay to use CFLAGS here because this are just
1216     # warning options and the user should have a chance of overriding
1217     # them.
1218     if test "$USE_MAINTAINER_MODE" = "yes"; then
1219         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1220         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1221     else
1222         CFLAGS="$CFLAGS -Wall"
1223     fi
1224
1225     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1226     _gcc_cflags_save=$CFLAGS
1227     CFLAGS="-Wno-pointer-sign"
1228     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1229     AC_MSG_RESULT($_gcc_psign)
1230     CFLAGS=$_gcc_cflags_save;
1231     if test x"$_gcc_psign" = xyes ; then
1232        CFLAGS="$CFLAGS -Wno-pointer-sign"
1233     fi
1234
1235     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1236     _gcc_cflags_save=$CFLAGS
1237     CFLAGS="-Wpointer-arith"
1238     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1239     AC_MSG_RESULT($_gcc_psign)
1240     CFLAGS=$_gcc_cflags_save;
1241     if test x"$_gcc_psign" = xyes ; then
1242        CFLAGS="$CFLAGS -Wpointer-arith"
1243     fi
1244 fi
1245
1246
1247 #
1248 # This is handy for debugging so the compiler doesn't rearrange
1249 # things and eliminate variables.
1250 #
1251 AC_ARG_ENABLE(optimization,
1252    AC_HELP_STRING([--disable-optimization],
1253                   [disable compiler optimization]),
1254                   [if test $enableval = no ; then
1255                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1256                    fi])
1257
1258 #
1259 # Prepare building of estream
1260 #
1261 estream_INIT
1262
1263
1264 #
1265 # Decide what to build
1266 #
1267 missing_pth=no
1268 if test $have_ksba = no; then
1269   build_gpgsm=no
1270   build_scdaemon=no
1271 fi
1272
1273 build_agent_threaded=""
1274 if test "$build_agent" = "yes"; then
1275   if test $have_pth = no; then
1276      build_agent_threaded="(not multi-threaded)"
1277      missing_pth=yes
1278   fi
1279 fi
1280
1281 build_scdaemon_extra=""
1282 if test "$build_scdaemon" = "yes"; then
1283   tmp=""
1284   if test $have_pth = no; then
1285      build_scdaemon_extra="not multi-threaded"
1286      tmp=", "
1287      missing_pth=yes
1288   fi
1289   if test $have_libusb = no; then
1290      build_scdaemon_extra="${tmp}without internal CCID driver"
1291      tmp=", "
1292   fi
1293   if test -n "$build_scdaemon_extra"; then
1294      build_scdaemon_extra="(${build_scdaemon_extra})"
1295   fi
1296 fi
1297
1298
1299 if test "$build_agent_only" = "yes" ; then
1300   build_gpg=no
1301   build_gpgsm=no
1302   build_scdaemon=no
1303   build_tools=no
1304   build_doc=no
1305 fi
1306
1307
1308 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1309 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1310 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1311 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1312 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1313 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1314 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1315
1316 AM_CONDITIONAL(RUN_GPG_TESTS,
1317         test x$cross_compiling = xno -a "$build_gpg" = yes )
1318
1319
1320 #
1321 # Print errors here so that they are visible all
1322 # together and the user can acquire them all together.
1323 #
1324 die=no
1325 if test "$have_gpg_error" = "no"; then
1326    die=yes
1327    AC_MSG_NOTICE([[
1328 ***  
1329 *** You need libgpg-error to build this program.
1330 **  This library is for example available at
1331 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1332 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1333 ***]])
1334 fi
1335 if test "$have_libgcrypt" = "no"; then
1336    die=yes
1337    AC_MSG_NOTICE([[
1338 ***  
1339 *** You need libgcrypt to build this program.
1340 **  This library is for example available at
1341 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1342 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1343 ***]])
1344 fi
1345 if test "$have_libassuan" = "no"; then
1346    die=yes
1347    AC_MSG_NOTICE([[
1348 ***
1349 *** You need libassuan with Pth support to build this program.
1350 *** This library is for example available at
1351 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1352 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1353 ***]])
1354 fi
1355 if test "$have_ksba" = "no"; then
1356     AC_MSG_NOTICE([[
1357 ***
1358 *** You need libksba to build this program.
1359 *** This library is for example available at
1360 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1361 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1362 ***]])
1363 fi
1364 if test "$missing_pth" = "yes"; then
1365     AC_MSG_NOTICE([[
1366 ***
1367 *** It is now required to build with support for the
1368 *** GNU Portable Threads Library (Pth). Please install this
1369 *** library first.  The library is for example available at
1370 ***   ftp://ftp.gnu.org/gnu/pth/
1371 *** On a Debian GNU/Linux system you can install it using 
1372 ***   apt-get install libpth-dev
1373 *** To build GnuPG for Windows you need to use the W32PTH
1374 *** package; available at:
1375 ***   ftp://ftp.g10code.com/g10code/w32pth/
1376 ***]])
1377    die=yes
1378 fi
1379
1380 if test "$die" = "yes"; then
1381     AC_MSG_ERROR([[
1382 ***
1383 *** Required libraries not found. Please consult the above messages
1384 *** and install them before running configure again.
1385 ***]])
1386 fi
1387
1388
1389
1390 AC_CONFIG_FILES([ m4/Makefile 
1391 Makefile
1392 po/Makefile.in
1393 gl/Makefile
1394 include/Makefile
1395 jnlib/Makefile
1396 common/Makefile
1397 kbx/Makefile
1398 g10/Makefile
1399 sm/Makefile
1400 agent/Makefile
1401 scd/Makefile
1402 keyserver/Makefile
1403 keyserver/gpg2keys_mailto
1404 keyserver/gpg2keys_test
1405 tools/gpg-zip
1406 tools/Makefile
1407 doc/Makefile
1408 tests/Makefile
1409 tests/openpgp/Makefile
1410 tests/pkits/Makefile
1411 ])
1412 AC_OUTPUT
1413
1414
1415 echo "
1416         GnuPG v${VERSION} has been configured as follows:
1417         
1418         Platform:  $PRINTABLE_OS_NAME ($host)
1419
1420         OpenPGP:   $build_gpg
1421         S/MIME:    $build_gpgsm
1422         Agent:     $build_agent $build_agent_threaded
1423         Smartcard: $build_scdaemon $build_scdaemon_extra
1424
1425         Protect tool:      $show_gnupg_protect_tool_pgm
1426         Default agent:     $show_gnupg_agent_pgm
1427         Default pinentry:  $show_gnupg_pinentry_pgm
1428         Default scdaemon:  $show_gnupg_scdaemon_pgm
1429         Default dirmngr:   $show_gnupg_dirmngr_pgm
1430 "
1431 if test x"$use_regex" != xyes ; then
1432 echo "
1433         Warning: No regular expression support available.
1434                  OpenPGP trust signatures won't work.
1435                  gpg-check-pattern will not be build.
1436 "
1437 fi
1438 if test  x"$use_camellia" = xyes ; then
1439   echo
1440   echo "WARNING: The Camellia cipher for gpg is for testing only"
1441   echo "         and is NOT for production use!"
1442   echo
1443 fi
1444