po: Update de.po.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2011 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 m4_define([my_full_version], [my_version[]m4_if(my_issvn,[yes],
35           [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])])
36
37 AC_INIT([gnupg],[my_full_version], [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.10
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.5.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.1.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.2.0
53
54 NEED_NPTH_API=1
55 NEED_NPTH_VERSION=0.0
56
57
58 PACKAGE=$PACKAGE_NAME
59 PACKAGE_GT=${PACKAGE_NAME}2
60 VERSION=$PACKAGE_VERSION
61
62 AC_CONFIG_AUX_DIR(scripts)
63 AC_CONFIG_SRCDIR(sm/gpgsm.c)
64 AM_CONFIG_HEADER(config.h)
65 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
66 AC_CANONICAL_HOST
67 AB_INIT
68
69 AC_GNU_SOURCE
70
71 # Some status variables.
72 have_gpg_error=no
73 have_libgcrypt=no
74 have_libassuan=no
75 have_ksba=no
76 have_npth=no
77 have_libusb=no
78 have_adns=no
79
80 use_zip=yes
81 use_bzip2=yes
82 use_exec=yes
83 disable_keyserver_path=no
84 use_ccid_driver=yes
85 use_standard_socket=yes
86 dirmngr_auto_start=no
87
88 try_ks_ldap=no
89
90 GNUPG_BUILD_PROGRAM(gpg, yes)
91 GNUPG_BUILD_PROGRAM(gpgsm, yes)
92 GNUPG_BUILD_PROGRAM(agent, yes)
93 GNUPG_BUILD_PROGRAM(scdaemon, yes)
94 GNUPG_BUILD_PROGRAM(g13, yes)
95 GNUPG_BUILD_PROGRAM(dirmngr, yes)
96 GNUPG_BUILD_PROGRAM(tools, yes)
97 GNUPG_BUILD_PROGRAM(doc, yes)
98 GNUPG_BUILD_PROGRAM(symcryptrun, no)
99 GNUPG_BUILD_PROGRAM(gpgtar, no)
100
101 AC_SUBST(PACKAGE)
102 AC_SUBST(PACKAGE_GT)
103 AC_SUBST(VERSION)
104 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
105 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
106                                 [Name of this package for gettext])
107 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
108 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
109                                         [Bug report address])
110 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
111                                        [Required version of Libgcrypt])
112 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
113                                        [Required version of Libksba])
114
115
116
117 # The default is to use the modules from this package and the few
118 # other packages in a standard place; i.e where this package gets
119 # installed.  With these options it is possible to override these
120 # ${prefix} depended values with fixed paths, which can't be replaced
121 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
122 AC_ARG_WITH(agent-pgm,
123     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
124           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
125 AC_SUBST(GNUPG_AGENT_PGM)
126 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
127 show_gnupg_agent_pgm="(default)"
128 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
129
130 AC_ARG_WITH(pinentry-pgm,
131     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
132           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
133 AC_SUBST(GNUPG_PINENTRY_PGM)
134 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
135 show_gnupg_pinentry_pgm="(default)"
136 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
137
138
139 AC_ARG_WITH(scdaemon-pgm,
140     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
141           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
142 AC_SUBST(GNUPG_SCDAEMON_PGM)
143 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
144 show_gnupg_scdaemon_pgm="(default)"
145 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
146
147
148 AC_ARG_WITH(dirmngr-pgm,
149     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
150           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
151 AC_SUBST(GNUPG_DIRMNGR_PGM)
152 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
153 show_gnupg_dirmngr_pgm="(default)"
154 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
155
156 AC_ARG_WITH(protect-tool-pgm,
157     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
158           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
159 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
160 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
161 show_gnupg_protect_tool_pgm="(default)"
162 test -n "$GNUPG_PROTECT_TOOL_PGM" \
163       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
164
165 AC_ARG_WITH(dirmngr-ldap-pgm,
166     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
167           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
168 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
169 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
170 show_gnupg_dirmngr_ldap_pgm="(default)"
171 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
172       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
173
174 #
175 # On some platforms gpg2 is usually installed as gpg without using a
176 # symlink.  For correct operation of gpgconf it needs to know the
177 # installed name of gpg.  This option sets "gpg2"'s installed name to
178 # just "gpg".  Note that it might be required to rename gpg2 to gpg
179 # manually after the build process.
180 #
181 AC_ARG_ENABLE(gpg2-is-gpg,
182     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
183     gpg2_is_gpg=$enableval)
184 if test "$gpg2_is_gpg" = "yes"; then
185    name_of_installed_gpg=gpg
186 else
187    name_of_installed_gpg=gpg2
188 fi
189 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
190                    [The name of the installed GPG tool])
191
192
193 # Some folks want to use only the agent from this packet.  Make it
194 # easier for them by providing the configure option
195 # --enable-only-agent.
196 AC_ARG_ENABLE(agent-only,
197     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
198     build_agent_only=$enableval)
199
200 # SELinux support includes tracking of sensitive files to avoid
201 # leaking their contents through processing these files by gpg itself
202 AC_MSG_CHECKING([whether SELinux support is requested])
203 AC_ARG_ENABLE(selinux-support,
204               AC_HELP_STRING([--enable-selinux-support],
205                              [enable SELinux support]),
206               selinux_support=$enableval, selinux_support=no)
207 AC_MSG_RESULT($selinux_support)
208
209 # Allow disabling of zip support.
210 # This is in general not a good idea because according to rfc4880 OpenPGP
211 # implementations SHOULD support ZLIB.
212 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
213 AC_ARG_ENABLE(zip,
214    AC_HELP_STRING([--disable-zip],
215                   [disable the ZIP and ZLIB compression algorithm]),
216    use_zip=$enableval)
217 AC_MSG_RESULT($use_zip)
218
219 # Allow disabling of bzib2 support.
220 # It is defined only after we confirm the library is available later
221 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
222 AC_ARG_ENABLE(bzip2,
223    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
224    use_bzip2=$enableval)
225 AC_MSG_RESULT($use_bzip2)
226
227 # Configure option to allow or disallow execution of external
228 # programs, like a photo viewer.
229 AC_MSG_CHECKING([whether to enable external program execution])
230 AC_ARG_ENABLE(exec,
231     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
232     use_exec=$enableval)
233 AC_MSG_RESULT($use_exec)
234 if test "$use_exec" = no ; then
235     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
236 fi
237
238 if test "$use_exec" = yes ; then
239   AC_MSG_CHECKING([whether to enable photo ID viewing])
240   AC_ARG_ENABLE(photo-viewers,
241       [  --disable-photo-viewers disable photo ID viewers],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
244       fi],enableval=yes)
245   gnupg_cv_enable_photo_viewers=$enableval
246   AC_MSG_RESULT($enableval)
247
248   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
249     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
250     AC_ARG_WITH(photo-viewer,
251         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
252         [if test "$withval" = yes ; then
253            withval=no
254         elif test "$withval" != no ; then
255            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
256                             [if set, restrict photo-viewer to this])
257         fi],withval=no)
258     AC_MSG_RESULT($withval)
259   fi
260
261   AC_MSG_CHECKING([whether to enable external keyserver helpers])
262   AC_ARG_ENABLE(keyserver-helpers,
263       [  --disable-keyserver-helpers  disable all external keyserver support],
264       [if test "$enableval" = no ; then
265          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
266                   [define to disable keyserver helpers])
267       fi],enableval=yes)
268   gnupg_cv_enable_keyserver_helpers=$enableval
269   AC_MSG_RESULT($enableval)
270
271   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
272     # LDAP is defined only after we confirm the library is available later
273     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
274     AC_ARG_ENABLE(ldap,
275       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
276       try_ks_ldap=$enableval, try_ks_ldap=yes)
277     AC_MSG_RESULT($try_ks_ldap)
278
279     AC_MSG_CHECKING([whether HKP keyserver support is requested])
280     AC_ARG_ENABLE(hkp,
281       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
282       try_hkp=$enableval, try_hkp=yes)
283     AC_MSG_RESULT($try_hkp)
284
285     AC_MSG_CHECKING([whether finger key fetching support is requested])
286     AC_ARG_ENABLE(finger,
287       AC_HELP_STRING([--disable-finger],
288         [disable finger key fetching interface only]),
289       try_finger=$enableval, try_finger=yes)
290     AC_MSG_RESULT($try_finger)
291
292     AC_MSG_CHECKING([whether generic object key fetching support is requested])
293     AC_ARG_ENABLE(generic,
294       AC_HELP_STRING([--disable-generic],
295         [disable generic object key fetching interface only]),
296       try_generic=$enableval, try_generic=yes)
297     AC_MSG_RESULT($try_generic)
298
299     AC_MSG_CHECKING([whether email keyserver support is requested])
300     AC_ARG_ENABLE(mailto,
301       AC_HELP_STRING([--enable-mailto],
302         [enable email keyserver interface only]),
303       try_mailto=$enableval, try_mailto=no)
304     AC_MSG_RESULT($try_mailto)
305   fi
306
307   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
308   AC_ARG_ENABLE(keyserver-path,
309       AC_HELP_STRING([--disable-keyserver-path],
310         [disable the exec-path option for keyserver helpers]),
311       [if test "$enableval" = no ; then
312          disable_keyserver_path=yes
313       fi],enableval=yes)
314   AC_MSG_RESULT($enableval)
315 fi
316
317
318 #
319 # Check for the key/uid cache size.  This can't be zero, but can be
320 # pretty small on embedded systems.  This is used for the gpg part.
321 #
322 AC_MSG_CHECKING([for the size of the key and uid cache])
323 AC_ARG_ENABLE(key-cache,
324         AC_HELP_STRING([--enable-key-cache=SIZE],
325                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
326 if test "$enableval" = "no"; then
327    enableval=5
328 elif test "$enableval" = "yes" || test "$enableval" = ""; then
329    enableval=4096
330 fi
331 changequote(,)dnl
332 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
333 changequote([,])dnl
334 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
335    AC_MSG_ERROR([invalid key-cache size])
336 fi
337 AC_MSG_RESULT($key_cache_size)
338 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
339                   [Size of the key and UID caches])
340
341
342
343 #
344 # Check whether we want to use Linux capabilities
345 #
346 AC_MSG_CHECKING([whether use of capabilities is requested])
347 AC_ARG_WITH(capabilities,
348     [  --with-capabilities     use linux capabilities [default=no]],
349 [use_capabilities="$withval"],[use_capabilities=no])
350 AC_MSG_RESULT($use_capabilities)
351
352
353 #
354 # Allow disabling of internal CCID support.
355 # It is defined only after we confirm the library is available later
356 #
357 AC_MSG_CHECKING([whether to enable the internal CCID driver])
358 AC_ARG_ENABLE(ccid-driver,
359               AC_HELP_STRING([--disable-ccid-driver],
360                              [disable the internal CCID driver]),
361               use_ccid_driver=$enableval)
362 AC_MSG_RESULT($use_ccid_driver)
363
364 #
365 # Dirmngr is nowadays a system service and thus it usually does no
366 # make sense to start it as needed.  However on some systems this is
367 # possible; this option enable the feature.
368 #
369 AC_MSG_CHECKING([whether to auto start dirmngr])
370 AC_ARG_ENABLE(dirmngr-auto-start,
371               AC_HELP_STRING([--enable-dirmngr-auto-start],
372                              [enable auto starting of the dirmngr]),
373               dirmngr_auto_start=$enableval)
374 AC_MSG_RESULT($dirmngr_auto_start)
375 if test "$dirmngr_auto_start" = yes ; then
376     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
377               [Define to enable auto starting of the dirmngr])
378 fi
379
380
381 #
382 # To avoid double inclusion of config.h which might happen at some
383 # places, we add the usual double inclusion protection at the top of
384 # config.h.
385 #
386 AH_TOP([
387 #ifndef GNUPG_CONFIG_H_INCLUDED
388 #define GNUPG_CONFIG_H_INCLUDED
389 ])
390
391 #
392 # Stuff which goes at the bottom of config.h.
393 #
394 AH_BOTTOM([
395 /* This is the major version number of GnuPG so that
396    source included files can test for this.  Note, that
397    we use 2 here even for GnuPG 1.9.x. */
398 #define GNUPG_MAJOR_VERSION 2
399
400 /* Now to separate file name parts.
401    Please note that the string version must not contain more
402    than one character because the code assumes strlen()==1 */
403 #ifdef HAVE_DOSISH_SYSTEM
404 #define DIRSEP_C '\\'
405 #define DIRSEP_S "\\"
406 #define EXTSEP_C '.'
407 #define EXTSEP_S "."
408 #define PATHSEP_C ';'
409 #define PATHSEP_S ";"
410 #define EXEEXT_S ".exe"
411 #else
412 #define DIRSEP_C '/'
413 #define DIRSEP_S "/"
414 #define EXTSEP_C '.'
415 #define EXTSEP_S "."
416 #define PATHSEP_C ':'
417 #define PATHSEP_S ":"
418 #define EXEEXT_S ""
419 #endif
420
421 /* This is the same as VERSION, but should be overridden if the
422    platform cannot handle things like dots '.' in filenames. Set
423    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
424    uses for dots and dashes. */
425 #define SAFE_VERSION VERSION
426 #define SAFE_VERSION_DOT  '.'
427 #define SAFE_VERSION_DASH '-'
428
429 /* Some global constants. */
430 #ifdef HAVE_DOSISH_SYSTEM
431 # ifdef HAVE_DRIVE_LETTERS
432 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
433 # else
434 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
435 # endif
436 #elif defined(__VMS)
437 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
438 #else
439 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
440 #endif
441 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
442
443 /* For some systems (DOS currently), we hardcode the path here.  For
444    POSIX systems the values are constructed by the Makefiles, so that
445    the values may be overridden by the make invocations; this is to
446    comply with the GNU coding standards.  Note that these values are
447    only defaults.  */
448 #ifdef HAVE_DOSISH_SYSTEM
449 # ifdef HAVE_DRIVE_LETTERS
450 #  define GNUPG_BINDIR      "c:\\gnupg"
451 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
452 #  define GNUPG_LIBDIR      "c:\\gnupg"
453 #  define GNUPG_DATADIR     "c:\\gnupg"
454 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
455 # else
456 #  define GNUPG_BINDIR      "\\gnupg"
457 #  define GNUPG_LIBEXECDIR  "\\gnupg"
458 #  define GNUPG_LIBDIR      "\\gnupg"
459 #  define GNUPG_DATADIR     "\\gnupg"
460 #  define GNUPG_SYSCONFDIR  "\\gnupg"
461 # endif
462 #endif
463
464 /* Derive some other constants. */
465 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
466 #define EXEC_TEMPFILE_ONLY
467 #endif
468
469
470 /* We didn't define endianness above, so get it from OS macros.  This
471    is intended for making fat binary builds on OS X. */
472 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
473 #if defined(__BIG_ENDIAN__)
474 #define BIG_ENDIAN_HOST 1
475 #elif defined(__LITTLE_ENDIAN__)
476 #define LITTLE_ENDIAN_HOST 1
477 #else
478 #error "No endianness found"
479 #endif
480 #endif
481
482
483 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
484    ldap_start_tls_s because that is the actual symbol used in the
485    library.  winldap.h redefines it to our commonly used value,
486    thus we define our usual macro here.  */
487 #ifdef HAVE_LDAP_START_TLS_SA
488 # ifndef HAVE_LDAP_START_TLS_S
489 #  define HAVE_LDAP_START_TLS_S 1
490 # endif
491 #endif
492
493 /* Hacks required for Android.  */
494 #ifdef __ANDROID__
495   /* ttyname is a stub in BIONIC, printing a FIXME warning.  */
496 # define ttyname broken_native_ttyname
497 # undef HAVE_TTYNAME
498 #endif /*__ANDROID__*/
499
500
501 /* Tell libgcrypt not to use its own libgpg-error implementation. */
502 #define USE_LIBGPG_ERROR 1
503
504 /* We use jnlib, so tell other modules about it.  */
505 #define HAVE_JNLIB_LOGGING 1
506
507 /* Our HTTP code is used in estream mode.  */
508 #define HTTP_USE_ESTREAM 1
509
510 /* Under W32 we do an explicit socket initialization, thus we need to
511    avoid the on-demand initialization which would also install an atexit
512    handler.  */
513 #define HTTP_NO_WSASTARTUP
514
515 /* We always include support for the OpenPGP card.  */
516 #define ENABLE_CARD_SUPPORT 1
517
518 /* We want to use the libgcrypt provided memory allocation for
519    asprintf.  */
520 #define _ESTREAM_PRINTF_REALLOC       gcry_realloc
521 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
522
523 /* Under Windows we use the gettext code from libgpg-error.  */
524 #define GPG_ERR_ENABLE_GETTEXT_MACROS
525
526 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
527 #define GPG_ERR_ENABLE_ERRNO_MACROS
528
529 #endif /*GNUPG_CONFIG_H_INCLUDED*/
530 ])
531
532
533 AM_MAINTAINER_MODE
534
535 # Checks for programs.
536 AC_MSG_NOTICE([checking for programs])
537 AC_PROG_MAKE_SET
538 AM_SANITY_CHECK
539 missing_dir=`cd $ac_aux_dir && pwd`
540 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
541 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
542 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
543 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
544 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
545 AC_PROG_AWK
546 AC_PROG_CC
547 AC_PROG_CPP
548 AM_PROG_CC_C_O
549 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
550   AC_MSG_ERROR([[No C-89 compiler found]])
551 fi
552 AC_PROG_INSTALL
553 AC_PROG_LN_S
554 AC_PROG_RANLIB
555 AC_CHECK_TOOL(AR, ar, :)
556 AC_PATH_PROG(PERL,"perl")
557 AC_CHECK_TOOL(WINDRES, windres, :)
558 AC_ISC_POSIX
559 gl_EARLY
560 AC_SYS_LARGEFILE
561 GNUPG_CHECK_USTAR
562
563 # We need to compile and run a program on the build machine.  A
564 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
565 # the AC archive is broken for autoconf 2.57.  Given that there is no
566 # newer version of that macro, we assume that it is also broken for
567 # autoconf 2.61 and thus we use a simple but usually sufficient
568 # approach.
569 AC_MSG_CHECKING(for cc for build)
570 if test "$cross_compiling" = "yes"; then
571   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
572 else
573   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
574 fi
575 AC_MSG_RESULT($CC_FOR_BUILD)
576 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
577
578
579
580 try_gettext=yes
581 have_dosish_system=no
582 have_w32_system=no
583 have_w32ce_system=no
584 use_simple_gettext=no
585 use_ldapwrapper=yes
586 mmap_needed=yes
587 case "${host}" in
588     *-mingw32*)
589         # special stuff for Windoze NT
590         ac_cv_have_dev_random=no
591         AC_DEFINE(USE_ONLY_8DOT3,1,
592                   [Set this to limit filenames to the 8.3 format])
593         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
594                   [Because the Unix gettext has too much overhead on
595                    MingW32 systems and these systems lack Posix functions,
596                    we use a simplified version of gettext])
597         disable_keyserver_path=yes
598         have_dosish_system=yes
599         have_w32_system=yes
600         use_ldapwrapper=no  # Fixme: Do this only for CE.
601         case "${host}" in
602           *-mingw32ce*)
603             have_w32ce_system=yes
604             ;;
605           *)
606             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
607                       [Defined if the OS supports drive letters.])
608             ;;
609         esac
610         try_gettext="no"
611         use_simple_gettext=yes
612         mmap_needed=no
613         ;;
614     i?86-emx-os2 | i?86-*-os2*emx )
615         # OS/2 with the EMX environment
616         ac_cv_have_dev_random=no
617         AC_DEFINE(HAVE_DRIVE_LETTERS)
618         have_dosish_system=yes
619         try_gettext="no"
620         ;;
621
622     i?86-*-msdosdjgpp*)
623         # DOS with the DJGPP environment
624         ac_cv_have_dev_random=no
625         AC_DEFINE(HAVE_DRIVE_LETTERS)
626         have_dosish_system=yes
627         try_gettext="no"
628         ;;
629
630     *-*-freebsd*)
631        # FreeBSD
632        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
633        LDFLAGS="$LDFLAGS -L/usr/local/lib"
634        ;;
635
636     *-*-hpux*)
637         if test -z "$GCC" ; then
638             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
639         fi
640         ;;
641     *-dec-osf4*)
642         if test -z "$GCC" ; then
643             # Suppress all warnings
644             # to get rid of the unsigned/signed char mismatch warnings.
645             CFLAGS="$CFLAGS -w"
646         fi
647         ;;
648     *-dec-osf5*)
649         if test -z "$GCC" ; then
650             # Use the newer compiler `-msg_disable ptrmismatch1' to
651             # get rid of the unsigned/signed char mismatch warnings.
652             # Using this may hide other pointer mismatch warnings, but
653             # it at least lets other warning classes through
654             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
655         fi
656         ;;
657     m68k-atari-mint)
658         ;;
659     *)
660        ;;
661 esac
662
663 if test "$have_dosish_system" = yes; then
664    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
665              [Defined if we run on some of the PCDOS like systems
666               (DOS, Windoze. OS/2) with special properties like
667               no file modes, case insensitive file names and preferred
668               use of backslashes as directory name separators.])
669 fi
670 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
671
672 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
673
674 if test "$have_w32_system" = yes; then
675    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
676    if test "$have_w32ce_system" = yes; then
677       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
678    fi
679 fi
680 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
681 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
682
683 if test "$use_ldapwrapper" = yes; then
684    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
685 fi
686 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
687
688 if test "$disable_keyserver_path" = yes; then
689     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
690               [Defined to disable exec-path for keyserver helpers])
691 fi
692
693 #
694 # Allows enabling the use of a standard socket by default This is
695 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
696 # the use of this.
697 #
698 AC_MSG_CHECKING([whether to use a standard socket by default])
699 AC_ARG_ENABLE(standard-socket,
700               AC_HELP_STRING([--disable-standard-socket],
701                              [don't use a standard socket by default]),
702               use_standard_socket=$enableval)
703 tmp=""
704 if test "$use_standard_socket" != yes; then
705   if test "$have_w32_system" = yes; then
706     use_standard_socket=yes
707     tmp=" (forced)"
708   fi
709 fi
710 AC_MSG_RESULT($use_standard_socket$tmp)
711 if test "$use_standard_socket" = yes; then
712   AC_DEFINE(USE_STANDARD_SOCKET,1,
713             [Use the standard socket for the agent by default])
714 fi
715
716
717 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
718 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
719
720 if test x"$try_hkp" = xyes ; then
721   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
722 fi
723
724 if test x"$try_finger" = xyes ; then
725   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
726 fi
727
728
729
730 #
731 # Checks for libraries.
732 #
733 AC_MSG_NOTICE([checking for libraries])
734
735
736 #
737 # libgpg-error is a library with error codes shared between GnuPG
738 # related projects.
739 #
740 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
741                   have_gpg_error=yes,have_gpg_error=no)
742
743
744 #
745 # Libgcrypt is our generic crypto library
746 #
747 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
748         have_libgcrypt=yes,have_libgcrypt=no)
749
750
751 #
752 # libassuan is used for IPC
753 #
754 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
755                   have_libassuan=yes,have_libassuan=no)
756 if test "$have_libassuan" = "yes"; then
757   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
758                      [version of the libassuan library])
759 fi
760
761
762
763 #
764 # libksba is our X.509 support library
765 #
766 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
767
768
769 #
770 # libusb allows us to use the integrated CCID smartcard reader driver.
771 #
772 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
773 if test "$use_ccid_driver" = yes ; then
774   AC_CHECK_LIB(usb, usb_bulk_write,
775                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
776                   AC_DEFINE(HAVE_LIBUSB,1,
777                            [defined if libusb is available])
778                   have_libusb=yes
779                ])
780   AC_CHECK_FUNCS(usb_create_match)
781 fi
782 AC_SUBST(LIBUSB_LIBS)
783
784 #
785 # Check wether it is necessary to link against libdl.
786 #
787 gnupg_dlopen_save_libs="$LIBS"
788 LIBS=""
789 AC_SEARCH_LIBS(dlopen, c dl,,,)
790 DL_LIBS=$LIBS
791 AC_SUBST(DL_LIBS)
792 LIBS="$gnupg_dlopen_save_libs"
793
794 # Checks for g13
795
796 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
797 AC_DEFINE_UNQUOTED(ENCFS,
798         "${ENCFS}", [defines the filename of the encfs program])
799
800 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
801 AC_DEFINE_UNQUOTED(FUSERMOUNT,
802         "${FUSERMOUNT}", [defines the filename of the fusermount program])
803
804
805 # Checks for dirmngr
806
807
808 #
809 # Checks for symcryptrun:
810 #
811
812 # libutil has openpty() and login_tty().
813 AC_CHECK_LIB(util, openpty,
814               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
815                 AC_DEFINE(HAVE_LIBUTIL,1,
816                          [defined if libutil is available])
817              ])
818 AC_SUBST(LIBUTIL_LIBS)
819
820 # shred is used to clean temporary plain text files.
821 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
822 AC_DEFINE_UNQUOTED(SHRED,
823         "${SHRED}", [defines the filename of the shred program])
824
825
826 #
827 # Check whether the nPth library is available
828 #
829 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
830 if test "$have_npth" = "yes"; then
831   # We define this macro because some code parts require it.
832   AC_DEFINE(USE_NPTH, 1,
833               [Defined if the New Portable Thread Library is available])
834 else
835   AC_MSG_WARN([[
836 ***
837 *** To support concurrent access for example in gpg-agent and the SCdaemon
838 *** we need the support of the New Portable Threads Library.
839 ***]])
840 fi
841
842
843 AC_MSG_NOTICE([checking for networking options])
844
845 #
846 # Must check for network library requirements before doing link tests
847 # for ldap, for example. If ldap libs are static (or dynamic and without
848 # ELF runtime link paths), then link will fail and LDAP support won't
849 # be detected.
850 #
851 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
852         [NETLIBS="-lnsl $NETLIBS"]))
853 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
854         [NETLIBS="-lsocket $NETLIBS"]))
855
856
857 #
858 # Check for ADNS.
859 #
860 _cppflags="${CPPFLAGS}"
861 _ldflags="${LDFLAGS}"
862 AC_ARG_WITH(adns,
863             AC_HELP_STRING([--with-adns=DIR],
864                            [look for the adns library in DIR]),
865             [if test -d "$withval"; then
866                CPPFLAGS="${CPPFLAGS} -I$withval/include"
867                LDFLAGS="${LDFLAGS} -L$withval/lib"
868              fi])
869 if test "$with_adns" != "no"; then
870   AC_CHECK_HEADERS(adns.h,
871                 AC_CHECK_LIB(adns, adns_init,
872                              [have_adns=yes],
873                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
874                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
875 fi
876 if test "$have_adns" = "yes"; then
877   ADNSLIBS="-ladns"
878 fi
879 AC_SUBST(ADNSLIBS)
880 # Newer adns versions feature a free function to be used under W32.
881 AC_CHECK_FUNCS(adns_free)
882
883
884
885 #
886 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
887 #
888 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
889   AC_ARG_ENABLE(dns-srv,
890      AC_HELP_STRING([--disable-dns-srv],
891                     [disable the use of DNS SRV in HKP and HTTP]),
892                 use_dns_srv=$enableval,use_dns_srv=yes)
893 fi
894
895 AC_ARG_ENABLE(dns-pka,
896    AC_HELP_STRING([--disable-dns-pka],
897         [disable the use of PKA records in DNS]),
898    use_dns_pka=$enableval,use_dns_pka=yes)
899
900 AC_ARG_ENABLE(dns-cert,
901    AC_HELP_STRING([--disable-dns-cert],
902         [disable the use of CERT records in DNS]),
903    use_dns_cert=$enableval,use_dns_cert=yes)
904
905 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
906    || test x"$use_dns_cert" = xyes; then
907   _dns_save_libs=$LIBS
908   LIBS=""
909   # the double underscore thing is a glibc-ism?
910   AC_SEARCH_LIBS(res_query,resolv bind,,
911                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
912   AC_SEARCH_LIBS(dn_expand,resolv bind,,
913                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
914   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
915                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
916
917   if test x"$have_resolver" != xno ; then
918
919     # Make sure that the BIND 4 resolver interface is workable before
920     # enabling any code that calls it.  At some point I'll rewrite the
921     # code to use the BIND 8 resolver API.
922     # We might also want to use adns instead.  Problem with ADNS is that
923     # it does not support v6.
924
925     AC_MSG_CHECKING([whether the resolver is usable])
926     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
927 #include <netinet/in.h>
928 #include <arpa/nameser.h>
929 #include <resolv.h>]],
930 [[unsigned char answer[PACKETSZ];
931   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
932   dn_skipname(0,0);
933   dn_expand(0,0,0,0,0);
934 ]])],have_resolver=yes,have_resolver=no)
935     AC_MSG_RESULT($have_resolver)
936
937     # This is Apple-specific and somewhat bizarre as they changed the
938     # define in bind 8 for some reason.
939
940     if test x"$have_resolver" != xyes ; then
941        AC_MSG_CHECKING(
942              [whether I can make the resolver usable with BIND_8_COMPAT])
943        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
944 #include <sys/types.h>
945 #include <netinet/in.h>
946 #include <arpa/nameser.h>
947 #include <resolv.h>]],
948 [[unsigned char answer[PACKETSZ];
949   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
950   dn_skipname(0,0); dn_expand(0,0,0,0,0);
951 ]])],[have_resolver=yes ; need_compat=yes])
952        AC_MSG_RESULT($have_resolver)
953     fi
954   fi
955
956   if test x"$have_resolver" = xyes ; then
957      DNSLIBS=$LIBS
958
959      if test x"$use_dns_srv" = xyes ; then
960         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
961      fi
962
963      if test x"$use_dns_pka" = xyes ; then
964         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
965      fi
966
967      if test x"$use_dns_cert" = xyes ; then
968         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
969      fi
970
971      if test x"$need_compat" = xyes ; then
972         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
973      fi
974   else
975      # If we have no resolver library but ADNS (e.g. under W32) enable the
976      # code parts which can be used with ADNS.
977      if test x"$have_adns" = xyes ; then
978         DNSLIBS="$ADNSLIBS"
979         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
980
981         if test x"$use_dns_srv" = xyes ; then
982            AC_DEFINE(USE_DNS_SRV,1)
983         fi
984
985         if test x"$use_dns_pka" = xyes ; then
986            AC_DEFINE(USE_DNS_PKA,1)
987         fi
988
989         if test x"$use_dns_cert" = xyes ; then
990            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
991         fi
992      else
993         use_dns_srv=no
994         use_dns_pka=no
995         use_dns_cert=no
996      fi
997   fi
998
999   LIBS=$_dns_save_libs
1000 fi
1001
1002 AC_SUBST(DNSLIBS)
1003
1004 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1005
1006
1007 #
1008 # Check for LDAP
1009 #
1010 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1011    GNUPG_CHECK_LDAP($NETLIBS)
1012    AC_CHECK_LIB(lber, ber_free,
1013                 [ LBER_LIBS="$LBER_LIBS -llber"
1014                   AC_DEFINE(HAVE_LBER,1,
1015                            [defined if liblber is available])
1016                   have_lber=yes
1017                ])
1018 fi
1019 AC_SUBST(LBER_LIBS)
1020
1021 #
1022 # Check for curl.  We fake the curl API if libcurl isn't installed.
1023 # We require 7.10 or later as we use curl_version_info().
1024 #
1025 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1026 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1027
1028 # Generic, for us, means curl
1029
1030 if test x"$try_generic" = xyes ; then
1031    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1032 fi
1033
1034 #
1035 # Check for sendmail
1036 #
1037 # This isn't necessarily sendmail itself, but anything that gives a
1038 # sendmail-ish interface to the outside world.  That includes Exim,
1039 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1040 if test "$try_mailto" = yes ; then
1041   AC_ARG_WITH(mailprog,
1042       AC_HELP_STRING([--with-mailprog=NAME],
1043                      [use "NAME -t" for mail transport]),
1044              ,with_mailprog=yes)
1045
1046   if test x"$with_mailprog" = xyes ; then
1047     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1048     if test "$ac_cv_path_SENDMAIL" ; then
1049       GPGKEYS_MAILTO="gpg2keys_mailto"
1050     fi
1051   elif test x"$with_mailprog" != xno ; then
1052     AC_MSG_CHECKING([for a mail transport program])
1053     AC_SUBST(SENDMAIL,$with_mailprog)
1054     AC_MSG_RESULT($with_mailprog)
1055     GPGKEYS_MAILTO="gpg2keys_mailto"
1056   fi
1057 fi
1058
1059 AC_SUBST(GPGKEYS_MAILTO)
1060
1061 #
1062 # Construct a printable name of the OS
1063 #
1064 case "${host}" in
1065     *-mingw32ce*)
1066         PRINTABLE_OS_NAME="W32CE"
1067         ;;
1068     *-mingw32*)
1069         PRINTABLE_OS_NAME="MingW32"
1070         ;;
1071     *-*-cygwin*)
1072         PRINTABLE_OS_NAME="Cygwin"
1073         ;;
1074     i?86-emx-os2 | i?86-*-os2*emx )
1075         PRINTABLE_OS_NAME="OS/2"
1076         ;;
1077     i?86-*-msdosdjgpp*)
1078         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1079         try_dynload=no
1080         ;;
1081     *-linux*)
1082         PRINTABLE_OS_NAME="GNU/Linux"
1083         ;;
1084     *)
1085         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1086         ;;
1087 esac
1088 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1089                    [A human readable text with the name of the OS])
1090
1091
1092 #
1093 # Checking for iconv
1094 #
1095 AM_ICONV
1096
1097
1098 #
1099 # Check for gettext
1100 #
1101 # This is "GNU gnupg" - The project-id script from gettext
1102 #                       needs this string
1103 #
1104 AC_MSG_NOTICE([checking for gettext])
1105 AM_PO_SUBDIRS
1106 AM_GNU_GETTEXT_VERSION([0.17])
1107 if test "$try_gettext" = yes; then
1108   AM_GNU_GETTEXT([external],[need-ngettext])
1109
1110   # gettext requires some extra checks.  These really should be part of
1111   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1112   # function checks to here.
1113
1114   AC_CHECK_FUNCS(strchr)
1115 else
1116   USE_NLS=no
1117   USE_INCLUDED_LIBINTL=no
1118   BUILD_INCLUDED_LIBINTL=no
1119   POSUB=po
1120   AC_SUBST(USE_NLS)
1121   AC_SUBST(USE_INCLUDED_LIBINTL)
1122   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1123   AC_SUBST(POSUB)
1124 fi
1125
1126 # We use HAVE_LANGINFO_CODESET in a couple of places.
1127 AM_LANGINFO_CODESET
1128
1129 # Checks required for our use locales
1130 gt_LC_MESSAGES
1131
1132
1133 #
1134 # SELinux support
1135 #
1136 if test "$selinux_support" = yes ; then
1137   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1138 fi
1139
1140
1141 #
1142 # Checks for header files.
1143 #
1144 AC_MSG_NOTICE([checking for header files])
1145 AC_HEADER_STDC
1146 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1147                   pty.h utmp.h pwd.h inttypes.h signal.h])
1148 AC_HEADER_TIME
1149
1150
1151 #
1152 # Checks for typedefs, structures, and compiler characteristics.
1153 #
1154 AC_MSG_NOTICE([checking for system characteristics])
1155 AC_C_CONST
1156 AC_C_INLINE
1157 AC_C_VOLATILE
1158 AC_TYPE_SIZE_T
1159 AC_TYPE_MODE_T
1160 AC_TYPE_SIGNAL
1161 AC_DECL_SYS_SIGLIST
1162
1163 gl_HEADER_SYS_SOCKET
1164 gl_TYPE_SOCKLEN_T
1165
1166 AC_ARG_ENABLE(endian-check,
1167               AC_HELP_STRING([--disable-endian-check],
1168               [disable the endian check and trust the OS provided macros]),
1169               endiancheck=$enableval,endiancheck=yes)
1170
1171 if test x"$endiancheck" = xyes ; then
1172   GNUPG_CHECK_ENDIAN
1173 fi
1174
1175 # fixme: we should get rid of the byte type
1176 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1177 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1178 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1179 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1180 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1181
1182 AC_CHECK_SIZEOF(unsigned short)
1183 AC_CHECK_SIZEOF(unsigned int)
1184 AC_CHECK_SIZEOF(unsigned long)
1185 AC_CHECK_SIZEOF(unsigned long long)
1186 AC_HEADER_TIME
1187 AC_CHECK_SIZEOF(time_t,,[[
1188 #include <stdio.h>
1189 #if TIME_WITH_SYS_TIME
1190 # include <sys/time.h>
1191 # include <time.h>
1192 #else
1193 # if HAVE_SYS_TIME_H
1194 #  include <sys/time.h>
1195 # else
1196 #  include <time.h>
1197 # endif
1198 #endif
1199 ]])
1200 GNUPG_TIME_T_UNSIGNED
1201
1202
1203 # Ensure that we have UINT64_C before we bother to check for uint64_t
1204 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1205 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1206    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1207        [[uint64_t foo=UINT64_C(42);]])],
1208      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1209 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1210    AC_CHECK_SIZEOF(uint64_t)
1211 fi
1212
1213 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1214    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1215    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1216     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1217 fi
1218
1219
1220 #
1221 # Checks for library functions.
1222 #
1223 AC_MSG_NOTICE([checking for library functions])
1224 AC_CHECK_DECLS(getpagesize)
1225 AC_FUNC_FSEEKO
1226 AC_FUNC_VPRINTF
1227 AC_FUNC_FORK
1228 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1229 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1230 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1231 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1232 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1233 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1234 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1235
1236 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1237
1238 # Dirmngr requires mmap on Unix systems.
1239 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1240   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1241 fi
1242
1243 #
1244 # These are needed by the jnlib parts in common.
1245 # Note:  We already checked pwd.h.
1246 AC_CHECK_HEADERS([signal.h])
1247 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1248                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1249                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1250                 getenv inet_pton])
1251 # end jnlib checks.
1252
1253
1254
1255 #
1256 # gnulib checks
1257 #
1258 gl_SOURCE_BASE([gl])
1259 gl_M4_BASE([gl/m4])
1260 gl_MODULES([setenv mkdtemp xsize strpbrk])
1261 gl_INIT
1262
1263
1264 #
1265 # W32 specific test
1266 #
1267 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1268
1269 #
1270 # Sanity check regex.  Tests adapted from mutt.
1271 #
1272 AC_MSG_CHECKING([whether regular expression support is requested])
1273 AC_ARG_ENABLE(regex,
1274   AC_HELP_STRING([--disable-regex],
1275     [do not handle regular expressions in trust signatures]),
1276   use_regex=$enableval, use_regex=yes)
1277 AC_MSG_RESULT($use_regex)
1278
1279 if test "$use_regex" = yes ; then
1280   _cppflags="${CPPFLAGS}"
1281   _ldflags="${LDFLAGS}"
1282   AC_ARG_WITH(regex,
1283      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1284       [
1285       if test -d "$withval" ; then
1286         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1287         LDFLAGS="${LDFLAGS} -L$withval/lib"
1288       fi
1289       ],withval="")
1290
1291   # Does the system have regex functions at all?
1292   AC_SEARCH_LIBS([regcomp], [regex])
1293   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1294
1295   if test $gnupg_cv_have_regex = no; then
1296     use_regex=no
1297   else
1298     if test x"$cross_compiling" = xyes; then
1299       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1300     else
1301       AC_CACHE_CHECK([whether your system's regexp library is broken],
1302        [gnupg_cv_regex_broken],
1303        AC_TRY_RUN([
1304 #include <unistd.h>
1305 #include <regex.h>
1306 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1307        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1308
1309       if test $gnupg_cv_regex_broken = yes; then
1310         AC_MSG_WARN([your regex is broken - disabling regex use])
1311         use_regex=no
1312       fi
1313     fi
1314   fi
1315   CPPFLAGS="${_cppflags}"
1316   LDFLAGS="${_ldflags}"
1317 fi
1318
1319 if test "$use_regex" != yes ; then
1320   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1321 fi
1322 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1323
1324
1325
1326 #
1327 # Do we have zlib? Must do it here because Solaris failed
1328 # when compiling a conftest (due to the "-lz" from LIBS).
1329 # Note that we combine zlib and bzlib2 in ZLIBS.
1330 #
1331 if test "$use_zip" = yes ; then
1332   _cppflags="${CPPFLAGS}"
1333   _ldflags="${LDFLAGS}"
1334   AC_ARG_WITH(zlib,
1335     [  --with-zlib=DIR         use libz in DIR],[
1336       if test -d "$withval"; then
1337         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1338         LDFLAGS="${LDFLAGS} -L$withval/lib"
1339       fi
1340     ])
1341
1342   AC_CHECK_HEADER(zlib.h,
1343         AC_CHECK_LIB(z, deflateInit2_,
1344          ZLIBS="-lz",
1345          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1346          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1347
1348   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1349 fi
1350
1351
1352 #
1353 # Check whether we can support bzip2
1354 #
1355 if test "$use_bzip2" = yes ; then
1356   _cppflags="${CPPFLAGS}"
1357   _ldflags="${LDFLAGS}"
1358   AC_ARG_WITH(bzip2,
1359      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1360       [
1361       if test -d "$withval" ; then
1362         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1363         LDFLAGS="${LDFLAGS} -L$withval/lib"
1364       fi
1365       ],withval="")
1366
1367   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1368   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1369   # woefully out of date.
1370   if test "$withval" != no ; then
1371      AC_CHECK_HEADER(bzlib.h,
1372         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1373           [
1374           have_bz2=yes
1375           ZLIBS="$ZLIBS -lbz2"
1376           AC_DEFINE(HAVE_BZIP2,1,
1377                   [Defined if the bz2 compression library is available])
1378           ],
1379           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1380           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1381   fi
1382 fi
1383 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1384 AC_SUBST(ZLIBS)
1385
1386
1387 # Check for readline support
1388 GNUPG_CHECK_READLINE
1389
1390 #
1391 # Allow users to append something to the version string without
1392 # flagging it as development version.  The user version parts is
1393 # considered everything after a dash.
1394 #
1395 if test "$development_version" != yes; then
1396   changequote(,)dnl
1397   tmp_pat='[a-zA-Z]'
1398   changequote([,])dnl
1399   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1400     development_version=yes
1401   fi
1402 fi
1403 if test "$development_version" = yes; then
1404     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1405             [Defined if this is not a regular release])
1406 fi
1407
1408 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1409
1410 GNUPG_CHECK_GNUMAKE
1411
1412 # Add some extra libs here so that previous tests don't fail for
1413 # mysterious reasons - the final link step should bail out.
1414 # W32SOCKLIBS is also defined so that if can be used for tools not
1415 # requiring any network stuff but linking to code in libcommon which
1416 # tracks in winsock stuff (e.g. init_common_subsystems).
1417 if test "$have_w32_system" = yes; then
1418    if test "$have_w32ce_system" = yes; then
1419      W32SOCKLIBS="-lws2"
1420    else
1421      W32SOCKLIBS="-lws2_32"
1422    fi
1423    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1424 fi
1425
1426 AC_SUBST(NETLIBS)
1427 AC_SUBST(W32SOCKLIBS)
1428
1429 #
1430 # Setup gcc specific options
1431 #
1432 AC_MSG_NOTICE([checking for cc features])
1433 if test "$GCC" = yes; then
1434     # Note that it is okay to use CFLAGS here because this are just
1435     # warning options and the user should have a chance of overriding
1436     # them.
1437     if test "$USE_MAINTAINER_MODE" = "yes"; then
1438         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1439         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1440         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1441         _gcc_cflags_save=$CFLAGS
1442         CFLAGS="-Wno-missing-field-initializers"
1443         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1444         AC_MSG_RESULT($_gcc_wopt)
1445         CFLAGS=$_gcc_cflags_save;
1446         if test x"$_gcc_wopt" = xyes ; then
1447           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1448         fi
1449         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1450         _gcc_cflags_save=$CFLAGS
1451         CFLAGS="-Wdeclaration-after-statement"
1452         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1453         AC_MSG_RESULT($_gcc_wopt)
1454         CFLAGS=$_gcc_cflags_save;
1455         if test x"$_gcc_wopt" = xyes ; then
1456           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1457         fi
1458     else
1459         CFLAGS="$CFLAGS -Wall"
1460     fi
1461
1462     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1463     _gcc_cflags_save=$CFLAGS
1464     CFLAGS="-Wno-pointer-sign"
1465     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1466     AC_MSG_RESULT($_gcc_psign)
1467     CFLAGS=$_gcc_cflags_save;
1468     if test x"$_gcc_psign" = xyes ; then
1469        CFLAGS="$CFLAGS -Wno-pointer-sign"
1470     fi
1471
1472     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1473     _gcc_cflags_save=$CFLAGS
1474     CFLAGS="-Wpointer-arith"
1475     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1476     AC_MSG_RESULT($_gcc_psign)
1477     CFLAGS=$_gcc_cflags_save;
1478     if test x"$_gcc_psign" = xyes ; then
1479        CFLAGS="$CFLAGS -Wpointer-arith"
1480     fi
1481 fi
1482
1483
1484 #
1485 # This is handy for debugging so the compiler doesn't rearrange
1486 # things and eliminate variables.
1487 #
1488 AC_ARG_ENABLE(optimization,
1489    AC_HELP_STRING([--disable-optimization],
1490                   [disable compiler optimization]),
1491                   [if test $enableval = no ; then
1492                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1493                    fi])
1494
1495 #
1496 # Prepare building of estream
1497 #
1498 estream_INIT
1499
1500
1501 #
1502 # Decide what to build
1503 #
1504 if test "$have_adns" = "yes"; then
1505   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1506 fi
1507
1508
1509 if test $have_ksba = no; then
1510   build_gpgsm=no
1511   build_scdaemon=no
1512 fi
1513
1514 build_scdaemon_extra=""
1515 if test "$build_scdaemon" = "yes"; then
1516   if test $have_libusb = no; then
1517      build_scdaemon_extra="${tmp}without internal CCID driver"
1518   fi
1519   if test -n "$build_scdaemon_extra"; then
1520      build_scdaemon_extra="(${build_scdaemon_extra})"
1521   fi
1522 fi
1523
1524
1525 if test "$build_agent_only" = "yes" ; then
1526   build_gpg=no
1527   build_gpgsm=no
1528   build_scdaemon=no
1529   build_tools=no
1530   build_doc=no
1531 fi
1532
1533 #
1534 # Set variables for use by th automake makefile.
1535 #
1536 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1537 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1538 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1539 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1540 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1541 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1542 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1543 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1544 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1545 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1546
1547 AM_CONDITIONAL(RUN_GPG_TESTS,
1548                test x$cross_compiling = xno -a "$build_gpg" = yes )
1549
1550 #
1551 # Set some defines for use gpgconf.
1552 #
1553 if test "$build_gpg" = yes ; then
1554     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1555 fi
1556 if test "$build_gpgsm" = yes ; then
1557     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1558 fi
1559 if test "$build_agent" = yes ; then
1560     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1561 fi
1562 if test "$build_scdaemon" = yes ; then
1563     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1564 fi
1565 if test "$build_dirmngr" = yes ; then
1566     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1567 fi
1568 if test "$build_g13" = yes ; then
1569     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1570 fi
1571
1572
1573
1574 #
1575 # Print errors here so that they are visible all
1576 # together and the user can acquire them all together.
1577 #
1578 die=no
1579 if test "$have_gpg_error" = "no"; then
1580    die=yes
1581    AC_MSG_NOTICE([[
1582 ***
1583 *** You need libgpg-error to build this program.
1584 **  This library is for example available at
1585 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1586 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1587 ***]])
1588 fi
1589 if test "$have_libgcrypt" = "no"; then
1590    die=yes
1591    AC_MSG_NOTICE([[
1592 ***
1593 *** You need libgcrypt to build this program.
1594 **  This library is for example available at
1595 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1596 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1597 ***]])
1598 dnl elif test "$gnupg_cv_gcry_kdf_derive" = no; then
1599 dnl    die=yes
1600 dnl    AC_MSG_NOTICE([[
1601 dnl ***
1602 dnl *** Libgcrypt 1.5.0 has not yet been released and thus the API
1603 dnl *** is a bit in a flux.  Your version misses the function
1604 dnl ***        gcry_kdf_derive
1605 dnl *** You need to install a newer Libgcrypt version.
1606 dnl #***]])
1607 fi
1608 if test "$have_libassuan" = "no"; then
1609    die=yes
1610    AC_MSG_NOTICE([[
1611 ***
1612 *** You need libassuan to build this program.
1613 *** This library is for example available at
1614 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1615 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1616 ***]])
1617 fi
1618 if test "$have_ksba" = "no"; then
1619     AC_MSG_NOTICE([[
1620 ***
1621 *** You need libksba to build this program.
1622 *** This library is for example available at
1623 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1624 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1625 ***]])
1626 fi
1627 if test "$gnupg_have_ldap" = "no"; then
1628     die=yes
1629     AC_MSG_NOTICE([[
1630 ***
1631 *** You need a LDAP library to build this program.
1632 *** Check out
1633 ***    http://www.openldap.org
1634 *** for a suitable implementation.
1635 ***]])
1636    if test "$have_w32ce_system" = yes; then
1637     AC_MSG_NOTICE([[
1638 *** Note that CeGCC might be broken, a package fixing this is:
1639 ***    http://files.kolab.org/local/windows-ce/
1640 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1641 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1642 ***]])
1643    fi
1644 fi
1645 if test "$have_npth" = "no"; then
1646     AC_MSG_NOTICE([[
1647 ***
1648 *** It is now required to build with support for the
1649 *** New Portable Threads Library (NPth). Please install this
1650 *** library first.  The library is for example available at
1651 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1652 *** On a Debian GNU/Linux system you can install it using
1653 ***   apt-get install libnpth-dev
1654 ***]])
1655    die=yes
1656 fi
1657
1658 if test "$die" = "yes"; then
1659     AC_MSG_ERROR([[
1660 ***
1661 *** Required libraries not found. Please consult the above messages
1662 *** and install them before running configure again.
1663 ***]])
1664 fi
1665
1666
1667
1668 AC_CONFIG_FILES([ m4/Makefile
1669 Makefile
1670 po/Makefile.in
1671 gl/Makefile
1672 include/Makefile
1673 common/Makefile
1674 kbx/Makefile
1675 g10/Makefile
1676 sm/Makefile
1677 agent/Makefile
1678 scd/Makefile
1679 g13/Makefile
1680 dirmngr/Makefile
1681 tools/gpg-zip
1682 tools/Makefile
1683 doc/Makefile
1684 tests/Makefile
1685 tests/openpgp/Makefile
1686 tests/pkits/Makefile
1687 ])
1688 #keyserver/Makefile
1689 #keyserver/gpg2keys_mailto
1690 #keyserver/gpg2keys_test
1691
1692
1693 AC_OUTPUT
1694
1695
1696 echo "
1697         GnuPG v${VERSION} has been configured as follows:
1698
1699         Platform:  $PRINTABLE_OS_NAME ($host)
1700
1701         OpenPGP:   $build_gpg
1702         S/MIME:    $build_gpgsm
1703         Agent:     $build_agent
1704         Smartcard: $build_scdaemon $build_scdaemon_extra
1705         G13:       $build_g13
1706         Dirmngr:   $build_dirmngr
1707         Gpgtar:    $build_gpgtar
1708
1709         Protect tool:      $show_gnupg_protect_tool_pgm
1710         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1711         Default agent:     $show_gnupg_agent_pgm
1712         Default pinentry:  $show_gnupg_pinentry_pgm
1713         Default scdaemon:  $show_gnupg_scdaemon_pgm
1714         Default dirmngr:   $show_gnupg_dirmngr_pgm
1715
1716         Use standard socket: $use_standard_socket
1717         Dirmngr auto start:  $dirmngr_auto_start
1718 "
1719 if test x"$use_regex" != xyes ; then
1720 echo "
1721         Warning: No regular expression support available.
1722                  OpenPGP trust signatures won't work.
1723                  gpg-check-pattern will not be build.
1724 "
1725 fi