* configure.ac (HAVE_LIBUSB): Added a simple test for libusb.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 # Version number: Remember to change it immediately *after* a release.
24 #                 Add a "-cvs" prefix for non-released code.
25 AC_INIT(gnupg, 1.9.1-cvs, gnupg-devel@gnupg.org)
26 # Set development_version to yes if the minor number is odd or you
27 # feel that the default check for a development version is not
28 # sufficient.
29 development_version=yes
30 NEED_GPG_ERROR_VERSION=0.2
31 NEED_LIBGCRYPT_VERSION=1.1.42
32 NEED_LIBASSUAN_VERSION=0.6.0
33 NEED_KSBA_VERSION=0.4.6
34 NEED_OPENSC_VERSION=0.7.0
35
36
37 PACKAGE=$PACKAGE_NAME
38 VERSION=$PACKAGE_VERSION
39
40 AM_GNU_GETTEXT_VERSION(0.11.5)
41
42 AC_CONFIG_AUX_DIR(scripts)
43 AC_CONFIG_SRCDIR(sm/gpgsm.c)
44 AM_CONFIG_HEADER(config.h)
45 AC_CANONICAL_TARGET()
46 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
47
48 AC_GNU_SOURCE
49
50 # Some status variables to give feedback at the end of a configure run
51 have_gpg_error=no
52 have_libgcrypt=no 
53 have_libassuan=no
54 have_ksba=no
55 have_opensc=no
56 have_pth=no
57
58 GNUPG_BUILD_PROGRAM(gpg, yes)
59 GNUPG_BUILD_PROGRAM(gpgsm, yes)
60 GNUPG_BUILD_PROGRAM(agent, yes)
61 GNUPG_BUILD_PROGRAM(scdaemon, yes)
62
63
64 AC_SUBST(PACKAGE)
65 AC_SUBST(VERSION)
66 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
67 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
68 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
69                                         [Bug report address])
70 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
71                                        [Required version of Libgcrypt])
72 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
73                                        [Required version of Libksba])
74
75
76
77
78 # I know that it is in general not a good idea to evaluate bindir in
79 # the configuration but we want to hard code the defaults into some of
80 # the programs and doing this during a make install is not a good
81 # idea.  We also have the problem that 2 of the programs are included
82 # in the package but the others are distributed in other packages.
83 eval my_default_bindir=${exec_prefix}
84 test "x${my_default_bindir}" = xNONE && my_default_bindir=${ac_default_prefix}
85 my_default_bindir=${my_default_bindir}/bin
86
87 # Same goes for the pkglibdir which is used to call the gpg-protect-tool.
88 eval my_default_pkglibdir=${exec_prefix}
89 test "x${my_default_pkglibdir}" = xNONE && my_default_pkglibdir=${ac_default_prefix}
90 my_default_pkglibdir=${my_default_pkglibdir}/lib/${PACKAGE_NAME}
91
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the gpg-agent)],
94           gnupg_agent_pgm="$withval",
95           gnupg_agent_pgm="${my_default_bindir}/gpg-agent" )
96 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_AGENT, "$gnupg_agent_pgm",
97                    [Default location of the gpg-agent program])
98 AC_ARG_WITH(pinentry-pgm,
99     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
100           gnupg_pinentry_pgm="$withval", gnupg_pinentry_pgm="" )
101 if test -z "$gnupg_pinentry_pgm"; then
102   gnupg_pinentry_pgm=${my_default_bindir}/pinentry
103 fi
104 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_PINENTRY, "$gnupg_pinentry_pgm",
105                    [Default location of the pinentry program])
106 AC_ARG_WITH(scdaemon-pgm,
107     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
108           gnupg_scdaemon_pgm="$withval", gnupg_scdaemon_pgm="" )
109 if test -z "$gnupg_scdaemon_pgm"; then
110   gnupg_scdaemon_pgm=${my_default_bindir}/scdaemon
111 fi
112 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_SCDAEMON, "$gnupg_scdaemon_pgm",
113                    [Default location of the scdaemon program])
114 AC_ARG_WITH(dirmngr-pgm,
115     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
116           gnupg_dirmngr_pgm="$withval", gnupg_dirmngr_pgm="" )
117 if test -z "$gnupg_dirmngr_pgm"; then
118   gnupg_dirmngr_pgm=${my_default_bindir}/dirmngr
119 fi
120 AC_DEFINE_UNQUOTED(GNUPG_DEFAULT_DIRMNGR, "$gnupg_dirmngr_pgm",
121                    [Default location of the dirmngr program])
122
123 AC_ARG_WITH(protect-tool,
124     [  --with-protect-tool=PATH  Use PATH as the protect-tool)],
125           gnupg_protect_tool="$withval", gnupg_protect_tool="" )
126 if test -z "$gnupg_protect_tool"; then
127   gnupg_protect_tool=${my_default_pkglibdir}/gpg-protect-tool
128 fi
129 AC_DEFINE_UNQUOTED(GNUPG_PROTECT_TOOL, "$gnupg_protect_tool",
130                    [Name of the protect tool program])
131
132
133
134 AC_MSG_CHECKING([whether to enable external program execution])
135 AC_ARG_ENABLE(exec,
136     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
137     use_exec=$enableval)
138 AC_MSG_RESULT($use_exec)
139 if test "$use_exec" = no ; then
140     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
141 fi
142
143 if test "$use_exec" = yes ; then
144   AC_MSG_CHECKING([whether to enable photo ID viewing])
145   AC_ARG_ENABLE(photo-viewers,
146       [  --disable-photo-viewers disable photo ID viewers],
147       [if test "$enableval" = no ; then
148          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
149       fi],enableval=yes)
150   gnupg_cv_enable_photo_viewers=$enableval
151   AC_MSG_RESULT($enableval)
152
153   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
154     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
155     AC_ARG_WITH(photo-viewer,
156         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
157         [if test "$withval" = yes ; then
158            withval=no
159         elif test "$withval" != no ; then
160            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
161                             [if set, restrict photo-viewer to this])
162         fi],withval=no)
163     AC_MSG_RESULT($withval)
164   fi
165
166   AC_MSG_CHECKING([whether to enable external keyserver helpers])
167   AC_ARG_ENABLE(keyserver-helpers,
168       [  --disable-keyserver-helpers  disable all external keyserver support],
169       [if test "$enableval" = no ; then
170          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
171                   [define to disable keyserver helpers])
172       fi],enableval=yes)
173   gnupg_cv_enable_keyserver_helpers=$enableval
174   AC_MSG_RESULT($enableval)
175
176   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
177     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
178     AC_ARG_ENABLE(ldap,
179     [  --disable-ldap          disable LDAP keyserver interface],
180         try_ldap=$enableval, try_ldap=yes)
181     AC_MSG_RESULT($try_ldap)
182
183     AC_MSG_CHECKING([whether HKP keyserver support is requested])
184     AC_ARG_ENABLE(hkp,
185     [  --disable-hkp           disable HKP keyserver interface],
186         try_hkp=$enableval, try_hkp=yes)
187     AC_MSG_RESULT($try_hkp)
188
189     if test "$try_hkp" = yes ; then
190       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
191     fi
192
193     AC_MSG_CHECKING([whether email keyserver support is requested])
194     AC_ARG_ENABLE(mailto,
195     [  --disable-mailto        disable email keyserver interface],
196         try_mailto=$enableval, try_mailto=yes)
197     AC_MSG_RESULT($try_mailto)
198     fi
199
200     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
201     AC_ARG_ENABLE(keyserver-path,
202         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
203         [if test "$enableval" = no ; then
204          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
205         fi],enableval=yes)
206     AC_MSG_RESULT($enableval)
207   fi
208
209 AC_MSG_CHECKING([whether the included zlib is requested])
210 AC_ARG_WITH(included-zlib,
211     [  --with-included-zlib    use the zlib code included here],
212 [g10_force_zlib=yes], [g10_force_zlib=no] )
213 AC_MSG_RESULT($g10_force_zlib)
214
215 dnl
216 dnl Check whether we want to use Linux capabilities
217 dnl
218 AC_MSG_CHECKING([whether use of capabilities is requested])
219 AC_ARG_WITH(capabilities,
220     [  --with-capabilities     use linux capabilities [default=no]],
221 [use_capabilities="$withval"],[use_capabilities=no])
222 AC_MSG_RESULT($use_capabilities)
223
224
225 AH_BOTTOM([
226 /* Some global constants. */
227 #ifdef HAVE_DRIVE_LETTERS
228 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
229 #else
230 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
231 #endif 
232 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
233
234 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
235 #define EXEC_TEMPFILE_ONLY
236 #endif
237
238 /* Tell libgcrypt not to use its own libgpg-error implementation. */
239 #define USE_LIBGPG_ERROR 1
240
241 #include "g10defs.h"
242
243 ])
244
245 AM_MAINTAINER_MODE
246
247 # Checks for programs.
248 AC_PROG_MAKE_SET
249 AM_SANITY_CHECK
250 missing_dir=`cd $ac_aux_dir && pwd`
251 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
252 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
253 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
254 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
255 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
256 AC_PROG_AWK
257 AC_PROG_CC
258 AC_PROG_CPP
259 AC_PROG_INSTALL
260 AC_PROG_LN_S
261 AC_PROG_MAKE_SET
262 AC_PROG_RANLIB
263 AC_CHECK_TOOL(AR, ar, :)
264 AC_PATH_PROG(PERL,"perl")
265 AC_ISC_POSIX
266 AC_SYS_LARGEFILE
267 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
268 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
269 GNUPG_CHECK_FAQPROG
270 GNUPG_CHECK_DOCBOOK_TO_TEXI
271
272
273 try_gettext=yes
274 have_dosish_system=no
275 case "${target}" in
276     *-*-mingw32*)
277         # special stuff for Windoze NT
278         ac_cv_have_dev_random=no
279         AC_DEFINE(USE_ONLY_8DOT3,1,
280                   [set this to limit filenames to the 8.3 format])
281         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
282                   [defined if we must run on a stupid file system])
283         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
284                   [because the Unix gettext has too much overhead on
285                    MingW32 systems and these systems lack Posix functions,
286                    we use a simplified version of gettext])
287         have_dosish_system=yes
288         try_gettext="no"
289         ;;
290     i?86-emx-os2 | i?86-*-os2*emx )
291         # OS/2 with the EMX environment
292         ac_cv_have_dev_random=no
293         AC_DEFINE(HAVE_DRIVE_LETTERS)
294         have_dosish_system=yes
295         try_gettext="no"
296         ;;
297
298     i?86-*-msdosdjgpp*)
299         # DOS with the DJGPP environment
300         ac_cv_have_dev_random=no
301         AC_DEFINE(HAVE_DRIVE_LETTERS)
302         have_dosish_system=yes
303         try_gettext="no"
304         ;;
305
306     *-*-freebsd*)
307        # FreeBSD
308        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
309        LDFLAGS="$LDFLAGS -L/usr/local/lib"
310        ;;
311
312     *-*-hpux*)
313         if test -z "$GCC" ; then
314             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
315         fi
316         ;;
317     *-dec-osf4*)
318         if test -z "$GCC" ; then
319             # Suppress all warnings
320             # to get rid of the unsigned/signed char mismatch warnings.
321             CFLAGS="$CFLAGS -w"
322         fi
323         ;;
324     *-dec-osf5*)
325         if test -z "$GCC" ; then
326             # Use the newer compiler `-msg_disable ptrmismatch' to
327             # get rid of the unsigned/signed char mismatch warnings.
328             # Using this may hide other pointer mismatch warnings, but
329             # it at least lets other warning classes through
330             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
331         fi
332         ;;
333     m68k-atari-mint)
334         ;;
335     *)
336        ;;
337 esac
338
339 if test "$have_dosish_system" = yes; then
340    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
341              [defined if we run on some of the PCDOS like systems 
342               (DOS, Windoze. OS/2) with special properties like
343               no file modes])
344 fi
345 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
346
347
348 #
349 # Checks for libraries.
350 #
351
352 #
353 # libgpg-error is a library with error codes shared between GnuPG
354 # related projects.
355 #
356 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
357                   have_gpg_error=yes,have_gpg_error=no)
358
359
360 #
361 # Libgcrypt is our generic crypto library
362 #
363 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_VERSION",
364         have_libgcrypt=yes,have_libgcrypt=no)
365
366
367 #
368 # libassuan is used for IPC
369 #
370 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
371                   have_libassuan=yes,have_libassuan=no)
372
373
374 #
375 # libksba is our X.509 support library
376 #
377 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
378
379 #
380 # libusb allows us to use the integrated CCID smartcard reader driver.
381
382 # Note, that we need the CVS version.  FIXME: libusb should have a
383 # regular check as the other libraries do.
384
385 AC_CHECK_LIB(usb, usb_find_device,
386               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
387                 AC_DEFINE(HAVE_LIBUSB,1,
388                          [defined if libusb is available])
389              ])
390 AC_SUBST(LIBUSB_LIBS)
391
392
393 #
394 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
395 # build a limited SCdaemon
396 #
397 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
398 if test $have_opensc = yes; then
399   AC_DEFINE(HAVE_OPENSC,1,
400             [defined if the OpenSC library is available])
401 fi
402
403
404 #
405 # Check whether the (highly desirable) GNU Pth library is available
406 #
407 AC_ARG_WITH(pth-prefix,
408             AC_HELP_STRING([--with-pth-prefix=PFX],
409                            [prefix where GNU Pth is installed (optional)]),
410      pth_config_prefix="$withval", pth_config_prefix="")
411 if test x$pth_config_prefix != x ; then
412    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
413 fi
414 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
415 if test "$PTH_CONFIG" = "no"; then
416     AC_MSG_WARN([[
417 ***
418 *** To support concurrent access to the gpg-agent and the SCdaemon
419 *** we need the support of the GNU Portable Threads Library.
420 *** Download it from ftp://ftp.gnu.org/gnu/pth/
421 *** On a Debian GNU/Linux system you might want to try 
422 ***   apt-get install libpth-dev
423 ***]])
424 else
425   GNUPG_PTH_VERSION_CHECK(1.3.7)
426   if test $have_pth = yes; then      
427      PTH_CFLAGS=`$PTH_CONFIG --cflags`
428      PTH_LIBS=`$PTH_CONFIG --ldflags`
429      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
430      AC_DEFINE(USE_GNU_PTH, 1,
431               [Defined if the GNU Portable Thread Library should be used])
432   fi
433 fi
434 AC_SUBST(PTH_CFLAGS)
435 AC_SUBST(PTH_LIBS)
436
437
438 dnl Must check for network library requirements before doing link tests
439 dnl for ldap, for example. If ldap libs are static (or dynamic and without
440 dnl ELF runtime link paths), then link will fail and LDAP support won't
441 dnl be detected.
442
443 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
444         [NETLIBS="-lnsl $NETLIBS"]))
445 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
446         [NETLIBS="-lsocket $NETLIBS"]))
447
448 dnl Now try for the resolver functions so we can use DNS SRV
449
450 AC_ARG_ENABLE(dns-srv,
451    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
452    use_dns_srv=$enableval,use_dns_srv=yes)
453
454 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
455   _srv_save_libs=$LIBS
456   LIBS=""
457   # the double underscore thing is a glibc-ism?
458   AC_SEARCH_LIBS(res_query,resolv bind,,
459                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
460   AC_SEARCH_LIBS(dn_expand,resolv bind,,
461                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
462   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
463                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
464
465   if test x"$use_dns_srv" = xyes ; then
466      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
467      SRVLIBS=$LIBS
468   else
469      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
470   fi
471   LIBS=$_srv_save_libs
472 fi
473
474 AC_SUBST(SRVLIBS)
475
476 # Try and link a LDAP test program to weed out unusable LDAP
477 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
478 # general is terrible with creating weird dependencies.  If all else
479 # fails, the user can play guess-the-dependency by using something
480 # like ./configure LDAPLIBS="-Lfoo -lbar"
481
482 if test "$try_ldap" = yes ; then
483   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
484     _ldap_save_libs=$LIBS
485     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
486
487     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
488     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
489                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
490     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
491
492     if test $gnupg_cv_func_ldap_init = no; then
493       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
494       AC_TRY_LINK([#include <lber.h>
495 #include <ldap.h>],[ldap_open("foobar",1234);],
496          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
497       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
498     fi
499
500     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
501        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
502     fi
503
504     if test "$gnupg_cv_func_ldap_init" = yes || \
505         test "$gnupg_cv_func_ldaplber_init" = yes ; then
506        LDAPLIBS=$MY_LDAPLIBS
507        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
508
509        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
510
511        if test "$gnupg_cv_func_ldap_init" = yes ; then
512           AC_TRY_LINK([#include <ldap.h>],
513              [ldap_get_option((void *)0,0,(void *)0);],
514              [gnupg_cv_func_ldap_get_option=yes],
515              [gnupg_cv_func_ldap_get_option=no])
516         else
517           AC_TRY_LINK([#include <lber.h>
518 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
519              [gnupg_cv_func_ldap_get_option=yes],
520              [gnupg_cv_func_ldap_get_option=no])
521        fi
522
523        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
524
525        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
526           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
527        else
528           AC_MSG_CHECKING([whether LDAP supports ld_errno])
529
530           if test "$gnupg_cv_func_ldap_init" = yes ; then
531             AC_TRY_COMPILE([#include <ldap.h>],
532                [LDAP *ldap; ldap->ld_errno;],
533                [gnupg_cv_func_ldap_ld_errno=yes],
534                [gnupg_cv_func_ldap_ld_errno=no])
535            else
536             AC_TRY_LINK([#include <lber.h>
537 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
538                [gnupg_cv_func_ldap_ld_errno=yes],
539                [gnupg_cv_func_ldap_ld_errno=no])
540           fi
541
542           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
543
544           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
545              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
546           fi
547        fi
548     fi
549
550     LIBS=$_ldap_save_libs
551
552     if test "$GPGKEYS_LDAP" != "" ; then break; fi
553   done
554 fi
555
556 AC_SUBST(GPGKEYS_LDAP)
557 AC_SUBST(LDAPLIBS)
558
559 dnl This isn't necessarily sendmail itself, but anything that gives a
560 dnl sendmail-ish interface to the outside world.  That includes qmail,
561 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
562
563 if test "$try_mailto" = yes ; then
564   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
565
566   if test "$with_mailprog" = yes ; then
567     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
568     if test "$ac_cv_path_SENDMAIL" ; then
569       GPGKEYS_MAILTO="gpgkeys_mailto"
570     fi
571   elif test "$with_mailprog" != no ; then
572     AC_MSG_CHECKING([for a mail transport program])
573     AC_SUBST(SENDMAIL,$with_mailprog)
574     AC_MSG_RESULT($with_mailprog)
575     GPGKEYS_MAILTO="gpgkeys_mailto"
576   fi
577 fi
578
579 AC_SUBST(GPGKEYS_MAILTO)
580
581 case "${target}" in
582     *-*-mingw32*)
583         PRINTABLE_OS_NAME="MingW32"
584         ;;
585     *-*-cygwin*)
586         PRINTABLE_OS_NAME="Cygwin"
587         ;;
588     i?86-emx-os2 | i?86-*-os2*emx )
589         PRINTABLE_OS_NAME="OS/2"
590         ;;
591     i?86-*-msdosdjgpp*)
592         PRINTABLE_OS_NAME="MSDOS/DJGPP"
593         try_dynload=no
594         ;;
595     *-linux*)
596         PRINTABLE_OS_NAME="GNU/Linux"
597         ;;
598 dnl let that after linux to avoid gnu-linux problems
599     *-gnu*)
600         PRINTABLE_OS_NAME="GNU/Hurd"
601         ;;
602     *)
603         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
604         ;;
605 esac
606 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
607                    [A human readable text with the name of the OS])
608
609
610 if test "$try_gettext" = yes; then
611   AM_GNU_GETTEXT(,[need-ngettext])
612
613   # gettext requires some extra checks.  These really should be part of
614   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
615   # function checks to here.
616
617   AC_CHECK_FUNCS(strchr)
618 else
619   USE_NLS=no
620   USE_INCLUDED_LIBINTL=no
621   BUILD_INCLUDED_LIBINTL=no
622   AC_SUBST(USE_NLS)
623   AC_SUBST(USE_INCLUDED_LIBINTL)
624   AC_SUBST(BUILD_INCLUDED_LIBINTL)
625 fi
626
627 # Checks for header files.
628 AC_HEADER_STDC
629 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
630
631 # Checks for typedefs, structures, and compiler characteristics.
632 AC_C_CONST
633 AC_C_INLINE
634 AC_TYPE_SIZE_T
635 AC_TYPE_SIGNAL
636 AC_DECL_SYS_SIGLIST
637
638 GNUPG_CHECK_ENDIAN
639
640 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
641 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
642 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
643 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
644 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
645
646 AC_CHECK_SIZEOF(unsigned short)
647 AC_CHECK_SIZEOF(unsigned int)
648 AC_CHECK_SIZEOF(unsigned long)
649 AC_CHECK_SIZEOF(unsigned long long)
650 AC_CHECK_SIZEOF(uint64_t)
651
652 if test "$ac_cv_sizeof_unsigned_short" = "0" \
653    || test "$ac_cv_sizeof_unsigned_int" = "0" \
654    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
655     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
656 fi
657
658 dnl Do we have any 64-bit data types?
659 if test "$ac_cv_sizeof_unsigned_int" != "8" \
660    && test "$ac_cv_sizeof_unsigned_long" != "8" \
661    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
662    && test "$ac_cv_sizeof_uint64_t" != "8"; then
663     AC_MSG_WARN([No 64-bit types.  Disabling TIGER/192, SHA-384, and SHA-512])
664 else
665   if test x"$use_tiger192" = xyes ; then
666      AC_SUBST(TIGER_O,tiger.o)
667      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
668   fi
669
670   if test "$use_old_tiger192" = yes ; then
671      AC_SUBST(TIGER_O,tiger.o)
672      AC_DEFINE(USE_TIGER192,1,[Define to include the TIGER/192 digest])
673      AC_DEFINE(USE_OLD_TIGER,1,[Define to use the old fake OID for TIGER/192 digest support])
674   fi
675
676   if test x"$use_sha512" = xyes ; then
677      AC_SUBST(SHA512_O,sha512.o)
678      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
679   fi
680 fi
681
682 GNUPG_SYS_SO_PEERCRED
683
684 # Checks for library functions.
685 AC_FUNC_FSEEKO
686 AC_FUNC_VPRINTF
687 AC_FUNC_FORK
688 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
689 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times)
690 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
691 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
692 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat)
693
694 # These are needed by libjnlib - fixme: we should have a macros for them
695 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
696 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
697 AC_CHECK_FUNCS(flockfile funlockfile)
698
699 AC_REPLACE_FUNCS(vasprintf)
700 AC_REPLACE_FUNCS(fopencookie)
701 AC_REPLACE_FUNCS(mkdtemp)
702 AC_REPLACE_FUNCS(fseeko ftello)
703 AC_REPLACE_FUNCS(isascii)
704 AC_REPLACE_FUNCS(putc_unlocked)
705
706 #
707 # check for gethrtime and run a testprogram to see whether
708 # it is broken.  It has been reported that some Solaris and HP UX systems 
709 # raise an SIGILL
710 #
711 AC_CACHE_CHECK([for gethrtime], 
712                [gnupg_cv_func_gethrtime],
713                [AC_TRY_LINK([#include <sys/times.h>],[
714                    hrtime_t tv;
715                    tv = gethrtime();
716                  ],
717                  [gnupg_cv_func_gethrtime=yes],
718                  [gnupg_cv_func_gethrtime=no])
719                ])
720 if test $gnupg_cv_func_gethrtime = yes; then
721      AC_DEFINE([HAVE_GETHRTIME], 1,
722                [Define if you have the `gethrtime(2)' function.])
723      AC_CACHE_CHECK([whether gethrtime is broken], 
724                [gnupg_cv_func_broken_gethrtime],
725                [AC_TRY_RUN([
726                    #include <sys/times.h>
727                    int main () {
728                    hrtime_t tv;
729                    tv = gethrtime(); 
730                  }
731                  ],
732                  [gnupg_cv_func_broken_gethrtime=no],
733                  [gnupg_cv_func_broken_gethrtime=yes],
734                  [gnupg_cv_func_broken_gethrtime=assume-no])
735                 ])
736     if test $gnupg_cv_func_broken_gethrtime = yes; then
737       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
738       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
739     fi
740 fi
741      
742
743 GNUPG_CHECK_MLOCK
744 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
745
746 dnl
747 dnl Check whether we can use Linux capabilities as requested
748 dnl
749 if test "$use_capabilities" = "yes" ; then
750 use_capabilities=no
751 AC_CHECK_HEADERS(sys/capability.h)
752 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
753   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
754   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
755      AC_DEFINE(USE_CAPABILITIES,1,
756                [define if capabilities should be used])
757      AC_SUBST(CAPLIBS,"-lcap")
758      use_capabilities=yes
759   fi
760 fi
761 if test "$use_capabilities" = "no" ; then
762     AC_MSG_WARN([[
763 ***
764 *** The use of capabilities on this system is not possible.
765 *** You need a recent Linux kernel and some patches:
766 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
767 ***   fcap-module-990613.tar.gz     (kernel module)
768 ***   libcap-1.92.tar.gz            (user mode library and utilities)
769 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
770 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
771 ***]])
772 fi
773 fi
774
775
776 # Sanity check regex.  Tests adapted from mutt.
777
778 AC_MSG_CHECKING([whether regular expression support is requested])
779 AC_ARG_ENABLE(regex,
780 [  --disable-regex         do not handle regular expressions in trust sigs],
781      use_regex=$enableval, use_regex=yes)
782 AC_MSG_RESULT($use_regex)
783
784 if test "$use_regex" = yes ; then
785   AC_MSG_CHECKING([whether the included regex lib is requested])
786   AC_ARG_WITH(included-regex,
787       [  --with-included-regex   use the included GNU regex library],
788       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
789   AC_MSG_RESULT($gnupg_cv_included_regex)
790
791   if test $gnupg_cv_included_regex = no ; then
792      # Does the system have regex functions at all?
793      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
794                            gnupg_cv_included_regex=yes)
795   fi
796
797   if test $gnupg_cv_included_regex = no ; then
798      AC_CACHE_CHECK([whether your system's regexp library is broken],
799        [gnupg_cv_regex_broken],
800        AC_TRY_RUN([
801 #include <unistd.h>
802 #include <regex.h>
803 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
804        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
805
806      if test $gnupg_cv_regex_broken = yes ; then
807       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
808       gnupg_cv_included_regex=yes
809      fi
810   fi
811
812   if test $gnupg_cv_included_regex = yes; then
813      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
814      AC_SUBST(REGEX_O,regex.o)
815   fi
816 else
817
818   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
819 fi
820
821 dnl Do we have zlib? Must do it here because Solaris failed
822 dnl when compiling a conftest (due to the "-lz" from LIBS).
823 use_local_zlib=yes
824 if test "$g10_force_zlib" = "yes"; then
825   :
826 else
827   _cppflags="${CPPFLAGS}"
828   _ldflags="${LDFLAGS}"
829
830   AC_ARG_WITH(zlib,
831   [  --with-zlib=DIR         use libz in DIR],[
832     if test -d "$withval"; then
833       CPPFLAGS="${CPPFLAGS} -I$withval/include"
834       LDFLAGS="${LDFLAGS} -L$withval/lib"
835     fi
836   ])
837
838   AC_CHECK_HEADER(zlib.h,
839       AC_CHECK_LIB(z, deflateInit2_,
840        use_local_zlib=no
841        LIBS="$LIBS -lz",
842        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
843        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
844 fi
845  
846 if test "$use_local_zlib" = yes ; then
847     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
848     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
849     ZLIBS="../zlib/libzlib.a"
850 else
851     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
852     ZLIBS=
853 fi
854 AC_SUBST(ZLIBS)
855
856 # Allow users to append something to the version string without
857 # flagging it as development version.  The user version parts is
858 # considered everything after a dash. 
859 if test "$development_version" != yes; then
860   changequote(,)dnl
861   tmp_pat='[a-zA-Z]'
862   changequote([,])dnl
863   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
864     development_version=yes
865   fi
866 fi
867 if test "$development_version" = yes; then
868     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
869             [Defined if this is not a regular release])
870 fi
871
872 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
873
874 GNUPG_CHECK_GNUMAKE
875
876 # add some extra libs here so that previous tests don't fail for
877 # mysterious reasons - the final link step should bail out. 
878 case "${target}" in
879     *-*-mingw32*)
880         LIBS="$LIBS -lwsock32"
881         ;;
882     *)
883        ;;
884 esac
885
886
887 if test "$GCC" = yes; then
888     if test "$USE_MAINTAINER_MODE" = "yes"; then
889         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
890     else
891         CFLAGS="$CFLAGS -Wall"
892     fi
893 fi
894
895 AC_SUBST(NETLIBS)
896
897
898 # We use jnlib, so tell other modules about it
899 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
900         [Defined if jnlib style logging fucntions are available])
901
902
903
904
905 #
906 # Print errors here so that they are visible all
907 # together and the user can acquire them all together.
908 #
909 die=no
910 if test "$have_gpg_error" = "no"; then
911    die=yes
912    AC_MSG_NOTICE([[
913 ***  
914 *** You need libgpg-error to build this program.
915 **  This library is for example available at
916 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgpg-error
917 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
918 ***]])
919 fi
920 if test "$have_libgcrypt" = "no"; then
921    die=yes
922    AC_MSG_NOTICE([[
923 ***  
924 *** You need libgcrypt to build this program.
925 **  This library is for example available at
926 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgcrypt/
927 *** (at least version $NEED_LIBGCRYPT_VERSION is required.)
928 ***]])
929 fi
930 if test "$have_libassuan" = "no"; then
931    die=yes
932    AC_MSG_NOTICE([[
933 ***
934 *** You need libassuan to build this program.
935 *** This library is for example available at
936 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/libassuan/
937 *** (at least version $NEED_LIBASSUAN_VERSION is required).
938 ***]])
939 fi
940 if test "$have_ksba" = "no"; then
941    die=yes
942     AC_MSG_NOTICE([[
943 ***
944 *** You need libksba to build this program.
945 *** This library is for example available at
946 ***   ftp://ftp.gnupg.org/pub/gcrypt/alpha/aegypten/
947 *** (at least version $NEED_KSBA_VERSION is required).
948 ***]])
949 fi
950
951 if test "$die" = "yes"; then
952     AC_MSG_ERROR([[
953 ***
954 *** Required libraries not found. Please consult the above messages
955 *** and install them before running configure again.
956 ***]])
957 fi
958
959
960 #
961 # Decide what to build
962 #
963 if test $have_ksba = no; then
964   build_gpgsm=no
965   build_scdaemon=no
966 fi
967
968 build_agent_threaded=""
969 if test "$build_agent" = "yes"; then
970   if test $have_pth = no; then
971      build_agent_threaded="(not multi-threaded)"
972   fi
973 fi
974
975 build_scdaemon_extra=""
976 if test "$build_scdaemon" = "yes"; then
977   tmp=""
978   if test $have_pth = no; then
979      build_scdaemon_extra="not multi-threaded"
980      tmp=", "
981   fi
982   if test $have_opensc = no; then
983      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
984      tmp=", "
985   fi      
986   if test -n "$build_scdaemon_extra"; then
987      build_scdaemon_extra="(${build_scdaemon_extra})"
988   fi
989 fi
990
991
992 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
993 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
994 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
995 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
996
997
998 AC_CONFIG_COMMANDS(g10defs.h,[[
999 cat >g10defs.tmp <<G10EOF
1000 /* Generated automatically by configure */
1001 /* FIXME: Shouldn't we replace GNUPG_HOMEDIR by GNUPG_DEFAULT_HOMEDIR
1002    and we propably can get rid of g10defs.h */
1003 #ifdef HAVE_DRIVE_LETTERS
1004 /*#define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"*/
1005 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1006 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1007 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1008 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1009 #else
1010 /*#define G10_LOCALEDIR     "${datadir}/locale"*/
1011 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1012 #define GNUPG_DATADIR     "${datadir}/gnupg"
1013 #ifdef __VMS
1014 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1015 #else
1016 #define GNUPG_HOMEDIR "~/.gnupg" 
1017 #endif
1018 #endif
1019 /* those are here to be redefined by handcrafted g10defs.h.
1020    Please note that the string version must not contain more
1021    than one character because the using code assumes strlen()==1 */
1022 #ifdef HAVE_DOSISH_SYSTEM
1023 #define DIRSEP_C '\\\\'
1024 #define EXTSEP_C '.'
1025 #define DIRSEP_S "\\\\"
1026 #define EXTSEP_S "."
1027 #else
1028 #define DIRSEP_C '/'
1029 #define EXTSEP_C '.'
1030 #define DIRSEP_S "/"
1031 #define EXTSEP_S "."
1032 #endif
1033 /* This is the same as VERSION, but should be overridden if the
1034    platform cannot handle things like dots '.' in filenames. */
1035 #define SAFE_VERSION VERSION
1036 G10EOF
1037 ## Do we really need the following?  It defines BYTES_PER-MPI_LIMB
1038 ## cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1039 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1040     echo "g10defs.h is unchanged"
1041     rm -f g10defs.tmp
1042 else
1043     rm -f g10defs.h
1044     mv g10defs.tmp g10defs.h
1045     echo "g10defs.h created"
1046 fi
1047 ]],[[
1048 prefix=$prefix
1049 exec_prefix=$exec_prefix
1050 libdir=$libdir
1051 libexecdir=$libexecdir
1052 datadir=$datadir
1053 DATADIRNAME=$DATADIRNAME
1054 ]])
1055
1056 AC_CONFIG_FILES([ m4/Makefile 
1057 Makefile
1058 po/Makefile.in
1059 intl/Makefile
1060 jnlib/Makefile
1061 common/Makefile
1062 kbx/Makefile
1063 g10/Makefile
1064 sm/Makefile
1065 agent/Makefile
1066 scd/Makefile
1067 doc/Makefile
1068 ])
1069 AC_OUTPUT
1070 #tests/Makefile
1071
1072
1073 echo "
1074         GnuPG v${VERSION} has been configured as follows:
1075         
1076         Platform:  $PRINTABLE_OS_NAME ($target)
1077
1078         OpenPGP:   $build_gpg
1079         S/MIME:    $build_gpgsm
1080         Agent:     $build_agent $build_agent_threaded
1081         Smartcard: $build_scdaemon $build_scdaemon_extra
1082
1083         Protect tool:     $gnupg_protect_tool
1084         Default agent:    $gnupg_agent_pgm
1085         Default pinentry: $gnupg_pinentry_pgm
1086         Default scdaemon: $gnupg_scdaemon_pgm
1087         Default dirmngr:  $gnupg_dirmngr_pgm
1088 "
1089