all: fix more spelling errors
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2018 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg24", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.29
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.5.0
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509
510 #define GNUPG_DEF_COPYRIGHT_LINE \
511         "Copyright (C) 2018 Free Software Foundation, Inc."
512
513 /* For some systems (DOS currently), we hardcode the path here.  For
514    POSIX systems the values are constructed by the Makefiles, so that
515    the values may be overridden by the make invocations; this is to
516    comply with the GNU coding standards.  Note that these values are
517    only defaults.  */
518 #ifdef HAVE_DOSISH_SYSTEM
519 # ifdef HAVE_DRIVE_LETTERS
520 #  define GNUPG_BINDIR      "c:\\gnupg"
521 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
522 #  define GNUPG_LIBDIR      "c:\\gnupg"
523 #  define GNUPG_DATADIR     "c:\\gnupg"
524 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
525 # else
526 #  define GNUPG_BINDIR      "\\gnupg"
527 #  define GNUPG_LIBEXECDIR  "\\gnupg"
528 #  define GNUPG_LIBDIR      "\\gnupg"
529 #  define GNUPG_DATADIR     "\\gnupg"
530 #  define GNUPG_SYSCONFDIR  "\\gnupg"
531 # endif
532 #endif
533
534 /* Derive some other constants. */
535 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
536 #define EXEC_TEMPFILE_ONLY
537 #endif
538
539
540 /* We didn't define endianness above, so get it from OS macros.  This
541    is intended for making fat binary builds on OS X. */
542 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
543 #if defined(__BIG_ENDIAN__)
544 #define BIG_ENDIAN_HOST 1
545 #elif defined(__LITTLE_ENDIAN__)
546 #define LITTLE_ENDIAN_HOST 1
547 #else
548 #error "No endianness found"
549 #endif
550 #endif
551
552
553 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
554    ldap_start_tls_s because that is the actual symbol used in the
555    library.  winldap.h redefines it to our commonly used value,
556    thus we define our usual macro here.  */
557 #ifdef HAVE_LDAP_START_TLS_SA
558 # ifndef HAVE_LDAP_START_TLS_S
559 #  define HAVE_LDAP_START_TLS_S 1
560 # endif
561 #endif
562
563 /* Enable the es_ macros from gpgrt.  */
564 #define GPGRT_ENABLE_ES_MACROS 1
565
566 /* Enable the log_ macros from gpgrt.  */
567 #define GPGRT_ENABLE_LOG_MACROS 1
568
569 /* Tell libgcrypt not to use its own libgpg-error implementation. */
570 #define USE_LIBGPG_ERROR 1
571
572 /* Tell Libgcrypt not to include deprecated definitions.  */
573 #define GCRYPT_NO_DEPRECATED 1
574
575 /* Our HTTP code is used in estream mode.  */
576 #define HTTP_USE_ESTREAM 1
577
578 /* Under W32 we do an explicit socket initialization, thus we need to
579    avoid the on-demand initialization which would also install an atexit
580    handler.  */
581 #define HTTP_NO_WSASTARTUP
582
583 /* Under Windows we use the gettext code from libgpg-error.  */
584 #define GPG_ERR_ENABLE_GETTEXT_MACROS
585
586 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
587 #define GPG_ERR_ENABLE_ERRNO_MACROS
588
589 #endif /*GNUPG_CONFIG_H_INCLUDED*/
590 ])
591
592
593 AM_MAINTAINER_MODE
594 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
595
596 # Checks for programs.
597 AC_MSG_NOTICE([checking for programs])
598 AC_PROG_MAKE_SET
599 AM_SANITY_CHECK
600 missing_dir=`cd $ac_aux_dir && pwd`
601 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
602 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
603 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
604 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
605 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
606 AM_SILENT_RULES
607 AC_PROG_AWK
608 AC_PROG_CC
609 AC_PROG_CPP
610 AM_PROG_CC_C_O
611 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
612   AC_MSG_ERROR([[No C-89 compiler found]])
613 fi
614 AC_PROG_INSTALL
615 AC_PROG_LN_S
616 AC_PROG_RANLIB
617 AC_CHECK_TOOL(AR, ar, :)
618 AC_PATH_PROG(PERL,"perl")
619 AC_CHECK_TOOL(WINDRES, windres, :)
620 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
621 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
622 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
623 AC_ISC_POSIX
624 AC_SYS_LARGEFILE
625 GNUPG_CHECK_USTAR
626
627
628 # We need to compile and run a program on the build machine.  A
629 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
630 # the AC archive is broken for autoconf 2.57.  Given that there is no
631 # newer version of that macro, we assume that it is also broken for
632 # autoconf 2.61 and thus we use a simple but usually sufficient
633 # approach.
634 AC_MSG_CHECKING(for cc for build)
635 if test "$cross_compiling" = "yes"; then
636   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
637 else
638   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
639 fi
640 AC_MSG_RESULT($CC_FOR_BUILD)
641 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
642
643 # We need to call this macro because other pkg-config macros are
644 # not always used.
645 PKG_PROG_PKG_CONFIG
646
647
648 try_gettext=yes
649 require_iconv=yes
650 have_dosish_system=no
651 have_w32_system=no
652 have_w32ce_system=no
653 have_android_system=no
654 use_simple_gettext=no
655 use_ldapwrapper=yes
656 mmap_needed=yes
657 require_pipe_to_unblock_pselect=yes
658 case "${host}" in
659     *-mingw32*)
660         # special stuff for Windoze NT
661         ac_cv_have_dev_random=no
662         AC_DEFINE(USE_ONLY_8DOT3,1,
663                   [Set this to limit filenames to the 8.3 format])
664         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
665                   [Because the Unix gettext has too much overhead on
666                    MingW32 systems and these systems lack Posix functions,
667                    we use a simplified version of gettext])
668         have_dosish_system=yes
669         have_w32_system=yes
670         require_iconv=no
671         require_pipe_to_unblock_pselect=no
672         case "${host}" in
673           *-mingw32ce*)
674             have_w32ce_system=yes
675             ;;
676           *)
677             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
678                       [Defined if the OS supports drive letters.])
679             ;;
680         esac
681         try_gettext="no"
682         use_simple_gettext=yes
683         mmap_needed=no
684         ;;
685     i?86-emx-os2 | i?86-*-os2*emx )
686         # OS/2 with the EMX environment
687         ac_cv_have_dev_random=no
688         AC_DEFINE(HAVE_DRIVE_LETTERS)
689         have_dosish_system=yes
690         try_gettext="no"
691         ;;
692
693     i?86-*-msdosdjgpp*)
694         # DOS with the DJGPP environment
695         ac_cv_have_dev_random=no
696         AC_DEFINE(HAVE_DRIVE_LETTERS)
697         have_dosish_system=yes
698         try_gettext="no"
699         ;;
700
701     *-*-hpux*)
702         if test -z "$GCC" ; then
703             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
704         fi
705         ;;
706     *-dec-osf4*)
707         if test -z "$GCC" ; then
708             # Suppress all warnings
709             # to get rid of the unsigned/signed char mismatch warnings.
710             CFLAGS="-w $CFLAGS"
711         fi
712         ;;
713     *-dec-osf5*)
714         if test -z "$GCC" ; then
715             # Use the newer compiler `-msg_disable ptrmismatch1' to
716             # get rid of the unsigned/signed char mismatch warnings.
717             # Using this may hide other pointer mismatch warnings, but
718             # it at least lets other warning classes through
719             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
720         fi
721         ;;
722     m68k-atari-mint)
723         ;;
724     *-linux-android*)
725         have_android_system=yes
726         # Android is fully utf-8 and we do not want to use iconv to
727         # keeps things simple
728         require_iconv=no
729         ;;
730     *-apple-darwin*)
731         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
732                   Expose all libc features (__DARWIN_C_FULL).)
733         ;;
734     *-*-netbsd*)
735         require_pipe_to_unblock_pselect=yes
736         ;;
737     *)
738         ;;
739 esac
740
741 if test "$require_pipe_to_unblock_pselect" = yes; then
742    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
743              [Defined if we run on systems like NetBSD, where
744               pselect cannot be unblocked by signal from a thread
745               within the same process.  We use pipe in this case, instead.])
746 fi
747
748 if test "$have_dosish_system" = yes; then
749    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
750              [Defined if we run on some of the PCDOS like systems
751               (DOS, Windoze. OS/2) with special properties like
752               no file modes, case insensitive file names and preferred
753               use of backslashes as directory name separators.])
754 fi
755 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
756
757 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
758
759 if test "$have_w32_system" = yes; then
760    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
761    if test "$have_w32ce_system" = yes; then
762       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
763    fi
764 fi
765 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
766 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
767
768 if test "$have_android_system" = yes; then
769    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
770 fi
771 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
772
773
774 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
775 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
776
777
778 #
779 # Checks for libraries.
780 #
781 AC_MSG_NOTICE([checking for libraries])
782
783
784 #
785 # libgpg-error is a library with error codes shared between GnuPG
786 # related projects.
787 #
788 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
789                   have_gpg_error=yes,have_gpg_error=no)
790
791
792 #
793 # Libgcrypt is our generic crypto library
794 #
795 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
796         have_libgcrypt=yes,have_libgcrypt=no)
797
798
799 #
800 # libassuan is used for IPC
801 #
802 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
803                   have_libassuan=yes,have_libassuan=no)
804 if test "$have_libassuan" = "yes"; then
805   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
806                      [version of the libassuan library])
807   show_tor_support="only .onion"
808 fi
809
810
811 #
812 # libksba is our X.509 support library
813 #
814 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
815
816
817 #
818 # libusb allows us to use the integrated CCID smartcard reader driver.
819 #
820 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
821 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
822    case "${host}" in
823      *-mingw32*)
824        LIBUSB_NAME=
825        LIBUSB_LIBS=
826        LIBUSB_CPPFLAGS=
827        ;;
828      *-*-darwin*)
829        LIBUSB_NAME=usb-1.0
830        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
831        ;;
832      *-*-freebsd*)
833        # FreeBSD has a native 1.0 compatible library by -lusb.
834        LIBUSB_NAME=usb
835        LIBUSB_LIBS=
836        ;;
837      *)
838        LIBUSB_NAME=usb-1.0
839        LIBUSB_LIBS=
840        ;;
841    esac
842 fi
843 if test x"$LIBUSB_NAME" != x ; then
844    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
845                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
846                   have_libusb=yes ])
847    AC_MSG_CHECKING([libusb include dir])
848    usb_incdir_found="no"
849    for _incdir in "" "/usr/include/libusb-1.0" \
850        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
851      _libusb_save_cppflags=$CPPFLAGS
852      if test -n "${_incdir}"; then
853        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
854      fi
855      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
856      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
857      CPPFLAGS=${_libusb_save_cppflags}
858      if test "$usb_incdir_found" = "yes"; then
859        break
860      fi
861    done
862    if test "$usb_incdir_found" = "yes"; then
863      AC_MSG_RESULT([${usb_incdir}])
864    else
865      AC_MSG_RESULT([not found])
866      usb_incdir=""
867      have_libusb=no
868      if test "$use_ccid_driver" != yes; then
869        use_ccid_driver=no
870      fi
871      LIBUSB_LIBS=""
872    fi
873
874    if test "$have_libusb" = yes; then
875      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
876    fi
877    if test x"$usb_incdir" = x; then
878      LIBUSB_CPPFLAGS=""
879    else
880      LIBUSB_CPPFLAGS="-I${usb_incdir}"
881    fi
882 fi
883 AC_SUBST(LIBUSB_LIBS)
884 AC_SUBST(LIBUSB_CPPFLAGS)
885
886 #
887 # Check whether it is necessary to link against libdl.
888 # (For example to load libpcsclite)
889 #
890 gnupg_dlopen_save_libs="$LIBS"
891 LIBS=""
892 AC_SEARCH_LIBS(dlopen, c dl,,,)
893 DL_LIBS=$LIBS
894 AC_SUBST(DL_LIBS)
895 LIBS="$gnupg_dlopen_save_libs"
896
897
898 # Checks for g10
899
900 AC_ARG_ENABLE(sqlite,
901                 AC_HELP_STRING([--disable-sqlite],
902                                [disable the use of SQLITE]),
903               try_sqlite=$enableval, try_sqlite=yes)
904
905 if test x"$use_tofu" = xyes ; then
906   if test x"$try_sqlite" = xyes ; then
907     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
908                                  [have_sqlite=yes],
909                                  [have_sqlite=no])
910   fi
911   if test "$have_sqlite" = "yes"; then
912     :
913     AC_SUBST([SQLITE3_CFLAGS])
914     AC_SUBST([SQLITE3_LIBS])
915   else
916     use_tofu=no
917     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
918     AC_MSG_WARN([[
919 ***
920 *** Building without SQLite support - TOFU disabled
921 ***
922 *** $tmp]])
923   fi
924 fi
925
926 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
927
928 if test x"$use_tofu" = xyes ; then
929     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
930 fi
931
932
933 # Checks for g13
934
935 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
936 AC_DEFINE_UNQUOTED(ENCFS,
937         "${ENCFS}", [defines the filename of the encfs program])
938
939 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
940 AC_DEFINE_UNQUOTED(FUSERMOUNT,
941         "${FUSERMOUNT}", [defines the filename of the fusermount program])
942
943
944 # Checks for dirmngr
945
946
947 #
948 # Checks for symcryptrun:
949 #
950
951 # libutil has openpty() and login_tty().
952 AC_CHECK_LIB(util, openpty,
953               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
954                 AC_DEFINE(HAVE_LIBUTIL,1,
955                          [defined if libutil is available])
956              ])
957 AC_SUBST(LIBUTIL_LIBS)
958
959 # shred is used to clean temporary plain text files.
960 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
961 AC_DEFINE_UNQUOTED(SHRED,
962         "${SHRED}", [defines the filename of the shred program])
963
964
965 #
966 # Check whether the nPth library is available
967 #
968 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
969 if test "$have_npth" = "yes"; then
970   AC_DEFINE(HAVE_NPTH, 1,
971               [Defined if the New Portable Thread Library is available])
972   AC_DEFINE(USE_NPTH, 1,
973               [Defined if support for nPth is requested and nPth is available])
974 else
975   AC_MSG_WARN([[
976 ***
977 *** To support concurrent access for example in gpg-agent and the SCdaemon
978 *** we need the support of the New Portable Threads Library.
979 ***]])
980 fi
981 #
982 # Enable debugging of nPth
983 #
984 AC_ARG_ENABLE(npth-debug,
985    AC_HELP_STRING([--enable-npth-debug],
986                   [build with debug version of npth]),
987                   [if test $enableval = yes ; then
988                      AC_DEFINE(NPTH_ENABLE_DEBUG,1,
989                               [Build with debug version of nPth])
990                   fi])
991
992
993
994 #
995 # NTBTLS is our TLS library.  If it is not available fallback to
996 # GNUTLS.
997 #
998 AC_ARG_ENABLE(ntbtls,
999               AC_HELP_STRING([--disable-ntbtls],
1000                              [disable the use of NTBTLS as TLS library]),
1001               try_ntbtls=$enableval, try_ntbtls=yes)
1002 if test x"$try_ntbtls" = xyes ; then
1003   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
1004                  [have_ntbtls=yes],[have_ntbtls=no])
1005 fi
1006 if test "$have_ntbtls" = yes ; then
1007    use_tls_library=ntbtls
1008    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
1009 else
1010   AC_ARG_ENABLE(gnutls,
1011                 AC_HELP_STRING([--disable-gnutls],
1012                                [disable GNUTLS as fallback TLS library]),
1013                 try_gnutls=$enableval, try_gnutls=yes)
1014   if test x"$try_gnutls" = xyes ; then
1015     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
1016                                    [have_gnutls=yes],
1017                                    [have_gnutls=no])
1018   fi
1019   if test "$have_gnutls" = "yes"; then
1020     AC_SUBST([LIBGNUTLS_CFLAGS])
1021     AC_SUBST([LIBGNUTLS_LIBS])
1022     use_tls_library=gnutls
1023     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
1024   else
1025     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1026     AC_MSG_WARN([[
1027 ***
1028 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1029 ***
1030 *** $tmp]])
1031   fi
1032 fi
1033
1034 #
1035 # Allow to set a fixed trust store file for system provided certificates.
1036 #
1037 AC_ARG_WITH([default-trust-store-file],
1038             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1039                             [Use FILE as system trust store])],
1040             default_trust_store_file="$withval",
1041             default_trust_store_file="")
1042 if test x"$default_trust_store_file" = xno;then
1043   default_trust_store_file=""
1044 fi
1045 if test x"$default_trust_store_file" != x ; then
1046   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1047     ["$default_trust_store_file"], [Use as default system trust store file])
1048 fi
1049
1050
1051 AC_MSG_NOTICE([checking for networking options])
1052
1053 #
1054 # Must check for network library requirements before doing link tests
1055 # for ldap, for example. If ldap libs are static (or dynamic and without
1056 # ELF runtime link paths), then link will fail and LDAP support won't
1057 # be detected.
1058 #
1059 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1060         [NETLIBS="-lnsl $NETLIBS"]))
1061 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1062         [NETLIBS="-lsocket $NETLIBS"]))
1063
1064
1065 #
1066 # Check standard resolver functions.
1067 #
1068 if test "$build_dirmngr" = "yes"; then
1069   _dns_save_libs=$LIBS
1070   LIBS=""
1071
1072   # Find the system resolver which can always be enabled with
1073   # the dirmngr option --standard-resolver.
1074
1075   # the double underscore thing is a glibc-ism?
1076   AC_SEARCH_LIBS(res_query,resolv bind,,
1077                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1078   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1079                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1080
1081   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1082   # and for some reason fools us into believing we don't need
1083   # -lresolv even if we do.  Since the test program checking for the
1084   # symbol does not include <resolv.h>, we need to check for the
1085   # renamed symbol explicitly.
1086   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1087       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1088           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1089
1090   if test x"$have_resolver" != xno ; then
1091
1092       # Make sure that the BIND 4 resolver interface is workable before
1093       # enabling any code that calls it.  At some point I'll rewrite the
1094       # code to use the BIND 8 resolver API.
1095       # We might also want to use libdns instead.
1096
1097     AC_MSG_CHECKING([whether the resolver is usable])
1098     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1099 #include <netinet/in.h>
1100 #include <arpa/nameser.h>
1101 #include <resolv.h>]],
1102 [[unsigned char answer[PACKETSZ];
1103   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1104   dn_skipname(0,0);
1105   dn_expand(0,0,0,0,0);
1106 ]])],have_resolver=yes,have_resolver=no)
1107     AC_MSG_RESULT($have_resolver)
1108
1109     # This is Apple-specific and somewhat bizarre as they changed the
1110     # define in bind 8 for some reason.
1111
1112     if test x"$have_resolver" != xyes ; then
1113       AC_MSG_CHECKING(
1114            [whether I can make the resolver usable with BIND_8_COMPAT])
1115       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1116 #include <sys/types.h>
1117 #include <netinet/in.h>
1118 #include <arpa/nameser.h>
1119 #include <resolv.h>]],
1120 [[unsigned char answer[PACKETSZ];
1121   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1122   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1123 ]])],[have_resolver=yes ; need_compat=yes])
1124       AC_MSG_RESULT($have_resolver)
1125     fi
1126   fi
1127
1128   if test x"$have_resolver" = xyes ; then
1129     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1130     DNSLIBS="$DNSLIBS $LIBS"
1131     if test x"$need_compat" = xyes ; then
1132       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1133     fi
1134     if test "$use_libdns" = yes; then
1135      show_tor_support=yes
1136     fi
1137   elif test "$use_libdns" = yes; then
1138     show_tor_support=yes
1139   else
1140     AC_MSG_WARN([[
1141 ***
1142 *** The system's DNS resolver is not usable.
1143 *** Dirmngr functionality is limited.
1144 ***]])
1145     show_tor_support="${show_tor_support} (no system resolver)"
1146   fi
1147
1148   if test "$have_w32_system" = yes; then
1149     if test "$use_libdns" = yes; then
1150       DNSLIBS="$DNSLIBS -liphlpapi"
1151     fi
1152   fi
1153
1154   LIBS=$_dns_save_libs
1155 fi
1156
1157 AC_SUBST(DNSLIBS)
1158
1159
1160 #
1161 # Check for LDAP
1162 #
1163 # Note that running the check changes the variable
1164 # gnupg_have_ldap from "n/a" to "no" or "yes".
1165
1166 AC_ARG_ENABLE(ldap,
1167     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1168     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1169
1170 if test "$gnupg_have_ldap" != "no" ; then
1171   if test "$build_dirmngr" = "yes" ; then
1172      GNUPG_CHECK_LDAP($NETLIBS)
1173      AC_CHECK_LIB(lber, ber_free,
1174                   [ LBER_LIBS="$LBER_LIBS -llber"
1175                     AC_DEFINE(HAVE_LBER,1,
1176                              [defined if liblber is available])
1177                     have_lber=yes
1178                  ])
1179   fi
1180 fi
1181 AC_SUBST(LBER_LIBS)
1182 if test "$gnupg_have_ldap" = "no"; then
1183     AC_MSG_WARN([[
1184 ***
1185 *** Building without LDAP support.
1186 *** No CRL access or X.509 certificate search available.
1187 ***]])
1188 fi
1189
1190 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1191 if test "$gnupg_have_ldap" = yes ; then
1192   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1193 else
1194  use_ldapwrapper=no
1195 fi
1196
1197 if test "$use_ldapwrapper" = yes; then
1198    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1199 fi
1200 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1201
1202
1203
1204
1205 #
1206 # Check for sendmail
1207 #
1208 # This isn't necessarily sendmail itself, but anything that gives a
1209 # sendmail-ish interface to the outside world.  That includes Exim,
1210 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1211 AC_ARG_WITH(mailprog,
1212       AC_HELP_STRING([--with-mailprog=NAME],
1213                      [use "NAME -t" for mail transport]),
1214              ,with_mailprog=yes)
1215 if test x"$with_mailprog" = xyes ; then
1216     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1217 elif test x"$with_mailprog" != xno ; then
1218     AC_MSG_CHECKING([for a mail transport program])
1219     AC_SUBST(SENDMAIL,$with_mailprog)
1220     AC_MSG_RESULT($with_mailprog)
1221 fi
1222 AC_DEFINE_UNQUOTED(NAME_OF_SENDMAIL,"$SENDMAIL",
1223                    [Tool with sendmail -t interface])
1224
1225
1226 #
1227 # Construct a printable name of the OS
1228 #
1229 case "${host}" in
1230     *-mingw32ce*)
1231         PRINTABLE_OS_NAME="W32CE"
1232         ;;
1233     *-mingw32*)
1234         PRINTABLE_OS_NAME="MingW32"
1235         ;;
1236     *-*-cygwin*)
1237         PRINTABLE_OS_NAME="Cygwin"
1238         ;;
1239     i?86-emx-os2 | i?86-*-os2*emx )
1240         PRINTABLE_OS_NAME="OS/2"
1241         ;;
1242     i?86-*-msdosdjgpp*)
1243         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1244         try_dynload=no
1245         ;;
1246     *-linux*)
1247         PRINTABLE_OS_NAME="GNU/Linux"
1248         ;;
1249     *)
1250         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1251         ;;
1252 esac
1253 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1254                    [A human readable text with the name of the OS])
1255
1256
1257 #
1258 # Checking for iconv
1259 #
1260 if test "$require_iconv" = yes; then
1261   AM_ICONV
1262 else
1263   LIBICONV=
1264   LTLIBICONV=
1265   AC_SUBST(LIBICONV)
1266   AC_SUBST(LTLIBICONV)
1267 fi
1268
1269
1270 #
1271 # Check for gettext
1272 #
1273 # This is "GNU gnupg" - The project-id script from gettext
1274 #                       needs this string
1275 #
1276 AC_MSG_NOTICE([checking for gettext])
1277 AM_PO_SUBDIRS
1278 AM_GNU_GETTEXT_VERSION([0.17])
1279 if test "$try_gettext" = yes; then
1280   AM_GNU_GETTEXT([external],[need-ngettext])
1281
1282   # gettext requires some extra checks.  These really should be part of
1283   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1284   # function checks to here.
1285
1286   AC_CHECK_FUNCS(strchr)
1287 else
1288   USE_NLS=no
1289   USE_INCLUDED_LIBINTL=no
1290   BUILD_INCLUDED_LIBINTL=no
1291   POSUB=po
1292   AC_SUBST(USE_NLS)
1293   AC_SUBST(USE_INCLUDED_LIBINTL)
1294   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1295   AC_SUBST(POSUB)
1296 fi
1297
1298 # We use HAVE_LANGINFO_CODESET in a couple of places.
1299 AM_LANGINFO_CODESET
1300
1301 # Checks required for our use of locales
1302 gt_LC_MESSAGES
1303
1304
1305 #
1306 # SELinux support
1307 #
1308 if test "$selinux_support" = yes ; then
1309   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1310 fi
1311
1312
1313 #
1314 # Checks for header files.
1315 #
1316 AC_MSG_NOTICE([checking for header files])
1317 AC_HEADER_STDC
1318 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1319                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1320                   stdint.h signal.h util.h libutil.h termios.h \
1321                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1322
1323 AC_HEADER_TIME
1324
1325
1326 #
1327 # Checks for typedefs, structures, and compiler characteristics.
1328 #
1329 AC_MSG_NOTICE([checking for system characteristics])
1330 AC_C_CONST
1331 AC_C_INLINE
1332 AC_C_VOLATILE
1333 AC_TYPE_SIZE_T
1334 AC_TYPE_MODE_T
1335 AC_TYPE_SIGNAL
1336 AC_DECL_SYS_SIGLIST
1337
1338 gl_HEADER_SYS_SOCKET
1339 gl_TYPE_SOCKLEN_T
1340
1341 AC_SEARCH_LIBS([inet_addr], [nsl])
1342
1343 AC_ARG_ENABLE(endian-check,
1344               AC_HELP_STRING([--disable-endian-check],
1345               [disable the endian check and trust the OS provided macros]),
1346               endiancheck=$enableval,endiancheck=yes)
1347
1348 if test x"$endiancheck" = xyes ; then
1349   GNUPG_CHECK_ENDIAN
1350 fi
1351
1352 # fixme: we should get rid of the byte type
1353 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1354 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1355 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1356 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1357 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1358
1359 AC_CHECK_SIZEOF(unsigned short)
1360 AC_CHECK_SIZEOF(unsigned int)
1361 AC_CHECK_SIZEOF(unsigned long)
1362 AC_CHECK_SIZEOF(unsigned long long)
1363 AC_HEADER_TIME
1364 AC_CHECK_SIZEOF(time_t,,[[
1365 #include <stdio.h>
1366 #if TIME_WITH_SYS_TIME
1367 # include <sys/time.h>
1368 # include <time.h>
1369 #else
1370 # if HAVE_SYS_TIME_H
1371 #  include <sys/time.h>
1372 # else
1373 #  include <time.h>
1374 # endif
1375 #endif
1376 ]])
1377 GNUPG_TIME_T_UNSIGNED
1378
1379
1380 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1381    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1382    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1383     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1384 fi
1385
1386
1387 #
1388 # Checks for library functions.
1389 #
1390 AC_MSG_NOTICE([checking for library functions])
1391 AC_CHECK_DECLS(getpagesize)
1392 AC_FUNC_FSEEKO
1393 AC_FUNC_VPRINTF
1394 AC_FUNC_FORK
1395 AC_CHECK_FUNCS([atexit canonicalize_file_name clock_gettime ctermid  \
1396                 fcntl flockfile fsync ftello ftruncate funlockfile   \
1397                 getaddrinfo getenv getpagesize getpwnam getpwuid     \
1398                 getrlimit getrusage gettimeofday gmtime_r            \
1399                 inet_ntop inet_pton isascii lstat                    \
1400                 memicmp memmove memrchr mmap nl_langinfo pipe        \
1401                 raise rand setenv setlocale setrlimit sigaction      \
1402                 sigprocmask stat stpcpy strcasecmp strerror strftime \
1403                 stricmp strlwr strncasecmp strpbrk strsep            \
1404                 strtol strtoul strtoull tcgetattr timegm times       \
1405                 ttyname unsetenv wait4 waitpid ])
1406
1407 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1408 # Given that we use nanosleep only as an optimization over a select
1409 # based wait function we want it only if it is available in libc.
1410 _save_libs="$LIBS"
1411 AC_SEARCH_LIBS([nanosleep], [],
1412                [AC_DEFINE(HAVE_NANOSLEEP,1,
1413                 [Define to 1 if you have the `nanosleep' function in libc.])])
1414 LIBS="$_save_libs"
1415
1416
1417 # See whether libc supports the Linux inotify interface
1418 case "${host}" in
1419     *-*-linux*)
1420         AC_CHECK_FUNCS([inotify_init])
1421         ;;
1422 esac
1423
1424
1425 if test "$have_android_system" = yes; then
1426    # On Android ttyname is a stub but prints an error message.
1427    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1428              [Defined if ttyname does not work properly])
1429 fi
1430
1431 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1432
1433 # Dirmngr requires mmap on Unix systems.
1434 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1435   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1436 fi
1437
1438
1439 #
1440 # Check for the getsockopt SO_PEERCRED, etc.
1441 #
1442 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1443 #include <sys/socket.h> ])
1444
1445 # (Open)Solaris
1446 AC_CHECK_FUNCS([getpeerucred])
1447
1448
1449 #
1450 # W32 specific test
1451 #
1452 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1453
1454 #
1455 # Sanity check regex.  Tests adapted from mutt.
1456 #
1457 AC_MSG_CHECKING([whether regular expression support is requested])
1458 AC_ARG_ENABLE(regex,
1459   AC_HELP_STRING([--disable-regex],
1460     [do not handle regular expressions in trust signatures]),
1461   use_regex=$enableval, use_regex=yes)
1462 AC_MSG_RESULT($use_regex)
1463
1464 if test "$use_regex" = yes ; then
1465   _cppflags="${CPPFLAGS}"
1466   _ldflags="${LDFLAGS}"
1467   AC_ARG_WITH(regex,
1468      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1469       [
1470       if test -d "$withval" ; then
1471         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1472         LDFLAGS="${LDFLAGS} -L$withval/lib"
1473       fi
1474       ],withval="")
1475
1476   # Does the system have regex functions at all?
1477   AC_SEARCH_LIBS([regcomp], [regex])
1478   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1479
1480   if test $gnupg_cv_have_regex = no; then
1481     use_regex=no
1482   else
1483     if test x"$cross_compiling" = xyes; then
1484       AC_MSG_WARN([cross compiling; assuming regexp library is not broken])
1485     else
1486       AC_CACHE_CHECK([whether your system's regexp library is broken],
1487        [gnupg_cv_regex_broken],
1488        AC_TRY_RUN([
1489 #include <unistd.h>
1490 #include <regex.h>
1491 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1492        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1493
1494       if test $gnupg_cv_regex_broken = yes; then
1495         AC_MSG_WARN([your regex is broken - disabling regex use])
1496         use_regex=no
1497       fi
1498     fi
1499   fi
1500   CPPFLAGS="${_cppflags}"
1501   LDFLAGS="${_ldflags}"
1502 fi
1503
1504 if test "$use_regex" != yes ; then
1505   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1506 fi
1507 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1508
1509
1510
1511 #
1512 # Do we have zlib? Must do it here because Solaris failed
1513 # when compiling a conftest (due to the "-lz" from LIBS).
1514 # Note that we combine zlib and bzlib2 in ZLIBS.
1515 #
1516 if test "$use_zip" = yes ; then
1517   _cppflags="${CPPFLAGS}"
1518   _ldflags="${LDFLAGS}"
1519   AC_ARG_WITH(zlib,
1520     [  --with-zlib=DIR         use libz in DIR],[
1521       if test -d "$withval"; then
1522         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1523         LDFLAGS="${LDFLAGS} -L$withval/lib"
1524       fi
1525     ])
1526
1527   AC_CHECK_HEADER(zlib.h,
1528      AC_CHECK_LIB(z, deflateInit2_,
1529        [
1530        ZLIBS="-lz"
1531        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1532        ],
1533        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1534        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1535 fi
1536
1537
1538 #
1539 # Check whether we can support bzip2
1540 #
1541 if test "$use_bzip2" = yes ; then
1542   _cppflags="${CPPFLAGS}"
1543   _ldflags="${LDFLAGS}"
1544   AC_ARG_WITH(bzip2,
1545      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1546       [
1547       if test -d "$withval" ; then
1548         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1549         LDFLAGS="${LDFLAGS} -L$withval/lib"
1550       fi
1551       ],withval="")
1552
1553   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1554   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1555   # woefully out of date.
1556   if test "$withval" != no ; then
1557      AC_CHECK_HEADER(bzlib.h,
1558         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1559           [
1560           have_bz2=yes
1561           ZLIBS="$ZLIBS -lbz2"
1562           AC_DEFINE(HAVE_BZIP2,1,
1563                   [Defined if the bz2 compression library is available])
1564           ],
1565           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1566           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1567   fi
1568 fi
1569 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1570 AC_SUBST(ZLIBS)
1571
1572
1573 # Check for readline support
1574 GNUPG_CHECK_READLINE
1575
1576
1577 if test "$development_version" = yes; then
1578     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1579             [Defined if this is not a regular release])
1580 fi
1581
1582 if test "$USE_MAINTAINER_MODE" = "yes"; then
1583     AC_DEFINE(MAINTAINER_MODE,1,
1584             [Defined if this build is in maintainer mode])
1585 fi
1586
1587 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1588
1589 GNUPG_CHECK_GNUMAKE
1590
1591 # Add some extra libs here so that previous tests don't fail for
1592 # mysterious reasons - the final link step should bail out.
1593 # W32SOCKLIBS is also defined so that if can be used for tools not
1594 # requiring any network stuff but linking to code in libcommon which
1595 # tracks in winsock stuff (e.g. init_common_subsystems).
1596 if test "$have_w32_system" = yes; then
1597    if test "$have_w32ce_system" = yes; then
1598      W32SOCKLIBS="-lws2"
1599    else
1600      W32SOCKLIBS="-lws2_32"
1601    fi
1602    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1603 fi
1604
1605 AC_SUBST(NETLIBS)
1606 AC_SUBST(W32SOCKLIBS)
1607
1608 #
1609 # Setup gcc specific options
1610 #
1611 USE_C99_CFLAGS=
1612 AC_MSG_NOTICE([checking for cc features])
1613 if test "$GCC" = yes; then
1614     mycflags=
1615     mycflags_save=$CFLAGS
1616
1617     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1618     # options.  This is the case for gcc >= 4.6
1619     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1620     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1621 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1622 #kickerror
1623 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1624     AC_MSG_RESULT($_gcc_silent_wno)
1625
1626     # Note that it is okay to use CFLAGS here because these are just
1627     # warning options and the user should have a chance of overriding
1628     # them.
1629     if test "$USE_MAINTAINER_MODE" = "yes"; then
1630         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1631         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1632         if test x"$_gcc_silent_wno" = xyes ; then
1633           _gcc_wopt=yes
1634         else
1635           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1636           CFLAGS="-Wno-missing-field-initializers"
1637           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1638                             [_gcc_wopt=yes],[_gcc_wopt=no])
1639           AC_MSG_RESULT($_gcc_wopt)
1640         fi
1641         if test x"$_gcc_wopt" = xyes ; then
1642           mycflags="$mycflags -W -Wno-sign-compare -Wno-format-zero-length"
1643           mycflags="$mycflags -Wno-missing-field-initializers"
1644         fi
1645
1646         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1647         CFLAGS="-Wdeclaration-after-statement"
1648         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1649         AC_MSG_RESULT($_gcc_wopt)
1650         if test x"$_gcc_wopt" = xyes ; then
1651           mycflags="$mycflags -Wdeclaration-after-statement"
1652         fi
1653
1654         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1655         CFLAGS="-Wlogical-op -Werror"
1656         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1657         AC_MSG_RESULT($_gcc_wopt)
1658         if test x"$_gcc_wopt" = xyes ; then
1659           mycflags="$mycflags -Wlogical-op"
1660         fi
1661
1662         AC_MSG_CHECKING([if gcc supports -Wvla])
1663         CFLAGS="-Wvla"
1664         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1665         AC_MSG_RESULT($_gcc_wopt)
1666         if test x"$_gcc_wopt" = xyes ; then
1667           mycflags="$mycflags -Wvla"
1668         fi
1669
1670     else
1671         mycflags="$mycflags -Wall"
1672     fi
1673
1674     if test x"$_gcc_silent_wno" = xyes ; then
1675       _gcc_psign=yes
1676     else
1677       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1678       CFLAGS="-Wno-pointer-sign"
1679       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1680                         [_gcc_psign=yes],[_gcc_psign=no])
1681       AC_MSG_RESULT($_gcc_psign)
1682     fi
1683     if test x"$_gcc_psign" = xyes ; then
1684        mycflags="$mycflags -Wno-pointer-sign"
1685     fi
1686
1687     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1688     CFLAGS="-Wpointer-arith"
1689     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1690     AC_MSG_RESULT($_gcc_psign)
1691     if test x"$_gcc_psign" = xyes ; then
1692        mycflags="$mycflags -Wpointer-arith"
1693     fi
1694
1695     CFLAGS="$mycflags $mycflags_save"
1696     if test "$use_libdns" = yes; then
1697        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1698        USE_C99_CFLAGS="-std=gnu99"
1699     fi
1700 fi
1701
1702 AC_SUBST(USE_C99_CFLAGS)
1703
1704
1705 #
1706 # This is handy for debugging so the compiler doesn't rearrange
1707 # things and eliminate variables.
1708 #
1709 AC_ARG_ENABLE(optimization,
1710    AC_HELP_STRING([--disable-optimization],
1711                   [disable compiler optimization]),
1712                   [if test $enableval = no ; then
1713                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1714                    fi])
1715
1716 #
1717 # log_debug has certain requirements which might hamper portability.
1718 # Thus we use an option to enable it.
1719 #
1720 AC_MSG_CHECKING([whether to enable log_clock])
1721 AC_ARG_ENABLE(log_clock,
1722               AC_HELP_STRING([--enable-log-clock],
1723                              [enable log_clock timestamps]),
1724               enable_log_clock=$enableval, enable_log_clock=no)
1725 AC_MSG_RESULT($enable_log_clock)
1726 if test "$enable_log_clock" = yes ; then
1727   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1728 fi
1729
1730 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1731 # misbehaving autoconf tests in case the user supplied -Werror.
1732 #
1733 AC_ARG_ENABLE(werror,
1734    AC_HELP_STRING([--enable-werror],
1735                   [append -Werror to CFLAGS]),
1736                   [if test $enableval = yes ; then
1737                       CFLAGS="$CFLAGS -Werror"
1738                    fi])
1739
1740 #
1741 # Configure option --enable-all-tests
1742 #
1743 AC_MSG_CHECKING([whether "make check" shall run all tests])
1744 AC_ARG_ENABLE(all-tests,
1745               AC_HELP_STRING([--enable-all-tests],
1746                              [let "make check" run all tests]),
1747               run_all_tests=$enableval, run_all_tests=no)
1748 AC_MSG_RESULT($run_all_tests)
1749 if test "$run_all_tests" = "yes"; then
1750     AC_DEFINE(RUN_ALL_TESTS,1,
1751             [Defined if "make check" shall run all tests])
1752 fi
1753
1754 #
1755 # We do not want support for the GNUPG_BUILDDIR environment variable
1756 # in a released version.  However, our regression tests suite requires
1757 # this and thus we build with support for it during "make distcheck".
1758 # This configure option implements this along with the top Makefile's
1759 # AM_DISTCHECK_CONFIGURE_FLAGS.
1760 #
1761 gnupg_builddir_envvar=no
1762 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1763               gnupg_builddir_envvar=$enableval)
1764 if test x"$gnupg_builddir_envvar" = x"yes"; then
1765    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1766       [This is only used with "make distcheck"])
1767 fi
1768
1769
1770 #
1771 # To avoid problems with systemd cleaning up the /run/user directory,
1772 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1773 # before /run/user
1774 #
1775 AC_ARG_ENABLE(run-gnupg-user-socket,
1776     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1777                    [try /run/gnupg/user for sockets prior to /run/user]),
1778     use_run_gnupg_user_socket=$enableval)
1779 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1780    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1781             [If defined try /run/gnupg/user before /run/user])
1782 fi
1783
1784
1785 #
1786 # Decide what to build
1787 #
1788
1789 build_scdaemon_extra=""
1790 if test "$build_scdaemon" = "yes"; then
1791   if test $have_libusb = no; then
1792      build_scdaemon_extra="without internal CCID driver"
1793   fi
1794   if test -n "$build_scdaemon_extra"; then
1795      build_scdaemon_extra="(${build_scdaemon_extra})"
1796   fi
1797 fi
1798
1799
1800 #
1801 # Set variables for use by automake makefiles.
1802 #
1803 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1804 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1805 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1806 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1807 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1808 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1809 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1810 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1811 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1812 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1813
1814 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1815 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1816 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1817
1818 #
1819 # Set some defines for use gpgconf.
1820 #
1821 if test "$build_gpg" = yes ; then
1822     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1823 fi
1824 if test "$build_gpgsm" = yes ; then
1825     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1826 fi
1827 if test "$build_agent" = yes ; then
1828     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1829 fi
1830 if test "$build_scdaemon" = yes ; then
1831     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1832 fi
1833 if test "$build_dirmngr" = yes ; then
1834     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1835 fi
1836 if test "$build_g13" = yes ; then
1837     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1838 fi
1839
1840
1841 #
1842 # Define Name strings
1843 #
1844 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1845
1846 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1847 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1848
1849 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1850 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1851
1852 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1853 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1854                                         [The displayed name of gpg-agent])
1855
1856 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1857 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1858                                        [The displayed name of scdaemon])
1859
1860 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1861 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1862                                       [The displayed name of dirmngr])
1863
1864 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1865 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1866
1867 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1868 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1869                                       [The displayed name of gpgconf])
1870
1871 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1872
1873 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1874                    [The name of the agent socket])
1875 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1876                    [The name of the agent socket for remote access])
1877 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1878                    [The name of the agent socket for browsers])
1879 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1880                    [The name of the agent socket for ssh])
1881 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1882                    [The name of the dirmngr info envvar])
1883 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1884                    [The name of the SCdaemon socket])
1885 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1886                    [The name of the dirmngr socket])
1887 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1888                    "hkps://hkps.pool.sks-keyservers.net",
1889       [The default keyserver for dirmngr to use, if none is explicitly given])
1890
1891 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1892
1893 if test "$have_w32_system" = yes; then
1894   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1895                      [The directory part of the W32 registry keys])
1896 fi
1897
1898
1899 #
1900 # Provide information about the build.
1901 #
1902 BUILD_REVISION="mym4_revision"
1903 AC_SUBST(BUILD_REVISION)
1904 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1905                    [GIT commit id revision used to build this package])
1906
1907 changequote(,)dnl
1908 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1909 changequote([,])dnl
1910 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1911 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1912 AC_SUBST(BUILD_VERSION)
1913 AC_SUBST(BUILD_FILEVERSION)
1914
1915 AC_ARG_ENABLE([build-timestamp],
1916   AC_HELP_STRING([--enable-build-timestamp],
1917                  [set an explicit build timestamp for reproducibility.
1918                   (default is the current time in ISO-8601 format)]),
1919      [if test "$enableval" = "yes"; then
1920         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1921       else
1922         BUILD_TIMESTAMP="$enableval"
1923       fi
1924       BUILD_HOSTNAME="$ac_hostname"],
1925      [BUILD_TIMESTAMP="<none>"
1926       BUILD_HOSTNAME="<anon>"])
1927 AC_SUBST(BUILD_TIMESTAMP)
1928 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1929                    [The time this package was configured for a build])
1930 AC_SUBST(BUILD_HOSTNAME)
1931
1932
1933 #
1934 # Print errors here so that they are visible all
1935 # together and the user can acquire them all together.
1936 #
1937 die=no
1938 if test "$have_gpg_error" = "no"; then
1939    die=yes
1940    AC_MSG_NOTICE([[
1941 ***
1942 *** You need libgpg-error to build this program.
1943 **  This library is for example available at
1944 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1945 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1946 ***]])
1947 fi
1948 if test "$have_libgcrypt" = "no"; then
1949    die=yes
1950    AC_MSG_NOTICE([[
1951 ***
1952 *** You need libgcrypt to build this program.
1953 **  This library is for example available at
1954 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1955 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1956 ***]])
1957 fi
1958 if test "$have_libassuan" = "no"; then
1959    die=yes
1960    AC_MSG_NOTICE([[
1961 ***
1962 *** You need libassuan to build this program.
1963 *** This library is for example available at
1964 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1965 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1966 ***]])
1967 fi
1968 if test "$have_ksba" = "no"; then
1969     die=yes
1970     AC_MSG_NOTICE([[
1971 ***
1972 *** You need libksba to build this program.
1973 *** This library is for example available at
1974 ***   https://gnupg.org/ftp/gcrypt/libksba/
1975 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1976 ***]])
1977 fi
1978 if test "$gnupg_have_ldap" = yes; then
1979   if test "$have_w32ce_system" = yes; then
1980     AC_MSG_NOTICE([[
1981 *** Note that CeGCC might be broken, a package fixing this is:
1982 ***    http://files.kolab.org/local/windows-ce/
1983 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1984 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1985 ***]])
1986    fi
1987 fi
1988 if test "$have_npth" = "no"; then
1989     die=yes
1990     AC_MSG_NOTICE([[
1991 ***
1992 *** It is now required to build with support for the
1993 *** New Portable Threads Library (nPth). Please install this
1994 *** library first.  The library is for example available at
1995 ***   https://gnupg.org/ftp/gcrypt/npth/
1996 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1997 ***]])
1998 fi
1999
2000 if test "$require_iconv" = yes; then
2001   if test "$am_func_iconv" != yes; then
2002     die=yes
2003     AC_MSG_NOTICE([[
2004 ***
2005 *** The system does not provide a working iconv function.  Please
2006 *** install a suitable library; for example GNU Libiconv which is
2007 *** available at:
2008 ***   https://ftp.gnu.org/gnu/libiconv/
2009 ***]])
2010   fi
2011 fi
2012
2013 if test "$use_ccid_driver" = yes; then
2014   if test "$have_libusb" != yes; then
2015     die=yes
2016     AC_MSG_NOTICE([[
2017 ***
2018 *** You need libusb to build the internal ccid driver.  Please
2019 *** install a libusb suitable for your system.
2020 ***]])
2021   fi
2022 fi
2023
2024 if test "$die" = "yes"; then
2025     AC_MSG_ERROR([[
2026 ***
2027 *** Required libraries not found. Please consult the above messages
2028 *** and install them before running configure again.
2029 ***]])
2030 fi
2031
2032
2033
2034 AC_CONFIG_FILES([ m4/Makefile
2035 Makefile
2036 po/Makefile.in
2037 common/Makefile
2038 common/w32info-rc.h
2039 kbx/Makefile
2040 g10/Makefile
2041 sm/Makefile
2042 agent/Makefile
2043 scd/Makefile
2044 g13/Makefile
2045 dirmngr/Makefile
2046 tools/gpg-zip
2047 tools/Makefile
2048 doc/Makefile
2049 tests/Makefile
2050 tests/gpgscm/Makefile
2051 tests/openpgp/Makefile
2052 tests/migrations/Makefile
2053 tests/gpgsm/Makefile
2054 tests/gpgme/Makefile
2055 tests/pkits/Makefile
2056 g10/gpg.w32-manifest
2057 ])
2058
2059
2060 AC_OUTPUT
2061
2062
2063 echo "
2064         GnuPG v${VERSION} has been configured as follows:
2065
2066         Revision:  mym4_revision  (mym4_revision_dec)
2067         Platform:  $PRINTABLE_OS_NAME ($host)
2068
2069         OpenPGP:   $build_gpg
2070         S/MIME:    $build_gpgsm
2071         Agent:     $build_agent
2072         Smartcard: $build_scdaemon $build_scdaemon_extra
2073         G13:       $build_g13
2074         Dirmngr:   $build_dirmngr
2075         Gpgtar:    $build_gpgtar
2076         WKS tools: $build_wks_tools
2077
2078         Protect tool:      $show_gnupg_protect_tool_pgm
2079         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2080         Default agent:     $show_gnupg_agent_pgm
2081         Default pinentry:  $show_gnupg_pinentry_pgm
2082         Default scdaemon:  $show_gnupg_scdaemon_pgm
2083         Default dirmngr:   $show_gnupg_dirmngr_pgm
2084
2085         Dirmngr auto start:  $dirmngr_auto_start
2086         Readline support:    $gnupg_cv_have_readline
2087         LDAP support:        $gnupg_have_ldap
2088         TLS support:         $use_tls_library
2089         TOFU support:        $use_tofu
2090         Tor support:         $show_tor_support
2091 "
2092 if test x"$use_regex" != xyes ; then
2093 echo "
2094         Warning: No regular expression support available.
2095                  OpenPGP trust signatures won't work.
2096                  gpg-check-pattern will not be built.
2097 "
2098 fi
2099 if test "x${gpg_config_script_warn}" != x; then
2100 cat <<G10EOF
2101         Warning: Mismatches between the target platform and the
2102                  to be used libraries have been detected for:
2103                   ${gpg_config_script_warn}
2104                  Please check above for more warning messages.
2105
2106 G10EOF
2107 fi