dnsmngr: Fix use of CPP.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2017 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [22])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://dev.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 use_libdns=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 # We use gpgtar to unpack test data, hence we always build it.  If the
132 # user opts out, we simply don't install it.
133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
134 GNUPG_BUILD_PROGRAM(wks-tools, no)
135
136 AC_SUBST(PACKAGE)
137 AC_SUBST(PACKAGE_GT)
138 AC_SUBST(VERSION)
139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
141                                 [Name of this package for gettext])
142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
144                                         [Bug report address])
145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
146                                        [Required version of Libgcrypt])
147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
148                                        [Required version of Libksba])
149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
150                                        [Required version of NTBTLS])
151
152
153
154 # The default is to use the modules from this package and the few
155 # other packages in a standard place; i.e where this package gets
156 # installed.  With these options it is possible to override these
157 # ${prefix} depended values with fixed paths, which can't be replaced
158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
159 AC_ARG_WITH(agent-pgm,
160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
162 AC_SUBST(GNUPG_AGENT_PGM)
163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
164 show_gnupg_agent_pgm="(default)"
165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
166
167 AC_ARG_WITH(pinentry-pgm,
168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
170 AC_SUBST(GNUPG_PINENTRY_PGM)
171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
172 show_gnupg_pinentry_pgm="(default)"
173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
174
175
176 AC_ARG_WITH(scdaemon-pgm,
177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
179 AC_SUBST(GNUPG_SCDAEMON_PGM)
180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
181 show_gnupg_scdaemon_pgm="(default)"
182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
183
184
185 AC_ARG_WITH(dirmngr-pgm,
186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
188 AC_SUBST(GNUPG_DIRMNGR_PGM)
189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
190 show_gnupg_dirmngr_pgm="(default)"
191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
192
193 AC_ARG_WITH(protect-tool-pgm,
194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
198 show_gnupg_protect_tool_pgm="(default)"
199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
201
202 AC_ARG_WITH(dirmngr-ldap-pgm,
203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
207 show_gnupg_dirmngr_ldap_pgm="(default)"
208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
210
211 #
212 # On some platforms gpg2 is usually installed as gpg without using a
213 # symlink.  For correct operation of gpgconf it needs to know the
214 # installed name of gpg.  This option sets "gpg2"'s installed name to
215 # just "gpg".  Note that it might be required to rename gpg2 to gpg
216 # manually after the build process.
217 #
218 AC_ARG_ENABLE(gpg2-is-gpg,
219     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
220     gpg2_is_gpg=$enableval)
221 if test "$gpg2_is_gpg" != "yes"; then
222    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
223 fi
224 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=$use_trust_models)
267 AC_MSG_RESULT($use_tofu)
268 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
269     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
270 fi
271
272 AC_MSG_CHECKING([whether to enable libdns])
273 AC_ARG_ENABLE(libdns,
274                 AC_HELP_STRING([--disable-libdns],
275                                [do not build with libdns support]),
276               use_libdns=$enableval, use_libdns=yes)
277 AC_MSG_RESULT($use_libdns)
278 if test x"$use_libdns" = xyes ; then
279     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
280 fi
281 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
282
283
284 #
285 # Options to disable algorithm
286 #
287
288 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
289 # Elgamal is a MUST algorithm
290 # DSA is a MUST algorithm
291 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
292 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
293 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
294
295 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
296 # 3DES is a MUST algorithm
297 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
298 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
299 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
300 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
301 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
302 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
303 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
304 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
305 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
306
307 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
308 # SHA1 is a MUST algorithm
309 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
310 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
311 # SHA256 is a MUST algorithm for GnuPG.
312 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
313 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
314
315
316 # Allow disabling of zip support.
317 # This is in general not a good idea because according to rfc4880 OpenPGP
318 # implementations SHOULD support ZLIB.
319 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
320 AC_ARG_ENABLE(zip,
321    AC_HELP_STRING([--disable-zip],
322                   [disable the ZIP and ZLIB compression algorithm]),
323    use_zip=$enableval)
324 AC_MSG_RESULT($use_zip)
325
326 # Allow disabling of bzib2 support.
327 # It is defined only after we confirm the library is available later
328 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
329 AC_ARG_ENABLE(bzip2,
330    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
331    use_bzip2=$enableval)
332 AC_MSG_RESULT($use_bzip2)
333
334 # Configure option to allow or disallow execution of external
335 # programs, like a photo viewer.
336 AC_MSG_CHECKING([whether to enable external program execution])
337 AC_ARG_ENABLE(exec,
338     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
339     use_exec=$enableval)
340 AC_MSG_RESULT($use_exec)
341 if test "$use_exec" = no ; then
342     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
343 fi
344
345 if test "$use_exec" = yes ; then
346   AC_MSG_CHECKING([whether to enable photo ID viewing])
347   AC_ARG_ENABLE(photo-viewers,
348       [  --disable-photo-viewers disable photo ID viewers],
349       [if test "$enableval" = no ; then
350          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
351       fi],enableval=yes)
352   gnupg_cv_enable_photo_viewers=$enableval
353   AC_MSG_RESULT($enableval)
354
355   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
356     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
357     AC_ARG_WITH(photo-viewer,
358         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
359         [if test "$withval" = yes ; then
360            withval=no
361         elif test "$withval" != no ; then
362            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
363                             [if set, restrict photo-viewer to this])
364         fi],withval=no)
365     AC_MSG_RESULT($withval)
366   fi
367 fi
368
369
370 #
371 # Check for the key/uid cache size.  This can't be zero, but can be
372 # pretty small on embedded systems.  This is used for the gpg part.
373 #
374 AC_MSG_CHECKING([for the size of the key and uid cache])
375 AC_ARG_ENABLE(key-cache,
376         AC_HELP_STRING([--enable-key-cache=SIZE],
377                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
378 if test "$enableval" = "no"; then
379    enableval=5
380 elif test "$enableval" = "yes" || test "$enableval" = ""; then
381    enableval=4096
382 fi
383 changequote(,)dnl
384 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
385 changequote([,])dnl
386 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
387    AC_MSG_ERROR([invalid key-cache size])
388 fi
389 AC_MSG_RESULT($key_cache_size)
390 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
391                   [Size of the key and UID caches])
392
393
394
395 #
396 # Check whether we want to use Linux capabilities
397 #
398 AC_MSG_CHECKING([whether use of capabilities is requested])
399 AC_ARG_WITH(capabilities,
400     [  --with-capabilities     use linux capabilities [default=no]],
401 [use_capabilities="$withval"],[use_capabilities=no])
402 AC_MSG_RESULT($use_capabilities)
403
404 #
405 # Check whether to disable the card support
406 AC_MSG_CHECKING([whether smartcard support is requested])
407 AC_ARG_ENABLE(card-support,
408               AC_HELP_STRING([--disable-card-support],
409                              [disable smartcard support]),
410               card_support=$enableval)
411 AC_MSG_RESULT($card_support)
412 if test "$card_support" = yes ; then
413   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
414 else
415   build_scdaemon=no
416 fi
417
418 #
419 # Allow disabling of internal CCID support.
420 # It is defined only after we confirm the library is available later
421 #
422 AC_MSG_CHECKING([whether to enable the internal CCID driver])
423 AC_ARG_ENABLE(ccid-driver,
424               AC_HELP_STRING([--disable-ccid-driver],
425                              [disable the internal CCID driver]),
426               use_ccid_driver=$enableval)
427 AC_MSG_RESULT($use_ccid_driver)
428
429 AC_MSG_CHECKING([whether to auto start dirmngr])
430 AC_ARG_ENABLE(dirmngr-auto-start,
431               AC_HELP_STRING([--disable-dirmngr-auto-start],
432                              [disable auto starting of the dirmngr]),
433               dirmngr_auto_start=$enableval)
434 AC_MSG_RESULT($dirmngr_auto_start)
435 if test "$dirmngr_auto_start" = yes ; then
436     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
437               [Define to enable auto starting of the dirmngr])
438 fi
439
440
441 #
442 # To avoid double inclusion of config.h which might happen at some
443 # places, we add the usual double inclusion protection at the top of
444 # config.h.
445 #
446 AH_TOP([
447 #ifndef GNUPG_CONFIG_H_INCLUDED
448 #define GNUPG_CONFIG_H_INCLUDED
449 ])
450
451 #
452 # Stuff which goes at the bottom of config.h.
453 #
454 AH_BOTTOM([
455 /* This is the major version number of GnuPG so that
456    source included files can test for this.  Note, that
457    we use 2 here even for GnuPG 1.9.x. */
458 #define GNUPG_MAJOR_VERSION 2
459
460 /* Now to separate file name parts.
461    Please note that the string version must not contain more
462    than one character because the code assumes strlen()==1 */
463 #ifdef HAVE_DOSISH_SYSTEM
464 #define DIRSEP_C '\\'
465 #define DIRSEP_S "\\"
466 #define EXTSEP_C '.'
467 #define EXTSEP_S "."
468 #define PATHSEP_C ';'
469 #define PATHSEP_S ";"
470 #define EXEEXT_S ".exe"
471 #else
472 #define DIRSEP_C '/'
473 #define DIRSEP_S "/"
474 #define EXTSEP_C '.'
475 #define EXTSEP_S "."
476 #define PATHSEP_C ':'
477 #define PATHSEP_S ":"
478 #define EXEEXT_S ""
479 #endif
480
481 /* This is the same as VERSION, but should be overridden if the
482    platform cannot handle things like dots '.' in filenames. Set
483    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
484    uses for dots and dashes. */
485 #define SAFE_VERSION VERSION
486 #define SAFE_VERSION_DOT  '.'
487 #define SAFE_VERSION_DASH '-'
488
489 /* Some global constants. */
490 #ifdef HAVE_DOSISH_SYSTEM
491 # ifdef HAVE_DRIVE_LETTERS
492 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
493 # else
494 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
495 # endif
496 #elif defined(__VMS)
497 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
498 #else
499 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
500 #endif
501 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
502 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
503
504 /* For some systems (DOS currently), we hardcode the path here.  For
505    POSIX systems the values are constructed by the Makefiles, so that
506    the values may be overridden by the make invocations; this is to
507    comply with the GNU coding standards.  Note that these values are
508    only defaults.  */
509 #ifdef HAVE_DOSISH_SYSTEM
510 # ifdef HAVE_DRIVE_LETTERS
511 #  define GNUPG_BINDIR      "c:\\gnupg"
512 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
513 #  define GNUPG_LIBDIR      "c:\\gnupg"
514 #  define GNUPG_DATADIR     "c:\\gnupg"
515 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
516 # else
517 #  define GNUPG_BINDIR      "\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "\\gnupg"
519 #  define GNUPG_LIBDIR      "\\gnupg"
520 #  define GNUPG_DATADIR     "\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "\\gnupg"
522 # endif
523 #endif
524
525 /* Derive some other constants. */
526 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
527 #define EXEC_TEMPFILE_ONLY
528 #endif
529
530
531 /* We didn't define endianness above, so get it from OS macros.  This
532    is intended for making fat binary builds on OS X. */
533 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
534 #if defined(__BIG_ENDIAN__)
535 #define BIG_ENDIAN_HOST 1
536 #elif defined(__LITTLE_ENDIAN__)
537 #define LITTLE_ENDIAN_HOST 1
538 #else
539 #error "No endianness found"
540 #endif
541 #endif
542
543
544 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
545    ldap_start_tls_s because that is the actual symbol used in the
546    library.  winldap.h redefines it to our commonly used value,
547    thus we define our usual macro here.  */
548 #ifdef HAVE_LDAP_START_TLS_SA
549 # ifndef HAVE_LDAP_START_TLS_S
550 #  define HAVE_LDAP_START_TLS_S 1
551 # endif
552 #endif
553
554 /* Provide the es_ macro for estream.  */
555 #define GPGRT_ENABLE_ES_MACROS 1
556
557 /* Tell libgcrypt not to use its own libgpg-error implementation. */
558 #define USE_LIBGPG_ERROR 1
559
560 /* Tell Libgcrypt not to include deprecated definitions.  */
561 #define GCRYPT_NO_DEPRECATED 1
562
563 /* Our HTTP code is used in estream mode.  */
564 #define HTTP_USE_ESTREAM 1
565
566 /* Under W32 we do an explicit socket initialization, thus we need to
567    avoid the on-demand initialization which would also install an atexit
568    handler.  */
569 #define HTTP_NO_WSASTARTUP
570
571 /* Under Windows we use the gettext code from libgpg-error.  */
572 #define GPG_ERR_ENABLE_GETTEXT_MACROS
573
574 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
575 #define GPG_ERR_ENABLE_ERRNO_MACROS
576
577 #endif /*GNUPG_CONFIG_H_INCLUDED*/
578 ])
579
580
581 AM_MAINTAINER_MODE
582 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
583
584 # Checks for programs.
585 AC_MSG_NOTICE([checking for programs])
586 AC_PROG_MAKE_SET
587 AM_SANITY_CHECK
588 missing_dir=`cd $ac_aux_dir && pwd`
589 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
590 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
591 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
592 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
593 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
594 AM_SILENT_RULES
595 AC_PROG_AWK
596 AC_PROG_CC
597 AC_PROG_CPP
598 AM_PROG_CC_C_O
599 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
600   AC_MSG_ERROR([[No C-89 compiler found]])
601 fi
602 AC_PROG_INSTALL
603 AC_PROG_LN_S
604 AC_PROG_RANLIB
605 AC_CHECK_TOOL(AR, ar, :)
606 AC_PATH_PROG(PERL,"perl")
607 AC_CHECK_TOOL(WINDRES, windres, :)
608 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
609 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
610 AC_ISC_POSIX
611 AC_SYS_LARGEFILE
612 GNUPG_CHECK_USTAR
613
614
615 # We need to compile and run a program on the build machine.  A
616 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
617 # the AC archive is broken for autoconf 2.57.  Given that there is no
618 # newer version of that macro, we assume that it is also broken for
619 # autoconf 2.61 and thus we use a simple but usually sufficient
620 # approach.
621 AC_MSG_CHECKING(for cc for build)
622 if test "$cross_compiling" = "yes"; then
623   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
624 else
625   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
626 fi
627 AC_MSG_RESULT($CC_FOR_BUILD)
628 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
629
630 # We need to call this macro because other pkg-config macros are
631 # not always used.
632 PKG_PROG_PKG_CONFIG
633
634
635 try_gettext=yes
636 require_iconv=yes
637 have_dosish_system=no
638 have_w32_system=no
639 have_w32ce_system=no
640 have_android_system=no
641 use_simple_gettext=no
642 use_ldapwrapper=yes
643 mmap_needed=yes
644 case "${host}" in
645     *-mingw32*)
646         # special stuff for Windoze NT
647         ac_cv_have_dev_random=no
648         AC_DEFINE(USE_ONLY_8DOT3,1,
649                   [Set this to limit filenames to the 8.3 format])
650         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
651                   [Because the Unix gettext has too much overhead on
652                    MingW32 systems and these systems lack Posix functions,
653                    we use a simplified version of gettext])
654         have_dosish_system=yes
655         have_w32_system=yes
656         require_iconv=no
657         use_ldapwrapper=no  # Fixme: Do this only for CE.
658         case "${host}" in
659           *-mingw32ce*)
660             have_w32ce_system=yes
661             ;;
662           *)
663             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
664                       [Defined if the OS supports drive letters.])
665             ;;
666         esac
667         try_gettext="no"
668         use_simple_gettext=yes
669         mmap_needed=no
670         ;;
671     i?86-emx-os2 | i?86-*-os2*emx )
672         # OS/2 with the EMX environment
673         ac_cv_have_dev_random=no
674         AC_DEFINE(HAVE_DRIVE_LETTERS)
675         have_dosish_system=yes
676         try_gettext="no"
677         ;;
678
679     i?86-*-msdosdjgpp*)
680         # DOS with the DJGPP environment
681         ac_cv_have_dev_random=no
682         AC_DEFINE(HAVE_DRIVE_LETTERS)
683         have_dosish_system=yes
684         try_gettext="no"
685         ;;
686
687     *-*-hpux*)
688         if test -z "$GCC" ; then
689             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
690         fi
691         ;;
692     *-dec-osf4*)
693         if test -z "$GCC" ; then
694             # Suppress all warnings
695             # to get rid of the unsigned/signed char mismatch warnings.
696             CFLAGS="-w $CFLAGS"
697         fi
698         ;;
699     *-dec-osf5*)
700         if test -z "$GCC" ; then
701             # Use the newer compiler `-msg_disable ptrmismatch1' to
702             # get rid of the unsigned/signed char mismatch warnings.
703             # Using this may hide other pointer mismatch warnings, but
704             # it at least lets other warning classes through
705             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
706         fi
707         ;;
708     m68k-atari-mint)
709         ;;
710     *-linux-android*)
711         have_android_system=yes
712         # Android is fully utf-8 and we do not want to use iconv to
713         # keeps things simple
714         require_iconv=no
715         ;;
716     *-apple-darwin*)
717         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
718                   Expose all libc features (__DARWIN_C_FULL).)
719         ;;
720     *)
721        ;;
722 esac
723
724 if test "$have_dosish_system" = yes; then
725    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
726              [Defined if we run on some of the PCDOS like systems
727               (DOS, Windoze. OS/2) with special properties like
728               no file modes, case insensitive file names and preferred
729               use of backslashes as directory name separators.])
730 fi
731 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
732
733 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
734
735 if test "$have_w32_system" = yes; then
736    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
737    if test "$have_w32ce_system" = yes; then
738       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
739    fi
740 fi
741 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
742 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
743
744 if test "$have_android_system" = yes; then
745    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
746 fi
747 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
748
749
750 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
751 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
752
753
754 #
755 # Checks for libraries.
756 #
757 AC_MSG_NOTICE([checking for libraries])
758
759
760 #
761 # libgpg-error is a library with error codes shared between GnuPG
762 # related projects.
763 #
764 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
765                   have_gpg_error=yes,have_gpg_error=no)
766
767
768 #
769 # Libgcrypt is our generic crypto library
770 #
771 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
772         have_libgcrypt=yes,have_libgcrypt=no)
773
774
775 #
776 # libassuan is used for IPC
777 #
778 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
779                   have_libassuan=yes,have_libassuan=no)
780 if test "$have_libassuan" = "yes"; then
781   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
782                      [version of the libassuan library])
783   show_tor_support="only .onion"
784 fi
785
786
787 #
788 # libksba is our X.509 support library
789 #
790 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
791
792
793 #
794 # libusb allows us to use the integrated CCID smartcard reader driver.
795 #
796 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
797 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
798    case "${host}" in
799      *-mingw32*)
800        LIBUSB_NAME=
801        LIBUSB_LIBS=
802        LIBUSB_CPPFLAGS=
803        ;;
804      *-*-darwin*)
805        LIBUSB_NAME=usb-1.0
806        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
807        ;;
808      *-*-freebsd*)
809        # FreeBSD has a native 1.0 compatible library by -lusb.
810        LIBUSB_NAME=usb
811        LIBUSB_LIBS=
812        ;;
813      *)
814        LIBUSB_NAME=usb-1.0
815        LIBUSB_LIBS=
816        ;;
817    esac
818 fi
819 if test x"$LIBUSB_NAME" != x ; then
820    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
821                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
822                   have_libusb=yes ])
823    AC_MSG_CHECKING([libusb include dir])
824    usb_incdir_found="no"
825    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
826      _libusb_save_cppflags=$CPPFLAGS
827      if test -n "${_incdir}"; then
828        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
829      fi
830      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
831      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
832      CPPFLAGS=${_libusb_save_cppflags}
833      if test "$usb_incdir_found" = "yes"; then
834        break
835      fi
836    done
837    if test "$usb_incdir_found" = "yes"; then
838      AC_MSG_RESULT([${usb_incdir}])
839    else
840      AC_MSG_RESULT([not found])
841      usb_incdir=""
842      have_libusb=no
843      if test "$use_ccid_driver" != yes; then
844        use_ccid_driver=no
845      fi
846      LIBUSB_LIBS=""
847    fi
848
849    if test "$have_libusb" = yes; then
850      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
851    fi
852    if test x"$usb_incdir" = x; then
853      LIBUSB_CPPFLAGS=""
854    else
855      LIBUSB_CPPFLAGS="-I${usb_incdir}"
856    fi
857 fi
858 AC_SUBST(LIBUSB_LIBS)
859 AC_SUBST(LIBUSB_CPPFLAGS)
860
861 #
862 # Check whether it is necessary to link against libdl.
863 # (For example to load libpcsclite)
864 #
865 gnupg_dlopen_save_libs="$LIBS"
866 LIBS=""
867 AC_SEARCH_LIBS(dlopen, c dl,,,)
868 DL_LIBS=$LIBS
869 AC_SUBST(DL_LIBS)
870 LIBS="$gnupg_dlopen_save_libs"
871
872
873 # Checks for g10
874
875 AC_ARG_ENABLE(sqlite,
876                 AC_HELP_STRING([--disable-sqlite],
877                                [disable the use of SQLITE]),
878               try_sqlite=$enableval, try_sqlite=yes)
879
880 if test x"$use_tofu" = xyes ; then
881   if test x"$try_sqlite" = xyes ; then
882     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
883                                  [have_sqlite=yes],
884                                  [have_sqlite=no])
885   fi
886   if test "$have_sqlite" = "yes"; then
887     :
888     AC_SUBST([SQLITE3_CFLAGS])
889     AC_SUBST([SQLITE3_LIBS])
890   else
891     use_tofu=no
892     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
893     AC_MSG_WARN([[
894 ***
895 *** Building without SQLite support - TOFU disabled
896 ***
897 *** $tmp]])
898   fi
899 fi
900
901 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
902
903 if test x"$use_tofu" = xyes ; then
904     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
905 fi
906
907
908 # Checks for g13
909
910 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
911 AC_DEFINE_UNQUOTED(ENCFS,
912         "${ENCFS}", [defines the filename of the encfs program])
913
914 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
915 AC_DEFINE_UNQUOTED(FUSERMOUNT,
916         "${FUSERMOUNT}", [defines the filename of the fusermount program])
917
918
919 # Checks for dirmngr
920
921
922 #
923 # Checks for symcryptrun:
924 #
925
926 # libutil has openpty() and login_tty().
927 AC_CHECK_LIB(util, openpty,
928               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
929                 AC_DEFINE(HAVE_LIBUTIL,1,
930                          [defined if libutil is available])
931              ])
932 AC_SUBST(LIBUTIL_LIBS)
933
934 # shred is used to clean temporary plain text files.
935 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
936 AC_DEFINE_UNQUOTED(SHRED,
937         "${SHRED}", [defines the filename of the shred program])
938
939
940 #
941 # Check whether the nPth library is available
942 #
943 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
944 if test "$have_npth" = "yes"; then
945   AC_DEFINE(HAVE_NPTH, 1,
946               [Defined if the New Portable Thread Library is available])
947   AC_DEFINE(USE_NPTH, 1,
948               [Defined if support for nPth is requested and nPth is available])
949 else
950   AC_MSG_WARN([[
951 ***
952 *** To support concurrent access for example in gpg-agent and the SCdaemon
953 *** we need the support of the New Portable Threads Library.
954 ***]])
955 fi
956
957
958 #
959 # NTBTLS is our TLS library.  If it is not available fallback to
960 # GNUTLS.
961 #
962 AC_ARG_ENABLE(ntbtls,
963               AC_HELP_STRING([--disable-ntbtls],
964                              [disable the use of NTBTLS as TLS library]),
965               try_ntbtls=$enableval, try_ntbtls=yes)
966 if test x"$try_ntbtls" = xyes ; then
967   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
968                  [have_ntbtls=yes],[have_ntbtls=no])
969 fi
970 if test "$have_ntbtls" = yes ; then
971    use_tls_library=ntbtls
972    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
973 else
974   AC_ARG_ENABLE(gnutls,
975                 AC_HELP_STRING([--disable-gnutls],
976                                [disable GNUTLS as fallback TLS library]),
977                 try_gnutls=$enableval, try_gnutls=yes)
978   if test x"$try_gnutls" = xyes ; then
979     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
980                                    [have_gnutls=yes],
981                                    [have_gnutls=no])
982   fi
983   if test "$have_gnutls" = "yes"; then
984     AC_SUBST([LIBGNUTLS_CFLAGS])
985     AC_SUBST([LIBGNUTLS_LIBS])
986     use_tls_library=gnutls
987     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
988   else
989     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
990     AC_MSG_WARN([[
991 ***
992 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
993 ***
994 *** $tmp]])
995   fi
996 fi
997
998 #
999 # Allow to set a fixed trust store file for system provided certificates.
1000 #
1001 AC_ARG_WITH([default-trust-store-file],
1002             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1003                             [Use FILE as system trust store])],
1004             default_trust_store_file="$withval",
1005             default_trust_store_file="")
1006 if test x"$default_trust_store_file" = xno;then
1007   default_trust_store_file=""
1008 fi
1009 if test x"$default_trust_store_file" != x ; then
1010   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1011     ["$default_trust_store_file"], [Use as default system trust store file])
1012 fi
1013
1014
1015 AC_MSG_NOTICE([checking for networking options])
1016
1017 #
1018 # Must check for network library requirements before doing link tests
1019 # for ldap, for example. If ldap libs are static (or dynamic and without
1020 # ELF runtime link paths), then link will fail and LDAP support won't
1021 # be detected.
1022 #
1023 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1024         [NETLIBS="-lnsl $NETLIBS"]))
1025 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1026         [NETLIBS="-lsocket $NETLIBS"]))
1027
1028
1029 #
1030 # Check standard resolver functions.
1031 #
1032 if test "$build_dirmngr" = "yes"; then
1033   _dns_save_libs=$LIBS
1034   LIBS=""
1035
1036   # Find the system resolver which can always be enabled with
1037   # the dirmngr option --standard-resolver.
1038
1039   # the double underscore thing is a glibc-ism?
1040   AC_SEARCH_LIBS(res_query,resolv bind,,
1041                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1042   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1043                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1044
1045   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1046   # and for some reason fools us into believing we don't need
1047   # -lresolv even if we do.  Since the test program checking for the
1048   # symbol does not include <resolv.h>, we need to check for the
1049   # renamed symbol explicitly.
1050   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1051       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1052           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1053
1054   if test x"$have_resolver" != xno ; then
1055
1056       # Make sure that the BIND 4 resolver interface is workable before
1057       # enabling any code that calls it.  At some point I'll rewrite the
1058       # code to use the BIND 8 resolver API.
1059       # We might also want to use libdns instead.
1060
1061     AC_MSG_CHECKING([whether the resolver is usable])
1062     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1063 #include <netinet/in.h>
1064 #include <arpa/nameser.h>
1065 #include <resolv.h>]],
1066 [[unsigned char answer[PACKETSZ];
1067   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1068   dn_skipname(0,0);
1069   dn_expand(0,0,0,0,0);
1070 ]])],have_resolver=yes,have_resolver=no)
1071     AC_MSG_RESULT($have_resolver)
1072
1073     # This is Apple-specific and somewhat bizarre as they changed the
1074     # define in bind 8 for some reason.
1075
1076     if test x"$have_resolver" != xyes ; then
1077       AC_MSG_CHECKING(
1078            [whether I can make the resolver usable with BIND_8_COMPAT])
1079       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1080 #include <sys/types.h>
1081 #include <netinet/in.h>
1082 #include <arpa/nameser.h>
1083 #include <resolv.h>]],
1084 [[unsigned char answer[PACKETSZ];
1085   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1086   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1087 ]])],[have_resolver=yes ; need_compat=yes])
1088       AC_MSG_RESULT($have_resolver)
1089     fi
1090   fi
1091
1092   if test x"$have_resolver" = xyes ; then
1093     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1094     DNSLIBS="$DNSLIBS $LIBS"
1095     if test x"$need_compat" = xyes ; then
1096       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1097     fi
1098     if test "$use_libdns" = yes; then
1099      show_tor_support=yes
1100     fi
1101   elif test "$use_libdns" = yes; then
1102     show_tor_support=yes
1103   else
1104     AC_MSG_WARN([[
1105 ***
1106 *** The system's DNS resolver is not usable.
1107 *** Dirmngr functionality is limited.
1108 ***]])
1109     show_tor_support="${show_tor_support} (no system resolver)"
1110   fi
1111
1112   if test "$have_w32_system" = yes; then
1113     if test "$use_libdns" = yes; then
1114       DNSLIBS="$DNSLIBS -liphlpapi"
1115     fi
1116   fi
1117
1118   LIBS=$_dns_save_libs
1119 fi
1120
1121 AC_SUBST(DNSLIBS)
1122
1123
1124 #
1125 # Check for LDAP
1126 #
1127 # Note that running the check changes the variable
1128 # gnupg_have_ldap from "n/a" to "no" or "yes".
1129
1130 AC_ARG_ENABLE(ldap,
1131     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1132     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1133
1134 if test "$gnupg_have_ldap" != "no" ; then
1135   if test "$build_dirmngr" = "yes" ; then
1136      GNUPG_CHECK_LDAP($NETLIBS)
1137      AC_CHECK_LIB(lber, ber_free,
1138                   [ LBER_LIBS="$LBER_LIBS -llber"
1139                     AC_DEFINE(HAVE_LBER,1,
1140                              [defined if liblber is available])
1141                     have_lber=yes
1142                  ])
1143   fi
1144 fi
1145 AC_SUBST(LBER_LIBS)
1146 if test "$gnupg_have_ldap" = "no"; then
1147     AC_MSG_WARN([[
1148 ***
1149 *** Building without LDAP support.
1150 *** No CRL access or X.509 certificate search available.
1151 ***]])
1152 fi
1153
1154 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1155 if test "$gnupg_have_ldap" = yes ; then
1156   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1157 else
1158  use_ldapwrapper=no
1159 fi
1160
1161 if test "$use_ldapwrapper" = yes; then
1162    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1163 fi
1164 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1165
1166
1167
1168
1169 #
1170 # Check for sendmail
1171 #
1172 # This isn't necessarily sendmail itself, but anything that gives a
1173 # sendmail-ish interface to the outside world.  That includes Exim,
1174 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1175 AC_ARG_WITH(mailprog,
1176       AC_HELP_STRING([--with-mailprog=NAME],
1177                      [use "NAME -t" for mail transport]),
1178              ,with_mailprog=yes)
1179 if test x"$with_mailprog" = xyes ; then
1180     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1181 elif test x"$with_mailprog" != xno ; then
1182     AC_MSG_CHECKING([for a mail transport program])
1183     AC_SUBST(SENDMAIL,$with_mailprog)
1184     AC_MSG_RESULT($with_mailprog)
1185 fi
1186
1187
1188 #
1189 # Construct a printable name of the OS
1190 #
1191 case "${host}" in
1192     *-mingw32ce*)
1193         PRINTABLE_OS_NAME="W32CE"
1194         ;;
1195     *-mingw32*)
1196         PRINTABLE_OS_NAME="MingW32"
1197         ;;
1198     *-*-cygwin*)
1199         PRINTABLE_OS_NAME="Cygwin"
1200         ;;
1201     i?86-emx-os2 | i?86-*-os2*emx )
1202         PRINTABLE_OS_NAME="OS/2"
1203         ;;
1204     i?86-*-msdosdjgpp*)
1205         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1206         try_dynload=no
1207         ;;
1208     *-linux*)
1209         PRINTABLE_OS_NAME="GNU/Linux"
1210         ;;
1211     *)
1212         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1213         ;;
1214 esac
1215 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1216                    [A human readable text with the name of the OS])
1217
1218
1219 #
1220 # Checking for iconv
1221 #
1222 if test "$require_iconv" = yes; then
1223   AM_ICONV
1224 else
1225   LIBICONV=
1226   LTLIBICONV=
1227   AC_SUBST(LIBICONV)
1228   AC_SUBST(LTLIBICONV)
1229 fi
1230
1231
1232 #
1233 # Check for gettext
1234 #
1235 # This is "GNU gnupg" - The project-id script from gettext
1236 #                       needs this string
1237 #
1238 AC_MSG_NOTICE([checking for gettext])
1239 AM_PO_SUBDIRS
1240 AM_GNU_GETTEXT_VERSION([0.17])
1241 if test "$try_gettext" = yes; then
1242   AM_GNU_GETTEXT([external],[need-ngettext])
1243
1244   # gettext requires some extra checks.  These really should be part of
1245   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1246   # function checks to here.
1247
1248   AC_CHECK_FUNCS(strchr)
1249 else
1250   USE_NLS=no
1251   USE_INCLUDED_LIBINTL=no
1252   BUILD_INCLUDED_LIBINTL=no
1253   POSUB=po
1254   AC_SUBST(USE_NLS)
1255   AC_SUBST(USE_INCLUDED_LIBINTL)
1256   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1257   AC_SUBST(POSUB)
1258 fi
1259
1260 # We use HAVE_LANGINFO_CODESET in a couple of places.
1261 AM_LANGINFO_CODESET
1262
1263 # Checks required for our use of locales
1264 gt_LC_MESSAGES
1265
1266
1267 #
1268 # SELinux support
1269 #
1270 if test "$selinux_support" = yes ; then
1271   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1272 fi
1273
1274
1275 #
1276 # Checks for header files.
1277 #
1278 AC_MSG_NOTICE([checking for header files])
1279 AC_HEADER_STDC
1280 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1281                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1282                   stdint.h signal.h util.h libutil.h termios.h \
1283                   ucred.h sys/sysmacros.h sys/mkdev.h])
1284
1285 AC_HEADER_TIME
1286
1287
1288 #
1289 # Checks for typedefs, structures, and compiler characteristics.
1290 #
1291 AC_MSG_NOTICE([checking for system characteristics])
1292 AC_C_CONST
1293 AC_C_INLINE
1294 AC_C_VOLATILE
1295 AC_TYPE_SIZE_T
1296 AC_TYPE_MODE_T
1297 AC_TYPE_SIGNAL
1298 AC_DECL_SYS_SIGLIST
1299
1300 gl_HEADER_SYS_SOCKET
1301 gl_TYPE_SOCKLEN_T
1302
1303 AC_SEARCH_LIBS([inet_addr], [nsl])
1304
1305 AC_ARG_ENABLE(endian-check,
1306               AC_HELP_STRING([--disable-endian-check],
1307               [disable the endian check and trust the OS provided macros]),
1308               endiancheck=$enableval,endiancheck=yes)
1309
1310 if test x"$endiancheck" = xyes ; then
1311   GNUPG_CHECK_ENDIAN
1312 fi
1313
1314 # fixme: we should get rid of the byte type
1315 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1316 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1317 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1318 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1319 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1320
1321 AC_CHECK_SIZEOF(unsigned short)
1322 AC_CHECK_SIZEOF(unsigned int)
1323 AC_CHECK_SIZEOF(unsigned long)
1324 AC_CHECK_SIZEOF(unsigned long long)
1325 AC_HEADER_TIME
1326 AC_CHECK_SIZEOF(time_t,,[[
1327 #include <stdio.h>
1328 #if TIME_WITH_SYS_TIME
1329 # include <sys/time.h>
1330 # include <time.h>
1331 #else
1332 # if HAVE_SYS_TIME_H
1333 #  include <sys/time.h>
1334 # else
1335 #  include <time.h>
1336 # endif
1337 #endif
1338 ]])
1339 GNUPG_TIME_T_UNSIGNED
1340
1341
1342 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1343    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1344    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1345     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1346 fi
1347
1348
1349 #
1350 # Checks for library functions.
1351 #
1352 AC_MSG_NOTICE([checking for library functions])
1353 AC_CHECK_DECLS(getpagesize)
1354 AC_FUNC_FSEEKO
1355 AC_FUNC_VPRINTF
1356 AC_FUNC_FORK
1357 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1358 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1359 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1360 AC_CHECK_FUNCS([canonicalize_file_name])
1361 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1362 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1363 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1364 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1365 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1366                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1367                 flockfile funlockfile getpwnam getpwuid \
1368                 getenv inet_pton strpbrk])
1369
1370 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1371 # Given that we use nanosleep only as an optimization over a select
1372 # based wait function we want it only if it is available in libc.
1373 _save_libs="$LIBS"
1374 AC_SEARCH_LIBS([nanosleep], [],
1375                [AC_DEFINE(HAVE_NANOSLEEP,1,
1376                 [Define to 1 if you have the `nanosleep' function in libc.])])
1377 LIBS="$_save_libs"
1378
1379
1380 # See whether libc supports the Linux inotify interface
1381 case "${host}" in
1382     *-*-linux*)
1383         AC_CHECK_FUNCS([inotify_init])
1384         ;;
1385 esac
1386
1387
1388 if test "$have_android_system" = yes; then
1389    # On Android ttyname is a stub but prints an error message.
1390    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1391              [Defined if ttyname does not work properly])
1392 fi
1393
1394 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1395
1396 # Dirmngr requires mmap on Unix systems.
1397 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1398   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1399 fi
1400
1401
1402 #
1403 # Check for the getsockopt SO_PEERCRED, etc.
1404 #
1405 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1406 #include <sys/socket.h> ])
1407
1408 # (Open)Solaris
1409 AC_CHECK_FUNCS([getpeerucred])
1410
1411
1412 #
1413 # W32 specific test
1414 #
1415 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1416
1417 #
1418 # Sanity check regex.  Tests adapted from mutt.
1419 #
1420 AC_MSG_CHECKING([whether regular expression support is requested])
1421 AC_ARG_ENABLE(regex,
1422   AC_HELP_STRING([--disable-regex],
1423     [do not handle regular expressions in trust signatures]),
1424   use_regex=$enableval, use_regex=yes)
1425 AC_MSG_RESULT($use_regex)
1426
1427 if test "$use_regex" = yes ; then
1428   _cppflags="${CPPFLAGS}"
1429   _ldflags="${LDFLAGS}"
1430   AC_ARG_WITH(regex,
1431      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1432       [
1433       if test -d "$withval" ; then
1434         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1435         LDFLAGS="${LDFLAGS} -L$withval/lib"
1436       fi
1437       ],withval="")
1438
1439   # Does the system have regex functions at all?
1440   AC_SEARCH_LIBS([regcomp], [regex])
1441   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1442
1443   if test $gnupg_cv_have_regex = no; then
1444     use_regex=no
1445   else
1446     if test x"$cross_compiling" = xyes; then
1447       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1448     else
1449       AC_CACHE_CHECK([whether your system's regexp library is broken],
1450        [gnupg_cv_regex_broken],
1451        AC_TRY_RUN([
1452 #include <unistd.h>
1453 #include <regex.h>
1454 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1455        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1456
1457       if test $gnupg_cv_regex_broken = yes; then
1458         AC_MSG_WARN([your regex is broken - disabling regex use])
1459         use_regex=no
1460       fi
1461     fi
1462   fi
1463   CPPFLAGS="${_cppflags}"
1464   LDFLAGS="${_ldflags}"
1465 fi
1466
1467 if test "$use_regex" != yes ; then
1468   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1469 fi
1470 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1471
1472
1473
1474 #
1475 # Do we have zlib? Must do it here because Solaris failed
1476 # when compiling a conftest (due to the "-lz" from LIBS).
1477 # Note that we combine zlib and bzlib2 in ZLIBS.
1478 #
1479 if test "$use_zip" = yes ; then
1480   _cppflags="${CPPFLAGS}"
1481   _ldflags="${LDFLAGS}"
1482   AC_ARG_WITH(zlib,
1483     [  --with-zlib=DIR         use libz in DIR],[
1484       if test -d "$withval"; then
1485         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1486         LDFLAGS="${LDFLAGS} -L$withval/lib"
1487       fi
1488     ])
1489
1490   AC_CHECK_HEADER(zlib.h,
1491      AC_CHECK_LIB(z, deflateInit2_,
1492        [
1493        ZLIBS="-lz"
1494        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1495        ],
1496        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1497        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1498 fi
1499
1500
1501 #
1502 # Check whether we can support bzip2
1503 #
1504 if test "$use_bzip2" = yes ; then
1505   _cppflags="${CPPFLAGS}"
1506   _ldflags="${LDFLAGS}"
1507   AC_ARG_WITH(bzip2,
1508      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1509       [
1510       if test -d "$withval" ; then
1511         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1512         LDFLAGS="${LDFLAGS} -L$withval/lib"
1513       fi
1514       ],withval="")
1515
1516   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1517   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1518   # woefully out of date.
1519   if test "$withval" != no ; then
1520      AC_CHECK_HEADER(bzlib.h,
1521         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1522           [
1523           have_bz2=yes
1524           ZLIBS="$ZLIBS -lbz2"
1525           AC_DEFINE(HAVE_BZIP2,1,
1526                   [Defined if the bz2 compression library is available])
1527           ],
1528           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1529           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1530   fi
1531 fi
1532 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1533 AC_SUBST(ZLIBS)
1534
1535
1536 # Check for readline support
1537 GNUPG_CHECK_READLINE
1538
1539
1540 if test "$development_version" = yes; then
1541     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1542             [Defined if this is not a regular release])
1543 fi
1544
1545 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1546
1547 GNUPG_CHECK_GNUMAKE
1548
1549 # Add some extra libs here so that previous tests don't fail for
1550 # mysterious reasons - the final link step should bail out.
1551 # W32SOCKLIBS is also defined so that if can be used for tools not
1552 # requiring any network stuff but linking to code in libcommon which
1553 # tracks in winsock stuff (e.g. init_common_subsystems).
1554 if test "$have_w32_system" = yes; then
1555    if test "$have_w32ce_system" = yes; then
1556      W32SOCKLIBS="-lws2"
1557    else
1558      W32SOCKLIBS="-lws2_32"
1559    fi
1560    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1561 fi
1562
1563 AC_SUBST(NETLIBS)
1564 AC_SUBST(W32SOCKLIBS)
1565
1566 #
1567 # Setup gcc specific options
1568 #
1569 USE_C99_CFLAGS=
1570 AC_MSG_NOTICE([checking for cc features])
1571 if test "$GCC" = yes; then
1572     mycflags=
1573     mycflags_save=$CFLAGS
1574
1575     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1576     # options.  This is the case for gcc >= 4.6
1577     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1578     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1579 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1580 #kickerror
1581 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1582     AC_MSG_RESULT($_gcc_silent_wno)
1583
1584     # Note that it is okay to use CFLAGS here because these are just
1585     # warning options and the user should have a chance of overriding
1586     # them.
1587     if test "$USE_MAINTAINER_MODE" = "yes"; then
1588         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1589         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1590         if test x"$_gcc_silent_wno" = xyes ; then
1591           _gcc_wopt=yes
1592         else
1593           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1594           CFLAGS="-Wno-missing-field-initializers"
1595           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1596                             [_gcc_wopt=yes],[_gcc_wopt=no])
1597           AC_MSG_RESULT($_gcc_wopt)
1598         fi
1599         if test x"$_gcc_wopt" = xyes ; then
1600           mycflags="$mycflags -W -Wno-sign-compare"
1601           mycflags="$mycflags -Wno-missing-field-initializers"
1602         fi
1603
1604         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1605         CFLAGS="-Wdeclaration-after-statement"
1606         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1607         AC_MSG_RESULT($_gcc_wopt)
1608         if test x"$_gcc_wopt" = xyes ; then
1609           mycflags="$mycflags -Wdeclaration-after-statement"
1610         fi
1611
1612         AC_MSG_CHECKING([if gcc supports -Wlogical-op and -Wvla])
1613         CFLAGS="-Wlogical-op -Wvla"
1614         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1615         AC_MSG_RESULT($_gcc_wopt)
1616         if test x"$_gcc_wopt" = xyes ; then
1617           mycflags="$mycflags -Wlogical-op -Wvla"
1618         fi
1619
1620     else
1621         mycflags="$mycflags -Wall"
1622     fi
1623
1624     if test x"$_gcc_silent_wno" = xyes ; then
1625       _gcc_psign=yes
1626     else
1627       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1628       CFLAGS="-Wno-pointer-sign"
1629       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1630                         [_gcc_psign=yes],[_gcc_psign=no])
1631       AC_MSG_RESULT($_gcc_psign)
1632     fi
1633     if test x"$_gcc_psign" = xyes ; then
1634        mycflags="$mycflags -Wno-pointer-sign"
1635     fi
1636
1637     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1638     CFLAGS="-Wpointer-arith"
1639     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1640     AC_MSG_RESULT($_gcc_psign)
1641     if test x"$_gcc_psign" = xyes ; then
1642        mycflags="$mycflags -Wpointer-arith"
1643     fi
1644
1645     CFLAGS="$mycflags $mycflags_save"
1646     if test "$use_libdns" = yes; then
1647        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1648        USE_C99_CFLAGS="-std=gnu99"
1649     fi
1650 fi
1651
1652 AC_SUBST(USE_C99_CFLAGS)
1653
1654
1655 #
1656 # This is handy for debugging so the compiler doesn't rearrange
1657 # things and eliminate variables.
1658 #
1659 AC_ARG_ENABLE(optimization,
1660    AC_HELP_STRING([--disable-optimization],
1661                   [disable compiler optimization]),
1662                   [if test $enableval = no ; then
1663                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1664                    fi])
1665
1666 #
1667 # We do not want support for the GNUPG_BUILDDIR environment variable
1668 # in a released version.  However, our regression tests suite requires
1669 # this and thus we build with support for it during "make distcheck".
1670 # This configure option implements this along with the top Makefile's
1671 # AM_DISTCHECK_CONFIGURE_FLAGS.
1672 #
1673 gnupg_builddir_envvar=no
1674 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1675               gnupg_builddir_envvar=$enableval)
1676 if test x"$gnupg_builddir_envvar" = x"yes"; then
1677    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1678       [This is only used with "make distcheck"])
1679 fi
1680
1681 #
1682 # Add user CFLAGS.
1683 #
1684 CFLAGS="$CFLAGS $CFLAGS_orig"
1685
1686 #
1687 # Decide what to build
1688 #
1689
1690 build_scdaemon_extra=""
1691 if test "$build_scdaemon" = "yes"; then
1692   if test $have_libusb = no; then
1693      build_scdaemon_extra="without internal CCID driver"
1694   fi
1695   if test -n "$build_scdaemon_extra"; then
1696      build_scdaemon_extra="(${build_scdaemon_extra})"
1697   fi
1698 fi
1699
1700
1701 #
1702 # Set variables for use by automake makefiles.
1703 #
1704 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1705 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1706 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1707 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1708 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1709 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1710 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1711 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1712 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1713 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1714
1715 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1716 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1717 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1718
1719 #
1720 # Set some defines for use gpgconf.
1721 #
1722 if test "$build_gpg" = yes ; then
1723     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1724 fi
1725 if test "$build_gpgsm" = yes ; then
1726     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1727 fi
1728 if test "$build_agent" = yes ; then
1729     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1730 fi
1731 if test "$build_scdaemon" = yes ; then
1732     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1733 fi
1734 if test "$build_dirmngr" = yes ; then
1735     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1736 fi
1737 if test "$build_g13" = yes ; then
1738     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1739 fi
1740
1741
1742 #
1743 # Define Name strings
1744 #
1745 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1746
1747 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1748 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1749
1750 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1751 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1752
1753 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1754 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1755                                         [The displayed name of gpg-agent])
1756
1757 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1758 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1759                                        [The displayed name of scdaemon])
1760
1761 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1762 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1763                                       [The displayed name of dirmngr])
1764
1765 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1766 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1767
1768 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1769 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1770                                       [The displayed name of gpgconf])
1771
1772 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1773
1774 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1775                    [The name of the agent socket])
1776 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1777                    [The name of the agent socket for remote access])
1778 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1779                    [The name of the agent socket for browsers])
1780 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1781                    [The name of the agent socket for ssh])
1782 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1783                    [The name of the dirmngr info envvar])
1784 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1785                    [The name of the SCdaemon socket])
1786 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1787                    [The name of the dirmngr socket])
1788 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1789                    "hkps://hkps.pool.sks-keyservers.net",
1790       [The default keyserver for dirmngr to use, if none is explicitly given])
1791
1792 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1793
1794 if test "$have_w32_system" = yes; then
1795   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1796                      [The directory part of the W32 registry keys])
1797 fi
1798
1799
1800 #
1801 # Provide information about the build.
1802 #
1803 BUILD_REVISION="mym4_revision"
1804 AC_SUBST(BUILD_REVISION)
1805 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1806                    [GIT commit id revision used to build this package])
1807
1808 changequote(,)dnl
1809 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1810 changequote([,])dnl
1811 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1812 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1813 AC_SUBST(BUILD_VERSION)
1814 AC_SUBST(BUILD_FILEVERSION)
1815
1816 AC_ARG_ENABLE([build-timestamp],
1817   AC_HELP_STRING([--enable-build-timestamp],
1818                  [set an explicit build timestamp for reproducibility.
1819                   (default is the current time in ISO-8601 format)]),
1820      [if test "$enableval" = "yes"; then
1821         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1822       else
1823         BUILD_TIMESTAMP="$enableval"
1824       fi
1825       BUILD_HOSTNAME="$ac_hostname"],
1826      [BUILD_TIMESTAMP="<none>"
1827       BUILD_HOSTNAME="<anon>"])
1828 AC_SUBST(BUILD_TIMESTAMP)
1829 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1830                    [The time this package was configured for a build])
1831 AC_SUBST(BUILD_HOSTNAME)
1832
1833
1834 #
1835 # Print errors here so that they are visible all
1836 # together and the user can acquire them all together.
1837 #
1838 die=no
1839 if test "$have_gpg_error" = "no"; then
1840    die=yes
1841    AC_MSG_NOTICE([[
1842 ***
1843 *** You need libgpg-error to build this program.
1844 **  This library is for example available at
1845 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1846 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1847 ***]])
1848 fi
1849 if test "$have_libgcrypt" = "no"; then
1850    die=yes
1851    AC_MSG_NOTICE([[
1852 ***
1853 *** You need libgcrypt to build this program.
1854 **  This library is for example available at
1855 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1856 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1857 ***]])
1858 fi
1859 if test "$have_libassuan" = "no"; then
1860    die=yes
1861    AC_MSG_NOTICE([[
1862 ***
1863 *** You need libassuan to build this program.
1864 *** This library is for example available at
1865 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1866 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1867 ***]])
1868 fi
1869 if test "$have_ksba" = "no"; then
1870     die=yes
1871     AC_MSG_NOTICE([[
1872 ***
1873 *** You need libksba to build this program.
1874 *** This library is for example available at
1875 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1876 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1877 ***]])
1878 fi
1879 if test "$gnupg_have_ldap" = yes; then
1880   if test "$have_w32ce_system" = yes; then
1881     AC_MSG_NOTICE([[
1882 *** Note that CeGCC might be broken, a package fixing this is:
1883 ***    http://files.kolab.org/local/windows-ce/
1884 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1885 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1886 ***]])
1887    fi
1888 fi
1889 if test "$have_npth" = "no"; then
1890     die=yes
1891     AC_MSG_NOTICE([[
1892 ***
1893 *** It is now required to build with support for the
1894 *** New Portable Threads Library (nPth). Please install this
1895 *** library first.  The library is for example available at
1896 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1897 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1898 ***]])
1899 fi
1900
1901 if test "$require_iconv" = yes; then
1902   if test "$am_func_iconv" != yes; then
1903     die=yes
1904     AC_MSG_NOTICE([[
1905 ***
1906 *** The system does not provide a working iconv function.  Please
1907 *** install a suitable library; for example GNU Libiconv which is
1908 *** available at:
1909 ***   http://ftp.gnu.org/gnu/libiconv/
1910 ***]])
1911   fi
1912 fi
1913
1914 if test "$use_ccid_driver" = yes; then
1915   if test "$have_libusb" != yes; then
1916     die=yes
1917     AC_MSG_NOTICE([[
1918 ***
1919 *** You need libusb to build the internal ccid driver.  Please
1920 *** install a libusb suitable for your system.
1921 ***]])
1922   fi
1923 fi
1924
1925 if test "$die" = "yes"; then
1926     AC_MSG_ERROR([[
1927 ***
1928 *** Required libraries not found. Please consult the above messages
1929 *** and install them before running configure again.
1930 ***]])
1931 fi
1932
1933
1934
1935 AC_CONFIG_FILES([ m4/Makefile
1936 Makefile
1937 po/Makefile.in
1938 common/Makefile
1939 common/w32info-rc.h
1940 kbx/Makefile
1941 g10/Makefile
1942 sm/Makefile
1943 agent/Makefile
1944 scd/Makefile
1945 g13/Makefile
1946 dirmngr/Makefile
1947 tools/gpg-zip
1948 tools/Makefile
1949 doc/Makefile
1950 tests/Makefile
1951 tests/gpgscm/Makefile
1952 tests/openpgp/Makefile
1953 tests/migrations/Makefile
1954 tests/gpgsm/Makefile
1955 tests/gpgme/Makefile
1956 tests/pkits/Makefile
1957 g10/gpg.w32-manifest
1958 ])
1959
1960
1961 AC_OUTPUT
1962
1963
1964 echo "
1965         GnuPG v${VERSION} has been configured as follows:
1966
1967         Revision:  mym4_revision  (mym4_revision_dec)
1968         Platform:  $PRINTABLE_OS_NAME ($host)
1969
1970         OpenPGP:   $build_gpg
1971         S/MIME:    $build_gpgsm
1972         Agent:     $build_agent
1973         Smartcard: $build_scdaemon $build_scdaemon_extra
1974         G13:       $build_g13
1975         Dirmngr:   $build_dirmngr
1976         Gpgtar:    $build_gpgtar
1977         WKS tools: $build_wks_tools
1978
1979         Protect tool:      $show_gnupg_protect_tool_pgm
1980         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1981         Default agent:     $show_gnupg_agent_pgm
1982         Default pinentry:  $show_gnupg_pinentry_pgm
1983         Default scdaemon:  $show_gnupg_scdaemon_pgm
1984         Default dirmngr:   $show_gnupg_dirmngr_pgm
1985
1986         Dirmngr auto start:  $dirmngr_auto_start
1987         Readline support:    $gnupg_cv_have_readline
1988         LDAP support:        $gnupg_have_ldap
1989         TLS support:         $use_tls_library
1990         TOFU support:        $use_tofu
1991         Tor support:         $show_tor_support
1992 "
1993 if test x"$use_regex" != xyes ; then
1994 echo "
1995         Warning: No regular expression support available.
1996                  OpenPGP trust signatures won't work.
1997                  gpg-check-pattern will not be built.
1998 "
1999 fi
2000 if test "x${gpg_config_script_warn}" != x; then
2001 cat <<G10EOF
2002         Warning: Mismatches between the target platform and the
2003                  to be used libraries have been detected for:
2004                   ${gpg_config_script_warn}
2005                  Please check above for more warning messages.
2006
2007 G10EOF
2008 fi