d9aac71cbd06ee04532ce638ce245f713d82ca70
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [10])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.16
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.1.0
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Some status variables.
89 have_gpg_error=no
90 have_libgcrypt=no
91 have_libassuan=no
92 have_ksba=no
93 have_ntbtls=no
94 have_gnutls=no
95 have_sqlite=no
96 have_npth=no
97 have_libusb=no
98 have_adns=no
99 gnupg_have_ldap="n/a"
100
101 use_zip=yes
102 use_bzip2=yes
103 use_exec=yes
104 use_trust_models=yes
105 use_tofu=yes
106 card_support=yes
107 use_ccid_driver=yes
108 dirmngr_auto_start=yes
109 use_tls_library=no
110 large_secmem=no
111
112 GNUPG_BUILD_PROGRAM(gpg, yes)
113 GNUPG_BUILD_PROGRAM(gpgsm, yes)
114 # The agent is a required part and can't be disabled anymore.
115 build_agent=yes
116 GNUPG_BUILD_PROGRAM(scdaemon, yes)
117 GNUPG_BUILD_PROGRAM(g13, no)
118 GNUPG_BUILD_PROGRAM(dirmngr, yes)
119 GNUPG_BUILD_PROGRAM(tools, yes)
120 GNUPG_BUILD_PROGRAM(doc, yes)
121 GNUPG_BUILD_PROGRAM(symcryptrun, no)
122 GNUPG_BUILD_PROGRAM(gpgtar, yes)
123
124 AC_SUBST(PACKAGE)
125 AC_SUBST(PACKAGE_GT)
126 AC_SUBST(VERSION)
127 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
128 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
129                                 [Name of this package for gettext])
130 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
131 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
132                                         [Bug report address])
133 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
134                                        [Required version of Libgcrypt])
135 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
136                                        [Required version of Libksba])
137 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
138                                        [Required version of NTBTLS])
139
140
141
142 # The default is to use the modules from this package and the few
143 # other packages in a standard place; i.e where this package gets
144 # installed.  With these options it is possible to override these
145 # ${prefix} depended values with fixed paths, which can't be replaced
146 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
147 AC_ARG_WITH(agent-pgm,
148     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
149           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
150 AC_SUBST(GNUPG_AGENT_PGM)
151 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
152 show_gnupg_agent_pgm="(default)"
153 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
154
155 AC_ARG_WITH(pinentry-pgm,
156     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
157           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
158 AC_SUBST(GNUPG_PINENTRY_PGM)
159 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
160 show_gnupg_pinentry_pgm="(default)"
161 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
162
163
164 AC_ARG_WITH(scdaemon-pgm,
165     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
166           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
167 AC_SUBST(GNUPG_SCDAEMON_PGM)
168 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
169 show_gnupg_scdaemon_pgm="(default)"
170 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
171
172
173 AC_ARG_WITH(dirmngr-pgm,
174     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
175           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
176 AC_SUBST(GNUPG_DIRMNGR_PGM)
177 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
178 show_gnupg_dirmngr_pgm="(default)"
179 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
180
181 AC_ARG_WITH(protect-tool-pgm,
182     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
183           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
184 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
185 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
186 show_gnupg_protect_tool_pgm="(default)"
187 test -n "$GNUPG_PROTECT_TOOL_PGM" \
188       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
189
190 AC_ARG_WITH(dirmngr-ldap-pgm,
191     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
192           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
193 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
194 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
195 show_gnupg_dirmngr_ldap_pgm="(default)"
196 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
197       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
198
199 #
200 # On some platforms gpg2 is usually installed as gpg without using a
201 # symlink.  For correct operation of gpgconf it needs to know the
202 # installed name of gpg.  This option sets "gpg2"'s installed name to
203 # just "gpg".  Note that it might be required to rename gpg2 to gpg
204 # manually after the build process.
205 #
206 AC_ARG_ENABLE(gpg2-is-gpg,
207     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
208     gpg2_is_gpg=$enableval)
209 if test "$gpg2_is_gpg" = "yes"; then
210    name_of_installed_gpg=gpg
211 else
212    name_of_installed_gpg=gpg2
213 fi
214 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
215                    [The name of the installed GPG tool])
216
217
218 # SELinux support includes tracking of sensitive files to avoid
219 # leaking their contents through processing these files by gpg itself
220 AC_MSG_CHECKING([whether SELinux support is requested])
221 AC_ARG_ENABLE(selinux-support,
222               AC_HELP_STRING([--enable-selinux-support],
223                              [enable SELinux support]),
224               selinux_support=$enableval, selinux_support=no)
225 AC_MSG_RESULT($selinux_support)
226
227
228 AC_MSG_CHECKING([whether to allocate extra secure memory])
229 AC_ARG_ENABLE(large-secmem,
230               AC_HELP_STRING([--enable-large-secmem],
231                              [allocate extra secure memory]),
232               large_secmem=$enableval, large_secmem=no)
233 AC_MSG_RESULT($large_secmem)
234 if test "$large_secmem" = yes ; then
235    SECMEM_BUFFER_SIZE=65536
236 else
237    SECMEM_BUFFER_SIZE=32768
238 fi
239 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
240                    [Size of secure memory buffer])
241
242 AC_MSG_CHECKING([whether to enable trust models])
243 AC_ARG_ENABLE(trust-models,
244               AC_HELP_STRING([--disable-trust-models],
245                              [disable all trust models except "always"]),
246               use_trust_models=$enableval)
247 AC_MSG_RESULT($use_trust_models)
248 if test "$use_trust_models" = no ; then
249     AC_DEFINE(NO_TRUST_MODELS, 1,
250              [Define to include only trust-model always])
251 fi
252
253 AC_MSG_CHECKING([whether to enable TOFU])
254 AC_ARG_ENABLE(tofu,
255                 AC_HELP_STRING([--disable-tofu],
256                                [disable the TOFU trust model]),
257               use_tofu=$enableval, use_tofu=yes)
258 AC_MSG_RESULT($use_tofu)
259
260
261
262 #
263 # Options to disable algorithm
264 #
265
266 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
267 # Elgamal is a MUST algorithm
268 # DSA is a MUST algorithm
269 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
270 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
271 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
272
273 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
274 # 3DES is a MUST algorithm
275 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
276 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
277 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
278 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
279 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
280 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
281 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
282 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
283 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
284
285 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
286 # SHA1 is a MUST algorithm
287 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
288 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
289 # SHA256 is a MUST algorithm for GnuPG.
290 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
291 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
292
293
294 # Allow disabling of zip support.
295 # This is in general not a good idea because according to rfc4880 OpenPGP
296 # implementations SHOULD support ZLIB.
297 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
298 AC_ARG_ENABLE(zip,
299    AC_HELP_STRING([--disable-zip],
300                   [disable the ZIP and ZLIB compression algorithm]),
301    use_zip=$enableval)
302 AC_MSG_RESULT($use_zip)
303
304 # Allow disabling of bzib2 support.
305 # It is defined only after we confirm the library is available later
306 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
307 AC_ARG_ENABLE(bzip2,
308    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
309    use_bzip2=$enableval)
310 AC_MSG_RESULT($use_bzip2)
311
312 # Configure option to allow or disallow execution of external
313 # programs, like a photo viewer.
314 AC_MSG_CHECKING([whether to enable external program execution])
315 AC_ARG_ENABLE(exec,
316     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
317     use_exec=$enableval)
318 AC_MSG_RESULT($use_exec)
319 if test "$use_exec" = no ; then
320     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
321 fi
322
323 if test "$use_exec" = yes ; then
324   AC_MSG_CHECKING([whether to enable photo ID viewing])
325   AC_ARG_ENABLE(photo-viewers,
326       [  --disable-photo-viewers disable photo ID viewers],
327       [if test "$enableval" = no ; then
328          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
329       fi],enableval=yes)
330   gnupg_cv_enable_photo_viewers=$enableval
331   AC_MSG_RESULT($enableval)
332
333   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
334     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
335     AC_ARG_WITH(photo-viewer,
336         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
337         [if test "$withval" = yes ; then
338            withval=no
339         elif test "$withval" != no ; then
340            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
341                             [if set, restrict photo-viewer to this])
342         fi],withval=no)
343     AC_MSG_RESULT($withval)
344   fi
345 fi
346
347
348 #
349 # Check for the key/uid cache size.  This can't be zero, but can be
350 # pretty small on embedded systems.  This is used for the gpg part.
351 #
352 AC_MSG_CHECKING([for the size of the key and uid cache])
353 AC_ARG_ENABLE(key-cache,
354         AC_HELP_STRING([--enable-key-cache=SIZE],
355                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
356 if test "$enableval" = "no"; then
357    enableval=5
358 elif test "$enableval" = "yes" || test "$enableval" = ""; then
359    enableval=4096
360 fi
361 changequote(,)dnl
362 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
363 changequote([,])dnl
364 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
365    AC_MSG_ERROR([invalid key-cache size])
366 fi
367 AC_MSG_RESULT($key_cache_size)
368 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
369                   [Size of the key and UID caches])
370
371
372
373 #
374 # Check whether we want to use Linux capabilities
375 #
376 AC_MSG_CHECKING([whether use of capabilities is requested])
377 AC_ARG_WITH(capabilities,
378     [  --with-capabilities     use linux capabilities [default=no]],
379 [use_capabilities="$withval"],[use_capabilities=no])
380 AC_MSG_RESULT($use_capabilities)
381
382 #
383 # Check whether to disable the card support
384 AC_MSG_CHECKING([whether smartcard support is requested])
385 AC_ARG_ENABLE(card-support,
386               AC_HELP_STRING([--disable-card-support],
387                              [disable smartcard support]),
388               card_support=$enableval)
389 AC_MSG_RESULT($card_support)
390 if test "$card_support" = yes ; then
391   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
392 else
393   build_scdaemon=no
394 fi
395
396 #
397 # Allow disabling of internal CCID support.
398 # It is defined only after we confirm the library is available later
399 #
400 AC_MSG_CHECKING([whether to enable the internal CCID driver])
401 AC_ARG_ENABLE(ccid-driver,
402               AC_HELP_STRING([--disable-ccid-driver],
403                              [disable the internal CCID driver]),
404               use_ccid_driver=$enableval)
405 AC_MSG_RESULT($use_ccid_driver)
406
407 AC_MSG_CHECKING([whether to auto start dirmngr])
408 AC_ARG_ENABLE(dirmngr-auto-start,
409               AC_HELP_STRING([--disable-dirmngr-auto-start],
410                              [disable auto starting of the dirmngr]),
411               dirmngr_auto_start=$enableval)
412 AC_MSG_RESULT($dirmngr_auto_start)
413 if test "$dirmngr_auto_start" = yes ; then
414     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
415               [Define to enable auto starting of the dirmngr])
416 fi
417
418
419 #
420 # To avoid double inclusion of config.h which might happen at some
421 # places, we add the usual double inclusion protection at the top of
422 # config.h.
423 #
424 AH_TOP([
425 #ifndef GNUPG_CONFIG_H_INCLUDED
426 #define GNUPG_CONFIG_H_INCLUDED
427 ])
428
429 #
430 # Stuff which goes at the bottom of config.h.
431 #
432 AH_BOTTOM([
433 /* This is the major version number of GnuPG so that
434    source included files can test for this.  Note, that
435    we use 2 here even for GnuPG 1.9.x. */
436 #define GNUPG_MAJOR_VERSION 2
437
438 /* Now to separate file name parts.
439    Please note that the string version must not contain more
440    than one character because the code assumes strlen()==1 */
441 #ifdef HAVE_DOSISH_SYSTEM
442 #define DIRSEP_C '\\'
443 #define DIRSEP_S "\\"
444 #define EXTSEP_C '.'
445 #define EXTSEP_S "."
446 #define PATHSEP_C ';'
447 #define PATHSEP_S ";"
448 #define EXEEXT_S ".exe"
449 #else
450 #define DIRSEP_C '/'
451 #define DIRSEP_S "/"
452 #define EXTSEP_C '.'
453 #define EXTSEP_S "."
454 #define PATHSEP_C ':'
455 #define PATHSEP_S ":"
456 #define EXEEXT_S ""
457 #endif
458
459 /* This is the same as VERSION, but should be overridden if the
460    platform cannot handle things like dots '.' in filenames. Set
461    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
462    uses for dots and dashes. */
463 #define SAFE_VERSION VERSION
464 #define SAFE_VERSION_DOT  '.'
465 #define SAFE_VERSION_DASH '-'
466
467 /* Some global constants. */
468 #ifdef HAVE_DOSISH_SYSTEM
469 # ifdef HAVE_DRIVE_LETTERS
470 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
471 # else
472 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
473 # endif
474 #elif defined(__VMS)
475 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
476 #else
477 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
478 #endif
479 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
480 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
481
482 /* For some systems (DOS currently), we hardcode the path here.  For
483    POSIX systems the values are constructed by the Makefiles, so that
484    the values may be overridden by the make invocations; this is to
485    comply with the GNU coding standards.  Note that these values are
486    only defaults.  */
487 #ifdef HAVE_DOSISH_SYSTEM
488 # ifdef HAVE_DRIVE_LETTERS
489 #  define GNUPG_BINDIR      "c:\\gnupg"
490 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
491 #  define GNUPG_LIBDIR      "c:\\gnupg"
492 #  define GNUPG_DATADIR     "c:\\gnupg"
493 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
494 # else
495 #  define GNUPG_BINDIR      "\\gnupg"
496 #  define GNUPG_LIBEXECDIR  "\\gnupg"
497 #  define GNUPG_LIBDIR      "\\gnupg"
498 #  define GNUPG_DATADIR     "\\gnupg"
499 #  define GNUPG_SYSCONFDIR  "\\gnupg"
500 # endif
501 #endif
502
503 /* Derive some other constants. */
504 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
505 #define EXEC_TEMPFILE_ONLY
506 #endif
507
508
509 /* We didn't define endianness above, so get it from OS macros.  This
510    is intended for making fat binary builds on OS X. */
511 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
512 #if defined(__BIG_ENDIAN__)
513 #define BIG_ENDIAN_HOST 1
514 #elif defined(__LITTLE_ENDIAN__)
515 #define LITTLE_ENDIAN_HOST 1
516 #else
517 #error "No endianness found"
518 #endif
519 #endif
520
521
522 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
523    ldap_start_tls_s because that is the actual symbol used in the
524    library.  winldap.h redefines it to our commonly used value,
525    thus we define our usual macro here.  */
526 #ifdef HAVE_LDAP_START_TLS_SA
527 # ifndef HAVE_LDAP_START_TLS_S
528 #  define HAVE_LDAP_START_TLS_S 1
529 # endif
530 #endif
531
532 /* Provide the es_ macro for estream.  */
533 #define GPGRT_ENABLE_ES_MACROS 1
534
535 /* Tell libgcrypt not to use its own libgpg-error implementation. */
536 #define USE_LIBGPG_ERROR 1
537
538 /* Tell Libgcrypt not to include deprecated definitions.  */
539 #define GCRYPT_NO_DEPRECATED 1
540
541 /* Our HTTP code is used in estream mode.  */
542 #define HTTP_USE_ESTREAM 1
543
544 /* Under W32 we do an explicit socket initialization, thus we need to
545    avoid the on-demand initialization which would also install an atexit
546    handler.  */
547 #define HTTP_NO_WSASTARTUP
548
549 /* Under Windows we use the gettext code from libgpg-error.  */
550 #define GPG_ERR_ENABLE_GETTEXT_MACROS
551
552 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
553 #define GPG_ERR_ENABLE_ERRNO_MACROS
554
555 #endif /*GNUPG_CONFIG_H_INCLUDED*/
556 ])
557
558
559 AM_MAINTAINER_MODE
560 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
561
562 # Checks for programs.
563 AC_MSG_NOTICE([checking for programs])
564 AC_PROG_MAKE_SET
565 AM_SANITY_CHECK
566 missing_dir=`cd $ac_aux_dir && pwd`
567 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
568 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
569 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
570 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
571 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
572 AM_SILENT_RULES
573 AC_PROG_AWK
574 AC_PROG_CC
575 AC_PROG_CPP
576 AM_PROG_CC_C_O
577 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
578   AC_MSG_ERROR([[No C-89 compiler found]])
579 fi
580 AC_PROG_INSTALL
581 AC_PROG_LN_S
582 AC_PROG_RANLIB
583 AC_CHECK_TOOL(AR, ar, :)
584 AC_PATH_PROG(PERL,"perl")
585 AC_CHECK_TOOL(WINDRES, windres, :)
586 AC_ISC_POSIX
587 AC_SYS_LARGEFILE
588 GNUPG_CHECK_USTAR
589
590 # We need to compile and run a program on the build machine.  A
591 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
592 # the AC archive is broken for autoconf 2.57.  Given that there is no
593 # newer version of that macro, we assume that it is also broken for
594 # autoconf 2.61 and thus we use a simple but usually sufficient
595 # approach.
596 AC_MSG_CHECKING(for cc for build)
597 if test "$cross_compiling" = "yes"; then
598   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
599 else
600   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
601 fi
602 AC_MSG_RESULT($CC_FOR_BUILD)
603 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
604
605
606
607 try_gettext=yes
608 require_iconv=yes
609 have_dosish_system=no
610 have_w32_system=no
611 have_w32ce_system=no
612 have_android_system=no
613 run_tests=yes
614 use_simple_gettext=no
615 use_ldapwrapper=yes
616 mmap_needed=yes
617 case "${host}" in
618     *-mingw32*)
619         # special stuff for Windoze NT
620         ac_cv_have_dev_random=no
621         AC_DEFINE(USE_ONLY_8DOT3,1,
622                   [Set this to limit filenames to the 8.3 format])
623         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
624                   [Because the Unix gettext has too much overhead on
625                    MingW32 systems and these systems lack Posix functions,
626                    we use a simplified version of gettext])
627         have_dosish_system=yes
628         have_w32_system=yes
629         run_tests=no
630         use_ldapwrapper=no  # Fixme: Do this only for CE.
631         case "${host}" in
632           *-mingw32ce*)
633             have_w32ce_system=yes
634             ;;
635           *)
636             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
637                       [Defined if the OS supports drive letters.])
638             ;;
639         esac
640         try_gettext="no"
641         use_simple_gettext=yes
642         mmap_needed=no
643         ;;
644     i?86-emx-os2 | i?86-*-os2*emx )
645         # OS/2 with the EMX environment
646         ac_cv_have_dev_random=no
647         AC_DEFINE(HAVE_DRIVE_LETTERS)
648         have_dosish_system=yes
649         try_gettext="no"
650         ;;
651
652     i?86-*-msdosdjgpp*)
653         # DOS with the DJGPP environment
654         ac_cv_have_dev_random=no
655         AC_DEFINE(HAVE_DRIVE_LETTERS)
656         have_dosish_system=yes
657         try_gettext="no"
658         ;;
659
660     *-*-hpux*)
661         if test -z "$GCC" ; then
662             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
663         fi
664         ;;
665     *-dec-osf4*)
666         if test -z "$GCC" ; then
667             # Suppress all warnings
668             # to get rid of the unsigned/signed char mismatch warnings.
669             CFLAGS="$CFLAGS -w"
670         fi
671         ;;
672     *-dec-osf5*)
673         if test -z "$GCC" ; then
674             # Use the newer compiler `-msg_disable ptrmismatch1' to
675             # get rid of the unsigned/signed char mismatch warnings.
676             # Using this may hide other pointer mismatch warnings, but
677             # it at least lets other warning classes through
678             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
679         fi
680         ;;
681     m68k-atari-mint)
682         ;;
683     *-linux-androideabi)
684         have_android_system=yes
685         # Android is fully utf-8 and we do not want to use iconv to
686         # keeps things simple
687         require_iconv=no
688         run_tests=no
689         ;;
690     *)
691        ;;
692 esac
693
694 if test "$have_dosish_system" = yes; then
695    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
696              [Defined if we run on some of the PCDOS like systems
697               (DOS, Windoze. OS/2) with special properties like
698               no file modes, case insensitive file names and preferred
699               use of backslashes as directory name separators.])
700 fi
701 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
702
703 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
704
705 if test "$have_w32_system" = yes; then
706    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
707    if test "$have_w32ce_system" = yes; then
708       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
709    fi
710 fi
711 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
712 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
713
714 if test "$have_android_system" = yes; then
715    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
716 fi
717 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
718
719 if test "$run_tests" = yes; then
720    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
721 fi
722 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
723
724
725 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
726 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
727
728
729 #
730 # Checks for libraries.
731 #
732 AC_MSG_NOTICE([checking for libraries])
733
734
735 #
736 # libgpg-error is a library with error codes shared between GnuPG
737 # related projects.
738 #
739 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
740                   have_gpg_error=yes,have_gpg_error=no)
741
742
743 #
744 # Libgcrypt is our generic crypto library
745 #
746 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
747         have_libgcrypt=yes,have_libgcrypt=no)
748
749
750 #
751 # libassuan is used for IPC
752 #
753 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
754                   have_libassuan=yes,have_libassuan=no)
755 if test "$have_libassuan" = "yes"; then
756   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
757                      [version of the libassuan library])
758 fi
759
760
761
762 #
763 # libksba is our X.509 support library
764 #
765 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
766
767
768 #
769 # libusb allows us to use the integrated CCID smartcard reader driver.
770 #
771 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
772 if test "$use_ccid_driver" = yes ; then
773   AC_CHECK_LIB(usb, usb_bulk_write,
774                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
775                   AC_DEFINE(HAVE_LIBUSB,1,
776                            [defined if libusb is available])
777                   have_libusb=yes
778                ])
779   AC_CHECK_FUNCS(usb_create_match)
780 fi
781 AC_SUBST(LIBUSB_LIBS)
782
783 #
784 # Check wether it is necessary to link against libdl.
785 # (For example to load libpcsclite)
786 #
787 gnupg_dlopen_save_libs="$LIBS"
788 LIBS=""
789 AC_SEARCH_LIBS(dlopen, c dl,,,)
790 DL_LIBS=$LIBS
791 AC_SUBST(DL_LIBS)
792 LIBS="$gnupg_dlopen_save_libs"
793
794
795 # Checks for g10
796
797 AC_ARG_ENABLE(sqlite,
798                 AC_HELP_STRING([--disable-sqlite],
799                                [disable the use of SQLITE]),
800               try_sqlite=$enableval, try_sqlite=yes)
801
802 if test x"$use_tofu" = xyes ; then
803   if test x"$try_sqlite" = xyes ; then
804     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
805                                  [have_sqlite=yes],
806                                  [have_sqlite=no])
807   fi
808   if test "$have_sqlite" = "yes"; then
809     :
810     AC_SUBST([SQLITE3_CFLAGS])
811     AC_SUBST([SQLITE3_LIBS])
812   else
813     use_tofu=no
814     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
815     AC_MSG_WARN([[
816 ***
817 *** Building without SQLite support - TOFU disabled
818 ***
819 *** $tmp]])
820   fi
821 fi
822
823 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
824
825 if test x"$use_tofu" = xyes ; then
826     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
827 fi
828
829
830 # Checks for g13
831
832 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
833 AC_DEFINE_UNQUOTED(ENCFS,
834         "${ENCFS}", [defines the filename of the encfs program])
835
836 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
837 AC_DEFINE_UNQUOTED(FUSERMOUNT,
838         "${FUSERMOUNT}", [defines the filename of the fusermount program])
839
840
841 # Checks for dirmngr
842
843
844 #
845 # Checks for symcryptrun:
846 #
847
848 # libutil has openpty() and login_tty().
849 AC_CHECK_LIB(util, openpty,
850               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
851                 AC_DEFINE(HAVE_LIBUTIL,1,
852                          [defined if libutil is available])
853              ])
854 AC_SUBST(LIBUTIL_LIBS)
855
856 # shred is used to clean temporary plain text files.
857 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
858 AC_DEFINE_UNQUOTED(SHRED,
859         "${SHRED}", [defines the filename of the shred program])
860
861
862 #
863 # Check whether the nPth library is available
864 #
865 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
866 if test "$have_npth" = "yes"; then
867   AC_DEFINE(HAVE_NPTH, 1,
868               [Defined if the New Portable Thread Library is available])
869   AC_DEFINE(USE_NPTH, 1,
870               [Defined if support for nPth is requested and nPth is available])
871 else
872   AC_MSG_WARN([[
873 ***
874 *** To support concurrent access for example in gpg-agent and the SCdaemon
875 *** we need the support of the New Portable Threads Library.
876 ***]])
877 fi
878
879
880 #
881 # NTBTLS is our TLS library.  If it is not available fallback to
882 # GNUTLS.
883 #
884 AC_ARG_ENABLE(ntbtls,
885               AC_HELP_STRING([--disable-ntbtls],
886                              [disable the use of NTBTLS as TLS library]),
887               try_ntbtls=$enableval, try_ntbtls=yes)
888 if test x"$try_ntbtls" = xyes ; then
889   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
890                  [have_ntbtls=yes],[have_ntbtls=no])
891 fi
892 if test "$have_ntbtls" = yes ; then
893    use_tls_library=ntbtls
894    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
895 else
896   AC_ARG_ENABLE(gnutls,
897                 AC_HELP_STRING([--disable-gnutls],
898                                [disable GNUTLS as fallback TLS library]),
899                 try_gnutls=$enableval, try_gnutls=yes)
900   if test x"$try_gnutls" = xyes ; then
901     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
902                                    [have_gnutls=yes],
903                                    [have_gnutls=no])
904   fi
905   if test "$have_gnutls" = "yes"; then
906     AC_SUBST([LIBGNUTLS_CFLAGS])
907     AC_SUBST([LIBGNUTLS_LIBS])
908     use_tls_library=gnutls
909     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
910   else
911     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
912     AC_MSG_WARN([[
913 ***
914 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
915 ***
916 *** $tmp]])
917   fi
918 fi
919
920
921 AC_MSG_NOTICE([checking for networking options])
922
923 #
924 # Must check for network library requirements before doing link tests
925 # for ldap, for example. If ldap libs are static (or dynamic and without
926 # ELF runtime link paths), then link will fail and LDAP support won't
927 # be detected.
928 #
929 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
930         [NETLIBS="-lnsl $NETLIBS"]))
931 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
932         [NETLIBS="-lsocket $NETLIBS"]))
933
934
935 #
936 # Check for ADNS.
937 #
938 _cppflags="${CPPFLAGS}"
939 _ldflags="${LDFLAGS}"
940 AC_ARG_WITH(adns,
941             AC_HELP_STRING([--with-adns=DIR],
942                            [look for the adns library in DIR]),
943             [if test -d "$withval"; then
944                CPPFLAGS="${CPPFLAGS} -I$withval/include"
945                LDFLAGS="${LDFLAGS} -L$withval/lib"
946              fi])
947 if test "$with_adns" != "no"; then
948   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
949   AC_CHECK_FUNCS(adns_free)
950   AC_MSG_CHECKING([if adns supports adns_if_tormode])
951   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
952     #include <adns.h>
953     adns_initflags flags = adns_if_tormode;
954   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
955   AC_MSG_RESULT($adns_if_tormode)
956   if test x"$adns_if_tormode" = xyes; then
957     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
958   fi
959 fi
960 CPPFLAGS=${_cppflags}
961 LDFLAGS=${_ldflags}
962 if test "$have_adns" = "yes"; then
963   ADNSLIBS="-ladns"
964 fi
965
966
967 #
968 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
969 #
970 AC_ARG_ENABLE(dns-srv,
971               AC_HELP_STRING([--disable-dns-srv],
972                              [disable the use of DNS SRV in HKP and HTTP]),
973               use_dns_srv=$enableval,use_dns_srv=yes)
974
975 AC_ARG_ENABLE(dns-cert,
976    AC_HELP_STRING([--disable-dns-cert],
977         [disable the use of CERT records in DNS]),
978    use_dns_cert=$enableval,use_dns_cert=yes)
979
980 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
981   _dns_save_libs=$LIBS
982   LIBS=""
983
984   if test x"$have_adns" = xyes ; then
985     # We prefer ADNS.
986     DNSLIBS="$ADNSLIBS"
987     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
988
989     if test x"$use_dns_srv" = xyes ; then
990         AC_DEFINE(USE_DNS_SRV,1)
991     fi
992
993     if test x"$use_dns_cert" = xyes ; then
994         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
995     fi
996   else
997     # With no ADNS find the system resolver.
998
999     # the double underscore thing is a glibc-ism?
1000     AC_SEARCH_LIBS(res_query,resolv bind,,
1001                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1002     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1003                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1004     AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1005                    AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
1006
1007     if test x"$have_resolver" != xno ; then
1008
1009       # Make sure that the BIND 4 resolver interface is workable before
1010       # enabling any code that calls it.  At some point I'll rewrite the
1011       # code to use the BIND 8 resolver API.
1012       # We might also want to use adns instead.  Problem with ADNS is that
1013       # it does not support v6.
1014
1015       AC_MSG_CHECKING([whether the resolver is usable])
1016       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1017 #include <netinet/in.h>
1018 #include <arpa/nameser.h>
1019 #include <resolv.h>]],
1020 [[unsigned char answer[PACKETSZ];
1021   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1022   dn_skipname(0,0);
1023   dn_expand(0,0,0,0,0);
1024 ]])],have_resolver=yes,have_resolver=no)
1025       AC_MSG_RESULT($have_resolver)
1026
1027       # This is Apple-specific and somewhat bizarre as they changed the
1028       # define in bind 8 for some reason.
1029
1030       if test x"$have_resolver" != xyes ; then
1031          AC_MSG_CHECKING(
1032              [whether I can make the resolver usable with BIND_8_COMPAT])
1033         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1034 #include <sys/types.h>
1035 #include <netinet/in.h>
1036 #include <arpa/nameser.h>
1037 #include <resolv.h>]],
1038 [[unsigned char answer[PACKETSZ];
1039   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1040   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1041 ]])],[have_resolver=yes ; need_compat=yes])
1042          AC_MSG_RESULT($have_resolver)
1043       fi
1044     fi
1045
1046     if test x"$have_resolver" = xyes ; then
1047       DNSLIBS=$LIBS
1048
1049       if test x"$use_dns_srv" = xyes ; then
1050          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1051       fi
1052
1053       if test x"$use_dns_cert" = xyes ; then
1054         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1055       fi
1056
1057       if test x"$need_compat" = xyes ; then
1058         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1059       fi
1060     else
1061       use_dns_srv=no
1062       use_dns_cert=no
1063     fi
1064   fi
1065
1066   LIBS=$_dns_save_libs
1067 fi
1068
1069 AC_SUBST(DNSLIBS)
1070
1071 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1072
1073
1074 #
1075 # Check for LDAP
1076 #
1077 # Note that running the check changes the variable
1078 # gnupg_have_ldap from "n/a" to "no" or "yes".
1079
1080 AC_ARG_ENABLE(ldap,
1081     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1082     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1083
1084 if test "$gnupg_have_ldap" != "no" ; then
1085   if test "$build_dirmngr" = "yes" ; then
1086      GNUPG_CHECK_LDAP($NETLIBS)
1087      AC_CHECK_LIB(lber, ber_free,
1088                   [ LBER_LIBS="$LBER_LIBS -llber"
1089                     AC_DEFINE(HAVE_LBER,1,
1090                              [defined if liblber is available])
1091                     have_lber=yes
1092                  ])
1093   fi
1094 fi
1095 AC_SUBST(LBER_LIBS)
1096 if test "$gnupg_have_ldap" = "no"; then
1097     AC_MSG_WARN([[
1098 ***
1099 *** Building without LDAP support.
1100 *** No CRL access or X.509 certificate search available.
1101 ***]])
1102 fi
1103
1104 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1105 if test "$gnupg_have_ldap" = yes ; then
1106   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1107 else
1108  use_ldapwrapper=no
1109 fi
1110
1111 if test "$use_ldapwrapper" = yes; then
1112    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1113 fi
1114 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1115
1116
1117
1118
1119 #
1120 # Check for sendmail
1121 #
1122 # This isn't necessarily sendmail itself, but anything that gives a
1123 # sendmail-ish interface to the outside world.  That includes Exim,
1124 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1125 AC_ARG_WITH(mailprog,
1126       AC_HELP_STRING([--with-mailprog=NAME],
1127                      [use "NAME -t" for mail transport]),
1128              ,with_mailprog=yes)
1129 if test x"$with_mailprog" = xyes ; then
1130     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1131 elif test x"$with_mailprog" != xno ; then
1132     AC_MSG_CHECKING([for a mail transport program])
1133     AC_SUBST(SENDMAIL,$with_mailprog)
1134     AC_MSG_RESULT($with_mailprog)
1135 fi
1136
1137
1138 #
1139 # Construct a printable name of the OS
1140 #
1141 case "${host}" in
1142     *-mingw32ce*)
1143         PRINTABLE_OS_NAME="W32CE"
1144         ;;
1145     *-mingw32*)
1146         PRINTABLE_OS_NAME="MingW32"
1147         ;;
1148     *-*-cygwin*)
1149         PRINTABLE_OS_NAME="Cygwin"
1150         ;;
1151     i?86-emx-os2 | i?86-*-os2*emx )
1152         PRINTABLE_OS_NAME="OS/2"
1153         ;;
1154     i?86-*-msdosdjgpp*)
1155         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1156         try_dynload=no
1157         ;;
1158     *-linux*)
1159         PRINTABLE_OS_NAME="GNU/Linux"
1160         ;;
1161     *)
1162         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1163         ;;
1164 esac
1165 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1166                    [A human readable text with the name of the OS])
1167
1168
1169 #
1170 # Checking for iconv
1171 #
1172 if test "$require_iconv" = yes; then
1173   AM_ICONV
1174 else
1175   LIBICONV=
1176   LTLIBICONV=
1177   AC_SUBST(LIBICONV)
1178   AC_SUBST(LTLIBICONV)
1179 fi
1180
1181
1182 #
1183 # Check for gettext
1184 #
1185 # This is "GNU gnupg" - The project-id script from gettext
1186 #                       needs this string
1187 #
1188 AC_MSG_NOTICE([checking for gettext])
1189 AM_PO_SUBDIRS
1190 AM_GNU_GETTEXT_VERSION([0.17])
1191 if test "$try_gettext" = yes; then
1192   AM_GNU_GETTEXT([external],[need-ngettext])
1193
1194   # gettext requires some extra checks.  These really should be part of
1195   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1196   # function checks to here.
1197
1198   AC_CHECK_FUNCS(strchr)
1199 else
1200   USE_NLS=no
1201   USE_INCLUDED_LIBINTL=no
1202   BUILD_INCLUDED_LIBINTL=no
1203   POSUB=po
1204   AC_SUBST(USE_NLS)
1205   AC_SUBST(USE_INCLUDED_LIBINTL)
1206   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1207   AC_SUBST(POSUB)
1208 fi
1209
1210 # We use HAVE_LANGINFO_CODESET in a couple of places.
1211 AM_LANGINFO_CODESET
1212
1213 # Checks required for our use of locales
1214 gt_LC_MESSAGES
1215
1216
1217 #
1218 # SELinux support
1219 #
1220 if test "$selinux_support" = yes ; then
1221   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1222 fi
1223
1224
1225 #
1226 # Checks for header files.
1227 #
1228 AC_MSG_NOTICE([checking for header files])
1229 AC_HEADER_STDC
1230 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1231                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1232                   signal.h])
1233 AC_HEADER_TIME
1234
1235
1236 #
1237 # Checks for typedefs, structures, and compiler characteristics.
1238 #
1239 AC_MSG_NOTICE([checking for system characteristics])
1240 AC_C_CONST
1241 AC_C_INLINE
1242 AC_C_VOLATILE
1243 AC_TYPE_SIZE_T
1244 AC_TYPE_MODE_T
1245 AC_TYPE_SIGNAL
1246 AC_DECL_SYS_SIGLIST
1247
1248 gl_HEADER_SYS_SOCKET
1249 gl_TYPE_SOCKLEN_T
1250
1251 AC_SEARCH_LIBS([inet_addr], [nsl])
1252
1253 AC_ARG_ENABLE(endian-check,
1254               AC_HELP_STRING([--disable-endian-check],
1255               [disable the endian check and trust the OS provided macros]),
1256               endiancheck=$enableval,endiancheck=yes)
1257
1258 if test x"$endiancheck" = xyes ; then
1259   GNUPG_CHECK_ENDIAN
1260 fi
1261
1262 # fixme: we should get rid of the byte type
1263 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1264 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1265 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1266 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1267 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1268
1269 AC_CHECK_SIZEOF(unsigned short)
1270 AC_CHECK_SIZEOF(unsigned int)
1271 AC_CHECK_SIZEOF(unsigned long)
1272 AC_CHECK_SIZEOF(unsigned long long)
1273 AC_HEADER_TIME
1274 AC_CHECK_SIZEOF(time_t,,[[
1275 #include <stdio.h>
1276 #if TIME_WITH_SYS_TIME
1277 # include <sys/time.h>
1278 # include <time.h>
1279 #else
1280 # if HAVE_SYS_TIME_H
1281 #  include <sys/time.h>
1282 # else
1283 #  include <time.h>
1284 # endif
1285 #endif
1286 ]])
1287 GNUPG_TIME_T_UNSIGNED
1288
1289
1290 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1291    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1292    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1293     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1294 fi
1295
1296
1297 #
1298 # Checks for library functions.
1299 #
1300 AC_MSG_NOTICE([checking for library functions])
1301 AC_CHECK_DECLS(getpagesize)
1302 AC_FUNC_FSEEKO
1303 AC_FUNC_VPRINTF
1304 AC_FUNC_FORK
1305 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1306 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1307 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1308 AC_CHECK_FUNCS([canonicalize_file_name])
1309 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1310 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1311 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1312 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1313 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1314                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1315                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1316                 getenv inet_pton strpbrk])
1317
1318 if test "$have_android_system" = yes; then
1319    # On Android ttyname is a stub but prints an error message.
1320    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1321              [Defined if ttyname does not work properly])
1322 fi
1323
1324 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1325
1326 # Dirmngr requires mmap on Unix systems.
1327 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1328   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1329 fi
1330
1331 #
1332 # W32 specific test
1333 #
1334 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1335
1336 #
1337 # Sanity check regex.  Tests adapted from mutt.
1338 #
1339 AC_MSG_CHECKING([whether regular expression support is requested])
1340 AC_ARG_ENABLE(regex,
1341   AC_HELP_STRING([--disable-regex],
1342     [do not handle regular expressions in trust signatures]),
1343   use_regex=$enableval, use_regex=yes)
1344 AC_MSG_RESULT($use_regex)
1345
1346 if test "$use_regex" = yes ; then
1347   _cppflags="${CPPFLAGS}"
1348   _ldflags="${LDFLAGS}"
1349   AC_ARG_WITH(regex,
1350      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1351       [
1352       if test -d "$withval" ; then
1353         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1354         LDFLAGS="${LDFLAGS} -L$withval/lib"
1355       fi
1356       ],withval="")
1357
1358   # Does the system have regex functions at all?
1359   AC_SEARCH_LIBS([regcomp], [regex])
1360   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1361
1362   if test $gnupg_cv_have_regex = no; then
1363     use_regex=no
1364   else
1365     if test x"$cross_compiling" = xyes; then
1366       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1367     else
1368       AC_CACHE_CHECK([whether your system's regexp library is broken],
1369        [gnupg_cv_regex_broken],
1370        AC_TRY_RUN([
1371 #include <unistd.h>
1372 #include <regex.h>
1373 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1374        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1375
1376       if test $gnupg_cv_regex_broken = yes; then
1377         AC_MSG_WARN([your regex is broken - disabling regex use])
1378         use_regex=no
1379       fi
1380     fi
1381   fi
1382   CPPFLAGS="${_cppflags}"
1383   LDFLAGS="${_ldflags}"
1384 fi
1385
1386 if test "$use_regex" != yes ; then
1387   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1388 fi
1389 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1390
1391
1392
1393 #
1394 # Do we have zlib? Must do it here because Solaris failed
1395 # when compiling a conftest (due to the "-lz" from LIBS).
1396 # Note that we combine zlib and bzlib2 in ZLIBS.
1397 #
1398 if test "$use_zip" = yes ; then
1399   _cppflags="${CPPFLAGS}"
1400   _ldflags="${LDFLAGS}"
1401   AC_ARG_WITH(zlib,
1402     [  --with-zlib=DIR         use libz in DIR],[
1403       if test -d "$withval"; then
1404         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1405         LDFLAGS="${LDFLAGS} -L$withval/lib"
1406       fi
1407     ])
1408
1409   AC_CHECK_HEADER(zlib.h,
1410      AC_CHECK_LIB(z, deflateInit2_,
1411        [
1412        ZLIBS="-lz"
1413        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1414        ],
1415        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1416        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1417 fi
1418
1419
1420 #
1421 # Check whether we can support bzip2
1422 #
1423 if test "$use_bzip2" = yes ; then
1424   _cppflags="${CPPFLAGS}"
1425   _ldflags="${LDFLAGS}"
1426   AC_ARG_WITH(bzip2,
1427      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1428       [
1429       if test -d "$withval" ; then
1430         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1431         LDFLAGS="${LDFLAGS} -L$withval/lib"
1432       fi
1433       ],withval="")
1434
1435   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1436   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1437   # woefully out of date.
1438   if test "$withval" != no ; then
1439      AC_CHECK_HEADER(bzlib.h,
1440         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1441           [
1442           have_bz2=yes
1443           ZLIBS="$ZLIBS -lbz2"
1444           AC_DEFINE(HAVE_BZIP2,1,
1445                   [Defined if the bz2 compression library is available])
1446           ],
1447           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1448           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1449   fi
1450 fi
1451 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1452 AC_SUBST(ZLIBS)
1453
1454
1455 # Check for readline support
1456 GNUPG_CHECK_READLINE
1457
1458
1459 if test "$development_version" = yes; then
1460     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1461             [Defined if this is not a regular release])
1462 fi
1463
1464 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1465
1466 GNUPG_CHECK_GNUMAKE
1467
1468 # Add some extra libs here so that previous tests don't fail for
1469 # mysterious reasons - the final link step should bail out.
1470 # W32SOCKLIBS is also defined so that if can be used for tools not
1471 # requiring any network stuff but linking to code in libcommon which
1472 # tracks in winsock stuff (e.g. init_common_subsystems).
1473 if test "$have_w32_system" = yes; then
1474    if test "$have_w32ce_system" = yes; then
1475      W32SOCKLIBS="-lws2"
1476    else
1477      W32SOCKLIBS="-lws2_32"
1478    fi
1479    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1480 fi
1481
1482 AC_SUBST(NETLIBS)
1483 AC_SUBST(W32SOCKLIBS)
1484
1485 #
1486 # Setup gcc specific options
1487 #
1488 AC_MSG_NOTICE([checking for cc features])
1489 if test "$GCC" = yes; then
1490     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1491     # options.  This is the case for gcc >= 4.6
1492     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1493     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1494 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1495 #kickerror
1496 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1497     AC_MSG_RESULT($_gcc_silent_wno)
1498
1499     # Note that it is okay to use CFLAGS here because these are just
1500     # warning options and the user should have a chance of overriding
1501     # them.
1502     if test "$USE_MAINTAINER_MODE" = "yes"; then
1503         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1504         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1505         if test x"$_gcc_silent_wno" = xyes ; then
1506           _gcc_wopt=yes
1507         else
1508           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1509           _gcc_cflags_save=$CFLAGS
1510           CFLAGS="-Wno-missing-field-initializers"
1511           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1512                             [_gcc_wopt=yes],[_gcc_wopt=no])
1513           AC_MSG_RESULT($_gcc_wopt)
1514           CFLAGS=$_gcc_cflags_save;
1515         fi
1516         if test x"$_gcc_wopt" = xyes ; then
1517           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1518         fi
1519
1520         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1521         _gcc_cflags_save=$CFLAGS
1522         CFLAGS="-Wdeclaration-after-statement"
1523         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1524         AC_MSG_RESULT($_gcc_wopt)
1525         CFLAGS=$_gcc_cflags_save;
1526         if test x"$_gcc_wopt" = xyes ; then
1527           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1528         fi
1529     else
1530         CFLAGS="$CFLAGS -Wall"
1531     fi
1532
1533     if test x"$_gcc_silent_wno" = xyes ; then
1534       _gcc_psign=yes
1535     else
1536       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1537       _gcc_cflags_save=$CFLAGS
1538       CFLAGS="-Wno-pointer-sign"
1539       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1540                         [_gcc_psign=yes],[_gcc_psign=no])
1541       AC_MSG_RESULT($_gcc_psign)
1542       CFLAGS=$_gcc_cflags_save;
1543     fi
1544     if test x"$_gcc_psign" = xyes ; then
1545        CFLAGS="$CFLAGS -Wno-pointer-sign"
1546     fi
1547
1548     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1549     _gcc_cflags_save=$CFLAGS
1550     CFLAGS="-Wpointer-arith"
1551     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1552     AC_MSG_RESULT($_gcc_psign)
1553     CFLAGS=$_gcc_cflags_save;
1554     if test x"$_gcc_psign" = xyes ; then
1555        CFLAGS="$CFLAGS -Wpointer-arith"
1556     fi
1557 fi
1558
1559
1560 #
1561 # This is handy for debugging so the compiler doesn't rearrange
1562 # things and eliminate variables.
1563 #
1564 AC_ARG_ENABLE(optimization,
1565    AC_HELP_STRING([--disable-optimization],
1566                   [disable compiler optimization]),
1567                   [if test $enableval = no ; then
1568                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1569                    fi])
1570
1571 #
1572 # Decide what to build
1573 #
1574
1575 build_scdaemon_extra=""
1576 if test "$build_scdaemon" = "yes"; then
1577   if test $have_libusb = no; then
1578      build_scdaemon_extra="without internal CCID driver"
1579   fi
1580   if test -n "$build_scdaemon_extra"; then
1581      build_scdaemon_extra="(${build_scdaemon_extra})"
1582   fi
1583 fi
1584
1585
1586 #
1587 # Set variables for use by automake makefiles.
1588 #
1589 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1590 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1591 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1592 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1593 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1594 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1595 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1596 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1597 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1598 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1599
1600 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1601 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1602 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1603
1604 AM_CONDITIONAL(RUN_GPG_TESTS,
1605                test x$cross_compiling = xno -a "$build_gpg" = yes )
1606
1607 #
1608 # Set some defines for use gpgconf.
1609 #
1610 if test "$build_gpg" = yes ; then
1611     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1612 fi
1613 if test "$build_gpgsm" = yes ; then
1614     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1615 fi
1616 if test "$build_agent" = yes ; then
1617     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1618 fi
1619 if test "$build_scdaemon" = yes ; then
1620     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1621 fi
1622 if test "$build_dirmngr" = yes ; then
1623     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1624 fi
1625 if test "$build_g13" = yes ; then
1626     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1627 fi
1628
1629
1630 #
1631 # Define Name strings
1632 #
1633 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1634
1635 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1636 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1637
1638 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1639 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1640
1641 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1642 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1643                                         [The displayed name of gpg-agent])
1644
1645 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1646 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1647                                        [The displayed name of scdaemon])
1648
1649 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1650 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1651                                       [The displayed name of dirmngr])
1652
1653 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1654 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1655
1656 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1657 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1658                                       [The displayed name of gpgconf])
1659
1660 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1661
1662 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1663                    [The name of the agent socket])
1664 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1665                    [The name of the agent socket for ssh])
1666 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1667                    [The name of the dirmngr info envvar])
1668 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1669                    [The name of the SCdaemon socket])
1670 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1671                    [The name of the dirmngr socket])
1672
1673 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1674
1675 if test "$have_w32_system" = yes; then
1676   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1677                      [The directory part of the W32 registry keys])
1678 fi
1679
1680
1681 #
1682 # Provide information about the build.
1683 #
1684 BUILD_REVISION="mym4_revision"
1685 AC_SUBST(BUILD_REVISION)
1686 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1687                    [GIT commit id revision used to build this package])
1688
1689 changequote(,)dnl
1690 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1691 changequote([,])dnl
1692 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1693 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1694 AC_SUBST(BUILD_VERSION)
1695 AC_SUBST(BUILD_FILEVERSION)
1696
1697 AC_ARG_ENABLE([build-timestamp],
1698   AC_HELP_STRING([--enable-build-timestamp],
1699                  [set an explicit build timestamp for reproducibility.
1700                   (default is the current time in ISO-8601 format)]),
1701      [if test "$enableval" = "yes"; then
1702         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1703       else
1704         BUILD_TIMESTAMP="$enableval"
1705       fi],
1706      [BUILD_TIMESTAMP="<none>"])
1707 AC_SUBST(BUILD_TIMESTAMP)
1708 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1709                    [The time this package was configured for a build])
1710 BUILD_HOSTNAME="$ac_hostname"
1711 AC_SUBST(BUILD_HOSTNAME)
1712
1713
1714 #
1715 # Print errors here so that they are visible all
1716 # together and the user can acquire them all together.
1717 #
1718 die=no
1719 if test "$have_gpg_error" = "no"; then
1720    die=yes
1721    AC_MSG_NOTICE([[
1722 ***
1723 *** You need libgpg-error to build this program.
1724 **  This library is for example available at
1725 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1726 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1727 ***]])
1728 fi
1729 if test "$have_libgcrypt" = "no"; then
1730    die=yes
1731    AC_MSG_NOTICE([[
1732 ***
1733 *** You need libgcrypt to build this program.
1734 **  This library is for example available at
1735 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1736 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1737 ***]])
1738 fi
1739 if test "$have_libassuan" = "no"; then
1740    die=yes
1741    AC_MSG_NOTICE([[
1742 ***
1743 *** You need libassuan to build this program.
1744 *** This library is for example available at
1745 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1746 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1747 ***]])
1748 fi
1749 if test "$have_ksba" = "no"; then
1750     die=yes
1751     AC_MSG_NOTICE([[
1752 ***
1753 *** You need libksba to build this program.
1754 *** This library is for example available at
1755 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1756 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1757 ***]])
1758 fi
1759 if test "$gnupg_have_ldap" = yes; then
1760   if test "$have_w32ce_system" = yes; then
1761     AC_MSG_NOTICE([[
1762 *** Note that CeGCC might be broken, a package fixing this is:
1763 ***    http://files.kolab.org/local/windows-ce/
1764 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1765 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1766 ***]])
1767    fi
1768 fi
1769 if test "$have_npth" = "no"; then
1770     die=yes
1771     AC_MSG_NOTICE([[
1772 ***
1773 *** It is now required to build with support for the
1774 *** New Portable Threads Library (nPth). Please install this
1775 *** library first.  The library is for example available at
1776 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1777 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1778 ***]])
1779 fi
1780
1781 if test "$require_iconv" = yes; then
1782   if test "$am_func_iconv" != yes; then
1783     die=yes
1784     AC_MSG_NOTICE([[
1785 ***
1786 *** The system does not provide a working iconv function.  Please
1787 *** install a suitable library; for example GNU Libiconv which is
1788 *** available at:
1789 ***   http://ftp.gnu.org/gnu/libiconv/
1790 ***]])
1791   fi
1792 fi
1793
1794 if test "$die" = "yes"; then
1795     AC_MSG_ERROR([[
1796 ***
1797 *** Required libraries not found. Please consult the above messages
1798 *** and install them before running configure again.
1799 ***]])
1800 fi
1801
1802
1803
1804 AC_CONFIG_FILES([ m4/Makefile
1805 Makefile
1806 po/Makefile.in
1807 common/Makefile
1808 common/w32info-rc.h
1809 kbx/Makefile
1810 g10/Makefile
1811 sm/Makefile
1812 agent/Makefile
1813 scd/Makefile
1814 g13/Makefile
1815 dirmngr/Makefile
1816 tools/gpg-zip
1817 tools/Makefile
1818 doc/Makefile
1819 tests/Makefile
1820 tests/openpgp/Makefile
1821 tests/pkits/Makefile
1822 g10/gpg.w32-manifest
1823 ])
1824
1825
1826 AC_OUTPUT
1827
1828
1829 echo "
1830         GnuPG v${VERSION} has been configured as follows:
1831
1832         Revision:  mym4_revision  (mym4_revision_dec)
1833         Platform:  $PRINTABLE_OS_NAME ($host)
1834
1835         OpenPGP:   $build_gpg
1836         S/MIME:    $build_gpgsm
1837         Agent:     $build_agent
1838         Smartcard: $build_scdaemon $build_scdaemon_extra
1839         G13:       $build_g13
1840         Dirmngr:   $build_dirmngr
1841         Gpgtar:    $build_gpgtar
1842
1843         Protect tool:      $show_gnupg_protect_tool_pgm
1844         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1845         Default agent:     $show_gnupg_agent_pgm
1846         Default pinentry:  $show_gnupg_pinentry_pgm
1847         Default scdaemon:  $show_gnupg_scdaemon_pgm
1848         Default dirmngr:   $show_gnupg_dirmngr_pgm
1849
1850         Dirmngr auto start:  $dirmngr_auto_start
1851         Readline support:    $gnupg_cv_have_readline
1852         LDAP support:        $gnupg_have_ldap
1853         DNS SRV support:     $use_dns_srv
1854         TLS support:         $use_tls_library
1855         TOFU support:        $use_tofu
1856 "
1857 if test x"$use_regex" != xyes ; then
1858 echo "
1859         Warning: No regular expression support available.
1860                  OpenPGP trust signatures won't work.
1861                  gpg-check-pattern will not be built.
1862 "
1863 fi
1864 if test "x${gpg_config_script_warn}" != x; then
1865 cat <<G10EOF
1866         Warning: Mismatches between the target platform and the
1867                  to be used libraries have been detected for:
1868                   ${gpg_config_script_warn}
1869                  Please check above for more warning messages.
1870
1871 G10EOF
1872 fi