* mainproc.c (proc_symkey_enc): Don't show algorithm information when
[gnupg.git] / configure.ac
1 dnl Configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 dnl               2003 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20 dnl
21 dnl (Process this file with autoconf to produce a configure script.)
22 dnlAC_REVISION($Revision$)dnl
23
24 AC_PREREQ(2.57)
25
26 # Remember to change the version number immediately *after* a release
27 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
28 AC_INIT(gnupg, 1.3.4-cvs, bug-gnupg@gnu.org)
29 # Set development_version to yes if the minor number is odd or you
30 # feel that the default check for a development version is not
31 # sufficient.
32 development_version=yes
33
34 AC_CONFIG_AUX_DIR(scripts)
35 AC_CONFIG_SRCDIR(g10/g10.c)
36 AC_CANONICAL_TARGET()
37 AM_INIT_AUTOMAKE
38 AM_CONFIG_HEADER(config.h)
39
40 AC_GNU_SOURCE
41
42 dnl
43 dnl  Check for random module options
44 dnl
45 AC_MSG_CHECKING([which random module to use])
46 AC_ARG_ENABLE(static-rnd,
47     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
48 [use_static_rnd=$enableval], [use_static_rnd=default] )
49
50 if test "$use_static_rnd" = no; then
51     use_static_rnd=default
52 fi
53
54 case "$use_static_rnd" in
55     egd | linux | unix | default )
56       AC_MSG_RESULT($use_static_rnd)
57       ;;
58     auto )
59       AC_MSG_RESULT(automagically selected at runtime)
60       ;;
61     * )
62       AC_MSG_RESULT(invalid argument)
63       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
64       ;;
65 esac
66
67 AC_ARG_WITH(egd-socket,
68     [  --with-egd-socket=NAME  use NAME for the EGD socket],
69             egd_socket_name="$withval", egd_socket_name="" )
70 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
71                    [Define if you don't want the default EGD socket name.
72                     For details see cipher/rndegd.c])
73
74
75 dnl
76 dnl See whether the user wants to disable checking for /dev/random
77
78 AC_MSG_CHECKING([whether use of /dev/random is requested])
79 AC_ARG_ENABLE(dev-random,
80 [  --disable-dev-random    disable the use of dev random],
81     try_dev_random=$enableval, try_dev_random=yes)
82 AC_MSG_RESULT($try_dev_random)
83
84
85 dnl
86 dnl  Check other options
87 dnl
88
89 AC_MSG_CHECKING([whether assembler modules are requested])
90 AC_ARG_ENABLE(asm,
91 [  --disable-asm           do not use assembler modules],
92      try_asm_modules=$enableval, try_asm_modules=yes)
93 AC_MSG_RESULT($try_asm_modules)
94
95 AC_MSG_CHECKING([whether memory guard is requested])
96 AC_ARG_ENABLE(m-guard,
97     [  --enable-m-guard        enable memory guard facility],
98     use_m_guard=$enableval, use_m_guard=no)
99 AC_MSG_RESULT($use_m_guard)
100 if test "$use_m_guard" = yes ; then
101     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
102 fi
103
104 AC_MSG_CHECKING([whether OpenPGP card support is requested])
105 AC_ARG_ENABLE(card-support,
106     [  --enable-card-support   enable OpenPGP card support],
107     card_support=$enableval, card_support=no)
108 AC_MSG_RESULT($card_support)
109
110 dnl See if we are disabling any algorithms or features for a smaller
111 dnl binary
112
113 try_extensions=no
114
115 use_idea=yes
116 use_cast5=yes
117 use_blowfish=yes
118 use_aes=yes
119 use_twofish=yes
120 use_sha256=yes
121 use_sha512=yes
122 use_bzip2=yes
123 use_exec=yes
124
125 AC_ARG_ENABLE(minimal,
126    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
127    use_idea=no
128    use_cast5=no
129    use_blowfish=no
130    use_aes=no
131    use_twofish=no
132    use_sha256=no
133    use_sha512=no
134    use_bzip2=no
135    use_exec=no)
136
137 AC_MSG_CHECKING([whether to enable the IDEA cipher])
138 AC_ARG_ENABLE(idea,
139    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
140    use_idea=$enableval)
141 AC_MSG_RESULT($use_idea)
142 if test x"$use_idea" = xyes ; then
143    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
144
145 # We don't need idea but some people claim that they need it for
146 # research etc., so we allow to place an idea source code into the
147 # cipher directory and statically link it if available, otherwise we
148 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
149
150    AC_MSG_CHECKING([for idea cipher module])
151    tmp=""
152    if test -f $srcdir/cipher/idea.c; then 
153       IDEA_O=idea.o
154       tmp=idea
155    else
156       IDEA_O=idea-stub.o
157       tmp=no
158       try_extensions=yes
159    fi
160    AC_SUBST(IDEA_O)
161    AC_MSG_RESULT($tmp)
162 fi
163
164 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
165 AC_ARG_ENABLE(cast5,
166    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
167    use_cast5=$enableval)
168 AC_MSG_RESULT($use_cast5)
169 if test x"$use_cast5" = xyes ; then
170    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
171 fi
172
173 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
174 AC_ARG_ENABLE(blowfish,
175    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
176    use_blowfish=$enableval)
177 AC_MSG_RESULT($use_blowfish)
178 if test x"$use_blowfish" = xyes ; then
179    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
180 fi
181
182 AC_MSG_CHECKING([whether to enable the AES ciphers])
183 AC_ARG_ENABLE(aes,
184    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
185    use_aes=$enableval)
186 AC_MSG_RESULT($use_aes)
187 if test x"$use_aes" = xyes ; then
188    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
189 fi
190
191 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
192 AC_ARG_ENABLE(twofish,
193    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
194    use_twofish=$enableval)
195 AC_MSG_RESULT($use_twofish)
196 if test x"$use_twofish" = xyes ; then
197    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
198 fi
199
200 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
201 AC_ARG_ENABLE(sha256,
202    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
203    use_sha256=$enableval)
204 AC_MSG_RESULT($use_sha256)
205 if test x"$use_sha256" = xyes ; then
206    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
207 fi
208
209 dnl SHA512 is defined only after we confirm 64-bit support later
210 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
211 AC_ARG_ENABLE(sha512,
212    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
213    use_sha512=$enableval)
214 AC_MSG_RESULT($use_sha512)
215
216 dnl BZLIB is defined only after we confirm the library is available later
217 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
218 AC_ARG_ENABLE(bzip2,
219    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
220    use_bzip2=$enableval)
221 AC_MSG_RESULT($use_bzip2)
222
223 AC_MSG_CHECKING([whether to enable external program execution])
224 AC_ARG_ENABLE(exec,
225     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
226     use_exec=$enableval)
227 AC_MSG_RESULT($use_exec)
228 if test "$use_exec" = no ; then
229     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
230 fi
231
232 if test "$use_exec" = yes ; then
233   AC_MSG_CHECKING([whether to enable photo ID viewing])
234   AC_ARG_ENABLE(photo-viewers,
235       [  --disable-photo-viewers disable photo ID viewers],
236       [if test "$enableval" = no ; then
237          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
238       fi],enableval=yes)
239   gnupg_cv_enable_photo_viewers=$enableval
240   AC_MSG_RESULT($enableval)
241
242   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
243     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
244     AC_ARG_WITH(photo-viewer,
245         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
246         [if test "$withval" = yes ; then
247            withval=no
248         elif test "$withval" != no ; then
249            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
250                             [if set, restrict photo-viewer to this])
251         fi],withval=no)
252     AC_MSG_RESULT($withval)
253   fi
254
255   AC_MSG_CHECKING([whether to enable external keyserver helpers])
256   AC_ARG_ENABLE(keyserver-helpers,
257       [  --disable-keyserver-helpers  disable all external keyserver support],
258       [if test "$enableval" = no ; then
259          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
260                   [define to disable keyserver helpers])
261       fi],enableval=yes)
262   gnupg_cv_enable_keyserver_helpers=$enableval
263   AC_MSG_RESULT($enableval)
264
265   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
266     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
267     AC_ARG_ENABLE(ldap,
268     [  --disable-ldap          disable LDAP keyserver interface],
269         try_ldap=$enableval, try_ldap=yes)
270     AC_MSG_RESULT($try_ldap)
271
272     AC_MSG_CHECKING([whether HKP keyserver support is requested])
273     AC_ARG_ENABLE(hkp,
274     [  --disable-hkp           disable HKP keyserver interface],
275         try_hkp=$enableval, try_hkp=yes)
276     AC_MSG_RESULT($try_hkp)
277
278     AC_MSG_CHECKING([whether email keyserver support is requested])
279     AC_ARG_ENABLE(mailto,
280     [  --disable-mailto        disable email keyserver interface],
281         try_mailto=$enableval, try_mailto=yes)
282     AC_MSG_RESULT($try_mailto)
283     fi
284
285     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
286     AC_ARG_ENABLE(keyserver-path,
287         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
288         [if test "$enableval" = no ; then
289          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
290         fi],enableval=yes)
291     AC_MSG_RESULT($enableval)
292   fi
293
294 AC_MSG_CHECKING([whether the included zlib is requested])
295 AC_ARG_WITH(included-zlib,
296     [  --with-included-zlib    use the zlib code included here],
297 [g10_force_zlib=yes], [g10_force_zlib=no] )
298 AC_MSG_RESULT($g10_force_zlib)
299
300 dnl
301 dnl Check whether we want to use Linux capabilities
302 dnl
303 AC_MSG_CHECKING([whether use of capabilities is requested])
304 AC_ARG_WITH(capabilities,
305     [  --with-capabilities     use linux capabilities [default=no]],
306 [use_capabilities="$withval"],[use_capabilities=no])
307 AC_MSG_RESULT($use_capabilities)
308
309
310 AH_BOTTOM([
311 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
312 #define EXEC_TEMPFILE_ONLY
313 #endif
314
315 /* This is the major version number of GnuPG so that
316    source included files can test for this. */
317 #define GNUPG_MAJOR_VERSION 1
318
319 #include "g10defs.h"
320 ])
321
322
323 AM_MAINTAINER_MODE
324
325 dnl Checks for programs.
326
327 AC_PROG_MAKE_SET
328 AM_SANITY_CHECK
329 missing_dir=`cd $ac_aux_dir && pwd`
330 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
331 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
332 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
333 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
334 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
335 AC_PROG_CC
336 AC_PROG_CPP
337 AC_PROG_RANLIB
338 AC_CHECK_TOOL(AR, ar, :)
339 AC_PATH_PROG(PERL,"perl")
340 AC_ISC_POSIX
341 AC_SYS_LARGEFILE
342 AC_PROG_INSTALL
343 AC_PROG_AWK
344 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
345 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
346 GNUPG_CHECK_FAQPROG
347 GNUPG_CHECK_DOCBOOK_TO_TEXI
348
349 MPI_OPT_FLAGS=""
350
351
352 try_gettext=yes
353 have_dosish_system=no
354 need_dlopen=yes
355 case "${target}" in
356     *-*-mingw32*)
357         # special stuff for Windoze NT
358         ac_cv_have_dev_random=no
359         AC_DEFINE(USE_ONLY_8DOT3,1,
360                   [set this to limit filenames to the 8.3 format])
361         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
362                   [defined if we must run on a stupid file system])
363         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
364                   [because the Unix gettext has too much overhead on
365                    MingW32 systems and these systems lack Posix functions,
366                    we use a simplified version of gettext])
367         have_dosish_system=yes
368         need_dlopen=no
369         try_gettext="no"
370         ;;
371     i?86-emx-os2 | i?86-*-os2*emx )
372         # OS/2 with the EMX environment
373         ac_cv_have_dev_random=no
374         AC_DEFINE(HAVE_DRIVE_LETTERS)
375         have_dosish_system=yes
376         try_gettext="no"
377         ;;
378
379     i?86-*-msdosdjgpp*)
380         # DOS with the DJGPP environment
381         ac_cv_have_dev_random=no
382         AC_DEFINE(HAVE_DRIVE_LETTERS)
383         have_dosish_system=yes
384         try_gettext="no"
385         ;;
386
387     *-*-freebsd*)
388        # FreeBSD
389        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
390        LDFLAGS="$LDFLAGS -L/usr/local/lib"
391        ;;
392
393     *-*-hpux*)
394         if test -z "$GCC" ; then
395             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
396         fi
397         ;;
398     *-dec-osf4*)
399         if test -z "$GCC" ; then
400             # Suppress all warnings
401             # to get rid of the unsigned/signed char mismatch warnings.
402             CFLAGS="$CFLAGS -w"
403         fi
404         ;;
405     *-dec-osf5*)
406         if test -z "$GCC" ; then
407             # Use the newer compiler `-msg_disable ptrmismatch' to
408             # get rid of the unsigned/signed char mismatch warnings.
409             # Using this may hide other pointer mismatch warnings, but
410             # it at least lets other warning classes through
411             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
412         fi
413         ;;
414     m68k-atari-mint)
415         ;;
416     *)
417        ;;
418 esac
419
420 if test "$have_dosish_system" = yes; then
421    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
422              [defined if we run on some of the PCDOS like systems 
423               (DOS, Windoze. OS/2) with special properties like
424               no file modes])
425 fi
426 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
427
428 AC_SUBST(MPI_OPT_FLAGS)
429 GNUPG_SYS_SYMBOL_UNDERSCORE
430
431 dnl This needs to go after AC_PROG_CC so that $EXEEXT is defined
432 if test "$try_hkp" = yes ; then
433   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
434 fi
435
436 dnl Must check for network library requirements before doing link tests
437 dnl for ldap, for example. If ldap libs are static (or dynamic and without
438 dnl ELF runtime link paths), then link will fail and LDAP support won't
439 dnl be detected.
440
441 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
442         [NETLIBS="-lnsl $NETLIBS"]))
443 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
444         [NETLIBS="-lsocket $NETLIBS"]))
445
446 dnl Now try for the resolver functions so we can use DNS SRV
447
448 AC_ARG_ENABLE(dns-srv,
449    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
450    use_dns_srv=$enableval,use_dns_srv=yes)
451
452 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
453   _srv_save_libs=$LIBS
454   LIBS=""
455   # the double underscore thing is a glibc-ism?
456   AC_SEARCH_LIBS(res_query,resolv bind,,
457                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
458   AC_SEARCH_LIBS(dn_expand,resolv bind,,
459                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
460   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
461                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
462
463   if test x"$use_dns_srv" = xyes ; then
464      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
465      SRVLIBS=$LIBS
466   else
467      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
468   fi
469   LIBS=$_srv_save_libs
470 fi
471
472 AC_SUBST(SRVLIBS)
473
474 # Try and link a LDAP test program to weed out unusable LDAP
475 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
476 # general is terrible with creating weird dependencies.  If all else
477 # fails, the user can play guess-the-dependency by using something
478 # like ./configure LDAPLIBS="-Lfoo -lbar"
479
480 if test "$try_ldap" = yes ; then
481   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
482     _ldap_save_libs=$LIBS
483     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
484
485     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
486     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
487                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
488     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
489
490     if test $gnupg_cv_func_ldap_init = no; then
491       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
492       AC_TRY_LINK([#include <lber.h>
493 #include <ldap.h>],[ldap_open("foobar",1234);],
494          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
495       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
496     fi
497
498     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
499        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
500     fi
501
502     if test "$gnupg_cv_func_ldap_init" = yes || \
503         test "$gnupg_cv_func_ldaplber_init" = yes ; then
504        LDAPLIBS=$MY_LDAPLIBS
505        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
506
507        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
508
509        if test "$gnupg_cv_func_ldap_init" = yes ; then
510           AC_TRY_LINK([#include <ldap.h>],
511              [ldap_get_option((void *)0,0,(void *)0);],
512              [gnupg_cv_func_ldap_get_option=yes],
513              [gnupg_cv_func_ldap_get_option=no])
514         else
515           AC_TRY_LINK([#include <lber.h>
516 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
517              [gnupg_cv_func_ldap_get_option=yes],
518              [gnupg_cv_func_ldap_get_option=no])
519        fi
520
521        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
522
523        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
524           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
525        else
526           AC_MSG_CHECKING([whether LDAP supports ld_errno])
527
528           if test "$gnupg_cv_func_ldap_init" = yes ; then
529             AC_TRY_COMPILE([#include <ldap.h>],
530                [LDAP *ldap; ldap->ld_errno;],
531                [gnupg_cv_func_ldap_ld_errno=yes],
532                [gnupg_cv_func_ldap_ld_errno=no])
533            else
534             AC_TRY_LINK([#include <lber.h>
535 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
536                [gnupg_cv_func_ldap_ld_errno=yes],
537                [gnupg_cv_func_ldap_ld_errno=no])
538           fi
539
540           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
541
542           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
543              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
544           fi
545        fi
546     fi
547
548     LIBS=$_ldap_save_libs
549
550     if test "$GPGKEYS_LDAP" != "" ; then break; fi
551   done
552 fi
553
554 AC_SUBST(GPGKEYS_LDAP)
555 AC_SUBST(LDAPLIBS)
556
557 dnl This isn't necessarily sendmail itself, but anything that gives a
558 dnl sendmail-ish interface to the outside world.  That includes qmail,
559 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
560
561 if test "$try_mailto" = yes ; then
562   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
563
564   if test "$with_mailprog" = yes ; then
565     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
566     if test "$ac_cv_path_SENDMAIL" ; then
567       GPGKEYS_MAILTO="gpgkeys_mailto"
568     fi
569   elif test "$with_mailprog" != no ; then
570     AC_MSG_CHECKING([for a mail transport program])
571     AC_SUBST(SENDMAIL,$with_mailprog)
572     AC_MSG_RESULT($with_mailprog)
573     GPGKEYS_MAILTO="gpgkeys_mailto"
574   fi
575 fi
576
577 AC_SUBST(GPGKEYS_MAILTO)
578
579 case "${target}" in
580     *-*-mingw32*)
581         PRINTABLE_OS_NAME="MingW32"
582         ;;
583     *-*-cygwin*)
584         PRINTABLE_OS_NAME="Cygwin"
585         ;;
586     i?86-emx-os2 | i?86-*-os2*emx )
587         PRINTABLE_OS_NAME="OS/2"
588         ;;
589     i?86-*-msdosdjgpp*)
590         PRINTABLE_OS_NAME="MSDOS/DJGPP"
591         try_extensions=no
592         ;;
593     *-linux*)
594         PRINTABLE_OS_NAME="GNU/Linux"
595         ;;
596     *)
597         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
598         ;;
599 esac
600 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
601                    [A human readable text with the name of the OS])
602
603
604 #
605 # 1. Set names of random devices
606 #
607 NAME_OF_DEV_RANDOM="/dev/random"
608 NAME_OF_DEV_URANDOM="/dev/urandom"
609 case "${target}" in
610     *-openbsd*)
611         NAME_OF_DEV_RANDOM="/dev/srandom"
612         NAME_OF_DEV_URANDOM="/dev/urandom"
613         ;;
614 esac
615 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
616                    [defined to the name of the strong random device])
617 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
618                    [defined to the name of the weaker random device])
619 AC_SUBST(MPI_OPT_FLAGS)
620
621
622 dnl Checks for libraries.
623
624 if test "$try_gettext" = yes; then
625   AM_GNU_GETTEXT(,[need-ngettext])
626
627   # gettext requires some extra checks.  These really should be part of
628   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
629   # function checks to here.
630
631   AC_CHECK_FUNCS(strchr)
632 else
633   USE_NLS=no
634   USE_INCLUDED_LIBINTL=no
635   BUILD_INCLUDED_LIBINTL=no
636   AC_SUBST(USE_NLS)
637   AC_SUBST(USE_INCLUDED_LIBINTL)
638   AC_SUBST(BUILD_INCLUDED_LIBINTL)
639 fi
640
641 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
642   if test "$need_dlopen" = yes; then
643     _dl_save_libs=$LIBS
644     LIBS=""
645     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
646     if test x"$found_dlopen" = "xyes" ; then
647       AC_DEFINE(HAVE_DL_DLOPEN,1,
648                 [Defined when the dlopen function family is available])
649       DLLIBS=$LIBS
650     else
651       if test "$try_extensions" = yes ; then
652          AC_MSG_WARN([dlopen not found.  Disabling extensions.])
653          try_extensions=no
654       fi
655   
656       if test "$card_support" = yes ; then
657          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
658          card_support=no
659       fi
660     fi
661     LIBS=$_dl_save_libs
662   fi
663 fi
664
665 AC_SUBST(DLLIBS)
666
667 if test "$card_support" = yes ; then
668   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
669 fi
670
671 if test "$try_extensions" = yes ; then
672   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
673 fi
674
675 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
676
677 dnl Checks for header files.
678 AC_HEADER_STDC
679 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h locale.h getopt.h)
680
681 dnl Checks for typedefs, structures, and compiler characteristics.
682 AC_C_CONST
683 AC_C_INLINE
684 AC_C_VOLATILE
685 AC_TYPE_SIZE_T
686 AC_TYPE_MODE_T
687 AC_TYPE_SIGNAL
688 AC_DECL_SYS_SIGLIST
689
690 GNUPG_CHECK_ENDIAN
691
692 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
693 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
694 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
695 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
696 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
697
698 AC_CHECK_SIZEOF(unsigned short)
699 AC_CHECK_SIZEOF(unsigned int)
700 AC_CHECK_SIZEOF(unsigned long)
701 AC_CHECK_SIZEOF(unsigned long long)
702
703 # Ensure that we have UINT64_C before we bother to check for uint64_t
704 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
705    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
706 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
707
708 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
709    AC_CHECK_SIZEOF(uint64_t)
710 fi
711
712 if test "$ac_cv_sizeof_unsigned_short" = "0" \
713    || test "$ac_cv_sizeof_unsigned_int" = "0" \
714    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
715     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
716 fi
717
718 dnl Do we have any 64-bit data types?
719 if test "$ac_cv_sizeof_unsigned_int" != "8" \
720    && test "$ac_cv_sizeof_unsigned_long" != "8" \
721    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
722    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
723     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384 and SHA-512])
724 else
725   if test x"$use_sha512" = xyes ; then
726      AC_SUBST(SHA512_O,sha512.o)
727      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
728   fi
729 fi
730
731 dnl Checks for library functions.
732 AC_FUNC_FSEEKO
733 AC_FUNC_VPRINTF
734 AC_FUNC_FORK
735 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
736 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
737 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
738 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
739 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
740 AC_REPLACE_FUNCS(mkdtemp)
741 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
742
743 # See if getopt is in libiberty.  This is of course not optimal since
744 # it might be somewhere other than libiberty, but does cover the
745 # mingw32 case.
746
747 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
748
749 #
750 # check for gethrtime and run a testprogram to see whether
751 # it is broken.  It has been reported that some Solaris and HP UX systems 
752 # raise an SIGILL
753 #
754 AC_CACHE_CHECK([for gethrtime], 
755                [gnupg_cv_func_gethrtime],
756                [AC_TRY_LINK([#include <sys/times.h>],[
757                    hrtime_t tv;
758                    tv = gethrtime();
759                  ],
760                  [gnupg_cv_func_gethrtime=yes],
761                  [gnupg_cv_func_gethrtime=no])
762                ])
763 if test $gnupg_cv_func_gethrtime = yes; then
764      AC_DEFINE([HAVE_GETHRTIME], 1,
765                [Define if you have the `gethrtime(2)' function.])
766      AC_CACHE_CHECK([whether gethrtime is broken], 
767                [gnupg_cv_func_broken_gethrtime],
768                [AC_TRY_RUN([
769                    #include <sys/times.h>
770                    int main () {
771                    hrtime_t tv;
772                    tv = gethrtime(); 
773                  }
774                  ],
775                  [gnupg_cv_func_broken_gethrtime=no],
776                  [gnupg_cv_func_broken_gethrtime=yes],
777                  [gnupg_cv_func_broken_gethrtime=assume-no])
778                 ])
779     if test $gnupg_cv_func_broken_gethrtime = yes; then
780       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
781       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
782     fi
783 fi
784      
785
786 GNUPG_CHECK_MLOCK
787 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
788
789 dnl
790 dnl Check whether we can use Linux capabilities as requested
791 dnl
792 if test "$use_capabilities" = "yes" ; then
793 use_capabilities=no
794 AC_CHECK_HEADERS(sys/capability.h)
795 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
796   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
797   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
798      AC_DEFINE(USE_CAPABILITIES,1,
799                [define if capabilities should be used])
800      AC_SUBST(CAPLIBS,"-lcap")
801      use_capabilities=yes
802   fi
803 fi
804 if test "$use_capabilities" = "no" ; then
805     AC_MSG_WARN([[
806 ***
807 *** The use of capabilities on this system is not possible.
808 *** You need a recent Linux kernel and some patches:
809 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
810 ***   fcap-module-990613.tar.gz     (kernel module)
811 ***   libcap-1.92.tar.gz            (user mode library and utilities)
812 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
813 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
814 ***]])
815 fi
816 fi
817
818
819 GNUPG_CHECK_IPC
820 if test "$ac_cv_header_sys_shm_h" = "yes"; then
821   AC_DEFINE(USE_SHM_COPROCESSING,1,
822             [define if the shared memory interface should be made available])
823 fi
824
825 dnl
826 dnl check whether we have a random device
827 dnl
828 if test "$try_dev_random" = yes ; then
829     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
830     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
831       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
832     if test "$ac_cv_have_dev_random" = yes; then
833         AC_DEFINE(HAVE_DEV_RANDOM,1,
834                  [defined if the system supports a random device] )
835     fi
836 else
837     AC_MSG_CHECKING(for random device)
838     ac_cv_have_dev_random=no
839     AC_MSG_RESULT(has been disabled)
840 fi
841
842
843 dnl
844 dnl Figure out the default random module.
845 dnl
846 random_modules=""
847 if test "$use_static_rnd" = default; then
848      if test "$ac_cv_have_dev_random" = yes; then
849         random_modules="rndlinux"
850      else
851          case "${target}" in
852             *-*-mingw32*|*-*-cygwin*)
853                 random_modules="rndw32"
854                 ;;
855             i?86-emx-os2|i?86-*-os2*emx)
856                 random_modules="rndos2"
857                 ;;
858             m68k-atari-mint)
859                 random_modules="rndatari"
860                 ;;
861             i?86-*-msdosdjgpp*)
862                 :
863                 ;;
864             *)
865                 random_modules="rndlinux rndegd rndunix"
866                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
867                           [Allow to select random modules at runtime.])
868                 ;;
869          esac
870      fi
871 else
872   if test "$use_static_rnd" = auto; then
873      random_modules="rndlinux rndegd rndunix"
874      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
875   else
876      random_modules="rnd$use_static_rnd";
877   fi
878 fi
879
880 if test -z "$random_modules"; then
881    AC_MSG_ERROR(no random module available)
882 fi
883 print_egd_warning=no
884 for rndmod in $random_modules "" ; do
885   case "$rndmod" in
886     rndlinux)
887          AC_DEFINE(USE_RNDLINUX,1, 
888                   [Defined if the /dev/random based RNG should be used.])
889          ;;
890     rndunix)
891          AC_DEFINE(USE_RNDUNIX,1, 
892                   [Defined if the default Unix RNG should be used.])
893          print_egd_warning=yes
894           ;;
895     rndegd)
896          AC_DEFINE(USE_RNDEGD,1, 
897                   [Defined if the EGD based RNG should be used.])
898          ;;
899     rndw32)
900          AC_DEFINE(USE_RNDW32,1, 
901                   [Defined if the Windows specific RNG should be used.])
902         ;;
903    esac
904 done
905
906 dnl setup assembler stuff
907 AC_MSG_CHECKING(for mpi assembler functions)
908 if test -f $srcdir/mpi/config.links ; then
909     . $srcdir/mpi/config.links
910     AC_CONFIG_LINKS("$mpi_ln_list")
911     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
912     ac_cv_mpi_sflags="$mpi_sflags"
913     ac_cv_mpi_config_done="yes"
914     AC_MSG_RESULT(done)
915 else
916     AC_MSG_RESULT(failed)
917     AC_MSG_ERROR([mpi/config.links missing!])
918 fi
919 MPI_EXTRA_ASM_OBJS=""
920 show_extraasm=""
921 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
922 for i in $ac_cv_mpi_extra_asm_modules; do
923     show_extraasm="$show_extraasm $i"
924     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
925 done
926 fi
927 AC_SUBST(MPI_EXTRA_ASM_OBJS)
928 MPI_SFLAGS="$ac_cv_mpi_sflags"
929 AC_SUBST(MPI_SFLAGS)
930
931 # Sanity check regex.  Tests adapted from mutt.
932
933 AC_MSG_CHECKING([whether regular expression support is requested])
934 AC_ARG_ENABLE(regex,
935 [  --disable-regex         do not handle regular expressions in trust sigs],
936      use_regex=$enableval, use_regex=yes)
937 AC_MSG_RESULT($use_regex)
938
939 if test "$use_regex" = yes ; then
940   AC_MSG_CHECKING([whether the included regex lib is requested])
941   AC_ARG_WITH(included-regex,
942       [  --with-included-regex   use the included GNU regex library],
943       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
944   AC_MSG_RESULT($gnupg_cv_included_regex)
945
946   if test $gnupg_cv_included_regex = no ; then
947      # Does the system have regex functions at all?
948      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
949                            gnupg_cv_included_regex=yes)
950   fi
951
952   if test $gnupg_cv_included_regex = no ; then
953      AC_CACHE_CHECK([whether your system's regexp library is broken],
954        [gnupg_cv_regex_broken],
955        AC_TRY_RUN([
956 #include <unistd.h>
957 #include <regex.h>
958 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
959        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
960
961      if test $gnupg_cv_regex_broken = yes ; then
962       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
963       gnupg_cv_included_regex=yes
964      fi
965   fi
966
967   if test $gnupg_cv_included_regex = yes; then
968      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
969      AC_SUBST(REGEX_O,regex.o)
970   fi
971 else
972
973   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
974 fi
975
976 dnl Do we have zlib? Must do it here because Solaris failed
977 dnl when compiling a conftest (due to the "-lz" from LIBS).
978 use_local_zlib=yes
979 if test "$g10_force_zlib" = "yes"; then
980   :
981 else
982   _cppflags="${CPPFLAGS}"
983   _ldflags="${LDFLAGS}"
984
985   AC_ARG_WITH(zlib,
986   [  --with-zlib=DIR         use libz in DIR],[
987     if test -d "$withval"; then
988       CPPFLAGS="${CPPFLAGS} -I$withval/include"
989       LDFLAGS="${LDFLAGS} -L$withval/lib"
990     fi
991   ])
992
993   AC_CHECK_HEADER(zlib.h,
994       AC_CHECK_LIB(z, deflateInit2_,
995        use_local_zlib=no
996        ZLIBS="-lz",
997        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
998        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
999 fi
1000
1001 if test "$use_local_zlib" = yes ; then
1002     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1003     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1004     ZLIBS="../zlib/libzlib.a"
1005 else
1006     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1007 fi
1008
1009 if test "$use_bzip2" = yes ; then
1010   _cppflags="${CPPFLAGS}"
1011   _ldflags="${LDFLAGS}"
1012   AC_ARG_WITH(bzip2,
1013      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1014       [
1015       if test -d "$withval" ; then
1016         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1017         LDFLAGS="${LDFLAGS} -L$withval/lib"
1018       fi
1019       ],withval="")
1020
1021   if test "$withval" != no ; then
1022      AC_CHECK_HEADER(bzlib.h,
1023         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1024           [
1025           have_bz2=yes
1026           ZLIBS="$ZLIBS -lbz2"
1027           AC_DEFINE(HAVE_BZIP2,1,
1028                   [Defined if the bz2 compression library is available])
1029           ],
1030           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1031           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1032   fi
1033 fi
1034
1035 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1036 AC_SUBST(ZLIBS)
1037
1038
1039 #
1040 # libusb allows us to use the integrated CCID smartcard reader driver.
1041 #
1042 # Note, that we need the CVS (unstable) version. 
1043 #
1044 LIBUSB_LIBS=""
1045 if test "$card_support" = yes; then
1046     AC_CHECK_LIB(usb, usb_find_device,
1047                  [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
1048                    AC_DEFINE(HAVE_LIBUSB,1,
1049                    [defined if libusb is available])
1050                  ])
1051 fi
1052 AC_SUBST(LIBUSB_LIBS)
1053
1054
1055
1056 # Allow users to append something to the version string without
1057 # flagging it as development version.  The user version parts is
1058 # considered everything after a dash. 
1059 if test "$development_version" != yes; then
1060   changequote(,)dnl
1061   tmp_pat='[a-zA-Z]'
1062   changequote([,])dnl
1063   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1064     development_version=yes
1065   fi
1066 fi
1067 if test "$development_version" = yes; then
1068     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1069             [Defined if this is not a regular release])
1070 fi
1071
1072 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1073
1074 GNUPG_CHECK_GNUMAKE
1075
1076 # add some extra libs here so that previous tests don't fail for
1077 # mysterious reasons - the final link step should bail out. 
1078 case "${target}" in
1079     *-*-mingw32*)
1080 dnl      NETLIBS="$NETLIBS -lwsock32"
1081         W32LIBS="-lwsock32"
1082         ;;
1083     *)
1084        ;;
1085 esac
1086
1087 AC_SUBST(NETLIBS)
1088 AC_SUBST(W32LIBS)
1089
1090 if test "$GCC" = yes; then
1091     if test "$USE_MAINTAINER_MODE" = "yes"; then
1092         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1093     else
1094         CFLAGS="$CFLAGS -Wall"
1095     fi
1096 fi
1097
1098
1099 if test "$print_egd_warning" = yes; then
1100   AC_MSG_WARN([[
1101 ***
1102 *** The performance of the UNIX random gatherer module is not very good
1103 *** and it does not keep the entropy pool over multiple invocations of
1104 *** GnuPG.  The suggested way to overcome this problem is to use the
1105 ***
1106 ***               Entropy Gathering Daemon (EGD)
1107 ***
1108 *** which provides a entropy source for the whole system.  It is written
1109 *** in Perl and available at the GnuPG FTP servers.  For more information
1110 *** consult the GnuPG webpages:
1111 ***
1112 ***           http://www.gnupg.org/download/#EGD
1113 ***
1114 *** You may want to run ./configure with --enable-static-rnd=egd or
1115 *** --enable-static-rnd=auto to use it.
1116 ***]])
1117 fi
1118
1119 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1120
1121 AC_CONFIG_COMMANDS(g10defs.h,[[
1122 cat >g10defs.tmp <<G10EOF
1123 /* Generated automatically by configure */
1124 #ifdef HAVE_DRIVE_LETTERS
1125 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1126 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1127 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1128 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1129 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1130 #else
1131 #define G10_LOCALEDIR     "${datadir}/locale"
1132 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1133 #define GNUPG_DATADIR     "${datadir}/gnupg"
1134 #ifdef __VMS
1135 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1136 #else
1137 #define GNUPG_HOMEDIR "~/.gnupg" 
1138 #endif
1139 #endif
1140 /* those are here to be redefined by handcrafted g10defs.h.
1141    Please note that the string version must not contain more
1142    than one character because the using code assumes strlen()==1 */
1143 #ifdef HAVE_DOSISH_SYSTEM
1144 #define DIRSEP_C '\\\\'
1145 #define EXTSEP_C '.'
1146 #define DIRSEP_S "\\\\"
1147 #define EXTSEP_S "."
1148 #else
1149 #define DIRSEP_C '/'
1150 #define EXTSEP_C '.'
1151 #define DIRSEP_S "/"
1152 #define EXTSEP_S "."
1153 #endif
1154 /* This is the same as VERSION, but should be overridden if the
1155    platform cannot handle things like dots'.' in filenames.  Set
1156    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1157    uses for dots and dashes. */
1158 #define SAFE_VERSION      VERSION
1159 #define SAFE_VERSION_DOT  '.'
1160 #define SAFE_VERSION_DASH '-'
1161 G10EOF
1162 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1163 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1164     echo "g10defs.h is unchanged"
1165     rm -f g10defs.tmp
1166 else
1167     rm -f g10defs.h
1168     mv g10defs.tmp g10defs.h
1169     echo "g10defs.h created"
1170 fi
1171 ]],[[
1172 prefix=$prefix
1173 exec_prefix=$exec_prefix
1174 libdir=$libdir
1175 libexecdir=$libexecdir
1176 datadir=$datadir
1177 DATADIRNAME=$DATADIRNAME
1178 ]])
1179
1180
1181 AC_CONFIG_FILES([
1182 Makefile
1183 m4/Makefile
1184 intl/Makefile
1185 po/Makefile.in
1186 util/Makefile
1187 mpi/Makefile
1188 cipher/Makefile
1189 g10/Makefile
1190 keyserver/Makefile
1191 keyserver/gpgkeys_mailto
1192 keyserver/gpgkeys_test
1193 doc/Makefile
1194 tools/Makefile
1195 zlib/Makefile
1196 checks/Makefile
1197 ])
1198 AC_OUTPUT
1199
1200 # Give some feedback
1201 echo
1202 echo   "                Configured for: $PRINTABLE_OS_NAME ($target)"
1203 if test -n "$show_extraasm"; then
1204   echo "  Extra cpu specific functions:$show_extraasm"
1205 fi
1206 echo