gpgconf, w32: Allow UNC paths
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2018 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [2])
31 m4_define([mym4_micro], [6])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg22", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.5.0
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119
120 GNUPG_BUILD_PROGRAM(gpg, yes)
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([whether to enable trust models])
248 AC_ARG_ENABLE(trust-models,
249               AC_HELP_STRING([--disable-trust-models],
250                              [disable all trust models except "always"]),
251               use_trust_models=$enableval)
252 AC_MSG_RESULT($use_trust_models)
253 if test "$use_trust_models" = no ; then
254     AC_DEFINE(NO_TRUST_MODELS, 1,
255              [Define to include only trust-model always])
256 fi
257
258 AC_MSG_CHECKING([whether to enable TOFU])
259 AC_ARG_ENABLE(tofu,
260                 AC_HELP_STRING([--disable-tofu],
261                                [disable the TOFU trust model]),
262               use_tofu=$enableval, use_tofu=$use_trust_models)
263 AC_MSG_RESULT($use_tofu)
264 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
265     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
266 fi
267
268 AC_MSG_CHECKING([whether to enable libdns])
269 AC_ARG_ENABLE(libdns,
270                 AC_HELP_STRING([--disable-libdns],
271                                [do not build with libdns support]),
272               use_libdns=$enableval, use_libdns=yes)
273 AC_MSG_RESULT($use_libdns)
274 if test x"$use_libdns" = xyes ; then
275     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
276 fi
277 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
278
279
280 #
281 # Options to disable algorithm
282 #
283
284 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
285 # Elgamal is a MUST algorithm
286 # DSA is a MUST algorithm
287 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
288 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
289 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
290
291 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
292 # 3DES is a MUST algorithm
293 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
294 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
295 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
296 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
297 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
298 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
299 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
300 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
301 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
302
303 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
304 # SHA1 is a MUST algorithm
305 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
306 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
307 # SHA256 is a MUST algorithm for GnuPG.
308 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
309 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
310
311
312 # Allow disabling of zip support.
313 # This is in general not a good idea because according to rfc4880 OpenPGP
314 # implementations SHOULD support ZLIB.
315 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
316 AC_ARG_ENABLE(zip,
317    AC_HELP_STRING([--disable-zip],
318                   [disable the ZIP and ZLIB compression algorithm]),
319    use_zip=$enableval)
320 AC_MSG_RESULT($use_zip)
321
322 # Allow disabling of bzib2 support.
323 # It is defined only after we confirm the library is available later
324 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
325 AC_ARG_ENABLE(bzip2,
326    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
327    use_bzip2=$enableval)
328 AC_MSG_RESULT($use_bzip2)
329
330 # Configure option to allow or disallow execution of external
331 # programs, like a photo viewer.
332 AC_MSG_CHECKING([whether to enable external program execution])
333 AC_ARG_ENABLE(exec,
334     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
335     use_exec=$enableval)
336 AC_MSG_RESULT($use_exec)
337 if test "$use_exec" = no ; then
338     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
339 fi
340
341 if test "$use_exec" = yes ; then
342   AC_MSG_CHECKING([whether to enable photo ID viewing])
343   AC_ARG_ENABLE(photo-viewers,
344       [  --disable-photo-viewers disable photo ID viewers],
345       [if test "$enableval" = no ; then
346          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
347       fi],enableval=yes)
348   gnupg_cv_enable_photo_viewers=$enableval
349   AC_MSG_RESULT($enableval)
350
351   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
352     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
353     AC_ARG_WITH(photo-viewer,
354         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
355         [if test "$withval" = yes ; then
356            withval=no
357         elif test "$withval" != no ; then
358            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
359                             [if set, restrict photo-viewer to this])
360         fi],withval=no)
361     AC_MSG_RESULT($withval)
362   fi
363 fi
364
365
366 #
367 # Check for the key/uid cache size.  This can't be zero, but can be
368 # pretty small on embedded systems.  This is used for the gpg part.
369 #
370 AC_MSG_CHECKING([for the size of the key and uid cache])
371 AC_ARG_ENABLE(key-cache,
372         AC_HELP_STRING([--enable-key-cache=SIZE],
373                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
374 if test "$enableval" = "no"; then
375    enableval=5
376 elif test "$enableval" = "yes" || test "$enableval" = ""; then
377    enableval=4096
378 fi
379 changequote(,)dnl
380 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
381 changequote([,])dnl
382 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
383    AC_MSG_ERROR([invalid key-cache size])
384 fi
385 AC_MSG_RESULT($key_cache_size)
386 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
387                   [Size of the key and UID caches])
388
389
390
391 #
392 # Check whether we want to use Linux capabilities
393 #
394 AC_MSG_CHECKING([whether use of capabilities is requested])
395 AC_ARG_WITH(capabilities,
396     [  --with-capabilities     use linux capabilities [default=no]],
397 [use_capabilities="$withval"],[use_capabilities=no])
398 AC_MSG_RESULT($use_capabilities)
399
400 #
401 # Check whether to disable the card support
402 AC_MSG_CHECKING([whether smartcard support is requested])
403 AC_ARG_ENABLE(card-support,
404               AC_HELP_STRING([--disable-card-support],
405                              [disable smartcard support]),
406               card_support=$enableval)
407 AC_MSG_RESULT($card_support)
408 if test "$card_support" = yes ; then
409   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
410 else
411   build_scdaemon=no
412 fi
413
414 #
415 # Allow disabling of internal CCID support.
416 # It is defined only after we confirm the library is available later
417 #
418 AC_MSG_CHECKING([whether to enable the internal CCID driver])
419 AC_ARG_ENABLE(ccid-driver,
420               AC_HELP_STRING([--disable-ccid-driver],
421                              [disable the internal CCID driver]),
422               use_ccid_driver=$enableval)
423 AC_MSG_RESULT($use_ccid_driver)
424
425 AC_MSG_CHECKING([whether to auto start dirmngr])
426 AC_ARG_ENABLE(dirmngr-auto-start,
427               AC_HELP_STRING([--disable-dirmngr-auto-start],
428                              [disable auto starting of the dirmngr]),
429               dirmngr_auto_start=$enableval)
430 AC_MSG_RESULT($dirmngr_auto_start)
431 if test "$dirmngr_auto_start" = yes ; then
432     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
433               [Define to enable auto starting of the dirmngr])
434 fi
435
436
437 #
438 # To avoid double inclusion of config.h which might happen at some
439 # places, we add the usual double inclusion protection at the top of
440 # config.h.
441 #
442 AH_TOP([
443 #ifndef GNUPG_CONFIG_H_INCLUDED
444 #define GNUPG_CONFIG_H_INCLUDED
445 ])
446
447 #
448 # Stuff which goes at the bottom of config.h.
449 #
450 AH_BOTTOM([
451 /* This is the major version number of GnuPG so that
452    source included files can test for this.  Note, that
453    we use 2 here even for GnuPG 1.9.x. */
454 #define GNUPG_MAJOR_VERSION 2
455
456 /* Now to separate file name parts.
457    Please note that the string version must not contain more
458    than one character because the code assumes strlen()==1 */
459 #ifdef HAVE_DOSISH_SYSTEM
460 #define DIRSEP_C '\\'
461 #define DIRSEP_S "\\"
462 #define EXTSEP_C '.'
463 #define EXTSEP_S "."
464 #define PATHSEP_C ';'
465 #define PATHSEP_S ";"
466 #define EXEEXT_S ".exe"
467 #else
468 #define DIRSEP_C '/'
469 #define DIRSEP_S "/"
470 #define EXTSEP_C '.'
471 #define EXTSEP_S "."
472 #define PATHSEP_C ':'
473 #define PATHSEP_S ":"
474 #define EXEEXT_S ""
475 #endif
476
477 /* This is the same as VERSION, but should be overridden if the
478    platform cannot handle things like dots '.' in filenames. Set
479    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
480    uses for dots and dashes. */
481 #define SAFE_VERSION VERSION
482 #define SAFE_VERSION_DOT  '.'
483 #define SAFE_VERSION_DASH '-'
484
485 /* Some global constants.
486  * Note that the homedir must not end in a slash.  */
487 #ifdef HAVE_DOSISH_SYSTEM
488 # ifdef HAVE_DRIVE_LETTERS
489 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
490 # else
491 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
492 # endif
493 #elif defined(__VMS)
494 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
495 #else
496 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
497 #endif
498 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
499 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
500
501 /* For some systems (DOS currently), we hardcode the path here.  For
502    POSIX systems the values are constructed by the Makefiles, so that
503    the values may be overridden by the make invocations; this is to
504    comply with the GNU coding standards.  Note that these values are
505    only defaults.  */
506 #ifdef HAVE_DOSISH_SYSTEM
507 # ifdef HAVE_DRIVE_LETTERS
508 #  define GNUPG_BINDIR      "c:\\gnupg"
509 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
510 #  define GNUPG_LIBDIR      "c:\\gnupg"
511 #  define GNUPG_DATADIR     "c:\\gnupg"
512 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
513 # else
514 #  define GNUPG_BINDIR      "\\gnupg"
515 #  define GNUPG_LIBEXECDIR  "\\gnupg"
516 #  define GNUPG_LIBDIR      "\\gnupg"
517 #  define GNUPG_DATADIR     "\\gnupg"
518 #  define GNUPG_SYSCONFDIR  "\\gnupg"
519 # endif
520 #endif
521
522 /* Derive some other constants. */
523 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
524 #define EXEC_TEMPFILE_ONLY
525 #endif
526
527
528 /* We didn't define endianness above, so get it from OS macros.  This
529    is intended for making fat binary builds on OS X. */
530 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
531 #if defined(__BIG_ENDIAN__)
532 #define BIG_ENDIAN_HOST 1
533 #elif defined(__LITTLE_ENDIAN__)
534 #define LITTLE_ENDIAN_HOST 1
535 #else
536 #error "No endianness found"
537 #endif
538 #endif
539
540
541 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
542    ldap_start_tls_s because that is the actual symbol used in the
543    library.  winldap.h redefines it to our commonly used value,
544    thus we define our usual macro here.  */
545 #ifdef HAVE_LDAP_START_TLS_SA
546 # ifndef HAVE_LDAP_START_TLS_S
547 #  define HAVE_LDAP_START_TLS_S 1
548 # endif
549 #endif
550
551 /* Provide the es_ macro for estream.  */
552 #define GPGRT_ENABLE_ES_MACROS 1
553
554 /* Tell libgcrypt not to use its own libgpg-error implementation. */
555 #define USE_LIBGPG_ERROR 1
556
557 /* Tell Libgcrypt not to include deprecated definitions.  */
558 #define GCRYPT_NO_DEPRECATED 1
559
560 /* Our HTTP code is used in estream mode.  */
561 #define HTTP_USE_ESTREAM 1
562
563 /* Under W32 we do an explicit socket initialization, thus we need to
564    avoid the on-demand initialization which would also install an atexit
565    handler.  */
566 #define HTTP_NO_WSASTARTUP
567
568 /* Under Windows we use the gettext code from libgpg-error.  */
569 #define GPG_ERR_ENABLE_GETTEXT_MACROS
570
571 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
572 #define GPG_ERR_ENABLE_ERRNO_MACROS
573
574 #endif /*GNUPG_CONFIG_H_INCLUDED*/
575 ])
576
577
578 AM_MAINTAINER_MODE
579 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
580
581 # Checks for programs.
582 AC_MSG_NOTICE([checking for programs])
583 AC_PROG_MAKE_SET
584 AM_SANITY_CHECK
585 missing_dir=`cd $ac_aux_dir && pwd`
586 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
587 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
588 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
589 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
590 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
591 AM_SILENT_RULES
592 AC_PROG_AWK
593 AC_PROG_CC
594 AC_PROG_CPP
595 AM_PROG_CC_C_O
596 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
597   AC_MSG_ERROR([[No C-89 compiler found]])
598 fi
599 AC_PROG_INSTALL
600 AC_PROG_LN_S
601 AC_PROG_RANLIB
602 AC_CHECK_TOOL(AR, ar, :)
603 AC_PATH_PROG(PERL,"perl")
604 AC_CHECK_TOOL(WINDRES, windres, :)
605 AC_PATH_PROG(YAT2M, "yat2m")
606 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
607 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
608 AC_ISC_POSIX
609 AC_SYS_LARGEFILE
610 GNUPG_CHECK_USTAR
611
612
613 # We need to compile and run a program on the build machine.  A
614 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
615 # the AC archive is broken for autoconf 2.57.  Given that there is no
616 # newer version of that macro, we assume that it is also broken for
617 # autoconf 2.61 and thus we use a simple but usually sufficient
618 # approach.
619 AC_MSG_CHECKING(for cc for build)
620 if test "$cross_compiling" = "yes"; then
621   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
622 else
623   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
624 fi
625 AC_MSG_RESULT($CC_FOR_BUILD)
626 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
627
628 # We need to call this macro because other pkg-config macros are
629 # not always used.
630 PKG_PROG_PKG_CONFIG
631
632
633 try_gettext=yes
634 require_iconv=yes
635 have_dosish_system=no
636 have_w32_system=no
637 have_w32ce_system=no
638 have_android_system=no
639 use_simple_gettext=no
640 use_ldapwrapper=yes
641 mmap_needed=yes
642 require_pipe_to_unblock_pselect=no
643 case "${host}" in
644     *-mingw32*)
645         # special stuff for Windoze NT
646         ac_cv_have_dev_random=no
647         AC_DEFINE(USE_ONLY_8DOT3,1,
648                   [Set this to limit filenames to the 8.3 format])
649         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
650                   [Because the Unix gettext has too much overhead on
651                    MingW32 systems and these systems lack Posix functions,
652                    we use a simplified version of gettext])
653         have_dosish_system=yes
654         have_w32_system=yes
655         require_iconv=no
656         use_ldapwrapper=no  # Fixme: Do this only for CE.
657         case "${host}" in
658           *-mingw32ce*)
659             have_w32ce_system=yes
660             ;;
661           *)
662             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
663                       [Defined if the OS supports drive letters.])
664             ;;
665         esac
666         try_gettext="no"
667         use_simple_gettext=yes
668         mmap_needed=no
669         ;;
670     i?86-emx-os2 | i?86-*-os2*emx )
671         # OS/2 with the EMX environment
672         ac_cv_have_dev_random=no
673         AC_DEFINE(HAVE_DRIVE_LETTERS)
674         have_dosish_system=yes
675         try_gettext="no"
676         ;;
677
678     i?86-*-msdosdjgpp*)
679         # DOS with the DJGPP environment
680         ac_cv_have_dev_random=no
681         AC_DEFINE(HAVE_DRIVE_LETTERS)
682         have_dosish_system=yes
683         try_gettext="no"
684         ;;
685
686     *-*-hpux*)
687         if test -z "$GCC" ; then
688             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
689         fi
690         ;;
691     *-dec-osf4*)
692         if test -z "$GCC" ; then
693             # Suppress all warnings
694             # to get rid of the unsigned/signed char mismatch warnings.
695             CFLAGS="-w $CFLAGS"
696         fi
697         ;;
698     *-dec-osf5*)
699         if test -z "$GCC" ; then
700             # Use the newer compiler `-msg_disable ptrmismatch1' to
701             # get rid of the unsigned/signed char mismatch warnings.
702             # Using this may hide other pointer mismatch warnings, but
703             # it at least lets other warning classes through
704             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
705         fi
706         ;;
707     m68k-atari-mint)
708         ;;
709     *-linux-android*)
710         have_android_system=yes
711         # Android is fully utf-8 and we do not want to use iconv to
712         # keeps things simple
713         require_iconv=no
714         ;;
715     *-apple-darwin*)
716         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
717                   Expose all libc features (__DARWIN_C_FULL).)
718         ;;
719     *-*-netbsd*)
720         require_pipe_to_unblock_pselect=yes
721         ;;
722     *)
723         ;;
724 esac
725
726 if test "$require_pipe_to_unblock_pselect" = yes; then
727    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
728              [Defined if we run on systems like NetBSD, where
729               pselect cannot be unblocked by signal from a thread
730               within the same process.  We use pipe in this case, instead.])
731 fi
732
733 if test "$have_dosish_system" = yes; then
734    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
735              [Defined if we run on some of the PCDOS like systems
736               (DOS, Windoze. OS/2) with special properties like
737               no file modes, case insensitive file names and preferred
738               use of backslashes as directory name separators.])
739 fi
740 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
741
742 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
743
744 if test "$have_w32_system" = yes; then
745    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
746    if test "$have_w32ce_system" = yes; then
747       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
748    fi
749 fi
750 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
751 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
752
753 if test "$have_android_system" = yes; then
754    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
755 fi
756 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
757
758
759 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
760 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
761
762
763 #
764 # Checks for libraries.
765 #
766 AC_MSG_NOTICE([checking for libraries])
767
768
769 #
770 # libgpg-error is a library with error codes shared between GnuPG
771 # related projects.
772 #
773 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
774                   have_gpg_error=yes,have_gpg_error=no)
775
776
777 #
778 # Libgcrypt is our generic crypto library
779 #
780 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
781         have_libgcrypt=yes,have_libgcrypt=no)
782
783
784 #
785 # libassuan is used for IPC
786 #
787 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
788                   have_libassuan=yes,have_libassuan=no)
789 if test "$have_libassuan" = "yes"; then
790   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
791                      [version of the libassuan library])
792   show_tor_support="only .onion"
793 fi
794
795
796 #
797 # libksba is our X.509 support library
798 #
799 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
800
801
802 #
803 # libusb allows us to use the integrated CCID smartcard reader driver.
804 #
805 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
806 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
807    case "${host}" in
808      *-mingw32*)
809        LIBUSB_NAME=
810        LIBUSB_LIBS=
811        LIBUSB_CPPFLAGS=
812        ;;
813      *-*-darwin*)
814        LIBUSB_NAME=usb-1.0
815        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
816        ;;
817      *-*-freebsd*)
818        # FreeBSD has a native 1.0 compatible library by -lusb.
819        LIBUSB_NAME=usb
820        LIBUSB_LIBS=
821        ;;
822      *)
823        LIBUSB_NAME=usb-1.0
824        LIBUSB_LIBS=
825        ;;
826    esac
827 fi
828 if test x"$LIBUSB_NAME" != x ; then
829    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
830                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
831                   have_libusb=yes ])
832    AC_MSG_CHECKING([libusb include dir])
833    usb_incdir_found="no"
834    for _incdir in "" "/usr/include/libusb-1.0" \
835        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
836      _libusb_save_cppflags=$CPPFLAGS
837      if test -n "${_incdir}"; then
838        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
839      fi
840      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
841      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
842      CPPFLAGS=${_libusb_save_cppflags}
843      if test "$usb_incdir_found" = "yes"; then
844        break
845      fi
846    done
847    if test "$usb_incdir_found" = "yes"; then
848      AC_MSG_RESULT([${usb_incdir}])
849    else
850      AC_MSG_RESULT([not found])
851      usb_incdir=""
852      have_libusb=no
853      if test "$use_ccid_driver" != yes; then
854        use_ccid_driver=no
855      fi
856      LIBUSB_LIBS=""
857    fi
858
859    if test "$have_libusb" = yes; then
860      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
861    fi
862    if test x"$usb_incdir" = x; then
863      LIBUSB_CPPFLAGS=""
864    else
865      LIBUSB_CPPFLAGS="-I${usb_incdir}"
866    fi
867 fi
868 AC_SUBST(LIBUSB_LIBS)
869 AC_SUBST(LIBUSB_CPPFLAGS)
870
871 #
872 # Check whether it is necessary to link against libdl.
873 # (For example to load libpcsclite)
874 #
875 gnupg_dlopen_save_libs="$LIBS"
876 LIBS=""
877 AC_SEARCH_LIBS(dlopen, c dl,,,)
878 DL_LIBS=$LIBS
879 AC_SUBST(DL_LIBS)
880 LIBS="$gnupg_dlopen_save_libs"
881
882
883 # Checks for g10
884
885 AC_ARG_ENABLE(sqlite,
886                 AC_HELP_STRING([--disable-sqlite],
887                                [disable the use of SQLITE]),
888               try_sqlite=$enableval, try_sqlite=yes)
889
890 if test x"$use_tofu" = xyes ; then
891   if test x"$try_sqlite" = xyes ; then
892     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
893                                  [have_sqlite=yes],
894                                  [have_sqlite=no])
895   fi
896   if test "$have_sqlite" = "yes"; then
897     :
898     AC_SUBST([SQLITE3_CFLAGS])
899     AC_SUBST([SQLITE3_LIBS])
900   else
901     use_tofu=no
902     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
903     AC_MSG_WARN([[
904 ***
905 *** Building without SQLite support - TOFU disabled
906 ***
907 *** $tmp]])
908   fi
909 fi
910
911 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
912
913 if test x"$use_tofu" = xyes ; then
914     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
915 fi
916
917
918 # Checks for g13
919
920 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
921 AC_DEFINE_UNQUOTED(ENCFS,
922         "${ENCFS}", [defines the filename of the encfs program])
923
924 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
925 AC_DEFINE_UNQUOTED(FUSERMOUNT,
926         "${FUSERMOUNT}", [defines the filename of the fusermount program])
927
928
929 # Checks for dirmngr
930
931
932 #
933 # Checks for symcryptrun:
934 #
935
936 # libutil has openpty() and login_tty().
937 AC_CHECK_LIB(util, openpty,
938               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
939                 AC_DEFINE(HAVE_LIBUTIL,1,
940                          [defined if libutil is available])
941              ])
942 AC_SUBST(LIBUTIL_LIBS)
943
944 # shred is used to clean temporary plain text files.
945 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
946 AC_DEFINE_UNQUOTED(SHRED,
947         "${SHRED}", [defines the filename of the shred program])
948
949
950 #
951 # Check whether the nPth library is available
952 #
953 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
954 if test "$have_npth" = "yes"; then
955   AC_DEFINE(HAVE_NPTH, 1,
956               [Defined if the New Portable Thread Library is available])
957   AC_DEFINE(USE_NPTH, 1,
958               [Defined if support for nPth is requested and nPth is available])
959 else
960   AC_MSG_WARN([[
961 ***
962 *** To support concurrent access for example in gpg-agent and the SCdaemon
963 *** we need the support of the New Portable Threads Library.
964 ***]])
965 fi
966
967
968 #
969 # NTBTLS is our TLS library.  If it is not available fallback to
970 # GNUTLS.
971 #
972 AC_ARG_ENABLE(ntbtls,
973               AC_HELP_STRING([--disable-ntbtls],
974                              [disable the use of NTBTLS as TLS library]),
975               try_ntbtls=$enableval, try_ntbtls=yes)
976 if test x"$try_ntbtls" = xyes ; then
977   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
978                  [have_ntbtls=yes],[have_ntbtls=no])
979 fi
980 if test "$have_ntbtls" = yes ; then
981    use_tls_library=ntbtls
982    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
983 else
984   AC_ARG_ENABLE(gnutls,
985                 AC_HELP_STRING([--disable-gnutls],
986                                [disable GNUTLS as fallback TLS library]),
987                 try_gnutls=$enableval, try_gnutls=yes)
988   if test x"$try_gnutls" = xyes ; then
989     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
990                                    [have_gnutls=yes],
991                                    [have_gnutls=no])
992   fi
993   if test "$have_gnutls" = "yes"; then
994     AC_SUBST([LIBGNUTLS_CFLAGS])
995     AC_SUBST([LIBGNUTLS_LIBS])
996     use_tls_library=gnutls
997     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
998   else
999     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1000     AC_MSG_WARN([[
1001 ***
1002 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1003 ***
1004 *** $tmp]])
1005   fi
1006 fi
1007
1008 #
1009 # Allow to set a fixed trust store file for system provided certificates.
1010 #
1011 AC_ARG_WITH([default-trust-store-file],
1012             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1013                             [Use FILE as system trust store])],
1014             default_trust_store_file="$withval",
1015             default_trust_store_file="")
1016 if test x"$default_trust_store_file" = xno;then
1017   default_trust_store_file=""
1018 fi
1019 if test x"$default_trust_store_file" != x ; then
1020   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1021     ["$default_trust_store_file"], [Use as default system trust store file])
1022 fi
1023
1024
1025 AC_MSG_NOTICE([checking for networking options])
1026
1027 #
1028 # Must check for network library requirements before doing link tests
1029 # for ldap, for example. If ldap libs are static (or dynamic and without
1030 # ELF runtime link paths), then link will fail and LDAP support won't
1031 # be detected.
1032 #
1033 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1034         [NETLIBS="-lnsl $NETLIBS"]))
1035 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1036         [NETLIBS="-lsocket $NETLIBS"]))
1037
1038
1039 #
1040 # Check standard resolver functions.
1041 #
1042 if test "$build_dirmngr" = "yes"; then
1043   _dns_save_libs=$LIBS
1044   LIBS=""
1045
1046   # Find the system resolver which can always be enabled with
1047   # the dirmngr option --standard-resolver.
1048
1049   # the double underscore thing is a glibc-ism?
1050   AC_SEARCH_LIBS(res_query,resolv bind,,
1051                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1052   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1053                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1054
1055   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1056   # and for some reason fools us into believing we don't need
1057   # -lresolv even if we do.  Since the test program checking for the
1058   # symbol does not include <resolv.h>, we need to check for the
1059   # renamed symbol explicitly.
1060   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1061       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1062           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1063
1064   if test x"$have_resolver" != xno ; then
1065
1066       # Make sure that the BIND 4 resolver interface is workable before
1067       # enabling any code that calls it.  At some point I'll rewrite the
1068       # code to use the BIND 8 resolver API.
1069       # We might also want to use libdns instead.
1070
1071     AC_MSG_CHECKING([whether the resolver is usable])
1072     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1073 #include <netinet/in.h>
1074 #include <arpa/nameser.h>
1075 #include <resolv.h>]],
1076 [[unsigned char answer[PACKETSZ];
1077   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1078   dn_skipname(0,0);
1079   dn_expand(0,0,0,0,0);
1080 ]])],have_resolver=yes,have_resolver=no)
1081     AC_MSG_RESULT($have_resolver)
1082
1083     # This is Apple-specific and somewhat bizarre as they changed the
1084     # define in bind 8 for some reason.
1085
1086     if test x"$have_resolver" != xyes ; then
1087       AC_MSG_CHECKING(
1088            [whether I can make the resolver usable with BIND_8_COMPAT])
1089       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1090 #include <sys/types.h>
1091 #include <netinet/in.h>
1092 #include <arpa/nameser.h>
1093 #include <resolv.h>]],
1094 [[unsigned char answer[PACKETSZ];
1095   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1096   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1097 ]])],[have_resolver=yes ; need_compat=yes])
1098       AC_MSG_RESULT($have_resolver)
1099     fi
1100   fi
1101
1102   if test x"$have_resolver" = xyes ; then
1103     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1104     DNSLIBS="$DNSLIBS $LIBS"
1105     if test x"$need_compat" = xyes ; then
1106       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1107     fi
1108     if test "$use_libdns" = yes; then
1109      show_tor_support=yes
1110     fi
1111   elif test "$use_libdns" = yes; then
1112     show_tor_support=yes
1113   else
1114     AC_MSG_WARN([[
1115 ***
1116 *** The system's DNS resolver is not usable.
1117 *** Dirmngr functionality is limited.
1118 ***]])
1119     show_tor_support="${show_tor_support} (no system resolver)"
1120   fi
1121
1122   if test "$have_w32_system" = yes; then
1123     if test "$use_libdns" = yes; then
1124       DNSLIBS="$DNSLIBS -liphlpapi"
1125     fi
1126   fi
1127
1128   LIBS=$_dns_save_libs
1129 fi
1130
1131 AC_SUBST(DNSLIBS)
1132
1133
1134 #
1135 # Check for LDAP
1136 #
1137 # Note that running the check changes the variable
1138 # gnupg_have_ldap from "n/a" to "no" or "yes".
1139
1140 AC_ARG_ENABLE(ldap,
1141     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1142     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1143
1144 if test "$gnupg_have_ldap" != "no" ; then
1145   if test "$build_dirmngr" = "yes" ; then
1146      GNUPG_CHECK_LDAP($NETLIBS)
1147      AC_CHECK_LIB(lber, ber_free,
1148                   [ LBER_LIBS="$LBER_LIBS -llber"
1149                     AC_DEFINE(HAVE_LBER,1,
1150                              [defined if liblber is available])
1151                     have_lber=yes
1152                  ])
1153   fi
1154 fi
1155 AC_SUBST(LBER_LIBS)
1156 if test "$gnupg_have_ldap" = "no"; then
1157     AC_MSG_WARN([[
1158 ***
1159 *** Building without LDAP support.
1160 *** No CRL access or X.509 certificate search available.
1161 ***]])
1162 fi
1163
1164 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1165 if test "$gnupg_have_ldap" = yes ; then
1166   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1167 else
1168  use_ldapwrapper=no
1169 fi
1170
1171 if test "$use_ldapwrapper" = yes; then
1172    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1173 fi
1174 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1175
1176
1177
1178
1179 #
1180 # Check for sendmail
1181 #
1182 # This isn't necessarily sendmail itself, but anything that gives a
1183 # sendmail-ish interface to the outside world.  That includes Exim,
1184 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1185 AC_ARG_WITH(mailprog,
1186       AC_HELP_STRING([--with-mailprog=NAME],
1187                      [use "NAME -t" for mail transport]),
1188              ,with_mailprog=yes)
1189 if test x"$with_mailprog" = xyes ; then
1190     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1191 elif test x"$with_mailprog" != xno ; then
1192     AC_MSG_CHECKING([for a mail transport program])
1193     AC_SUBST(SENDMAIL,$with_mailprog)
1194     AC_MSG_RESULT($with_mailprog)
1195 fi
1196
1197
1198 #
1199 # Construct a printable name of the OS
1200 #
1201 case "${host}" in
1202     *-mingw32ce*)
1203         PRINTABLE_OS_NAME="W32CE"
1204         ;;
1205     *-mingw32*)
1206         PRINTABLE_OS_NAME="MingW32"
1207         ;;
1208     *-*-cygwin*)
1209         PRINTABLE_OS_NAME="Cygwin"
1210         ;;
1211     i?86-emx-os2 | i?86-*-os2*emx )
1212         PRINTABLE_OS_NAME="OS/2"
1213         ;;
1214     i?86-*-msdosdjgpp*)
1215         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1216         try_dynload=no
1217         ;;
1218     *-linux*)
1219         PRINTABLE_OS_NAME="GNU/Linux"
1220         ;;
1221     *)
1222         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1223         ;;
1224 esac
1225 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1226                    [A human readable text with the name of the OS])
1227
1228
1229 #
1230 # Checking for iconv
1231 #
1232 if test "$require_iconv" = yes; then
1233   AM_ICONV
1234 else
1235   LIBICONV=
1236   LTLIBICONV=
1237   AC_SUBST(LIBICONV)
1238   AC_SUBST(LTLIBICONV)
1239 fi
1240
1241
1242 #
1243 # Check for gettext
1244 #
1245 # This is "GNU gnupg" - The project-id script from gettext
1246 #                       needs this string
1247 #
1248 AC_MSG_NOTICE([checking for gettext])
1249 AM_PO_SUBDIRS
1250 AM_GNU_GETTEXT_VERSION([0.17])
1251 if test "$try_gettext" = yes; then
1252   AM_GNU_GETTEXT([external],[need-ngettext])
1253
1254   # gettext requires some extra checks.  These really should be part of
1255   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1256   # function checks to here.
1257
1258   AC_CHECK_FUNCS(strchr)
1259 else
1260   USE_NLS=no
1261   USE_INCLUDED_LIBINTL=no
1262   BUILD_INCLUDED_LIBINTL=no
1263   POSUB=po
1264   AC_SUBST(USE_NLS)
1265   AC_SUBST(USE_INCLUDED_LIBINTL)
1266   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1267   AC_SUBST(POSUB)
1268 fi
1269
1270 # We use HAVE_LANGINFO_CODESET in a couple of places.
1271 AM_LANGINFO_CODESET
1272
1273 # Checks required for our use of locales
1274 gt_LC_MESSAGES
1275
1276
1277 #
1278 # SELinux support
1279 #
1280 if test "$selinux_support" = yes ; then
1281   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1282 fi
1283
1284
1285 #
1286 # Checks for header files.
1287 #
1288 AC_MSG_NOTICE([checking for header files])
1289 AC_HEADER_STDC
1290 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1291                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1292                   stdint.h signal.h util.h libutil.h termios.h \
1293                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1294
1295 AC_HEADER_TIME
1296
1297
1298 #
1299 # Checks for typedefs, structures, and compiler characteristics.
1300 #
1301 AC_MSG_NOTICE([checking for system characteristics])
1302 AC_C_CONST
1303 AC_C_INLINE
1304 AC_C_VOLATILE
1305 AC_TYPE_SIZE_T
1306 AC_TYPE_MODE_T
1307 AC_TYPE_SIGNAL
1308 AC_DECL_SYS_SIGLIST
1309
1310 gl_HEADER_SYS_SOCKET
1311 gl_TYPE_SOCKLEN_T
1312
1313 AC_SEARCH_LIBS([inet_addr], [nsl])
1314
1315 AC_ARG_ENABLE(endian-check,
1316               AC_HELP_STRING([--disable-endian-check],
1317               [disable the endian check and trust the OS provided macros]),
1318               endiancheck=$enableval,endiancheck=yes)
1319
1320 if test x"$endiancheck" = xyes ; then
1321   GNUPG_CHECK_ENDIAN
1322 fi
1323
1324 # fixme: we should get rid of the byte type
1325 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1326 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1327 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1328 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1329 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1330
1331 AC_CHECK_SIZEOF(unsigned short)
1332 AC_CHECK_SIZEOF(unsigned int)
1333 AC_CHECK_SIZEOF(unsigned long)
1334 AC_CHECK_SIZEOF(unsigned long long)
1335 AC_HEADER_TIME
1336 AC_CHECK_SIZEOF(time_t,,[[
1337 #include <stdio.h>
1338 #if TIME_WITH_SYS_TIME
1339 # include <sys/time.h>
1340 # include <time.h>
1341 #else
1342 # if HAVE_SYS_TIME_H
1343 #  include <sys/time.h>
1344 # else
1345 #  include <time.h>
1346 # endif
1347 #endif
1348 ]])
1349 GNUPG_TIME_T_UNSIGNED
1350
1351
1352 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1353    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1354    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1355     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1356 fi
1357
1358
1359 #
1360 # Checks for library functions.
1361 #
1362 AC_MSG_NOTICE([checking for library functions])
1363 AC_CHECK_DECLS(getpagesize)
1364 AC_FUNC_FSEEKO
1365 AC_FUNC_VPRINTF
1366 AC_FUNC_FORK
1367 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1368 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1369 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1370 AC_CHECK_FUNCS([canonicalize_file_name])
1371 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1372 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1373 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1374 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1375 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1376                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1377                 flockfile funlockfile getpwnam getpwuid \
1378                 getenv inet_pton strpbrk])
1379
1380 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1381 # Given that we use nanosleep only as an optimization over a select
1382 # based wait function we want it only if it is available in libc.
1383 _save_libs="$LIBS"
1384 AC_SEARCH_LIBS([nanosleep], [],
1385                [AC_DEFINE(HAVE_NANOSLEEP,1,
1386                 [Define to 1 if you have the `nanosleep' function in libc.])])
1387 LIBS="$_save_libs"
1388
1389
1390 # See whether libc supports the Linux inotify interface
1391 case "${host}" in
1392     *-*-linux*)
1393         AC_CHECK_FUNCS([inotify_init])
1394         ;;
1395 esac
1396
1397
1398 if test "$have_android_system" = yes; then
1399    # On Android ttyname is a stub but prints an error message.
1400    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1401              [Defined if ttyname does not work properly])
1402 fi
1403
1404 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1405
1406 # Dirmngr requires mmap on Unix systems.
1407 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1408   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1409 fi
1410
1411
1412 #
1413 # Check for the getsockopt SO_PEERCRED, etc.
1414 #
1415 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1416 #include <sys/socket.h> ])
1417
1418 # (Open)Solaris
1419 AC_CHECK_FUNCS([getpeerucred])
1420
1421
1422 #
1423 # W32 specific test
1424 #
1425 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1426
1427 #
1428 # Sanity check regex.  Tests adapted from mutt.
1429 #
1430 AC_MSG_CHECKING([whether regular expression support is requested])
1431 AC_ARG_ENABLE(regex,
1432   AC_HELP_STRING([--disable-regex],
1433     [do not handle regular expressions in trust signatures]),
1434   use_regex=$enableval, use_regex=yes)
1435 AC_MSG_RESULT($use_regex)
1436
1437 if test "$use_regex" = yes ; then
1438   _cppflags="${CPPFLAGS}"
1439   _ldflags="${LDFLAGS}"
1440   AC_ARG_WITH(regex,
1441      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1442       [
1443       if test -d "$withval" ; then
1444         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1445         LDFLAGS="${LDFLAGS} -L$withval/lib"
1446       fi
1447       ],withval="")
1448
1449   # Does the system have regex functions at all?
1450   AC_SEARCH_LIBS([regcomp], [regex])
1451   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1452
1453   if test $gnupg_cv_have_regex = no; then
1454     use_regex=no
1455   else
1456     if test x"$cross_compiling" = xyes; then
1457       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1458     else
1459       AC_CACHE_CHECK([whether your system's regexp library is broken],
1460        [gnupg_cv_regex_broken],
1461        AC_TRY_RUN([
1462 #include <unistd.h>
1463 #include <regex.h>
1464 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1465        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1466
1467       if test $gnupg_cv_regex_broken = yes; then
1468         AC_MSG_WARN([your regex is broken - disabling regex use])
1469         use_regex=no
1470       fi
1471     fi
1472   fi
1473   CPPFLAGS="${_cppflags}"
1474   LDFLAGS="${_ldflags}"
1475 fi
1476
1477 if test "$use_regex" != yes ; then
1478   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1479 fi
1480 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1481
1482
1483
1484 #
1485 # Do we have zlib? Must do it here because Solaris failed
1486 # when compiling a conftest (due to the "-lz" from LIBS).
1487 # Note that we combine zlib and bzlib2 in ZLIBS.
1488 #
1489 if test "$use_zip" = yes ; then
1490   _cppflags="${CPPFLAGS}"
1491   _ldflags="${LDFLAGS}"
1492   AC_ARG_WITH(zlib,
1493     [  --with-zlib=DIR         use libz in DIR],[
1494       if test -d "$withval"; then
1495         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1496         LDFLAGS="${LDFLAGS} -L$withval/lib"
1497       fi
1498     ])
1499
1500   AC_CHECK_HEADER(zlib.h,
1501      AC_CHECK_LIB(z, deflateInit2_,
1502        [
1503        ZLIBS="-lz"
1504        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1505        ],
1506        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1507        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1508 fi
1509
1510
1511 #
1512 # Check whether we can support bzip2
1513 #
1514 if test "$use_bzip2" = yes ; then
1515   _cppflags="${CPPFLAGS}"
1516   _ldflags="${LDFLAGS}"
1517   AC_ARG_WITH(bzip2,
1518      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1519       [
1520       if test -d "$withval" ; then
1521         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1522         LDFLAGS="${LDFLAGS} -L$withval/lib"
1523       fi
1524       ],withval="")
1525
1526   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1527   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1528   # woefully out of date.
1529   if test "$withval" != no ; then
1530      AC_CHECK_HEADER(bzlib.h,
1531         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1532           [
1533           have_bz2=yes
1534           ZLIBS="$ZLIBS -lbz2"
1535           AC_DEFINE(HAVE_BZIP2,1,
1536                   [Defined if the bz2 compression library is available])
1537           ],
1538           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1539           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1540   fi
1541 fi
1542 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1543 AC_SUBST(ZLIBS)
1544
1545
1546 # Check for readline support
1547 GNUPG_CHECK_READLINE
1548
1549
1550 if test "$development_version" = yes; then
1551     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1552             [Defined if this is not a regular release])
1553 fi
1554
1555 if test "$USE_MAINTAINER_MODE" = "yes"; then
1556     AC_DEFINE(MAINTAINER_MODE,1,
1557             [Defined if this build is in maintainer mode])
1558 fi
1559
1560 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1561
1562 GNUPG_CHECK_GNUMAKE
1563
1564 # Add some extra libs here so that previous tests don't fail for
1565 # mysterious reasons - the final link step should bail out.
1566 # W32SOCKLIBS is also defined so that if can be used for tools not
1567 # requiring any network stuff but linking to code in libcommon which
1568 # tracks in winsock stuff (e.g. init_common_subsystems).
1569 if test "$have_w32_system" = yes; then
1570    if test "$have_w32ce_system" = yes; then
1571      W32SOCKLIBS="-lws2"
1572    else
1573      W32SOCKLIBS="-lws2_32"
1574    fi
1575    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1576 fi
1577
1578 AC_SUBST(NETLIBS)
1579 AC_SUBST(W32SOCKLIBS)
1580
1581 #
1582 # Setup gcc specific options
1583 #
1584 USE_C99_CFLAGS=
1585 AC_MSG_NOTICE([checking for cc features])
1586 if test "$GCC" = yes; then
1587     mycflags=
1588     mycflags_save=$CFLAGS
1589
1590     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1591     # options.  This is the case for gcc >= 4.6
1592     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1593     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1594 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1595 #kickerror
1596 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1597     AC_MSG_RESULT($_gcc_silent_wno)
1598
1599     # Note that it is okay to use CFLAGS here because these are just
1600     # warning options and the user should have a chance of overriding
1601     # them.
1602     if test "$USE_MAINTAINER_MODE" = "yes"; then
1603         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1604         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1605         if test x"$_gcc_silent_wno" = xyes ; then
1606           _gcc_wopt=yes
1607         else
1608           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1609           CFLAGS="-Wno-missing-field-initializers"
1610           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1611                             [_gcc_wopt=yes],[_gcc_wopt=no])
1612           AC_MSG_RESULT($_gcc_wopt)
1613         fi
1614         if test x"$_gcc_wopt" = xyes ; then
1615           mycflags="$mycflags -W -Wno-sign-compare"
1616           mycflags="$mycflags -Wno-missing-field-initializers"
1617         fi
1618
1619         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1620         CFLAGS="-Wdeclaration-after-statement"
1621         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1622         AC_MSG_RESULT($_gcc_wopt)
1623         if test x"$_gcc_wopt" = xyes ; then
1624           mycflags="$mycflags -Wdeclaration-after-statement"
1625         fi
1626
1627         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1628         CFLAGS="-Wlogical-op -Werror"
1629         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1630         AC_MSG_RESULT($_gcc_wopt)
1631         if test x"$_gcc_wopt" = xyes ; then
1632           mycflags="$mycflags -Wlogical-op"
1633         fi
1634
1635         AC_MSG_CHECKING([if gcc supports -Wvla])
1636         CFLAGS="-Wvla"
1637         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1638         AC_MSG_RESULT($_gcc_wopt)
1639         if test x"$_gcc_wopt" = xyes ; then
1640           mycflags="$mycflags -Wvla"
1641         fi
1642
1643     else
1644         mycflags="$mycflags -Wall"
1645     fi
1646
1647     if test x"$_gcc_silent_wno" = xyes ; then
1648       _gcc_psign=yes
1649     else
1650       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1651       CFLAGS="-Wno-pointer-sign"
1652       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1653                         [_gcc_psign=yes],[_gcc_psign=no])
1654       AC_MSG_RESULT($_gcc_psign)
1655     fi
1656     if test x"$_gcc_psign" = xyes ; then
1657        mycflags="$mycflags -Wno-pointer-sign"
1658     fi
1659
1660     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1661     CFLAGS="-Wpointer-arith"
1662     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1663     AC_MSG_RESULT($_gcc_psign)
1664     if test x"$_gcc_psign" = xyes ; then
1665        mycflags="$mycflags -Wpointer-arith"
1666     fi
1667
1668     CFLAGS="$mycflags $mycflags_save"
1669     if test "$use_libdns" = yes; then
1670        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1671        USE_C99_CFLAGS="-std=gnu99"
1672     fi
1673 fi
1674
1675 AC_SUBST(USE_C99_CFLAGS)
1676
1677
1678 #
1679 # This is handy for debugging so the compiler doesn't rearrange
1680 # things and eliminate variables.
1681 #
1682 AC_ARG_ENABLE(optimization,
1683    AC_HELP_STRING([--disable-optimization],
1684                   [disable compiler optimization]),
1685                   [if test $enableval = no ; then
1686                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1687                    fi])
1688
1689 #
1690 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1691 # misbehaving autoconf tests in case the user supplied -Werror.
1692 #
1693 AC_ARG_ENABLE(werror,
1694    AC_HELP_STRING([--enable-werror],
1695                   [append -Werror to CFLAGS]),
1696                   [if test $enableval = yes ; then
1697                       CFLAGS="$CFLAGS -Werror"
1698                    fi])
1699
1700 #
1701 # Configure option --enable-all-tests
1702 #
1703 AC_MSG_CHECKING([whether "make check" shall run all tests])
1704 AC_ARG_ENABLE(all-tests,
1705               AC_HELP_STRING([--enable-all-tests],
1706                              [let "make check" run all tests]),
1707               run_all_tests=$enableval, run_all_tests=no)
1708 AC_MSG_RESULT($run_all_tests)
1709 if test "$run_all_tests" = "yes"; then
1710     AC_DEFINE(RUN_ALL_TESTS,1,
1711             [Defined if "make check" shall run all tests])
1712 fi
1713
1714 #
1715 # We do not want support for the GNUPG_BUILDDIR environment variable
1716 # in a released version.  However, our regression tests suite requires
1717 # this and thus we build with support for it during "make distcheck".
1718 # This configure option implements this along with the top Makefile's
1719 # AM_DISTCHECK_CONFIGURE_FLAGS.
1720 #
1721 gnupg_builddir_envvar=no
1722 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1723               gnupg_builddir_envvar=$enableval)
1724 if test x"$gnupg_builddir_envvar" = x"yes"; then
1725    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1726       [This is only used with "make distcheck"])
1727 fi
1728
1729
1730 #
1731 # To avoid problems with systemd cleaning up the /run/user directory,
1732 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1733 # before /run/user
1734 #
1735 AC_ARG_ENABLE(run-gnupg-user-socket,
1736     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1737                    [try /run/gnupg/user for sockets prior to /run/user]),
1738     use_run_gnupg_user_socket=$enableval)
1739 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1740    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1741             [If defined try /run/gnupg/user before /run/user])
1742 fi
1743
1744
1745 #
1746 # Decide what to build
1747 #
1748
1749 build_scdaemon_extra=""
1750 if test "$build_scdaemon" = "yes"; then
1751   if test $have_libusb = no; then
1752      build_scdaemon_extra="without internal CCID driver"
1753   fi
1754   if test -n "$build_scdaemon_extra"; then
1755      build_scdaemon_extra="(${build_scdaemon_extra})"
1756   fi
1757 fi
1758
1759
1760 #
1761 # Set variables for use by automake makefiles.
1762 #
1763 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1764 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1765 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1766 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1767 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1768 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1769 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1770 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1771 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1772 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1773
1774 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1775 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1776 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1777
1778 #
1779 # Set some defines for use gpgconf.
1780 #
1781 if test "$build_gpg" = yes ; then
1782     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1783 fi
1784 if test "$build_gpgsm" = yes ; then
1785     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1786 fi
1787 if test "$build_agent" = yes ; then
1788     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1789 fi
1790 if test "$build_scdaemon" = yes ; then
1791     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1792 fi
1793 if test "$build_dirmngr" = yes ; then
1794     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1795 fi
1796 if test "$build_g13" = yes ; then
1797     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1798 fi
1799
1800
1801 #
1802 # Define Name strings
1803 #
1804 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1805
1806 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1807 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1808
1809 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1810 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1811
1812 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1813 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1814                                         [The displayed name of gpg-agent])
1815
1816 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1817 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1818                                        [The displayed name of scdaemon])
1819
1820 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1821 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1822                                       [The displayed name of dirmngr])
1823
1824 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1825 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1826
1827 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1828 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1829                                       [The displayed name of gpgconf])
1830
1831 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1832
1833 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1834                    [The name of the agent socket])
1835 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1836                    [The name of the agent socket for remote access])
1837 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1838                    [The name of the agent socket for browsers])
1839 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1840                    [The name of the agent socket for ssh])
1841 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1842                    [The name of the dirmngr info envvar])
1843 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1844                    [The name of the SCdaemon socket])
1845 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1846                    [The name of the dirmngr socket])
1847 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1848                    "hkps://hkps.pool.sks-keyservers.net",
1849       [The default keyserver for dirmngr to use, if none is explicitly given])
1850
1851 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1852
1853 if test "$have_w32_system" = yes; then
1854   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1855                      [The directory part of the W32 registry keys])
1856 fi
1857
1858
1859 #
1860 # Provide information about the build.
1861 #
1862 BUILD_REVISION="mym4_revision"
1863 AC_SUBST(BUILD_REVISION)
1864 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1865                    [GIT commit id revision used to build this package])
1866
1867 changequote(,)dnl
1868 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1869 changequote([,])dnl
1870 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1871 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1872 AC_SUBST(BUILD_VERSION)
1873 AC_SUBST(BUILD_FILEVERSION)
1874
1875 AC_ARG_ENABLE([build-timestamp],
1876   AC_HELP_STRING([--enable-build-timestamp],
1877                  [set an explicit build timestamp for reproducibility.
1878                   (default is the current time in ISO-8601 format)]),
1879      [if test "$enableval" = "yes"; then
1880         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1881       else
1882         BUILD_TIMESTAMP="$enableval"
1883       fi
1884       BUILD_HOSTNAME="$ac_hostname"],
1885      [BUILD_TIMESTAMP="<none>"
1886       BUILD_HOSTNAME="<anon>"])
1887 AC_SUBST(BUILD_TIMESTAMP)
1888 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1889                    [The time this package was configured for a build])
1890 AC_SUBST(BUILD_HOSTNAME)
1891
1892
1893 #
1894 # Print errors here so that they are visible all
1895 # together and the user can acquire them all together.
1896 #
1897 die=no
1898 if test "$have_gpg_error" = "no"; then
1899    die=yes
1900    AC_MSG_NOTICE([[
1901 ***
1902 *** You need libgpg-error to build this program.
1903 **  This library is for example available at
1904 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1905 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1906 ***]])
1907 fi
1908 if test "$have_libgcrypt" = "no"; then
1909    die=yes
1910    AC_MSG_NOTICE([[
1911 ***
1912 *** You need libgcrypt to build this program.
1913 **  This library is for example available at
1914 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1915 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1916 ***]])
1917 fi
1918 if test "$have_libassuan" = "no"; then
1919    die=yes
1920    AC_MSG_NOTICE([[
1921 ***
1922 *** You need libassuan to build this program.
1923 *** This library is for example available at
1924 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1925 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1926 ***]])
1927 fi
1928 if test "$have_ksba" = "no"; then
1929     die=yes
1930     AC_MSG_NOTICE([[
1931 ***
1932 *** You need libksba to build this program.
1933 *** This library is for example available at
1934 ***   https://gnupg.org/ftp/gcrypt/libksba/
1935 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1936 ***]])
1937 fi
1938 if test "$gnupg_have_ldap" = yes; then
1939   if test "$have_w32ce_system" = yes; then
1940     AC_MSG_NOTICE([[
1941 *** Note that CeGCC might be broken, a package fixing this is:
1942 ***    http://files.kolab.org/local/windows-ce/
1943 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1944 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1945 ***]])
1946    fi
1947 fi
1948 if test "$have_npth" = "no"; then
1949     die=yes
1950     AC_MSG_NOTICE([[
1951 ***
1952 *** It is now required to build with support for the
1953 *** New Portable Threads Library (nPth). Please install this
1954 *** library first.  The library is for example available at
1955 ***   https://gnupg.org/ftp/gcrypt/npth/
1956 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1957 ***]])
1958 fi
1959
1960 if test "$require_iconv" = yes; then
1961   if test "$am_func_iconv" != yes; then
1962     die=yes
1963     AC_MSG_NOTICE([[
1964 ***
1965 *** The system does not provide a working iconv function.  Please
1966 *** install a suitable library; for example GNU Libiconv which is
1967 *** available at:
1968 ***   https://ftp.gnu.org/gnu/libiconv/
1969 ***]])
1970   fi
1971 fi
1972
1973 if test "$use_ccid_driver" = yes; then
1974   if test "$have_libusb" != yes; then
1975     die=yes
1976     AC_MSG_NOTICE([[
1977 ***
1978 *** You need libusb to build the internal ccid driver.  Please
1979 *** install a libusb suitable for your system.
1980 ***]])
1981   fi
1982 fi
1983
1984 if test "$die" = "yes"; then
1985     AC_MSG_ERROR([[
1986 ***
1987 *** Required libraries not found. Please consult the above messages
1988 *** and install them before running configure again.
1989 ***]])
1990 fi
1991
1992
1993
1994 AC_CONFIG_FILES([ m4/Makefile
1995 Makefile
1996 po/Makefile.in
1997 common/Makefile
1998 common/w32info-rc.h
1999 kbx/Makefile
2000 g10/Makefile
2001 sm/Makefile
2002 agent/Makefile
2003 scd/Makefile
2004 g13/Makefile
2005 dirmngr/Makefile
2006 tools/gpg-zip
2007 tools/Makefile
2008 doc/Makefile
2009 tests/Makefile
2010 tests/gpgscm/Makefile
2011 tests/openpgp/Makefile
2012 tests/migrations/Makefile
2013 tests/gpgsm/Makefile
2014 tests/gpgme/Makefile
2015 tests/pkits/Makefile
2016 g10/gpg.w32-manifest
2017 ])
2018
2019
2020 AC_OUTPUT
2021
2022
2023 echo "
2024         GnuPG v${VERSION} has been configured as follows:
2025
2026         Revision:  mym4_revision  (mym4_revision_dec)
2027         Platform:  $PRINTABLE_OS_NAME ($host)
2028
2029         OpenPGP:   $build_gpg
2030         S/MIME:    $build_gpgsm
2031         Agent:     $build_agent
2032         Smartcard: $build_scdaemon $build_scdaemon_extra
2033         G13:       $build_g13
2034         Dirmngr:   $build_dirmngr
2035         Gpgtar:    $build_gpgtar
2036         WKS tools: $build_wks_tools
2037
2038         Protect tool:      $show_gnupg_protect_tool_pgm
2039         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2040         Default agent:     $show_gnupg_agent_pgm
2041         Default pinentry:  $show_gnupg_pinentry_pgm
2042         Default scdaemon:  $show_gnupg_scdaemon_pgm
2043         Default dirmngr:   $show_gnupg_dirmngr_pgm
2044
2045         Dirmngr auto start:  $dirmngr_auto_start
2046         Readline support:    $gnupg_cv_have_readline
2047         LDAP support:        $gnupg_have_ldap
2048         TLS support:         $use_tls_library
2049         TOFU support:        $use_tofu
2050         Tor support:         $show_tor_support
2051 "
2052 if test x"$use_regex" != xyes ; then
2053 echo "
2054         Warning: No regular expression support available.
2055                  OpenPGP trust signatures won't work.
2056                  gpg-check-pattern will not be built.
2057 "
2058 fi
2059 if test "x${gpg_config_script_warn}" != x; then
2060 cat <<G10EOF
2061         Warning: Mismatches between the target platform and the
2062                  to be used libraries have been detected for:
2063                   ${gpg_config_script_warn}
2064                  Please check above for more warning messages.
2065
2066 G10EOF
2067 fi