gpg: Prettify a 2 octet hex output.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [12])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.21
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.1
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=yes
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132
133 AC_SUBST(PACKAGE)
134 AC_SUBST(PACKAGE_GT)
135 AC_SUBST(VERSION)
136 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
137 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
138                                 [Name of this package for gettext])
139 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
141                                         [Bug report address])
142 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
143                                        [Required version of Libgcrypt])
144 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
145                                        [Required version of Libksba])
146 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
147                                        [Required version of NTBTLS])
148
149
150
151 # The default is to use the modules from this package and the few
152 # other packages in a standard place; i.e where this package gets
153 # installed.  With these options it is possible to override these
154 # ${prefix} depended values with fixed paths, which can't be replaced
155 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
156 AC_ARG_WITH(agent-pgm,
157     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
158           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
159 AC_SUBST(GNUPG_AGENT_PGM)
160 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
161 show_gnupg_agent_pgm="(default)"
162 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
163
164 AC_ARG_WITH(pinentry-pgm,
165     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
166           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
167 AC_SUBST(GNUPG_PINENTRY_PGM)
168 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
169 show_gnupg_pinentry_pgm="(default)"
170 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
171
172
173 AC_ARG_WITH(scdaemon-pgm,
174     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
175           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
176 AC_SUBST(GNUPG_SCDAEMON_PGM)
177 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
178 show_gnupg_scdaemon_pgm="(default)"
179 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
180
181
182 AC_ARG_WITH(dirmngr-pgm,
183     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
184           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
185 AC_SUBST(GNUPG_DIRMNGR_PGM)
186 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
187 show_gnupg_dirmngr_pgm="(default)"
188 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
189
190 AC_ARG_WITH(protect-tool-pgm,
191     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
192           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
193 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
194 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
195 show_gnupg_protect_tool_pgm="(default)"
196 test -n "$GNUPG_PROTECT_TOOL_PGM" \
197       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
198
199 AC_ARG_WITH(dirmngr-ldap-pgm,
200     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
201           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
202 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
203 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
204 show_gnupg_dirmngr_ldap_pgm="(default)"
205 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
206       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
207
208 #
209 # On some platforms gpg2 is usually installed as gpg without using a
210 # symlink.  For correct operation of gpgconf it needs to know the
211 # installed name of gpg.  This option sets "gpg2"'s installed name to
212 # just "gpg".  Note that it might be required to rename gpg2 to gpg
213 # manually after the build process.
214 #
215 AC_ARG_ENABLE(gpg2-is-gpg,
216     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
217     gpg2_is_gpg=$enableval)
218 if test "$gpg2_is_gpg" = "yes"; then
219    name_of_installed_gpg=gpg
220 else
221    name_of_installed_gpg=gpg2
222 fi
223 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
224                    [The name of the installed GPG tool])
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=yes)
267 AC_MSG_RESULT($use_tofu)
268
269
270
271 #
272 # Options to disable algorithm
273 #
274
275 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
276 # Elgamal is a MUST algorithm
277 # DSA is a MUST algorithm
278 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
279 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
280 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
281
282 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
283 # 3DES is a MUST algorithm
284 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
285 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
286 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
287 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
288 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
289 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
290 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
291 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
292 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
293
294 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
295 # SHA1 is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
297 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
298 # SHA256 is a MUST algorithm for GnuPG.
299 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
301
302
303 # Allow disabling of zip support.
304 # This is in general not a good idea because according to rfc4880 OpenPGP
305 # implementations SHOULD support ZLIB.
306 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
307 AC_ARG_ENABLE(zip,
308    AC_HELP_STRING([--disable-zip],
309                   [disable the ZIP and ZLIB compression algorithm]),
310    use_zip=$enableval)
311 AC_MSG_RESULT($use_zip)
312
313 # Allow disabling of bzib2 support.
314 # It is defined only after we confirm the library is available later
315 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
316 AC_ARG_ENABLE(bzip2,
317    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
318    use_bzip2=$enableval)
319 AC_MSG_RESULT($use_bzip2)
320
321 # Configure option to allow or disallow execution of external
322 # programs, like a photo viewer.
323 AC_MSG_CHECKING([whether to enable external program execution])
324 AC_ARG_ENABLE(exec,
325     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
326     use_exec=$enableval)
327 AC_MSG_RESULT($use_exec)
328 if test "$use_exec" = no ; then
329     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
330 fi
331
332 if test "$use_exec" = yes ; then
333   AC_MSG_CHECKING([whether to enable photo ID viewing])
334   AC_ARG_ENABLE(photo-viewers,
335       [  --disable-photo-viewers disable photo ID viewers],
336       [if test "$enableval" = no ; then
337          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
338       fi],enableval=yes)
339   gnupg_cv_enable_photo_viewers=$enableval
340   AC_MSG_RESULT($enableval)
341
342   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
343     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
344     AC_ARG_WITH(photo-viewer,
345         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
346         [if test "$withval" = yes ; then
347            withval=no
348         elif test "$withval" != no ; then
349            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
350                             [if set, restrict photo-viewer to this])
351         fi],withval=no)
352     AC_MSG_RESULT($withval)
353   fi
354 fi
355
356
357 #
358 # Check for the key/uid cache size.  This can't be zero, but can be
359 # pretty small on embedded systems.  This is used for the gpg part.
360 #
361 AC_MSG_CHECKING([for the size of the key and uid cache])
362 AC_ARG_ENABLE(key-cache,
363         AC_HELP_STRING([--enable-key-cache=SIZE],
364                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
365 if test "$enableval" = "no"; then
366    enableval=5
367 elif test "$enableval" = "yes" || test "$enableval" = ""; then
368    enableval=4096
369 fi
370 changequote(,)dnl
371 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
372 changequote([,])dnl
373 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
374    AC_MSG_ERROR([invalid key-cache size])
375 fi
376 AC_MSG_RESULT($key_cache_size)
377 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
378                   [Size of the key and UID caches])
379
380
381
382 #
383 # Check whether we want to use Linux capabilities
384 #
385 AC_MSG_CHECKING([whether use of capabilities is requested])
386 AC_ARG_WITH(capabilities,
387     [  --with-capabilities     use linux capabilities [default=no]],
388 [use_capabilities="$withval"],[use_capabilities=no])
389 AC_MSG_RESULT($use_capabilities)
390
391 #
392 # Check whether to disable the card support
393 AC_MSG_CHECKING([whether smartcard support is requested])
394 AC_ARG_ENABLE(card-support,
395               AC_HELP_STRING([--disable-card-support],
396                              [disable smartcard support]),
397               card_support=$enableval)
398 AC_MSG_RESULT($card_support)
399 if test "$card_support" = yes ; then
400   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
401 else
402   build_scdaemon=no
403 fi
404
405 #
406 # Allow disabling of internal CCID support.
407 # It is defined only after we confirm the library is available later
408 #
409 AC_MSG_CHECKING([whether to enable the internal CCID driver])
410 AC_ARG_ENABLE(ccid-driver,
411               AC_HELP_STRING([--disable-ccid-driver],
412                              [disable the internal CCID driver]),
413               use_ccid_driver=$enableval)
414 AC_MSG_RESULT($use_ccid_driver)
415
416 AC_MSG_CHECKING([whether to auto start dirmngr])
417 AC_ARG_ENABLE(dirmngr-auto-start,
418               AC_HELP_STRING([--disable-dirmngr-auto-start],
419                              [disable auto starting of the dirmngr]),
420               dirmngr_auto_start=$enableval)
421 AC_MSG_RESULT($dirmngr_auto_start)
422 if test "$dirmngr_auto_start" = yes ; then
423     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
424               [Define to enable auto starting of the dirmngr])
425 fi
426
427
428 #
429 # To avoid double inclusion of config.h which might happen at some
430 # places, we add the usual double inclusion protection at the top of
431 # config.h.
432 #
433 AH_TOP([
434 #ifndef GNUPG_CONFIG_H_INCLUDED
435 #define GNUPG_CONFIG_H_INCLUDED
436 ])
437
438 #
439 # Stuff which goes at the bottom of config.h.
440 #
441 AH_BOTTOM([
442 /* This is the major version number of GnuPG so that
443    source included files can test for this.  Note, that
444    we use 2 here even for GnuPG 1.9.x. */
445 #define GNUPG_MAJOR_VERSION 2
446
447 /* Now to separate file name parts.
448    Please note that the string version must not contain more
449    than one character because the code assumes strlen()==1 */
450 #ifdef HAVE_DOSISH_SYSTEM
451 #define DIRSEP_C '\\'
452 #define DIRSEP_S "\\"
453 #define EXTSEP_C '.'
454 #define EXTSEP_S "."
455 #define PATHSEP_C ';'
456 #define PATHSEP_S ";"
457 #define EXEEXT_S ".exe"
458 #else
459 #define DIRSEP_C '/'
460 #define DIRSEP_S "/"
461 #define EXTSEP_C '.'
462 #define EXTSEP_S "."
463 #define PATHSEP_C ':'
464 #define PATHSEP_S ":"
465 #define EXEEXT_S ""
466 #endif
467
468 /* This is the same as VERSION, but should be overridden if the
469    platform cannot handle things like dots '.' in filenames. Set
470    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
471    uses for dots and dashes. */
472 #define SAFE_VERSION VERSION
473 #define SAFE_VERSION_DOT  '.'
474 #define SAFE_VERSION_DASH '-'
475
476 /* Some global constants. */
477 #ifdef HAVE_DOSISH_SYSTEM
478 # ifdef HAVE_DRIVE_LETTERS
479 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
480 # else
481 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
482 # endif
483 #elif defined(__VMS)
484 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
485 #else
486 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
487 #endif
488 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
489 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
490
491 /* For some systems (DOS currently), we hardcode the path here.  For
492    POSIX systems the values are constructed by the Makefiles, so that
493    the values may be overridden by the make invocations; this is to
494    comply with the GNU coding standards.  Note that these values are
495    only defaults.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_BINDIR      "c:\\gnupg"
499 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
500 #  define GNUPG_LIBDIR      "c:\\gnupg"
501 #  define GNUPG_DATADIR     "c:\\gnupg"
502 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
503 # else
504 #  define GNUPG_BINDIR      "\\gnupg"
505 #  define GNUPG_LIBEXECDIR  "\\gnupg"
506 #  define GNUPG_LIBDIR      "\\gnupg"
507 #  define GNUPG_DATADIR     "\\gnupg"
508 #  define GNUPG_SYSCONFDIR  "\\gnupg"
509 # endif
510 #endif
511
512 /* Derive some other constants. */
513 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
514 #define EXEC_TEMPFILE_ONLY
515 #endif
516
517
518 /* We didn't define endianness above, so get it from OS macros.  This
519    is intended for making fat binary builds on OS X. */
520 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
521 #if defined(__BIG_ENDIAN__)
522 #define BIG_ENDIAN_HOST 1
523 #elif defined(__LITTLE_ENDIAN__)
524 #define LITTLE_ENDIAN_HOST 1
525 #else
526 #error "No endianness found"
527 #endif
528 #endif
529
530
531 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
532    ldap_start_tls_s because that is the actual symbol used in the
533    library.  winldap.h redefines it to our commonly used value,
534    thus we define our usual macro here.  */
535 #ifdef HAVE_LDAP_START_TLS_SA
536 # ifndef HAVE_LDAP_START_TLS_S
537 #  define HAVE_LDAP_START_TLS_S 1
538 # endif
539 #endif
540
541 /* Provide the es_ macro for estream.  */
542 #define GPGRT_ENABLE_ES_MACROS 1
543
544 /* Tell libgcrypt not to use its own libgpg-error implementation. */
545 #define USE_LIBGPG_ERROR 1
546
547 /* Tell Libgcrypt not to include deprecated definitions.  */
548 #define GCRYPT_NO_DEPRECATED 1
549
550 /* Our HTTP code is used in estream mode.  */
551 #define HTTP_USE_ESTREAM 1
552
553 /* Under W32 we do an explicit socket initialization, thus we need to
554    avoid the on-demand initialization which would also install an atexit
555    handler.  */
556 #define HTTP_NO_WSASTARTUP
557
558 /* Under Windows we use the gettext code from libgpg-error.  */
559 #define GPG_ERR_ENABLE_GETTEXT_MACROS
560
561 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
562 #define GPG_ERR_ENABLE_ERRNO_MACROS
563
564 #endif /*GNUPG_CONFIG_H_INCLUDED*/
565 ])
566
567
568 AM_MAINTAINER_MODE
569 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
570
571 # Checks for programs.
572 AC_MSG_NOTICE([checking for programs])
573 AC_PROG_MAKE_SET
574 AM_SANITY_CHECK
575 missing_dir=`cd $ac_aux_dir && pwd`
576 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
577 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
578 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
579 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
580 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
581 AM_SILENT_RULES
582 AC_PROG_AWK
583 AC_PROG_CC
584 AC_PROG_CPP
585 AM_PROG_CC_C_O
586 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
587   AC_MSG_ERROR([[No C-89 compiler found]])
588 fi
589 AC_PROG_INSTALL
590 AC_PROG_LN_S
591 AC_PROG_RANLIB
592 AC_CHECK_TOOL(AR, ar, :)
593 AC_PATH_PROG(PERL,"perl")
594 AC_CHECK_TOOL(WINDRES, windres, :)
595 AC_ISC_POSIX
596 AC_SYS_LARGEFILE
597 GNUPG_CHECK_USTAR
598
599
600 # We need to compile and run a program on the build machine.  A
601 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
602 # the AC archive is broken for autoconf 2.57.  Given that there is no
603 # newer version of that macro, we assume that it is also broken for
604 # autoconf 2.61 and thus we use a simple but usually sufficient
605 # approach.
606 AC_MSG_CHECKING(for cc for build)
607 if test "$cross_compiling" = "yes"; then
608   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
609 else
610   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
611 fi
612 AC_MSG_RESULT($CC_FOR_BUILD)
613 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
614
615 # We need to call this macro because other pkg-config macros are
616 # not always used.
617 PKG_PROG_PKG_CONFIG
618
619
620 try_gettext=yes
621 require_iconv=yes
622 have_dosish_system=no
623 have_w32_system=no
624 have_w32ce_system=no
625 have_android_system=no
626 run_tests=yes
627 use_simple_gettext=no
628 use_ldapwrapper=yes
629 mmap_needed=yes
630 case "${host}" in
631     *-mingw32*)
632         # special stuff for Windoze NT
633         ac_cv_have_dev_random=no
634         AC_DEFINE(USE_ONLY_8DOT3,1,
635                   [Set this to limit filenames to the 8.3 format])
636         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
637                   [Because the Unix gettext has too much overhead on
638                    MingW32 systems and these systems lack Posix functions,
639                    we use a simplified version of gettext])
640         have_dosish_system=yes
641         have_w32_system=yes
642         run_tests=no
643         use_ldapwrapper=no  # Fixme: Do this only for CE.
644         case "${host}" in
645           *-mingw32ce*)
646             have_w32ce_system=yes
647             ;;
648           *)
649             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
650                       [Defined if the OS supports drive letters.])
651             ;;
652         esac
653         try_gettext="no"
654         use_simple_gettext=yes
655         mmap_needed=no
656         ;;
657     i?86-emx-os2 | i?86-*-os2*emx )
658         # OS/2 with the EMX environment
659         ac_cv_have_dev_random=no
660         AC_DEFINE(HAVE_DRIVE_LETTERS)
661         have_dosish_system=yes
662         try_gettext="no"
663         ;;
664
665     i?86-*-msdosdjgpp*)
666         # DOS with the DJGPP environment
667         ac_cv_have_dev_random=no
668         AC_DEFINE(HAVE_DRIVE_LETTERS)
669         have_dosish_system=yes
670         try_gettext="no"
671         ;;
672
673     *-*-hpux*)
674         if test -z "$GCC" ; then
675             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
676         fi
677         ;;
678     *-dec-osf4*)
679         if test -z "$GCC" ; then
680             # Suppress all warnings
681             # to get rid of the unsigned/signed char mismatch warnings.
682             CFLAGS="-w $CFLAGS"
683         fi
684         ;;
685     *-dec-osf5*)
686         if test -z "$GCC" ; then
687             # Use the newer compiler `-msg_disable ptrmismatch1' to
688             # get rid of the unsigned/signed char mismatch warnings.
689             # Using this may hide other pointer mismatch warnings, but
690             # it at least lets other warning classes through
691             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
692         fi
693         ;;
694     m68k-atari-mint)
695         ;;
696     *-linux-androideabi)
697         have_android_system=yes
698         # Android is fully utf-8 and we do not want to use iconv to
699         # keeps things simple
700         require_iconv=no
701         run_tests=no
702         ;;
703     *)
704        ;;
705 esac
706
707 if test "$have_dosish_system" = yes; then
708    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
709              [Defined if we run on some of the PCDOS like systems
710               (DOS, Windoze. OS/2) with special properties like
711               no file modes, case insensitive file names and preferred
712               use of backslashes as directory name separators.])
713 fi
714 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
715
716 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
717
718 if test "$have_w32_system" = yes; then
719    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
720    if test "$have_w32ce_system" = yes; then
721       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
722    fi
723 fi
724 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
725 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
726
727 if test "$have_android_system" = yes; then
728    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
729 fi
730 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
731
732 if test "$run_tests" = yes; then
733    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
734 fi
735 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
736
737
738 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
739 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
740
741
742 #
743 # Checks for libraries.
744 #
745 AC_MSG_NOTICE([checking for libraries])
746
747
748 #
749 # libgpg-error is a library with error codes shared between GnuPG
750 # related projects.
751 #
752 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
753                   have_gpg_error=yes,have_gpg_error=no)
754
755
756 #
757 # Libgcrypt is our generic crypto library
758 #
759 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
760         have_libgcrypt=yes,have_libgcrypt=no)
761
762
763 #
764 # libassuan is used for IPC
765 #
766 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
767                   have_libassuan=yes,have_libassuan=no)
768 if test "$have_libassuan" = "yes"; then
769   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
770                      [version of the libassuan library])
771   show_tor_support="only .onion"
772 fi
773
774
775 #
776 # libksba is our X.509 support library
777 #
778 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
779
780
781 #
782 # libusb allows us to use the integrated CCID smartcard reader driver.
783 #
784 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
785 if test "$use_ccid_driver" = yes ; then
786    case "${host}" in
787      *-mingw32*)
788        LIBUSB_LIBS=
789        LIBUSB_CPPFLAGS=
790        ;;
791      *-*-darwin*)
792        LIBUSB_LIBS="-lusb-1.0 -Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
793        ;;
794      *-*-freebsd*)
795        # FreeBSD has a native 1.0 compatible library by -lusb.
796        LIBUSB_LIBS="-lusb"
797        ;;
798      *)
799        LIBUSB_LIBS="-lusb-1.0"
800        ;;
801    esac
802 fi
803 if test x"$LIBUSB_LIBS" != x ; then
804    AC_CHECK_LIB(usb-1.0, libusb_init,
805                 [ LIBUSB_LIBS="$LIBUSB_LIBS"
806                   have_libusb=yes ])
807    AC_MSG_CHECKING([libusb include dir])
808    usb_incdir_found="no"
809    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
810      _libusb_save_cppflags=$CPPFLAGS
811      if test -n "${_incdir}"; then
812        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
813      fi
814      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
815      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
816      CPPFLAGS=${_libusb_save_cppflags}
817      if test "$usb_incdir_found" = "yes"; then
818        break
819      fi
820    done
821    if test "$usb_incdir_found" = "yes"; then
822      AC_MSG_RESULT([${usb_incdir}])
823    else
824      AC_MSG_RESULT([not found])
825      usb_incdir=""
826      have_libusb=no
827      use_ccid_driver=no
828      LIBUSB_LIBS=""
829    fi
830
831    if test "$have_libusb" = yes; then
832      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
833    fi
834    if test x"$usb_incdir" = x; then
835      LIBUSB_CPPFLAGS=""
836    else
837      LIBUSB_CPPFLAGS="-I${usb_incdir}"
838    fi
839 fi
840 AC_SUBST(LIBUSB_LIBS)
841 AC_SUBST(LIBUSB_CPPFLAGS)
842
843 #
844 # Check wether it is necessary to link against libdl.
845 # (For example to load libpcsclite)
846 #
847 gnupg_dlopen_save_libs="$LIBS"
848 LIBS=""
849 AC_SEARCH_LIBS(dlopen, c dl,,,)
850 DL_LIBS=$LIBS
851 AC_SUBST(DL_LIBS)
852 LIBS="$gnupg_dlopen_save_libs"
853
854
855 # Checks for g10
856
857 AC_ARG_ENABLE(sqlite,
858                 AC_HELP_STRING([--disable-sqlite],
859                                [disable the use of SQLITE]),
860               try_sqlite=$enableval, try_sqlite=yes)
861
862 if test x"$use_tofu" = xyes ; then
863   if test x"$try_sqlite" = xyes ; then
864     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
865                                  [have_sqlite=yes],
866                                  [have_sqlite=no])
867   fi
868   if test "$have_sqlite" = "yes"; then
869     :
870     AC_SUBST([SQLITE3_CFLAGS])
871     AC_SUBST([SQLITE3_LIBS])
872   else
873     use_tofu=no
874     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
875     AC_MSG_WARN([[
876 ***
877 *** Building without SQLite support - TOFU disabled
878 ***
879 *** $tmp]])
880   fi
881 fi
882
883 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
884
885 if test x"$use_tofu" = xyes ; then
886     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
887 fi
888
889
890 # Checks for g13
891
892 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
893 AC_DEFINE_UNQUOTED(ENCFS,
894         "${ENCFS}", [defines the filename of the encfs program])
895
896 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
897 AC_DEFINE_UNQUOTED(FUSERMOUNT,
898         "${FUSERMOUNT}", [defines the filename of the fusermount program])
899
900
901 # Checks for dirmngr
902
903
904 #
905 # Checks for symcryptrun:
906 #
907
908 # libutil has openpty() and login_tty().
909 AC_CHECK_LIB(util, openpty,
910               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
911                 AC_DEFINE(HAVE_LIBUTIL,1,
912                          [defined if libutil is available])
913              ])
914 AC_SUBST(LIBUTIL_LIBS)
915
916 # shred is used to clean temporary plain text files.
917 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
918 AC_DEFINE_UNQUOTED(SHRED,
919         "${SHRED}", [defines the filename of the shred program])
920
921
922 #
923 # Check whether the nPth library is available
924 #
925 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
926 if test "$have_npth" = "yes"; then
927   AC_DEFINE(HAVE_NPTH, 1,
928               [Defined if the New Portable Thread Library is available])
929   AC_DEFINE(USE_NPTH, 1,
930               [Defined if support for nPth is requested and nPth is available])
931 else
932   AC_MSG_WARN([[
933 ***
934 *** To support concurrent access for example in gpg-agent and the SCdaemon
935 *** we need the support of the New Portable Threads Library.
936 ***]])
937 fi
938
939
940 #
941 # NTBTLS is our TLS library.  If it is not available fallback to
942 # GNUTLS.
943 #
944 AC_ARG_ENABLE(ntbtls,
945               AC_HELP_STRING([--disable-ntbtls],
946                              [disable the use of NTBTLS as TLS library]),
947               try_ntbtls=$enableval, try_ntbtls=yes)
948 if test x"$try_ntbtls" = xyes ; then
949   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
950                  [have_ntbtls=yes],[have_ntbtls=no])
951 fi
952 if test "$have_ntbtls" = yes ; then
953    use_tls_library=ntbtls
954    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
955 else
956   AC_ARG_ENABLE(gnutls,
957                 AC_HELP_STRING([--disable-gnutls],
958                                [disable GNUTLS as fallback TLS library]),
959                 try_gnutls=$enableval, try_gnutls=yes)
960   if test x"$try_gnutls" = xyes ; then
961     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
962                                    [have_gnutls=yes],
963                                    [have_gnutls=no])
964   fi
965   if test "$have_gnutls" = "yes"; then
966     AC_SUBST([LIBGNUTLS_CFLAGS])
967     AC_SUBST([LIBGNUTLS_LIBS])
968     use_tls_library=gnutls
969     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
970   else
971     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
972     AC_MSG_WARN([[
973 ***
974 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
975 ***
976 *** $tmp]])
977   fi
978 fi
979
980
981 AC_MSG_NOTICE([checking for networking options])
982
983 #
984 # Must check for network library requirements before doing link tests
985 # for ldap, for example. If ldap libs are static (or dynamic and without
986 # ELF runtime link paths), then link will fail and LDAP support won't
987 # be detected.
988 #
989 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
990         [NETLIBS="-lnsl $NETLIBS"]))
991 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
992         [NETLIBS="-lsocket $NETLIBS"]))
993
994
995 #
996 # Check for ADNS.
997 #
998 _cppflags="${CPPFLAGS}"
999 _ldflags="${LDFLAGS}"
1000 AC_ARG_WITH(adns,
1001             AC_HELP_STRING([--with-adns=DIR],
1002                            [look for the adns library in DIR]),
1003             [if test -d "$withval"; then
1004                CPPFLAGS="${CPPFLAGS} -I$withval/include"
1005                LDFLAGS="${LDFLAGS} -L$withval/lib"
1006              fi])
1007 if test "$with_adns" != "no"; then
1008   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
1009   AC_CHECK_FUNCS(adns_free)
1010   AC_MSG_CHECKING([if adns supports adns_if_tormode])
1011   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1012     #include <adns.h>
1013     adns_initflags flags = adns_if_tormode;
1014   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
1015   AC_MSG_RESULT($adns_if_tormode)
1016   if test x"$adns_if_tormode" = xyes; then
1017     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
1018     if test "$show_tor_support" != "no"; then
1019       show_tor_support=yes
1020     fi
1021   fi
1022 fi
1023 CPPFLAGS=${_cppflags}
1024 LDFLAGS=${_ldflags}
1025 if test "$have_adns" = "yes"; then
1026   ADNSLIBS="-ladns"
1027 fi
1028
1029
1030 #
1031 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
1032 #
1033 AC_ARG_ENABLE(dns-srv,
1034               AC_HELP_STRING([--disable-dns-srv],
1035                              [disable the use of DNS SRV in HKP and HTTP]),
1036               use_dns_srv=$enableval,use_dns_srv=yes)
1037
1038 AC_ARG_ENABLE(dns-cert,
1039    AC_HELP_STRING([--disable-dns-cert],
1040         [disable the use of CERT records in DNS]),
1041    use_dns_cert=$enableval,use_dns_cert=yes)
1042
1043 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
1044   _dns_save_libs=$LIBS
1045   LIBS=""
1046
1047   if test x"$have_adns" = xyes ; then
1048     # We prefer ADNS.
1049     DNSLIBS="$ADNSLIBS"
1050     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1051
1052     if test x"$use_dns_srv" = xyes ; then
1053         AC_DEFINE(USE_DNS_SRV,1)
1054     fi
1055
1056     if test x"$use_dns_cert" = xyes ; then
1057         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1058     fi
1059   else
1060     # With no ADNS find the system resolver.
1061
1062     # the double underscore thing is a glibc-ism?
1063     AC_SEARCH_LIBS(res_query,resolv bind,,
1064                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1065     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1066                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1067     AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1068                    AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
1069
1070     if test x"$have_resolver" != xno ; then
1071
1072       # Make sure that the BIND 4 resolver interface is workable before
1073       # enabling any code that calls it.  At some point I'll rewrite the
1074       # code to use the BIND 8 resolver API.
1075       # We might also want to use adns instead.  Problem with ADNS is that
1076       # it does not support v6.
1077
1078       AC_MSG_CHECKING([whether the resolver is usable])
1079       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1080 #include <netinet/in.h>
1081 #include <arpa/nameser.h>
1082 #include <resolv.h>]],
1083 [[unsigned char answer[PACKETSZ];
1084   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1085   dn_skipname(0,0);
1086   dn_expand(0,0,0,0,0);
1087 ]])],have_resolver=yes,have_resolver=no)
1088       AC_MSG_RESULT($have_resolver)
1089
1090       # This is Apple-specific and somewhat bizarre as they changed the
1091       # define in bind 8 for some reason.
1092
1093       if test x"$have_resolver" != xyes ; then
1094          AC_MSG_CHECKING(
1095              [whether I can make the resolver usable with BIND_8_COMPAT])
1096         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1097 #include <sys/types.h>
1098 #include <netinet/in.h>
1099 #include <arpa/nameser.h>
1100 #include <resolv.h>]],
1101 [[unsigned char answer[PACKETSZ];
1102   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1103   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1104 ]])],[have_resolver=yes ; need_compat=yes])
1105          AC_MSG_RESULT($have_resolver)
1106       fi
1107     fi
1108
1109     if test x"$have_resolver" = xyes ; then
1110       DNSLIBS=$LIBS
1111
1112       if test x"$use_dns_srv" = xyes ; then
1113          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1114       fi
1115
1116       if test x"$use_dns_cert" = xyes ; then
1117         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1118       fi
1119
1120       if test x"$need_compat" = xyes ; then
1121         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1122       fi
1123     else
1124       use_dns_srv=no
1125       use_dns_cert=no
1126     fi
1127   fi
1128
1129   LIBS=$_dns_save_libs
1130 fi
1131
1132 AC_SUBST(DNSLIBS)
1133
1134 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1135
1136
1137 #
1138 # Check for LDAP
1139 #
1140 # Note that running the check changes the variable
1141 # gnupg_have_ldap from "n/a" to "no" or "yes".
1142
1143 AC_ARG_ENABLE(ldap,
1144     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1145     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1146
1147 if test "$gnupg_have_ldap" != "no" ; then
1148   if test "$build_dirmngr" = "yes" ; then
1149      GNUPG_CHECK_LDAP($NETLIBS)
1150      AC_CHECK_LIB(lber, ber_free,
1151                   [ LBER_LIBS="$LBER_LIBS -llber"
1152                     AC_DEFINE(HAVE_LBER,1,
1153                              [defined if liblber is available])
1154                     have_lber=yes
1155                  ])
1156   fi
1157 fi
1158 AC_SUBST(LBER_LIBS)
1159 if test "$gnupg_have_ldap" = "no"; then
1160     AC_MSG_WARN([[
1161 ***
1162 *** Building without LDAP support.
1163 *** No CRL access or X.509 certificate search available.
1164 ***]])
1165 fi
1166
1167 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1168 if test "$gnupg_have_ldap" = yes ; then
1169   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1170 else
1171  use_ldapwrapper=no
1172 fi
1173
1174 if test "$use_ldapwrapper" = yes; then
1175    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1176 fi
1177 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1178
1179
1180
1181
1182 #
1183 # Check for sendmail
1184 #
1185 # This isn't necessarily sendmail itself, but anything that gives a
1186 # sendmail-ish interface to the outside world.  That includes Exim,
1187 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1188 AC_ARG_WITH(mailprog,
1189       AC_HELP_STRING([--with-mailprog=NAME],
1190                      [use "NAME -t" for mail transport]),
1191              ,with_mailprog=yes)
1192 if test x"$with_mailprog" = xyes ; then
1193     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1194 elif test x"$with_mailprog" != xno ; then
1195     AC_MSG_CHECKING([for a mail transport program])
1196     AC_SUBST(SENDMAIL,$with_mailprog)
1197     AC_MSG_RESULT($with_mailprog)
1198 fi
1199
1200
1201 #
1202 # Construct a printable name of the OS
1203 #
1204 case "${host}" in
1205     *-mingw32ce*)
1206         PRINTABLE_OS_NAME="W32CE"
1207         ;;
1208     *-mingw32*)
1209         PRINTABLE_OS_NAME="MingW32"
1210         ;;
1211     *-*-cygwin*)
1212         PRINTABLE_OS_NAME="Cygwin"
1213         ;;
1214     i?86-emx-os2 | i?86-*-os2*emx )
1215         PRINTABLE_OS_NAME="OS/2"
1216         ;;
1217     i?86-*-msdosdjgpp*)
1218         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1219         try_dynload=no
1220         ;;
1221     *-linux*)
1222         PRINTABLE_OS_NAME="GNU/Linux"
1223         ;;
1224     *)
1225         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1226         ;;
1227 esac
1228 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1229                    [A human readable text with the name of the OS])
1230
1231
1232 #
1233 # Checking for iconv
1234 #
1235 if test "$require_iconv" = yes; then
1236   AM_ICONV
1237 else
1238   LIBICONV=
1239   LTLIBICONV=
1240   AC_SUBST(LIBICONV)
1241   AC_SUBST(LTLIBICONV)
1242 fi
1243
1244
1245 #
1246 # Check for gettext
1247 #
1248 # This is "GNU gnupg" - The project-id script from gettext
1249 #                       needs this string
1250 #
1251 AC_MSG_NOTICE([checking for gettext])
1252 AM_PO_SUBDIRS
1253 AM_GNU_GETTEXT_VERSION([0.17])
1254 if test "$try_gettext" = yes; then
1255   AM_GNU_GETTEXT([external],[need-ngettext])
1256
1257   # gettext requires some extra checks.  These really should be part of
1258   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1259   # function checks to here.
1260
1261   AC_CHECK_FUNCS(strchr)
1262 else
1263   USE_NLS=no
1264   USE_INCLUDED_LIBINTL=no
1265   BUILD_INCLUDED_LIBINTL=no
1266   POSUB=po
1267   AC_SUBST(USE_NLS)
1268   AC_SUBST(USE_INCLUDED_LIBINTL)
1269   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1270   AC_SUBST(POSUB)
1271 fi
1272
1273 # We use HAVE_LANGINFO_CODESET in a couple of places.
1274 AM_LANGINFO_CODESET
1275
1276 # Checks required for our use of locales
1277 gt_LC_MESSAGES
1278
1279
1280 #
1281 # SELinux support
1282 #
1283 if test "$selinux_support" = yes ; then
1284   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1285 fi
1286
1287
1288 #
1289 # Checks for header files.
1290 #
1291 AC_MSG_NOTICE([checking for header files])
1292 AC_HEADER_STDC
1293 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1294                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1295                   signal.h])
1296 AC_HEADER_TIME
1297
1298
1299 #
1300 # Checks for typedefs, structures, and compiler characteristics.
1301 #
1302 AC_MSG_NOTICE([checking for system characteristics])
1303 AC_C_CONST
1304 AC_C_INLINE
1305 AC_C_VOLATILE
1306 AC_TYPE_SIZE_T
1307 AC_TYPE_MODE_T
1308 AC_TYPE_SIGNAL
1309 AC_DECL_SYS_SIGLIST
1310
1311 gl_HEADER_SYS_SOCKET
1312 gl_TYPE_SOCKLEN_T
1313
1314 AC_SEARCH_LIBS([inet_addr], [nsl])
1315
1316 AC_ARG_ENABLE(endian-check,
1317               AC_HELP_STRING([--disable-endian-check],
1318               [disable the endian check and trust the OS provided macros]),
1319               endiancheck=$enableval,endiancheck=yes)
1320
1321 if test x"$endiancheck" = xyes ; then
1322   GNUPG_CHECK_ENDIAN
1323 fi
1324
1325 # fixme: we should get rid of the byte type
1326 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1327 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1328 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1329 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1330 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1331
1332 AC_CHECK_SIZEOF(unsigned short)
1333 AC_CHECK_SIZEOF(unsigned int)
1334 AC_CHECK_SIZEOF(unsigned long)
1335 AC_CHECK_SIZEOF(unsigned long long)
1336 AC_HEADER_TIME
1337 AC_CHECK_SIZEOF(time_t,,[[
1338 #include <stdio.h>
1339 #if TIME_WITH_SYS_TIME
1340 # include <sys/time.h>
1341 # include <time.h>
1342 #else
1343 # if HAVE_SYS_TIME_H
1344 #  include <sys/time.h>
1345 # else
1346 #  include <time.h>
1347 # endif
1348 #endif
1349 ]])
1350 GNUPG_TIME_T_UNSIGNED
1351
1352
1353 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1354    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1355    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1356     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1357 fi
1358
1359
1360 #
1361 # Checks for library functions.
1362 #
1363 AC_MSG_NOTICE([checking for library functions])
1364 AC_CHECK_DECLS(getpagesize)
1365 AC_FUNC_FSEEKO
1366 AC_FUNC_VPRINTF
1367 AC_FUNC_FORK
1368 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1369 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1370 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1371 AC_CHECK_FUNCS([canonicalize_file_name])
1372 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1373 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1374 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1375 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1376 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1377                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1378                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1379                 getenv inet_pton strpbrk])
1380
1381 if test "$have_android_system" = yes; then
1382    # On Android ttyname is a stub but prints an error message.
1383    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1384              [Defined if ttyname does not work properly])
1385 fi
1386
1387 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1388
1389 # Dirmngr requires mmap on Unix systems.
1390 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1391   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1392 fi
1393
1394 #
1395 # W32 specific test
1396 #
1397 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1398
1399 #
1400 # Sanity check regex.  Tests adapted from mutt.
1401 #
1402 AC_MSG_CHECKING([whether regular expression support is requested])
1403 AC_ARG_ENABLE(regex,
1404   AC_HELP_STRING([--disable-regex],
1405     [do not handle regular expressions in trust signatures]),
1406   use_regex=$enableval, use_regex=yes)
1407 AC_MSG_RESULT($use_regex)
1408
1409 if test "$use_regex" = yes ; then
1410   _cppflags="${CPPFLAGS}"
1411   _ldflags="${LDFLAGS}"
1412   AC_ARG_WITH(regex,
1413      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1414       [
1415       if test -d "$withval" ; then
1416         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1417         LDFLAGS="${LDFLAGS} -L$withval/lib"
1418       fi
1419       ],withval="")
1420
1421   # Does the system have regex functions at all?
1422   AC_SEARCH_LIBS([regcomp], [regex])
1423   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1424
1425   if test $gnupg_cv_have_regex = no; then
1426     use_regex=no
1427   else
1428     if test x"$cross_compiling" = xyes; then
1429       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1430     else
1431       AC_CACHE_CHECK([whether your system's regexp library is broken],
1432        [gnupg_cv_regex_broken],
1433        AC_TRY_RUN([
1434 #include <unistd.h>
1435 #include <regex.h>
1436 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1437        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1438
1439       if test $gnupg_cv_regex_broken = yes; then
1440         AC_MSG_WARN([your regex is broken - disabling regex use])
1441         use_regex=no
1442       fi
1443     fi
1444   fi
1445   CPPFLAGS="${_cppflags}"
1446   LDFLAGS="${_ldflags}"
1447 fi
1448
1449 if test "$use_regex" != yes ; then
1450   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1451 fi
1452 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1453
1454
1455
1456 #
1457 # Do we have zlib? Must do it here because Solaris failed
1458 # when compiling a conftest (due to the "-lz" from LIBS).
1459 # Note that we combine zlib and bzlib2 in ZLIBS.
1460 #
1461 if test "$use_zip" = yes ; then
1462   _cppflags="${CPPFLAGS}"
1463   _ldflags="${LDFLAGS}"
1464   AC_ARG_WITH(zlib,
1465     [  --with-zlib=DIR         use libz in DIR],[
1466       if test -d "$withval"; then
1467         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1468         LDFLAGS="${LDFLAGS} -L$withval/lib"
1469       fi
1470     ])
1471
1472   AC_CHECK_HEADER(zlib.h,
1473      AC_CHECK_LIB(z, deflateInit2_,
1474        [
1475        ZLIBS="-lz"
1476        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1477        ],
1478        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1479        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1480 fi
1481
1482
1483 #
1484 # Check whether we can support bzip2
1485 #
1486 if test "$use_bzip2" = yes ; then
1487   _cppflags="${CPPFLAGS}"
1488   _ldflags="${LDFLAGS}"
1489   AC_ARG_WITH(bzip2,
1490      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1491       [
1492       if test -d "$withval" ; then
1493         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1494         LDFLAGS="${LDFLAGS} -L$withval/lib"
1495       fi
1496       ],withval="")
1497
1498   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1499   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1500   # woefully out of date.
1501   if test "$withval" != no ; then
1502      AC_CHECK_HEADER(bzlib.h,
1503         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1504           [
1505           have_bz2=yes
1506           ZLIBS="$ZLIBS -lbz2"
1507           AC_DEFINE(HAVE_BZIP2,1,
1508                   [Defined if the bz2 compression library is available])
1509           ],
1510           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1511           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1512   fi
1513 fi
1514 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1515 AC_SUBST(ZLIBS)
1516
1517
1518 # Check for readline support
1519 GNUPG_CHECK_READLINE
1520
1521
1522 if test "$development_version" = yes; then
1523     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1524             [Defined if this is not a regular release])
1525 fi
1526
1527 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1528
1529 GNUPG_CHECK_GNUMAKE
1530
1531 # Add some extra libs here so that previous tests don't fail for
1532 # mysterious reasons - the final link step should bail out.
1533 # W32SOCKLIBS is also defined so that if can be used for tools not
1534 # requiring any network stuff but linking to code in libcommon which
1535 # tracks in winsock stuff (e.g. init_common_subsystems).
1536 if test "$have_w32_system" = yes; then
1537    if test "$have_w32ce_system" = yes; then
1538      W32SOCKLIBS="-lws2"
1539    else
1540      W32SOCKLIBS="-lws2_32"
1541    fi
1542    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1543 fi
1544
1545 AC_SUBST(NETLIBS)
1546 AC_SUBST(W32SOCKLIBS)
1547
1548 #
1549 # Setup gcc specific options
1550 #
1551 AC_MSG_NOTICE([checking for cc features])
1552 if test "$GCC" = yes; then
1553     mycflags=
1554     mycflags_save=$CFLAGS
1555
1556     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1557     # options.  This is the case for gcc >= 4.6
1558     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1559     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1560 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1561 #kickerror
1562 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1563     AC_MSG_RESULT($_gcc_silent_wno)
1564
1565     # Note that it is okay to use CFLAGS here because these are just
1566     # warning options and the user should have a chance of overriding
1567     # them.
1568     if test "$USE_MAINTAINER_MODE" = "yes"; then
1569         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1570         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1571         if test x"$_gcc_silent_wno" = xyes ; then
1572           _gcc_wopt=yes
1573         else
1574           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1575           CFLAGS="-Wno-missing-field-initializers"
1576           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1577                             [_gcc_wopt=yes],[_gcc_wopt=no])
1578           AC_MSG_RESULT($_gcc_wopt)
1579         fi
1580         if test x"$_gcc_wopt" = xyes ; then
1581           mycflags="$mycflags -W -Wno-sign-compare"
1582           mycflags="$mycflags -Wno-missing-field-initializers"
1583         fi
1584
1585         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1586         CFLAGS="-Wdeclaration-after-statement"
1587         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1588         AC_MSG_RESULT($_gcc_wopt)
1589         if test x"$_gcc_wopt" = xyes ; then
1590           mycflags="$mycflags -Wdeclaration-after-statement"
1591         fi
1592     else
1593         mycflags="$mycflags -Wall"
1594     fi
1595
1596     if test x"$_gcc_silent_wno" = xyes ; then
1597       _gcc_psign=yes
1598     else
1599       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1600       CFLAGS="-Wno-pointer-sign"
1601       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1602                         [_gcc_psign=yes],[_gcc_psign=no])
1603       AC_MSG_RESULT($_gcc_psign)
1604     fi
1605     if test x"$_gcc_psign" = xyes ; then
1606        mycflags="$mycflags -Wno-pointer-sign"
1607     fi
1608
1609     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1610     CFLAGS="-Wpointer-arith"
1611     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1612     AC_MSG_RESULT($_gcc_psign)
1613     if test x"$_gcc_psign" = xyes ; then
1614        mycflags="$mycflags -Wpointer-arith"
1615     fi
1616
1617     CFLAGS="$mycflags $mycflags_save"
1618 fi
1619
1620
1621 #
1622 # This is handy for debugging so the compiler doesn't rearrange
1623 # things and eliminate variables.
1624 #
1625 AC_ARG_ENABLE(optimization,
1626    AC_HELP_STRING([--disable-optimization],
1627                   [disable compiler optimization]),
1628                   [if test $enableval = no ; then
1629                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1630                    fi])
1631
1632 #
1633 # Add user CFLAGS.
1634 #
1635 CFLAGS="$CFLAGS $CFLAGS_orig"
1636
1637 #
1638 # Decide what to build
1639 #
1640
1641 build_scdaemon_extra=""
1642 if test "$build_scdaemon" = "yes"; then
1643   if test $have_libusb = no; then
1644      build_scdaemon_extra="without internal CCID driver"
1645   fi
1646   if test -n "$build_scdaemon_extra"; then
1647      build_scdaemon_extra="(${build_scdaemon_extra})"
1648   fi
1649 fi
1650
1651
1652 #
1653 # Set variables for use by automake makefiles.
1654 #
1655 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1656 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1657 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1658 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1659 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1660 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1661 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1662 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1663 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1664 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1665
1666 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1667 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1668 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1669
1670 AM_CONDITIONAL(RUN_GPG_TESTS,
1671                test x$cross_compiling = xno -a "$build_gpg" = yes )
1672
1673 #
1674 # Set some defines for use gpgconf.
1675 #
1676 if test "$build_gpg" = yes ; then
1677     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1678 fi
1679 if test "$build_gpgsm" = yes ; then
1680     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1681 fi
1682 if test "$build_agent" = yes ; then
1683     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1684 fi
1685 if test "$build_scdaemon" = yes ; then
1686     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1687 fi
1688 if test "$build_dirmngr" = yes ; then
1689     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1690 fi
1691 if test "$build_g13" = yes ; then
1692     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1693 fi
1694
1695
1696 #
1697 # Define Name strings
1698 #
1699 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1700
1701 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1702 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1703
1704 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1705 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1706
1707 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1708 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1709                                         [The displayed name of gpg-agent])
1710
1711 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1712 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1713                                        [The displayed name of scdaemon])
1714
1715 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1716 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1717                                       [The displayed name of dirmngr])
1718
1719 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1720 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1721
1722 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1723 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1724                                       [The displayed name of gpgconf])
1725
1726 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1727
1728 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1729                    [The name of the agent socket])
1730 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1731                    [The name of the agent socket for ssh])
1732 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1733                    [The name of the dirmngr info envvar])
1734 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1735                    [The name of the SCdaemon socket])
1736 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1737                    [The name of the dirmngr socket])
1738
1739 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1740
1741 if test "$have_w32_system" = yes; then
1742   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1743                      [The directory part of the W32 registry keys])
1744 fi
1745
1746
1747 #
1748 # Provide information about the build.
1749 #
1750 BUILD_REVISION="mym4_revision"
1751 AC_SUBST(BUILD_REVISION)
1752 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1753                    [GIT commit id revision used to build this package])
1754
1755 changequote(,)dnl
1756 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1757 changequote([,])dnl
1758 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1759 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1760 AC_SUBST(BUILD_VERSION)
1761 AC_SUBST(BUILD_FILEVERSION)
1762
1763 AC_ARG_ENABLE([build-timestamp],
1764   AC_HELP_STRING([--enable-build-timestamp],
1765                  [set an explicit build timestamp for reproducibility.
1766                   (default is the current time in ISO-8601 format)]),
1767      [if test "$enableval" = "yes"; then
1768         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1769       else
1770         BUILD_TIMESTAMP="$enableval"
1771       fi],
1772      [BUILD_TIMESTAMP="<none>"])
1773 AC_SUBST(BUILD_TIMESTAMP)
1774 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1775                    [The time this package was configured for a build])
1776 BUILD_HOSTNAME="$ac_hostname"
1777 AC_SUBST(BUILD_HOSTNAME)
1778
1779
1780 #
1781 # Print errors here so that they are visible all
1782 # together and the user can acquire them all together.
1783 #
1784 die=no
1785 if test "$have_gpg_error" = "no"; then
1786    die=yes
1787    AC_MSG_NOTICE([[
1788 ***
1789 *** You need libgpg-error to build this program.
1790 **  This library is for example available at
1791 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1792 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1793 ***]])
1794 fi
1795 if test "$have_libgcrypt" = "no"; then
1796    die=yes
1797    AC_MSG_NOTICE([[
1798 ***
1799 *** You need libgcrypt to build this program.
1800 **  This library is for example available at
1801 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1802 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1803 ***]])
1804 fi
1805 if test "$have_libassuan" = "no"; then
1806    die=yes
1807    AC_MSG_NOTICE([[
1808 ***
1809 *** You need libassuan to build this program.
1810 *** This library is for example available at
1811 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1812 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1813 ***]])
1814 fi
1815 if test "$have_ksba" = "no"; then
1816     die=yes
1817     AC_MSG_NOTICE([[
1818 ***
1819 *** You need libksba to build this program.
1820 *** This library is for example available at
1821 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1822 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1823 ***]])
1824 fi
1825 if test "$gnupg_have_ldap" = yes; then
1826   if test "$have_w32ce_system" = yes; then
1827     AC_MSG_NOTICE([[
1828 *** Note that CeGCC might be broken, a package fixing this is:
1829 ***    http://files.kolab.org/local/windows-ce/
1830 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1831 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1832 ***]])
1833    fi
1834 fi
1835 if test "$have_npth" = "no"; then
1836     die=yes
1837     AC_MSG_NOTICE([[
1838 ***
1839 *** It is now required to build with support for the
1840 *** New Portable Threads Library (nPth). Please install this
1841 *** library first.  The library is for example available at
1842 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1843 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1844 ***]])
1845 fi
1846
1847 if test "$require_iconv" = yes; then
1848   if test "$am_func_iconv" != yes; then
1849     die=yes
1850     AC_MSG_NOTICE([[
1851 ***
1852 *** The system does not provide a working iconv function.  Please
1853 *** install a suitable library; for example GNU Libiconv which is
1854 *** available at:
1855 ***   http://ftp.gnu.org/gnu/libiconv/
1856 ***]])
1857   fi
1858 fi
1859
1860 if test "$die" = "yes"; then
1861     AC_MSG_ERROR([[
1862 ***
1863 *** Required libraries not found. Please consult the above messages
1864 *** and install them before running configure again.
1865 ***]])
1866 fi
1867
1868
1869
1870 AC_CONFIG_FILES([ m4/Makefile
1871 Makefile
1872 po/Makefile.in
1873 common/Makefile
1874 common/w32info-rc.h
1875 kbx/Makefile
1876 g10/Makefile
1877 sm/Makefile
1878 agent/Makefile
1879 scd/Makefile
1880 g13/Makefile
1881 dirmngr/Makefile
1882 tools/gpg-zip
1883 tools/Makefile
1884 doc/Makefile
1885 tests/Makefile
1886 tests/openpgp/Makefile
1887 tests/pkits/Makefile
1888 g10/gpg.w32-manifest
1889 ])
1890
1891
1892 AC_OUTPUT
1893
1894
1895 echo "
1896         GnuPG v${VERSION} has been configured as follows:
1897
1898         Revision:  mym4_revision  (mym4_revision_dec)
1899         Platform:  $PRINTABLE_OS_NAME ($host)
1900
1901         OpenPGP:   $build_gpg
1902         S/MIME:    $build_gpgsm
1903         Agent:     $build_agent
1904         Smartcard: $build_scdaemon $build_scdaemon_extra
1905         G13:       $build_g13
1906         Dirmngr:   $build_dirmngr
1907         Gpgtar:    $build_gpgtar
1908
1909         Protect tool:      $show_gnupg_protect_tool_pgm
1910         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1911         Default agent:     $show_gnupg_agent_pgm
1912         Default pinentry:  $show_gnupg_pinentry_pgm
1913         Default scdaemon:  $show_gnupg_scdaemon_pgm
1914         Default dirmngr:   $show_gnupg_dirmngr_pgm
1915
1916         Dirmngr auto start:  $dirmngr_auto_start
1917         Readline support:    $gnupg_cv_have_readline
1918         LDAP support:        $gnupg_have_ldap
1919         DNS SRV support:     $use_dns_srv
1920         TLS support:         $use_tls_library
1921         TOFU support:        $use_tofu
1922         Tor support:         $show_tor_support
1923 "
1924 if test x"$use_regex" != xyes ; then
1925 echo "
1926         Warning: No regular expression support available.
1927                  OpenPGP trust signatures won't work.
1928                  gpg-check-pattern will not be built.
1929 "
1930 fi
1931 if test "x${gpg_config_script_warn}" != x; then
1932 cat <<G10EOF
1933         Warning: Mismatches between the target platform and the
1934                  to be used libraries have been detected for:
1935                   ${gpg_config_script_warn}
1936                  Please check above for more warning messages.
1937
1938 G10EOF
1939 fi