c06defd77b697e7d2a1e3798f286255c1f879962
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.4
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.0.2
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_zip=yes
78 use_bzip2=yes
79 use_exec=yes
80 disable_keyserver_path=no
81 use_ccid_driver=yes
82 use_standard_socket=no
83
84 try_ks_ldap=no
85
86 GNUPG_BUILD_PROGRAM(gpg, yes)
87 GNUPG_BUILD_PROGRAM(gpgsm, yes)
88 GNUPG_BUILD_PROGRAM(agent, yes)
89 GNUPG_BUILD_PROGRAM(scdaemon, yes)
90 GNUPG_BUILD_PROGRAM(g13, yes)
91 GNUPG_BUILD_PROGRAM(dirmngr, yes)
92 GNUPG_BUILD_PROGRAM(tools, yes)
93 GNUPG_BUILD_PROGRAM(doc, yes)
94 GNUPG_BUILD_PROGRAM(symcryptrun, no)
95 GNUPG_BUILD_PROGRAM(gpgtar, no)
96
97 AC_SUBST(PACKAGE)
98 AC_SUBST(PACKAGE_GT)
99 AC_SUBST(VERSION)
100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
101 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
102                                 [Name of this package for gettext])
103 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
104 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
105                                         [Bug report address])
106 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
107                                        [Required version of Libgcrypt])
108 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
109                                        [Required version of Libksba])
110
111
112
113 # The default is to use the modules from this package and the few
114 # other packages in a standard place; i.e where this package gets
115 # installed.  With these options it is possible to override these
116 # ${prefix} depended values with fixed paths, which can't be replaced
117 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
118 AC_ARG_WITH(agent-pgm,
119     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
120           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
121 AC_SUBST(GNUPG_AGENT_PGM)
122 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
123 show_gnupg_agent_pgm="(default)"
124 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
125
126 AC_ARG_WITH(pinentry-pgm,
127     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
128           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
129 AC_SUBST(GNUPG_PINENTRY_PGM)
130 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
131 show_gnupg_pinentry_pgm="(default)"
132 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
133
134
135 AC_ARG_WITH(scdaemon-pgm,
136     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
137           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
138 AC_SUBST(GNUPG_SCDAEMON_PGM)
139 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
140 show_gnupg_scdaemon_pgm="(default)"
141 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
142
143
144 AC_ARG_WITH(dirmngr-pgm,
145     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
146           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
147 AC_SUBST(GNUPG_DIRMNGR_PGM)
148 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
149 show_gnupg_dirmngr_pgm="(default)"
150 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
151
152 AC_ARG_WITH(protect-tool-pgm,
153     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
154           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
155 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
156 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
157 show_gnupg_protect_tool_pgm="(default)"
158 test -n "$GNUPG_PROTECT_TOOL_PGM" \
159       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
160
161 AC_ARG_WITH(dirmngr-ldap-pgm,
162     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
163           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
164 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
165 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
166 show_gnupg_dirmngr_ldap_pgm="(default)"
167 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
168       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
169
170
171 # Some folks want to use only the agent from this packet.  Make it
172 # easier for them by providing the configure option
173 # --enable-only-agent.
174 AC_ARG_ENABLE(agent-only,
175     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
176     build_agent_only=$enableval)
177
178 # SELinux support includes tracking of sensitive files to avoid
179 # leaking their contents through processing these files by gpg itself
180 AC_MSG_CHECKING([whether SELinux support is requested])
181 AC_ARG_ENABLE(selinux-support,
182               AC_HELP_STRING([--enable-selinux-support],
183                              [enable SELinux support]),
184               selinux_support=$enableval, selinux_support=no)
185 AC_MSG_RESULT($selinux_support)
186
187 # Allow disabling of zip support.
188 # This is in general not a good idea because according to rfc4880 OpenPGP
189 # implementations SHOULD support ZLIB.
190 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
191 AC_ARG_ENABLE(zip,
192    AC_HELP_STRING([--disable-zip],
193                   [disable the ZIP and ZLIB compression algorithm]),
194    use_zip=$enableval)
195 AC_MSG_RESULT($use_zip)
196
197 # Allow disabling of bzib2 support.
198 # It is defined only after we confirm the library is available later
199 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
200 AC_ARG_ENABLE(bzip2,
201    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
202    use_bzip2=$enableval)
203 AC_MSG_RESULT($use_bzip2)
204
205 # Configure option to allow or disallow execution of external
206 # programs, like a photo viewer.
207 AC_MSG_CHECKING([whether to enable external program execution])
208 AC_ARG_ENABLE(exec,
209     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
210     use_exec=$enableval)
211 AC_MSG_RESULT($use_exec)
212 if test "$use_exec" = no ; then
213     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
214 fi
215
216 if test "$use_exec" = yes ; then
217   AC_MSG_CHECKING([whether to enable photo ID viewing])
218   AC_ARG_ENABLE(photo-viewers,
219       [  --disable-photo-viewers disable photo ID viewers],
220       [if test "$enableval" = no ; then
221          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
222       fi],enableval=yes)
223   gnupg_cv_enable_photo_viewers=$enableval
224   AC_MSG_RESULT($enableval)
225
226   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
227     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
228     AC_ARG_WITH(photo-viewer,
229         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
230         [if test "$withval" = yes ; then
231            withval=no
232         elif test "$withval" != no ; then
233            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
234                             [if set, restrict photo-viewer to this])
235         fi],withval=no)
236     AC_MSG_RESULT($withval)
237   fi
238
239   AC_MSG_CHECKING([whether to enable external keyserver helpers])
240   AC_ARG_ENABLE(keyserver-helpers,
241       [  --disable-keyserver-helpers  disable all external keyserver support],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
244                   [define to disable keyserver helpers])
245       fi],enableval=yes)
246   gnupg_cv_enable_keyserver_helpers=$enableval
247   AC_MSG_RESULT($enableval)
248
249   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
250     # LDAP is defined only after we confirm the library is available later
251     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
252     AC_ARG_ENABLE(ldap,
253       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
254       try_ks_ldap=$enableval, try_ks_ldap=yes)
255     AC_MSG_RESULT($try_ks_ldap)
256
257     AC_MSG_CHECKING([whether HKP keyserver support is requested])
258     AC_ARG_ENABLE(hkp,
259       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
260       try_hkp=$enableval, try_hkp=yes)
261     AC_MSG_RESULT($try_hkp)
262
263     AC_MSG_CHECKING([whether finger key fetching support is requested])
264     AC_ARG_ENABLE(finger,
265       AC_HELP_STRING([--disable-finger],
266         [disable finger key fetching interface only]),
267       try_finger=$enableval, try_finger=yes)
268     AC_MSG_RESULT($try_finger)
269
270     AC_MSG_CHECKING([whether generic object key fetching support is requested])
271     AC_ARG_ENABLE(generic,
272       AC_HELP_STRING([--disable-generic],
273         [disable generic object key fetching interface only]),
274       try_generic=$enableval, try_generic=yes)
275     AC_MSG_RESULT($try_generic)
276
277     AC_MSG_CHECKING([whether email keyserver support is requested])
278     AC_ARG_ENABLE(mailto,
279       AC_HELP_STRING([--enable-mailto],
280         [enable email keyserver interface only]),
281       try_mailto=$enableval, try_mailto=no)
282     AC_MSG_RESULT($try_mailto)
283   fi
284
285   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
286   AC_ARG_ENABLE(keyserver-path,
287       AC_HELP_STRING([--disable-keyserver-path],
288         [disable the exec-path option for keyserver helpers]),
289       [if test "$enableval" = no ; then
290          disable_keyserver_path=yes
291       fi],enableval=yes)
292   AC_MSG_RESULT($enableval)
293 fi
294
295
296 #
297 # Check for the key/uid cache size.  This can't be zero, but can be
298 # pretty small on embedded systems.  This is used for the gpg part.
299 #
300 AC_MSG_CHECKING([for the size of the key and uid cache])
301 AC_ARG_ENABLE(key-cache,
302         AC_HELP_STRING([--enable-key-cache=SIZE],
303                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
304 if test "$enableval" = "no"; then
305    enableval=5
306 elif test "$enableval" = "yes" || test "$enableval" = ""; then
307    enableval=4096
308 fi
309 changequote(,)dnl
310 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
311 changequote([,])dnl
312 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
313    AC_MSG_ERROR([invalid key-cache size])
314 fi
315 AC_MSG_RESULT($key_cache_size)
316 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
317                   [Size of the key and UID caches])
318
319
320
321 #
322 # Check whether we want to use Linux capabilities
323 #
324 AC_MSG_CHECKING([whether use of capabilities is requested])
325 AC_ARG_WITH(capabilities,
326     [  --with-capabilities     use linux capabilities [default=no]],
327 [use_capabilities="$withval"],[use_capabilities=no])
328 AC_MSG_RESULT($use_capabilities)
329
330
331 #
332 # Allow disabling of internal CCID support.
333 # It is defined only after we confirm the library is available later
334 #
335 AC_MSG_CHECKING([whether to enable the internal CCID driver])
336 AC_ARG_ENABLE(ccid-driver,
337               AC_HELP_STRING([--disable-ccid-driver],
338                              [disable the internal CCID driver]),
339               use_ccid_driver=$enableval)
340 AC_MSG_RESULT($use_ccid_driver)
341
342
343 #
344 # To avoid double inclusion of config.h which might happen at some
345 # places, we add the usual double inclusion protection at the top of
346 # config.h.
347 #
348 AH_TOP([
349 #ifndef GNUPG_CONFIG_H_INCLUDED
350 #define GNUPG_CONFIG_H_INCLUDED
351 ])
352
353 #
354 # Stuff which goes at the bottom of config.h.
355 #
356 AH_BOTTOM([
357 /* This is the major version number of GnuPG so that
358    source included files can test for this.  Note, that
359    we use 2 here even for GnuPG 1.9.x. */
360 #define GNUPG_MAJOR_VERSION 2
361
362 /* Now to separate file name parts.
363    Please note that the string version must not contain more
364    than one character because the code assumes strlen()==1 */
365 #ifdef HAVE_DOSISH_SYSTEM
366 #define DIRSEP_C '\\'
367 #define DIRSEP_S "\\"
368 #define EXTSEP_C '.'
369 #define EXTSEP_S "."
370 #define PATHSEP_C ';'
371 #define PATHSEP_S ";"
372 #define EXEEXT_S ".exe"
373 #else
374 #define DIRSEP_C '/'
375 #define DIRSEP_S "/"
376 #define EXTSEP_C '.'
377 #define EXTSEP_S "."
378 #define PATHSEP_C ':'
379 #define PATHSEP_S ":"
380 #define EXEEXT_S ""
381 #endif
382
383 /* This is the same as VERSION, but should be overridden if the
384    platform cannot handle things like dots '.' in filenames. Set
385    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
386    uses for dots and dashes. */
387 #define SAFE_VERSION VERSION
388 #define SAFE_VERSION_DOT  '.'
389 #define SAFE_VERSION_DASH '-'
390
391 /* Some global constants. */
392 #ifdef HAVE_DOSISH_SYSTEM
393 # ifdef HAVE_DRIVE_LETTERS
394 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
395 # else
396 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
397 # endif
398 #elif defined(__VMS)
399 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
400 #else
401 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
402 #endif 
403 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
404
405 /* For some systems (DOS currently), we hardcode the path here.  For
406    POSIX systems the values are constructed by the Makefiles, so that
407    the values may be overridden by the make invocations; this is to
408    comply with the GNU coding standards.  Note that these values are
409    only defaults.  */
410 #ifdef HAVE_DOSISH_SYSTEM
411 # ifdef HAVE_DRIVE_LETTERS
412 #  define GNUPG_BINDIR      "c:\\gnupg"
413 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
414 #  define GNUPG_LIBDIR      "c:\\gnupg"
415 #  define GNUPG_DATADIR     "c:\\gnupg"
416 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
417 # else
418 #  define GNUPG_BINDIR      "\\gnupg"
419 #  define GNUPG_LIBEXECDIR  "\\gnupg"
420 #  define GNUPG_LIBDIR      "\\gnupg"
421 #  define GNUPG_DATADIR     "\\gnupg"
422 #  define GNUPG_SYSCONFDIR  "\\gnupg"
423 # endif
424 #endif
425
426 /* Derive some other constants. */
427 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
428 #define EXEC_TEMPFILE_ONLY
429 #endif
430
431
432 /* We didn't define endianness above, so get it from OS macros.  This
433    is intended for making fat binary builds on OS X. */
434 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
435 #if defined(__BIG_ENDIAN__)
436 #define BIG_ENDIAN_HOST 1
437 #elif defined(__LITTLE_ENDIAN__)
438 #define LITTLE_ENDIAN_HOST 1
439 #else
440 #error "No endianness found"
441 #endif
442 #endif
443
444
445 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
446    ldap_start_tls_s because that is the actual symbol used in the
447    library.  winldap.h redefines it to our commonly used value,
448    thus we define our usual macro here.  */
449 #ifdef HAVE_LDAP_START_TLS_SA
450 # ifndef HAVE_LDAP_START_TLS_S
451 #  define HAVE_LDAP_START_TLS_S 1
452 # endif
453 #endif
454
455
456 /* Tell libgcrypt not to use its own libgpg-error implementation. */
457 #define USE_LIBGPG_ERROR 1
458
459 /* We use jnlib, so tell other modules about it.  */
460 #define HAVE_JNLIB_LOGGING 1
461
462 /* Our HTTP code is used in estream mode.  */
463 #define HTTP_USE_ESTREAM 1
464
465 /* Under W32 we do an explicit socket initialization, thus we need to
466    avoid the on-demand initialization which would also install an atexit
467    handler.  */
468 #define HTTP_NO_WSASTARTUP
469
470 /* We always include support for the OpenPGP card.  */
471 /* Disabled for now ENABLE_CARD_SUPPORT 1 */
472
473 /* We explicitly need to disable PTH's soft mapping as Debian
474    currently enables it by default for no reason. */
475 #define PTH_SYSCALL_SOFT 0
476
477 /* We want to use the libgcrypt provided memory allocation for
478    asprintf.  */
479 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
480 #define _ESTREAM_PRINTF_FREE          gcry_free
481 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
482
483 /* Under Windows we use the gettext code from libgpg-error.  */
484 #define GPG_ERR_ENABLE_GETTEXT_MACROS
485
486 #endif /*GNUPG_CONFIG_H_INCLUDED*/
487 ])
488
489
490 AM_MAINTAINER_MODE
491
492 # Checks for programs.
493 AC_MSG_NOTICE([checking for programs])
494 AC_PROG_MAKE_SET
495 AM_SANITY_CHECK
496 missing_dir=`cd $ac_aux_dir && pwd`
497 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
498 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
499 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
500 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
501 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
502 AC_PROG_AWK
503 AC_PROG_CC
504 AC_PROG_CPP
505 AM_PROG_CC_C_O
506 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
507   AC_MSG_ERROR([[No C-89 compiler found]])
508 fi
509 AC_PROG_INSTALL
510 AC_PROG_LN_S
511 AC_PROG_RANLIB
512 AC_CHECK_TOOL(AR, ar, :)
513 AC_PATH_PROG(PERL,"perl")
514 AC_CHECK_TOOL(WINDRES, windres, :)
515 AC_ISC_POSIX
516 gl_EARLY
517 AC_SYS_LARGEFILE
518 GNUPG_CHECK_FAQPROG
519 GNUPG_CHECK_USTAR
520
521 # We need to compile and run a program on the build machine.  A
522 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
523 # the AC archive is broken for autoconf 2.57.  Given that there is no
524 # newer version of that macro, we assume that it is also broken for
525 # autoconf 2.61 and thus we use a simple but usually sufficient
526 # approach.
527 AC_MSG_CHECKING(for cc for build)
528 if test "$cross_compiling" = "yes"; then
529   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
530 else
531   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
532 fi
533 AC_MSG_RESULT($CC_FOR_BUILD)
534 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
535
536
537
538 try_gettext=yes
539 have_dosish_system=no
540 have_w32_system=no
541 have_w32ce_system=no
542 use_simple_gettext=no
543 mmap_needed=yes
544 case "${host}" in
545     *-mingw32*)
546         # special stuff for Windoze NT
547         ac_cv_have_dev_random=no
548         AC_DEFINE(USE_ONLY_8DOT3,1,
549                   [Set this to limit filenames to the 8.3 format])
550         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
551                   [Because the Unix gettext has too much overhead on
552                    MingW32 systems and these systems lack Posix functions,
553                    we use a simplified version of gettext])
554         disable_keyserver_path=yes
555         have_dosish_system=yes
556         have_w32_system=yes
557         case "${host}" in 
558           *-mingw32ce*)
559             have_w32ce_system=yes
560             ;;
561           *)
562             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
563                       [Defined if the OS supports drive letters.])
564             ;;
565         esac
566         try_gettext="no"
567         use_simple_gettext=yes
568         mmap_needed=no
569         ;;
570     i?86-emx-os2 | i?86-*-os2*emx )
571         # OS/2 with the EMX environment
572         ac_cv_have_dev_random=no
573         AC_DEFINE(HAVE_DRIVE_LETTERS)
574         have_dosish_system=yes
575         try_gettext="no"
576         ;;
577
578     i?86-*-msdosdjgpp*)
579         # DOS with the DJGPP environment
580         ac_cv_have_dev_random=no
581         AC_DEFINE(HAVE_DRIVE_LETTERS)
582         have_dosish_system=yes
583         try_gettext="no"
584         ;;
585
586     *-*-freebsd*)
587        # FreeBSD
588        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
589        LDFLAGS="$LDFLAGS -L/usr/local/lib"
590        ;;
591
592     *-*-hpux*)
593         if test -z "$GCC" ; then
594             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
595         fi
596         ;;
597     *-dec-osf4*)
598         if test -z "$GCC" ; then
599             # Suppress all warnings
600             # to get rid of the unsigned/signed char mismatch warnings.
601             CFLAGS="$CFLAGS -w"
602         fi
603         ;;
604     *-dec-osf5*)
605         if test -z "$GCC" ; then
606             # Use the newer compiler `-msg_disable ptrmismatch1' to
607             # get rid of the unsigned/signed char mismatch warnings.
608             # Using this may hide other pointer mismatch warnings, but
609             # it at least lets other warning classes through
610             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
611         fi
612         ;;
613     m68k-atari-mint)
614         ;;
615     *)
616        ;;
617 esac
618
619 if test "$have_dosish_system" = yes; then
620    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
621              [Defined if we run on some of the PCDOS like systems 
622               (DOS, Windoze. OS/2) with special properties like
623               no file modes, case insensitive file names and preferred
624               use of backslashes as directory name separators.])
625 fi
626 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
627
628 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
629
630 if test "$have_w32_system" = yes; then
631    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
632    if test "$have_w32ce_system" = yes; then
633       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
634    fi
635 fi
636 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
637 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
638
639 if test "$disable_keyserver_path" = yes; then
640     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
641               [Defined to disable exec-path for keyserver helpers])
642 fi
643
644 #
645 # Allows enabling the use of a standard socket by default This is
646 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
647 # the use of this.
648 #
649 AC_MSG_CHECKING([whether to use a standard socket by default])
650 AC_ARG_ENABLE(standard-socket,
651               AC_HELP_STRING([--enable-standard-socket],
652                              [use a standard socket for the agent by default]),
653               use_standard_socket=$enableval)
654 tmp=""
655 if test "$use_standard_socket" != yes; then
656   if test "$have_w32_system" = yes; then
657     use_standard_socket=yes
658     tmp=" (forced)"
659   fi
660 fi
661 AC_MSG_RESULT($use_standard_socket$tmp)
662 if test "$use_standard_socket" = yes; then
663   AC_DEFINE(USE_STANDARD_SOCKET,1,
664             [Use the standard socket for the agent by default])
665 fi
666
667
668 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
669 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
670
671 if test x"$try_hkp" = xyes ; then
672   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
673 fi
674
675 if test x"$try_finger" = xyes ; then
676   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
677 fi
678
679
680
681 #
682 # Checks for libraries.
683 #
684 AC_MSG_NOTICE([checking for libraries])
685
686
687 #
688 # libgpg-error is a library with error codes shared between GnuPG
689 # related projects.
690 #
691 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
692                   have_gpg_error=yes,have_gpg_error=no)
693
694
695 #
696 # Libgcrypt is our generic crypto library
697 #
698 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
699         have_libgcrypt=yes,have_libgcrypt=no)
700
701
702 #
703 # libassuan is used for IPC
704 #
705 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
706                   have_libassuan=yes,have_libassuan=no)
707 if test "$have_libassuan" = "yes"; then
708   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
709                      [version of the libassuan library])
710 fi
711
712
713
714 #
715 # libksba is our X.509 support library
716 #
717 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
718
719
720 #
721 # libusb allows us to use the integrated CCID smartcard reader driver.
722 #
723 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
724 if test "$use_ccid_driver" = yes ; then
725   AC_CHECK_LIB(usb, usb_bulk_write,
726                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
727                   AC_DEFINE(HAVE_LIBUSB,1,
728                            [defined if libusb is available])
729                   have_libusb=yes
730                ])
731   AC_CHECK_FUNCS(usb_create_match)
732 fi
733 AC_SUBST(LIBUSB_LIBS)
734
735 #
736 # Check wether it is necessary to link against libdl.
737 #
738 gnupg_dlopen_save_libs="$LIBS"
739 LIBS=""
740 AC_SEARCH_LIBS(dlopen, c dl,,,)
741 DL_LIBS=$LIBS
742 AC_SUBST(DL_LIBS)
743 LIBS="$gnupg_dlopen_save_libs"
744
745 # Checks for g13
746
747 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
748 AC_DEFINE_UNQUOTED(ENCFS,
749         "${ENCFS}", [defines the filename of the encfs program])
750
751 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
752 AC_DEFINE_UNQUOTED(FUSERMOUNT,
753         "${FUSERMOUNT}", [defines the filename of the fusermount program])
754
755
756 # Checks for dirmngr
757
758
759 #
760 # Checks for symcryptrun:
761 #
762
763 # libutil has openpty() and login_tty().
764 AC_CHECK_LIB(util, openpty,
765               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
766                 AC_DEFINE(HAVE_LIBUTIL,1,
767                          [defined if libutil is available])
768              ])
769 AC_SUBST(LIBUTIL_LIBS)
770
771 # shred is used to clean temporary plain text files.
772 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
773 AC_DEFINE_UNQUOTED(SHRED,
774         "${SHRED}", [defines the filename of the shred program])
775
776
777 #
778 # Check whether the GNU Pth library is available
779 # Note, that we include a Pth emulation for W32.
780 #
781 GNUPG_PATH_PTH
782 if test "$have_pth" = "yes"; then
783   AC_DEFINE(USE_GNU_PTH, 1,
784               [Defined if the GNU Portable Thread Library should be used])
785 else
786   AC_MSG_WARN([[
787 ***
788 *** To support concurrent access to the gpg-agent and the SCdaemon
789 *** we need the support of the GNU Portable Threads Library.
790 *** Download it from ftp://ftp.gnu.org/gnu/pth/
791 *** On a Debian GNU/Linux system you might want to try 
792 ***   apt-get install libpth-dev
793 ***]])
794 fi
795
796
797 AC_MSG_NOTICE([checking for networking options])
798
799 #
800 # Must check for network library requirements before doing link tests
801 # for ldap, for example. If ldap libs are static (or dynamic and without
802 # ELF runtime link paths), then link will fail and LDAP support won't
803 # be detected.
804 #
805 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
806         [NETLIBS="-lnsl $NETLIBS"]))
807 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
808         [NETLIBS="-lsocket $NETLIBS"]))
809
810
811 #
812 # Check for ADNS.
813 #
814 _cppflags="${CPPFLAGS}"
815 _ldflags="${LDFLAGS}"
816 AC_ARG_WITH(adns,
817             AC_HELP_STRING([--with-adns=DIR],
818                            [look for the adns library in DIR]),
819             [if test -d "$withval"; then
820                CPPFLAGS="${CPPFLAGS} -I$withval/include"
821                LDFLAGS="${LDFLAGS} -L$withval/lib"
822              fi])
823 if test "$with_adns" != "no"; then
824   AC_CHECK_HEADERS(adns.h,
825                 AC_CHECK_LIB(adns, adns_init,
826                              [have_adns=yes],
827                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
828                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
829 fi
830 if test "$have_adns" = "yes"; then
831   ADNSLIBS="-ladns" 
832 fi
833 AC_SUBST(ADNSLIBS)
834 # Newer adns versions feature a free function to be used under W32.
835 AC_CHECK_FUNCS(adns_free)
836
837
838
839 #
840 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
841 #
842 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
843   AC_ARG_ENABLE(dns-srv,
844      AC_HELP_STRING([--disable-dns-srv],
845                     [disable the use of DNS SRV in HKP and HTTP]),
846                 use_dns_srv=$enableval,use_dns_srv=yes)
847 fi
848
849 AC_ARG_ENABLE(dns-pka,
850    AC_HELP_STRING([--disable-dns-pka],
851         [disable the use of PKA records in DNS]),
852    use_dns_pka=$enableval,use_dns_pka=yes)
853
854 AC_ARG_ENABLE(dns-cert,
855    AC_HELP_STRING([--disable-dns-cert],
856         [disable the use of CERT records in DNS]),
857    use_dns_cert=$enableval,use_dns_cert=yes)
858
859 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
860    || test x"$use_dns_cert" = xyes; then
861   _dns_save_libs=$LIBS
862   LIBS=""
863   # the double underscore thing is a glibc-ism?
864   AC_SEARCH_LIBS(res_query,resolv bind,,
865                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
866   AC_SEARCH_LIBS(dn_expand,resolv bind,,
867                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
868   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
869                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
870
871   if test x"$have_resolver" != xno ; then
872
873     # Make sure that the BIND 4 resolver interface is workable before
874     # enabling any code that calls it.  At some point I'll rewrite the
875     # code to use the BIND 8 resolver API.
876     # We might also want to use adns instead.  Problem with ADNS is that
877     # it does not support v6.
878
879     AC_MSG_CHECKING([whether the resolver is usable])
880     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
881 #include <netinet/in.h>
882 #include <arpa/nameser.h>
883 #include <resolv.h>],
884 [[unsigned char answer[PACKETSZ];
885   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
886   dn_skipname(0,0); 
887   dn_expand(0,0,0,0,0);
888 ]])],have_resolver=yes,have_resolver=no)
889     AC_MSG_RESULT($have_resolver)
890
891     # This is Apple-specific and somewhat bizarre as they changed the
892     # define in bind 8 for some reason.
893
894     if test x"$have_resolver" != xyes ; then
895        AC_MSG_CHECKING(
896              [whether I can make the resolver usable with BIND_8_COMPAT])
897        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
898 #include <sys/types.h>
899 #include <netinet/in.h>
900 #include <arpa/nameser.h>
901 #include <resolv.h>],
902 [[unsigned char answer[PACKETSZ];
903   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
904   dn_skipname(0,0); dn_expand(0,0,0,0,0);
905 ]])],[have_resolver=yes ; need_compat=yes])
906        AC_MSG_RESULT($have_resolver)
907     fi
908   fi
909
910   if test x"$have_resolver" = xyes ; then
911      DNSLIBS=$LIBS
912
913      if test x"$use_dns_srv" = xyes ; then
914         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
915      fi
916
917      if test x"$use_dns_pka" = xyes ; then
918         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
919      fi
920
921      if test x"$use_dns_cert" = xyes ; then
922         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
923      fi
924
925      if test x"$need_compat" = xyes ; then
926         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
927      fi
928   else
929      # If we have no resolver library but ADNS (e.g. under W32) enable the
930      # code parts which can be used with ADNS.
931      if test x"$have_adns" = xyes ; then
932         DNSLIBS="$ADNSLIBS"
933         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
934
935         if test x"$use_dns_srv" = xyes ; then
936            AC_DEFINE(USE_DNS_SRV,1)
937         fi
938
939         if test x"$use_dns_pka" = xyes ; then
940            AC_DEFINE(USE_DNS_PKA,1)
941         fi
942
943         if test x"$use_dns_cert" = xyes ; then
944            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
945         fi
946      else
947         use_dns_srv=no
948         use_dns_pka=no
949         use_dns_cert=no
950      fi
951   fi
952
953   LIBS=$_dns_save_libs
954 fi
955
956 AC_SUBST(DNSLIBS)
957
958 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
959
960
961 #
962 # Check for LDAP
963 #
964 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
965    GNUPG_CHECK_LDAP($NETLIBS)
966 fi
967
968 #
969 # Check for curl.  We fake the curl API if libcurl isn't installed.
970 # We require 7.10 or later as we use curl_version_info().
971 #
972 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
973 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
974
975 # Generic, for us, means curl
976
977 if test x"$try_generic" = xyes ; then
978    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
979 fi
980
981 #
982 # Check for sendmail
983 #
984 # This isn't necessarily sendmail itself, but anything that gives a
985 # sendmail-ish interface to the outside world.  That includes Exim,
986 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
987 if test "$try_mailto" = yes ; then
988   AC_ARG_WITH(mailprog,
989       AC_HELP_STRING([--with-mailprog=NAME],
990                      [use "NAME -t" for mail transport]),
991              ,with_mailprog=yes)
992
993   if test x"$with_mailprog" = xyes ; then
994     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
995     if test "$ac_cv_path_SENDMAIL" ; then
996       GPGKEYS_MAILTO="gpg2keys_mailto"
997     fi
998   elif test x"$with_mailprog" != xno ; then
999     AC_MSG_CHECKING([for a mail transport program])
1000     AC_SUBST(SENDMAIL,$with_mailprog)
1001     AC_MSG_RESULT($with_mailprog)
1002     GPGKEYS_MAILTO="gpg2keys_mailto"
1003   fi
1004 fi
1005
1006 AC_SUBST(GPGKEYS_MAILTO)
1007
1008 #
1009 # Construct a printable name of the OS
1010 #
1011 case "${host}" in
1012     *-mingw32ce*)
1013         PRINTABLE_OS_NAME="W32CE"
1014         ;;
1015     *-mingw32*)
1016         PRINTABLE_OS_NAME="MingW32"
1017         ;;
1018     *-*-cygwin*)
1019         PRINTABLE_OS_NAME="Cygwin"
1020         ;;
1021     i?86-emx-os2 | i?86-*-os2*emx )
1022         PRINTABLE_OS_NAME="OS/2"
1023         ;;
1024     i?86-*-msdosdjgpp*)
1025         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1026         try_dynload=no
1027         ;;
1028     *-linux*)
1029         PRINTABLE_OS_NAME="GNU/Linux"
1030         ;;
1031     *)
1032         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1033         ;;
1034 esac
1035 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1036                    [A human readable text with the name of the OS])
1037
1038
1039 #
1040 # Checking for iconv
1041 #
1042 AM_ICONV
1043
1044
1045 #
1046 # Check for gettext
1047 #
1048 # This is "GNU gnupg" - The project-id script from gettext
1049 #                       needs this string
1050 #
1051 AC_MSG_NOTICE([checking for gettext])
1052 AM_PO_SUBDIRS
1053 AM_GNU_GETTEXT_VERSION([0.17])
1054 if test "$try_gettext" = yes; then
1055   AM_GNU_GETTEXT([external],[need-ngettext])
1056
1057   # gettext requires some extra checks.  These really should be part of
1058   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1059   # function checks to here.
1060
1061   AC_CHECK_FUNCS(strchr)
1062 else
1063   USE_NLS=no
1064   USE_INCLUDED_LIBINTL=no
1065   BUILD_INCLUDED_LIBINTL=no
1066   POSUB=po
1067   AC_SUBST(USE_NLS)
1068   AC_SUBST(USE_INCLUDED_LIBINTL)
1069   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1070   AC_SUBST(POSUB)
1071 fi
1072
1073 # We use HAVE_LANGINFO_CODESET in a couple of places.
1074 AM_LANGINFO_CODESET
1075
1076 # Checks required for our use locales
1077 gt_LC_MESSAGES
1078
1079
1080 #
1081 # SELinux support
1082 #
1083 if test "$selinux_support" = yes ; then
1084   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1085 fi
1086
1087
1088 #
1089 # Checks for header files.
1090 #
1091 AC_MSG_NOTICE([checking for header files])
1092 AC_HEADER_STDC
1093 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1094                   pty.h pwd.h inttypes.h signal.h])
1095 AC_HEADER_TIME
1096
1097
1098 #
1099 # Checks for typedefs, structures, and compiler characteristics.
1100 #
1101 AC_MSG_NOTICE([checking for system characteristics])
1102 AC_C_CONST
1103 AC_C_INLINE
1104 AC_C_VOLATILE
1105 AC_TYPE_SIZE_T
1106 AC_TYPE_MODE_T
1107 AC_TYPE_SIGNAL
1108 AC_DECL_SYS_SIGLIST
1109
1110 gl_HEADER_SYS_SOCKET
1111 gl_TYPE_SOCKLEN_T
1112
1113 AC_ARG_ENABLE(endian-check,
1114               AC_HELP_STRING([--disable-endian-check],
1115               [disable the endian check and trust the OS provided macros]),
1116               endiancheck=$enableval,endiancheck=yes)
1117
1118 if test x"$endiancheck" = xyes ; then
1119   GNUPG_CHECK_ENDIAN
1120 fi
1121
1122 # fixme: we should get rid of the byte type
1123 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1124 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1125 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1126 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1127 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1128
1129 AC_CHECK_SIZEOF(unsigned short)
1130 AC_CHECK_SIZEOF(unsigned int)
1131 AC_CHECK_SIZEOF(unsigned long)
1132 AC_CHECK_SIZEOF(unsigned long long)
1133 AC_CHECK_SIZEOF(time_t,,[[
1134 #include <stdio.h>
1135 #if TIME_WITH_SYS_TIME
1136 # include <sys/time.h>
1137 # include <time.h>
1138 #else
1139 # if HAVE_SYS_TIME_H
1140 #  include <sys/time.h>
1141 # else
1142 #  include <time.h>
1143 # endif
1144 #endif
1145 ]])
1146
1147
1148 # Ensure that we have UINT64_C before we bother to check for uint64_t
1149 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1150 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1151    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1152        uint64_t foo=UINT64_C(42);]),
1153      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1154 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1155    AC_CHECK_SIZEOF(uint64_t)
1156 fi
1157
1158 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1159    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1160    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1161     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1162 fi
1163
1164
1165 #
1166 # Checks for library functions.
1167 #
1168 AC_MSG_NOTICE([checking for library functions])
1169 AC_CHECK_DECLS(getpagesize)
1170 AC_FUNC_FSEEKO
1171 AC_FUNC_VPRINTF
1172 AC_FUNC_FORK
1173 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1174 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1175 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1176 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1177 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1178 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1179 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1180
1181 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1182
1183 # Dirmngr requires mmap on Unix systems.
1184 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1185   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1186 fi
1187
1188 #
1189 # These are needed by the jnlib parts in common.
1190 # Note:  We already checked pwd.h.
1191 AC_CHECK_HEADERS([signal.h])
1192 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1193                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1194                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1195                 getenv ])
1196 # end jnlib checks.
1197
1198
1199
1200 #
1201 # gnulib checks
1202 #
1203 gl_SOURCE_BASE([gl])
1204 gl_M4_BASE([gl/m4])
1205 gl_MODULES([setenv mkdtemp xsize strpbrk])
1206 gl_INIT
1207
1208
1209 #
1210 # W32 specific test
1211 #
1212 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1213
1214 #
1215 # Sanity check regex.  Tests adapted from mutt.
1216 #
1217 AC_MSG_CHECKING([whether regular expression support is requested])
1218 AC_ARG_ENABLE(regex,
1219   AC_HELP_STRING([--disable-regex],
1220     [do not handle regular expressions in trust signatures]),
1221   use_regex=$enableval, use_regex=yes)
1222 AC_MSG_RESULT($use_regex)
1223
1224 if test "$use_regex" = yes ; then
1225   _cppflags="${CPPFLAGS}"
1226   _ldflags="${LDFLAGS}"
1227   AC_ARG_WITH(regex,
1228      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1229       [
1230       if test -d "$withval" ; then
1231         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1232         LDFLAGS="${LDFLAGS} -L$withval/lib"
1233       fi
1234       ],withval="")     
1235
1236   # Does the system have regex functions at all?
1237   AC_SEARCH_LIBS([regcomp], [regex])
1238   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1239
1240   if test $gnupg_cv_have_regex = no; then
1241     use_regex=no
1242   else
1243     if test x"$cross_compiling" = xyes; then
1244       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1245     else
1246       AC_CACHE_CHECK([whether your system's regexp library is broken],
1247        [gnupg_cv_regex_broken],
1248        AC_TRY_RUN([
1249 #include <unistd.h>
1250 #include <regex.h>
1251 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1252        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1253
1254       if test $gnupg_cv_regex_broken = yes; then
1255         AC_MSG_WARN([your regex is broken - disabling regex use])
1256         use_regex=no
1257       fi
1258     fi
1259   fi
1260   CPPFLAGS="${_cppflags}"
1261   LDFLAGS="${_ldflags}"
1262 fi
1263
1264 if test "$use_regex" != yes ; then
1265   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1266 fi
1267 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1268
1269
1270
1271 #
1272 # Do we have zlib? Must do it here because Solaris failed
1273 # when compiling a conftest (due to the "-lz" from LIBS).
1274 # Note that we combine zlib and bzlib2 in ZLIBS.
1275 #
1276 if test "$use_zip" = yes ; then
1277   _cppflags="${CPPFLAGS}"
1278   _ldflags="${LDFLAGS}"
1279   AC_ARG_WITH(zlib,
1280     [  --with-zlib=DIR         use libz in DIR],[
1281       if test -d "$withval"; then
1282         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1283         LDFLAGS="${LDFLAGS} -L$withval/lib"
1284       fi
1285     ])
1286   
1287   AC_CHECK_HEADER(zlib.h,
1288         AC_CHECK_LIB(z, deflateInit2_,
1289          ZLIBS="-lz",
1290          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1291          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1292          
1293   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1294 fi
1295
1296
1297 #
1298 # Check whether we can support bzip2
1299
1300 if test "$use_bzip2" = yes ; then
1301   _cppflags="${CPPFLAGS}"
1302   _ldflags="${LDFLAGS}"
1303   AC_ARG_WITH(bzip2,
1304      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1305       [
1306       if test -d "$withval" ; then
1307         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1308         LDFLAGS="${LDFLAGS} -L$withval/lib"
1309       fi
1310       ],withval="")
1311
1312   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1313   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1314   # woefully out of date.
1315   if test "$withval" != no ; then
1316      AC_CHECK_HEADER(bzlib.h,
1317         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1318           [
1319           have_bz2=yes
1320           ZLIBS="$ZLIBS -lbz2"
1321           AC_DEFINE(HAVE_BZIP2,1,
1322                   [Defined if the bz2 compression library is available])
1323           ],
1324           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1325           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1326   fi
1327 fi
1328 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1329 AC_SUBST(ZLIBS)
1330
1331
1332 # Check for readline support
1333 GNUPG_CHECK_READLINE
1334
1335 #
1336 # Allow users to append something to the version string without
1337 # flagging it as development version.  The user version parts is
1338 # considered everything after a dash. 
1339 #
1340 if test "$development_version" != yes; then
1341   changequote(,)dnl
1342   tmp_pat='[a-zA-Z]'
1343   changequote([,])dnl
1344   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1345     development_version=yes
1346   fi
1347 fi
1348 if test "$development_version" = yes; then
1349     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1350             [Defined if this is not a regular release])
1351 fi
1352
1353 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1354
1355 GNUPG_CHECK_GNUMAKE
1356
1357 # Add some extra libs here so that previous tests don't fail for
1358 # mysterious reasons - the final link step should bail out.
1359 # W32SOCKLIBS is also defined so that if can be used for tools not
1360 # requiring any network stuff but linking to code in libcommon which
1361 # tracks in winsock stuff (e.g. init_common_subsystems).
1362 if test "$have_w32_system" = yes; then
1363    if test "$have_w32ce_system" = yes; then
1364      W32SOCKLIBS="-lws2"
1365    else
1366      W32SOCKLIBS="-lws2_32"
1367    fi
1368    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1369 fi
1370
1371 AC_SUBST(NETLIBS)
1372 AC_SUBST(W32SOCKLIBS)
1373
1374 #
1375 # Setup gcc specific options
1376 #
1377 AC_MSG_NOTICE([checking for cc features])
1378 if test "$GCC" = yes; then
1379     # Note that it is okay to use CFLAGS here because this are just
1380     # warning options and the user should have a chance of overriding
1381     # them.
1382     if test "$USE_MAINTAINER_MODE" = "yes"; then
1383         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1384         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1385         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1386         _gcc_cflags_save=$CFLAGS
1387         CFLAGS="-Wno-missing-field-initializers"
1388         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1389         AC_MSG_RESULT($_gcc_wopt)
1390         CFLAGS=$_gcc_cflags_save;
1391         if test x"$_gcc_wopt" = xyes ; then
1392           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1393         fi
1394         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1395         _gcc_cflags_save=$CFLAGS
1396         CFLAGS="-Wdeclaration-after-statement"
1397         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1398         AC_MSG_RESULT($_gcc_wopt)
1399         CFLAGS=$_gcc_cflags_save;
1400         if test x"$_gcc_wopt" = xyes ; then
1401           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1402         fi
1403     else
1404         CFLAGS="$CFLAGS -Wall"
1405     fi
1406
1407     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1408     _gcc_cflags_save=$CFLAGS
1409     CFLAGS="-Wno-pointer-sign"
1410     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1411     AC_MSG_RESULT($_gcc_psign)
1412     CFLAGS=$_gcc_cflags_save;
1413     if test x"$_gcc_psign" = xyes ; then
1414        CFLAGS="$CFLAGS -Wno-pointer-sign"
1415     fi
1416
1417     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1418     _gcc_cflags_save=$CFLAGS
1419     CFLAGS="-Wpointer-arith"
1420     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1421     AC_MSG_RESULT($_gcc_psign)
1422     CFLAGS=$_gcc_cflags_save;
1423     if test x"$_gcc_psign" = xyes ; then
1424        CFLAGS="$CFLAGS -Wpointer-arith"
1425     fi
1426 fi
1427
1428
1429 #
1430 # This is handy for debugging so the compiler doesn't rearrange
1431 # things and eliminate variables.
1432 #
1433 AC_ARG_ENABLE(optimization,
1434    AC_HELP_STRING([--disable-optimization],
1435                   [disable compiler optimization]),
1436                   [if test $enableval = no ; then
1437                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1438                    fi])
1439
1440 #
1441 # Prepare building of estream
1442 #
1443 estream_INIT
1444
1445
1446 #
1447 # Decide what to build
1448 #
1449 if test "$have_adns" = "yes"; then
1450   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1451 fi
1452
1453
1454 missing_pth=no
1455 if test $have_ksba = no; then
1456   build_gpgsm=no
1457   build_scdaemon=no
1458 fi
1459
1460 build_agent_threaded=""
1461 if test "$build_agent" = "yes"; then
1462   if test $have_pth = no; then
1463      build_agent_threaded="(not multi-threaded)"
1464      missing_pth=yes
1465   fi
1466 fi
1467
1468 build_scdaemon_extra=""
1469 if test "$build_scdaemon" = "yes"; then
1470   tmp=""
1471   if test $have_pth = no; then
1472      build_scdaemon_extra="not multi-threaded"
1473      tmp=", "
1474      missing_pth=yes
1475   fi
1476   if test $have_libusb = no; then
1477      build_scdaemon_extra="${tmp}without internal CCID driver"
1478      tmp=", "
1479   fi
1480   if test -n "$build_scdaemon_extra"; then
1481      build_scdaemon_extra="(${build_scdaemon_extra})"
1482   fi
1483 fi
1484
1485
1486 if test "$build_agent_only" = "yes" ; then
1487   build_gpg=no
1488   build_gpgsm=no
1489   build_scdaemon=no
1490   build_tools=no
1491   build_doc=no
1492 fi
1493
1494
1495 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1496 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1497 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1498 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1499 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1500 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1501 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1502 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1503 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1504 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1505
1506 AM_CONDITIONAL(RUN_GPG_TESTS,
1507                test x$cross_compiling = xno -a "$build_gpg" = yes )
1508
1509
1510 #
1511 # Print errors here so that they are visible all
1512 # together and the user can acquire them all together.
1513 #
1514 die=no
1515 if test "$have_gpg_error" = "no"; then
1516    die=yes
1517    AC_MSG_NOTICE([[
1518 ***  
1519 *** You need libgpg-error to build this program.
1520 **  This library is for example available at
1521 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1522 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1523 ***]])
1524 fi
1525 if test "$have_libgcrypt" = "no"; then
1526    die=yes
1527    AC_MSG_NOTICE([[
1528 ***  
1529 *** You need libgcrypt to build this program.
1530 **  This library is for example available at
1531 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1532 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1533 ***]])
1534 fi
1535 if test "$have_libassuan" = "no"; then
1536    die=yes
1537    AC_MSG_NOTICE([[
1538 ***
1539 *** You need libassuan to build this program.
1540 *** This library is for example available at
1541 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1542 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1543 ***]])
1544 fi
1545 if test "$have_ksba" = "no"; then
1546     AC_MSG_NOTICE([[
1547 ***
1548 *** You need libksba to build this program.
1549 *** This library is for example available at
1550 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1551 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1552 ***]])
1553 fi
1554 if test "$gnupg_have_ldap" = "no"; then
1555     die=yes
1556     AC_MSG_NOTICE([[
1557 ***
1558 *** You need a LDAP library to build this program.
1559 *** Check out 
1560 ***    http://www.openldap.org 
1561 *** for a suitable implementation. 
1562 ***]])
1563 fi
1564 if test "$missing_pth" = "yes"; then
1565     AC_MSG_NOTICE([[
1566 ***
1567 *** It is now required to build with support for the
1568 *** GNU Portable Threads Library (Pth). Please install this
1569 *** library first.  The library is for example available at
1570 ***   ftp://ftp.gnu.org/gnu/pth/
1571 *** On a Debian GNU/Linux system you can install it using 
1572 ***   apt-get install libpth-dev
1573 *** To build GnuPG for Windows you need to use the W32PTH
1574 *** package; available at:
1575 ***   ftp://ftp.g10code.com/g10code/w32pth/
1576 ***]])
1577    die=yes
1578 fi
1579
1580 if test "$die" = "yes"; then
1581     AC_MSG_ERROR([[
1582 ***
1583 *** Required libraries not found. Please consult the above messages
1584 *** and install them before running configure again.
1585 ***]])
1586 fi
1587
1588
1589
1590 AC_CONFIG_FILES([ m4/Makefile 
1591 Makefile
1592 po/Makefile.in
1593 gl/Makefile
1594 include/Makefile
1595 common/Makefile
1596 kbx/Makefile
1597 g10/Makefile
1598 sm/Makefile
1599 agent/Makefile
1600 scd/Makefile
1601 g13/Makefile
1602 dirmngr/Makefile
1603 keyserver/Makefile
1604 keyserver/gpg2keys_mailto
1605 keyserver/gpg2keys_test
1606 tools/gpg-zip
1607 tools/Makefile
1608 doc/Makefile
1609 tests/Makefile
1610 tests/openpgp/Makefile
1611 tests/pkits/Makefile
1612 ])
1613 AC_OUTPUT
1614
1615
1616 echo "
1617         GnuPG v${VERSION} has been configured as follows:
1618         
1619         Platform:  $PRINTABLE_OS_NAME ($host)
1620
1621         OpenPGP:   $build_gpg
1622         S/MIME:    $build_gpgsm
1623         Agent:     $build_agent $build_agent_threaded
1624         Smartcard: $build_scdaemon $build_scdaemon_extra
1625         G13:       $build_g13
1626         Dirmngr:   $build_dirmngr
1627         Gpgtar:    $build_gpgtar
1628
1629         Protect tool:      $show_gnupg_protect_tool_pgm
1630         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1631         Default agent:     $show_gnupg_agent_pgm
1632         Default pinentry:  $show_gnupg_pinentry_pgm
1633         Default scdaemon:  $show_gnupg_scdaemon_pgm
1634         Default dirmngr:   $show_gnupg_dirmngr_pgm
1635
1636         Use standard socket: $use_standard_socket
1637 "
1638 if test x"$use_regex" != xyes ; then
1639 echo "
1640         Warning: No regular expression support available.
1641                  OpenPGP trust signatures won't work.
1642                  gpg-check-pattern will not be build.
1643 "
1644 fi