Some cleanup so we don't build files that are completely ifdeffed out.
[gnupg.git] / configure.ac
1 dnl configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
3 dnl               2005 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, 
20 dnl MA 02110-1301, USA
21 dnl
22 dnl (Process this file with autoconf to produce a configure script.)
23
24 AC_PREREQ(2.59)
25 min_automake_version="1.9.3"
26
27 # Remember to change the version number immediately *after* a release
28 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
29 AC_INIT(gnupg, 1.4.3-cvs, bug-gnupg@gnu.org)
30 # Set development_version to yes if the minor number is odd or you
31 # feel that the default check for a development version is not
32 # sufficient.
33 development_version=no
34
35 AC_CONFIG_AUX_DIR(scripts)
36 AC_CONFIG_SRCDIR(g10/gpg.c)
37 AC_CANONICAL_HOST
38 AM_INIT_AUTOMAKE([std-options])
39 AM_CONFIG_HEADER(config.h)
40
41 AC_GNU_SOURCE
42
43 dnl
44 dnl  Check for random module options
45 dnl
46 AC_MSG_CHECKING([which random module to use])
47 AC_ARG_ENABLE(static-rnd,
48     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
49 [use_static_rnd=$enableval], [use_static_rnd=default] )
50
51 if test "$use_static_rnd" = no; then
52     use_static_rnd=default
53 fi
54
55 case "$use_static_rnd" in
56     egd | linux | unix | default )
57       AC_MSG_RESULT($use_static_rnd)
58       ;;
59     auto )
60       AC_MSG_RESULT(automagically selected at runtime)
61       ;;
62     * )
63       AC_MSG_RESULT(invalid argument)
64       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
65       ;;
66 esac
67
68 AC_ARG_WITH(egd-socket,
69     [  --with-egd-socket=NAME  use NAME for the EGD socket],
70             egd_socket_name="$withval", egd_socket_name="" )
71 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
72                    [Define if you don't want the default EGD socket name.
73                     For details see cipher/rndegd.c])
74
75
76 dnl
77 dnl See whether the user wants to disable checking for /dev/random
78
79 AC_MSG_CHECKING([whether use of /dev/random is requested])
80 AC_ARG_ENABLE(dev-random,
81 [  --disable-dev-random    disable the use of dev random],
82     try_dev_random=$enableval, try_dev_random=yes)
83 AC_MSG_RESULT($try_dev_random)
84
85
86 dnl
87 dnl  Check other options
88 dnl
89
90 AC_MSG_CHECKING([whether assembler modules are requested])
91 AC_ARG_ENABLE(asm,
92 [  --disable-asm           do not use assembler modules],
93      try_asm_modules=$enableval, try_asm_modules=yes)
94 AC_MSG_RESULT($try_asm_modules)
95
96 AC_MSG_CHECKING([whether memory guard is requested])
97 AC_ARG_ENABLE(m-guard,
98     [  --enable-m-guard        enable memory guard facility],
99     use_m_guard=$enableval, use_m_guard=no)
100 AC_MSG_RESULT($use_m_guard)
101 if test "$use_m_guard" = yes ; then
102     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
103 fi
104
105 # We don't have a test to check whether as(1) knows about the
106 # non executable stack option.  Thus we provide an option to enable
107 # it.
108 AC_MSG_CHECKING([whether non excutable stack support is requested])
109 AC_ARG_ENABLE(noexecstack,
110               AC_HELP_STRING([--enable-noexecstack],
111                              [enable non executable stack support (gcc only)]),
112               noexecstack_support=$enableval, noexecstack_support=no)
113 AC_MSG_RESULT($noexecstack_support)
114
115 # SELinux support includes tracking of sensitive files to avoid
116 # leaking their contents through processing these files by gpg itself
117 AC_MSG_CHECKING([whether SELinux support is requested])
118 AC_ARG_ENABLE(selinux-support,
119               AC_HELP_STRING([--enable-selinux-support],
120                              [enable SELinux support]),
121               selinux_support=$enableval, selinux_support=no)
122 AC_MSG_RESULT($selinux_support)
123
124
125 AC_MSG_CHECKING([whether the new iconv based code is requested])
126 AC_ARG_ENABLE(gnupg-iconv,
127               AC_HELP_STRING([--disable-gnupg-iconv],
128                              [disable the new iconv code]),
129               gnupg_use_iconv=$enableval, gnupg_use_iconv=yes)
130 AC_MSG_RESULT($gnupg_use_iconv)
131
132 dnl See if we are disabling any algorithms or features for a smaller
133 dnl binary
134
135 try_extensions=no
136
137 use_rsa=yes
138 use_idea=yes
139 use_cast5=yes
140 use_blowfish=yes
141 use_aes=yes
142 use_twofish=yes
143 use_sha256=yes
144 use_sha512=yes
145 use_bzip2=yes
146 use_exec=yes
147 card_support=yes
148 agent_support=yes
149 disable_keyserver_path=no
150
151 AC_ARG_ENABLE(minimal,
152    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
153    use_rsa=no
154    use_idea=no
155    use_cast5=no
156    use_blowfish=no
157    use_aes=no
158    use_twofish=no
159    use_sha256=no
160    use_sha512=no
161    use_bzip2=no
162    use_exec=no
163    card_support=no
164    agent_support=no)
165
166
167 AC_MSG_CHECKING([whether OpenPGP card support is requested])
168 AC_ARG_ENABLE(card-support,
169               AC_HELP_STRING([--disable-card-support],
170                              [disable OpenPGP card support]),
171               card_support=$enableval)
172 AC_MSG_RESULT($card_support)
173
174
175 # Note that we may later disable the agent support based on the platform.
176 AC_MSG_CHECKING([whether gpg-agent support is requested])
177 AC_ARG_ENABLE(agent-support,
178               AC_HELP_STRING([--disable-agent-support],
179                              [disable gpg-agent support]),
180               agent_support=$enableval)
181 AC_MSG_RESULT($agent_support)
182
183
184 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
185 AC_ARG_ENABLE(rsa,
186    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
187    use_rsa=$enableval)
188 AC_MSG_RESULT($use_rsa)
189 if test x"$use_rsa" = xyes ; then
190    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the IDEA cipher])
194 AC_ARG_ENABLE(idea,
195    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
196    use_idea=$enableval)
197 AC_MSG_RESULT($use_idea)
198 if test x"$use_idea" = xyes ; then
199    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
200
201 # We don't need idea but some people claim that they need it for
202 # research etc., so we allow to place an idea source code into the
203 # cipher directory and statically link it if available, otherwise we
204 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
205
206    AC_MSG_CHECKING([for idea cipher module])
207    tmp=""
208    if test -f $srcdir/cipher/idea.c; then 
209       IDEA_O=idea.o
210       tmp=idea
211    else
212       IDEA_O=idea-stub.o
213       tmp=no
214       try_extensions=yes
215    fi
216    AC_SUBST(IDEA_O)
217    AC_MSG_RESULT($tmp)
218 fi
219
220 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
221 AC_ARG_ENABLE(cast5,
222    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
223    use_cast5=$enableval)
224 AC_MSG_RESULT($use_cast5)
225 if test x"$use_cast5" = xyes ; then
226    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
227 fi
228
229 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
230 AC_ARG_ENABLE(blowfish,
231    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
232    use_blowfish=$enableval)
233 AC_MSG_RESULT($use_blowfish)
234 if test x"$use_blowfish" = xyes ; then
235    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
236 fi
237
238 AC_MSG_CHECKING([whether to enable the AES ciphers])
239 AC_ARG_ENABLE(aes,
240    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
241    use_aes=$enableval)
242 AC_MSG_RESULT($use_aes)
243 if test x"$use_aes" = xyes ; then
244    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
245 fi
246
247 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
248 AC_ARG_ENABLE(twofish,
249    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
250    use_twofish=$enableval)
251 AC_MSG_RESULT($use_twofish)
252 if test x"$use_twofish" = xyes ; then
253    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
254 fi
255
256 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
257 AC_ARG_ENABLE(sha256,
258    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
259    use_sha256=$enableval)
260 AC_MSG_RESULT($use_sha256)
261 if test x"$use_sha256" = xyes ; then
262    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
263 fi
264
265 dnl SHA512 is defined only after we confirm 64-bit support later
266 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
267 AC_ARG_ENABLE(sha512,
268    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
269    use_sha512=$enableval)
270 AC_MSG_RESULT($use_sha512)
271
272 dnl BZLIB is defined only after we confirm the library is available later
273 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
274 AC_ARG_ENABLE(bzip2,
275    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
276    use_bzip2=$enableval)
277 AC_MSG_RESULT($use_bzip2)
278
279 AC_MSG_CHECKING([whether to enable external program execution])
280 AC_ARG_ENABLE(exec,
281     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
282     use_exec=$enableval)
283 AC_MSG_RESULT($use_exec)
284 if test "$use_exec" = no ; then
285     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
286 fi
287
288 if test "$use_exec" = yes ; then
289   AC_MSG_CHECKING([whether to enable photo ID viewing])
290   AC_ARG_ENABLE(photo-viewers,
291       [  --disable-photo-viewers disable photo ID viewers],
292       [if test "$enableval" = no ; then
293          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
294       fi],enableval=yes)
295   gnupg_cv_enable_photo_viewers=$enableval
296   AC_MSG_RESULT($enableval)
297
298   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
299     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
300     AC_ARG_WITH(photo-viewer,
301         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
302         [if test "$withval" = yes ; then
303            withval=no
304         elif test "$withval" != no ; then
305            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
306                             [if set, restrict photo-viewer to this])
307         fi],withval=no)
308     AC_MSG_RESULT($withval)
309   fi
310
311   AC_MSG_CHECKING([whether to enable external keyserver helpers])
312   AC_ARG_ENABLE(keyserver-helpers,
313       [  --disable-keyserver-helpers  disable all external keyserver support],
314       [if test "$enableval" = no ; then
315          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
316                   [define to disable keyserver helpers])
317       fi],enableval=yes)
318   gnupg_cv_enable_keyserver_helpers=$enableval
319   AC_MSG_RESULT($enableval)
320
321   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
322 dnl LDAP is defined only after we confirm the library is available later
323     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
324     AC_ARG_ENABLE(ldap,
325       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
326       try_ldap=$enableval, try_ldap=yes)
327     AC_MSG_RESULT($try_ldap)
328
329     AC_MSG_CHECKING([whether HKP keyserver support is requested])
330     AC_ARG_ENABLE(hkp,
331       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
332       try_hkp=$enableval, try_hkp=yes)
333     AC_MSG_RESULT($try_hkp)
334
335     AC_MSG_CHECKING([whether finger key fetching support is requested])
336     AC_ARG_ENABLE(finger,
337       AC_HELP_STRING([--disable-finger],
338         [disable finger key fetching interface only]),
339       try_finger=$enableval, try_finger=yes)
340     AC_MSG_RESULT($try_finger)
341
342     AC_MSG_CHECKING([whether email keyserver support is requested])
343     AC_ARG_ENABLE(mailto,
344       AC_HELP_STRING([--enable-mailto],
345         [enable email keyserver interface only]),
346       try_mailto=$enableval, try_mailto=no)
347     AC_MSG_RESULT($try_mailto)
348     fi
349
350     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
351     AC_ARG_ENABLE(keyserver-path,
352       AC_HELP_STRING([--disable-keyserver-path],
353         [disable the exec-path option for keyserver helpers]),
354       [if test "$enableval" = no ; then
355          disable_keyserver_path=yes
356       fi],enableval=yes)
357     AC_MSG_RESULT($enableval)
358   fi
359
360 AC_MSG_CHECKING([whether the included zlib is requested])
361 AC_ARG_WITH(included-zlib,
362     [  --with-included-zlib    use the zlib code included here],
363 [g10_force_zlib="$withval"], [g10_force_zlib=no] )
364 AC_MSG_RESULT($g10_force_zlib)
365
366 dnl
367 dnl Check for the key/uid cache size.  This can't be zero, but can be
368 dnl pretty small on embedded systems.
369 dnl
370 AC_MSG_CHECKING([for the size of the key and uid cache])
371 AC_ARG_ENABLE(key-cache,
372         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
373
374 if test "$enableval" = "no"; then
375    enableval=5
376 elif test "$enableval" = "yes" || test "$enableval" = ""; then
377    enableval=4096
378 fi
379
380 changequote(,)dnl
381 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
382 changequote([,])dnl
383
384 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
385    AC_MSG_ERROR([invalid key-cache size])
386 fi
387
388 AC_MSG_RESULT($key_cache_size)
389 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
390
391 dnl
392 dnl Check whether we want to use Linux capabilities
393 dnl
394 AC_MSG_CHECKING([whether use of capabilities is requested])
395 AC_ARG_WITH(capabilities,
396     [  --with-capabilities     use linux capabilities [default=no]],
397 [use_capabilities="$withval"],[use_capabilities=no])
398 AC_MSG_RESULT($use_capabilities)
399
400 # To avoid double inclusion of config.h which might happen at some
401 # places, we add the usual double inclusion protection.
402 AH_TOP([
403 #ifndef GNUPG_CONFIG_H_INCLUDED
404 #define GNUPG_CONFIG_H_INCLUDED
405 ])
406
407 AH_BOTTOM([
408 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
409 #define EXEC_TEMPFILE_ONLY
410 #endif
411
412 /* This is the major version number of GnuPG so that
413    source included files can test for this. */
414 #define GNUPG_MAJOR_VERSION 1
415
416 #include "g10defs.h"
417
418 #endif /*GNUPG_CONFIG_H_INCLUDED*/
419 ])
420
421 AM_MAINTAINER_MODE
422
423 dnl Checks for programs.
424
425 AC_PROG_MAKE_SET
426 AM_SANITY_CHECK
427 missing_dir=`cd $ac_aux_dir && pwd`
428 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
429 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
430 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
431 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
432 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
433 AC_PROG_CC
434 AC_PROG_CPP
435 AC_PROG_RANLIB
436 AC_CHECK_TOOL(AR, ar, :)
437 AC_PATH_PROG(PERL,"perl")
438 AC_ISC_POSIX
439 AC_SYS_LARGEFILE
440 AC_PROG_INSTALL
441 AC_PROG_AWK
442 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
443 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
444 GNUPG_CHECK_FAQPROG
445 GNUPG_CHECK_DOCBOOK_TO_TEXI
446 GNUPG_CHECK_USTAR
447
448 MPI_OPT_FLAGS=""
449
450 try_gettext=yes
451 have_dosish_system=no
452 need_dlopen=yes
453 case "${host}" in
454     *-mingw32*)
455         # special stuff for Windoze NT
456         ac_cv_have_dev_random=no
457         AC_DEFINE(USE_ONLY_8DOT3,1,
458                   [set this to limit filenames to the 8.3 format])
459         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
460                   [defined if we must run on a stupid file system])
461         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
462                   [because the Unix gettext has too much overhead on
463                    MingW32 systems and these systems lack Posix functions,
464                    we use a simplified version of gettext])
465         AC_DEFINE(HAVE_W32_SYSTEM,1,
466                   [Defined if we run on a W32 API based system])
467         disable_keyserver_path=yes
468         have_dosish_system=yes
469         need_dlopen=no
470         try_gettext="no"
471         agent_support=no
472         use_simple_gettext=yes
473         have_w32_system=yes
474         ;;
475     i?86-emx-os2 | i?86-*-os2*emx )
476         # OS/2 with the EMX environment
477         ac_cv_have_dev_random=no
478         AC_DEFINE(HAVE_DRIVE_LETTERS)
479         have_dosish_system=yes
480         try_gettext="no"
481         agent_support=no
482         ;;
483
484     i?86-*-msdosdjgpp*)
485         # DOS with the DJGPP environment
486         ac_cv_have_dev_random=no
487         AC_DEFINE(HAVE_DRIVE_LETTERS)
488         have_dosish_system=yes
489         try_gettext="no"
490         agent_support=no
491         ;;
492
493     *-*-hpux*)
494         if test -z "$GCC" ; then
495             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
496         fi
497         ;;
498     *-dec-osf4*)
499         if test -z "$GCC" ; then
500             # Suppress all warnings
501             # to get rid of the unsigned/signed char mismatch warnings.
502             CFLAGS="$CFLAGS -w"
503         fi
504         ;;
505     *-dec-osf5*)
506         if test -z "$GCC" ; then
507             # Use the newer compiler `-msg_disable ptrmismatch' to
508             # get rid of the unsigned/signed char mismatch warnings.
509             # Using this may hide other pointer mismatch warnings, but
510             # it at least lets other warning classes through
511             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
512         fi
513         ;;
514     m68k-atari-mint)
515         ;;
516     *)
517        ;;
518 esac
519
520 if test "$have_dosish_system" = yes; then
521    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
522              [defined if we run on some of the PCDOS like systems 
523               (DOS, Windoze. OS/2) with special properties like
524               no file modes])
525 fi
526 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
527
528 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
529 AM_CONDITIONAL(HAVE_W32_SYSTEM, test x"$have_w32_system" = xyes)
530
531 if test "$disable_keyserver_path" = yes; then
532     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
533               [define to disable exec-path for keyserver helpers])
534 fi
535
536 AC_SUBST(MPI_OPT_FLAGS)
537 GNUPG_SYS_SYMBOL_UNDERSCORE
538
539 dnl These need to go after AC_PROG_CC so that $EXEEXT is defined
540 if test x"$try_hkp" = xyes ; then
541   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
542 fi
543
544 if test x"$try_finger" = xyes ; then
545   AC_SUBST(GPGKEYS_FINGER,"gpgkeys_finger$EXEEXT")
546 fi
547
548 dnl Must check for network library requirements before doing link tests
549 dnl for ldap, for example. If ldap libs are static (or dynamic and without
550 dnl ELF runtime link paths), then link will fail and LDAP support won't
551 dnl be detected.
552
553 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
554         [NETLIBS="-lnsl $NETLIBS"]))
555 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
556         [NETLIBS="-lsocket $NETLIBS"]))
557
558 dnl Now try for the resolver functions so we can use DNS SRV and our 
559 dnl PKA feature.
560
561 AC_ARG_ENABLE(dns-srv,
562    AC_HELP_STRING([--disable-dns-srv],
563         [disable the use of DNS SRV in HKP and HTTP]),
564    use_dns_srv=$enableval,use_dns_srv=yes)
565
566 if (test x"$try_hkp" = xyes || test x"$try_http" = xyes) && test x"$use_dns_srv" = xyes ; then
567   _srv_save_libs=$LIBS
568   LIBS=""
569   # the double underscore thing is a glibc-ism?
570   AC_SEARCH_LIBS(res_query,resolv bind,,
571                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
572   AC_SEARCH_LIBS(dn_expand,resolv bind,,
573                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
574   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
575                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
576
577   if test x"$use_dns_srv" = xyes ; then
578
579     # Make sure that the BIND 4 resolver interface is workable before
580     # enabling SRVs.  At some point I'll rewrite the code to use the
581     # BIND 8 resolver API.
582
583     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
584 #include <netinet/in.h>
585 #include <arpa/nameser.h>
586 #include <resolv.h>],
587 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);]])],,use_dns_srv=no)
588   fi
589
590   if test x"$use_dns_srv" = xyes ; then
591      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
592      SRVLIBS=$LIBS
593      AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
594   fi
595
596   LIBS=$_srv_save_libs
597 fi
598
599 AC_SUBST(SRVLIBS)
600
601 # Check for LDAP
602
603 if test "$try_ldap" = yes ; then
604    GNUPG_CHECK_LDAP($NETLIBS)
605 fi
606
607 # Which keyserver helpers are we building?
608
609 AC_ARG_ENABLE(old-keyserver-helpers,
610    AC_HELP_STRING([--enable-old-keyserver-helpers],[enable old keyserver helpers]),old_ks=$enableval,old_ks=no)
611
612 if test "$old_ks" = yes ; then
613    AC_SUBST(GPGKEYS_HTTP,"gpgkeys_http$EXEEXT")
614 else
615    LIBCURL_CHECK_CONFIG([yes],,[with_curl=yes],[fake_curl=yes])
616    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
617 fi
618
619 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
620 AM_CONDITIONAL(WITH_CURL,test x"$with_curl" = xyes || test x"$fake_curl" = xyes)
621
622 if test x"$fake_curl" = xyes ; then
623    AC_DEFINE(FAKE_CURL,1,[define to fake the libcurl API internally])
624 fi
625
626 dnl This isn't necessarily sendmail itself, but anything that gives a
627 dnl sendmail-ish interface to the outside world.  That includes qmail,
628 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
629
630 if test "$try_mailto" = yes ; then
631   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
632
633   if test "$with_mailprog" = yes ; then
634     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
635     if test "$ac_cv_path_SENDMAIL" ; then
636       GPGKEYS_MAILTO="gpgkeys_mailto"
637     fi
638   elif test "$with_mailprog" != no ; then
639     AC_MSG_CHECKING([for a mail transport program])
640     AC_SUBST(SENDMAIL,$with_mailprog)
641     AC_MSG_RESULT($with_mailprog)
642     GPGKEYS_MAILTO="gpgkeys_mailto"
643   fi
644 fi
645
646 AC_SUBST(GPGKEYS_MAILTO)
647
648 case "${host}" in
649     *-mingw32*)
650         PRINTABLE_OS_NAME="MingW32"
651         ;;
652     *-*-cygwin*)
653         PRINTABLE_OS_NAME="Cygwin"
654         ;;
655     i?86-emx-os2 | i?86-*-os2*emx )
656         PRINTABLE_OS_NAME="OS/2"
657         ;;
658     i?86-*-msdosdjgpp*)
659         PRINTABLE_OS_NAME="MSDOS/DJGPP"
660         try_extensions=no
661         ;;
662     *-linux*)
663         PRINTABLE_OS_NAME="GNU/Linux"
664         ;;
665     *)
666         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
667         ;;
668 esac
669 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
670                    [A human readable text with the name of the OS])
671
672
673 #
674 # 1. Set names of random devices
675 #
676 NAME_OF_DEV_RANDOM="/dev/random"
677 NAME_OF_DEV_URANDOM="/dev/urandom"
678 case "${host}" in
679     *-openbsd*)
680         NAME_OF_DEV_RANDOM="/dev/srandom"
681         NAME_OF_DEV_URANDOM="/dev/urandom"
682         ;;
683 esac
684 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
685                    [defined to the name of the strong random device])
686 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
687                    [defined to the name of the weaker random device])
688 AC_SUBST(MPI_OPT_FLAGS)
689
690
691 dnl Checks for libraries.
692
693 AM_GNU_GETTEXT_VERSION(0.14.1)
694 if test "$try_gettext" = yes; then
695   AM_GNU_GETTEXT(,[need-ngettext])
696
697   # gettext requires some extra checks.  These really should be part of
698   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
699   # function checks to here.
700
701   AC_CHECK_FUNCS(strchr)
702 else
703   USE_NLS=no
704   USE_INCLUDED_LIBINTL=no
705   BUILD_INCLUDED_LIBINTL=no
706   AC_SUBST(USE_NLS)
707   AC_SUBST(USE_INCLUDED_LIBINTL)
708   AC_SUBST(BUILD_INCLUDED_LIBINTL)
709   AM_PO_SUBDIRS
710 fi
711
712 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
713   if test "$need_dlopen" = yes; then
714     _dl_save_libs=$LIBS
715     LIBS=""
716     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
717     if test x"$found_dlopen" = "xyes" ; then
718       AC_DEFINE(HAVE_DL_DLOPEN,1,
719                 [Defined when the dlopen function family is available])
720       DLLIBS=$LIBS
721     else
722       if test "$try_extensions" = yes ; then
723          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
724          try_extensions=no
725       fi
726   
727       if test "$card_support" = yes ; then
728          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
729          card_support=no
730       fi
731     fi
732     LIBS=$_dl_save_libs
733   fi
734 fi
735
736 AC_SUBST(DLLIBS)
737
738 if test "$card_support" = yes ; then
739   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
740 fi
741
742 if test "$agent_support" = yes ; then
743   AC_DEFINE(ENABLE_AGENT_SUPPORT,1,[Define to include gpg-agent support])
744 fi
745
746 if test "$try_extensions" = yes ; then
747   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
748 fi
749
750 if test "$selinux_support" = yes ; then
751   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
752 fi
753
754 if test "$gnupg_use_iconv" = yes ; then
755   AC_DEFINE(USE_GNUPG_ICONV,1,[Define to use the new iconv based code])
756 fi
757
758 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
759 AM_CONDITIONAL(ENABLE_AGENT_SUPPORT, test "$agent_support" = yes)
760
761 dnl Checks for header files.
762 AC_HEADER_STDC
763 AC_CHECK_HEADERS([unistd.h langinfo.h termio.h locale.h getopt.h pwd.h])
764
765 # Note that we do not check for iconv here because this is done anyway
766 # by the gettext checks and thus it allows us to disable the use of
767 # iconv by using --disable-nls.
768
769 dnl Checks for typedefs, structures, and compiler characteristics.
770 AC_C_CONST
771 AC_C_INLINE
772 AC_C_VOLATILE
773 AC_TYPE_SIZE_T
774 AC_TYPE_MODE_T
775 AC_TYPE_SIGNAL
776 AC_DECL_SYS_SIGLIST
777
778 GNUPG_CHECK_ENDIAN
779
780 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
781 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
782 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
783 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
784 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
785
786 AC_CHECK_SIZEOF(unsigned short)
787 AC_CHECK_SIZEOF(unsigned int)
788 AC_CHECK_SIZEOF(unsigned long)
789 AC_CHECK_SIZEOF(unsigned long long)
790
791 # Ensure that we have UINT64_C before we bother to check for uint64_t
792 gt_HEADER_INTTYPES_H
793 AC_CACHE_CHECK([for UINT64_C], [gnupg_cv_uint64_c_works],
794                AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>],[
795 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
796
797 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
798    AC_CHECK_SIZEOF(uint64_t)
799 fi
800
801 if test "$ac_cv_sizeof_unsigned_short" = "0" \
802    || test "$ac_cv_sizeof_unsigned_int" = "0" \
803    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
804     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
805 fi
806
807 dnl Do we have any 64-bit data types?
808 if test x"$use_sha512" = xyes \
809    && test "$ac_cv_sizeof_unsigned_int" != "8" \
810    && test "$ac_cv_sizeof_unsigned_long" != "8" \
811    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
812    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
813     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
814     use_sha512=no
815 fi
816
817 if test x"$use_sha512" ; then
818     AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
819 fi
820
821 AM_CONDITIONAL(USE_SHA512, test x"$use_sha512" = xyes)
822
823 dnl Checks for library functions.
824 AC_CHECK_DECLS(getpagesize)
825 AC_FUNC_FSEEKO
826 AC_FUNC_VPRINTF
827 AC_FUNC_FORK
828 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
829 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times unsetenv getpwnam getpwuid)
830 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
831 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
832 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
833 AC_REPLACE_FUNCS(mkdtemp timegm isascii memrchr)
834
835 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
836
837 # See if getopt is in libiberty.  This is of course not optimal since
838 # it might be somewhere other than libiberty, but does cover the
839 # mingw32 case.
840
841 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
842
843 #
844 # check for gethrtime and run a testprogram to see whether
845 # it is broken.  It has been reported that some Solaris and HP UX systems 
846 # raise an SIGILL
847 #
848 AC_CACHE_CHECK([for gethrtime], 
849                [gnupg_cv_func_gethrtime],
850                [AC_TRY_LINK([#include <sys/times.h>],[
851                    hrtime_t tv;
852                    tv = gethrtime();
853                  ],
854                  [gnupg_cv_func_gethrtime=yes],
855                  [gnupg_cv_func_gethrtime=no])
856                ])
857 if test $gnupg_cv_func_gethrtime = yes; then
858      AC_DEFINE([HAVE_GETHRTIME], 1,
859                [Define if you have the `gethrtime(2)' function.])
860      AC_CACHE_CHECK([whether gethrtime is broken], 
861                [gnupg_cv_func_broken_gethrtime],
862                [AC_TRY_RUN([
863                    #include <sys/times.h>
864                    int main () {
865                    hrtime_t tv;
866                    tv = gethrtime(); 
867                  }
868                  ],
869                  [gnupg_cv_func_broken_gethrtime=no],
870                  [gnupg_cv_func_broken_gethrtime=yes],
871                  [gnupg_cv_func_broken_gethrtime=assume-no])
872                 ])
873     if test $gnupg_cv_func_broken_gethrtime = yes; then
874       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
875       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
876     fi
877 fi
878      
879
880 GNUPG_CHECK_MLOCK
881 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
882
883 dnl
884 dnl Check whether we can use Linux capabilities as requested
885 dnl
886 if test "$use_capabilities" = "yes" ; then
887
888 AC_MSG_WARN([[
889 ***
890 *** WARNING: using capabilities with GnuPG is experimental code!
891 ***]])
892
893 use_capabilities=no
894 AC_CHECK_HEADERS(sys/capability.h)
895 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
896   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
897   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
898      AC_DEFINE(USE_CAPABILITIES,1,
899                [define if capabilities should be used])
900      AC_SUBST(CAPLIBS,"-lcap")
901      use_capabilities=yes
902   fi
903 fi
904 if test "$use_capabilities" = "no" ; then
905     AC_MSG_WARN([[
906 ***
907 *** The use of capabilities on this system is not possible.
908 *** You need a recent Linux kernel and some patches:
909 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
910 ***   fcap-module-990613.tar.gz     (kernel module)
911 ***   libcap-1.92.tar.gz            (user mode library and utilities)
912 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
913 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
914 ***]])
915 fi
916 fi
917
918
919 GNUPG_CHECK_IPC
920 if test "$ac_cv_header_sys_shm_h" = "yes"; then
921   AC_DEFINE(USE_SHM_COPROCESSING,1,
922             [define if the shared memory interface should be made available])
923 fi
924
925 dnl
926 dnl check whether we have a random device
927 dnl
928 if test "$try_dev_random" = yes ; then
929     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
930     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
931       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
932     if test "$ac_cv_have_dev_random" = yes; then
933         AC_DEFINE(HAVE_DEV_RANDOM,1,
934                  [defined if the system supports a random device] )
935     fi
936 else
937     AC_MSG_CHECKING(for random device)
938     ac_cv_have_dev_random=no
939     AC_MSG_RESULT(has been disabled)
940 fi
941
942
943 dnl
944 dnl Figure out the default random module.
945 dnl
946 random_modules=""
947 if test "$use_static_rnd" = default; then
948      if test "$ac_cv_have_dev_random" = yes; then
949         random_modules="rndlinux"
950      else
951          case "${host}" in
952             *-mingw32*|*-*-cygwin*)
953                 random_modules="rndw32"
954                 ;;
955             i?86-emx-os2|i?86-*-os2*emx)
956                 random_modules="rndos2"
957                 ;;
958             m68k-atari-mint)
959                 random_modules="rndatari"
960                 ;;
961             i?86-*-msdosdjgpp*)
962                 :
963                 ;;
964             *)
965                 random_modules="rndlinux rndegd rndunix"
966                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
967                           [Allow to select random modules at runtime.])
968                 ;;
969          esac
970      fi
971 else
972   if test "$use_static_rnd" = auto; then
973      random_modules="rndlinux rndegd rndunix"
974      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
975   else
976      random_modules="rnd$use_static_rnd";
977   fi
978 fi
979
980 if test -z "$random_modules"; then
981    AC_MSG_ERROR(no random module available)
982 fi
983 print_egd_warning=no
984 for rndmod in $random_modules "" ; do
985   case "$rndmod" in
986     rndlinux)
987          AC_DEFINE(USE_RNDLINUX,1, 
988                   [Defined if the /dev/random based RNG should be used.])
989          use_rndlinux=yes
990          ;;
991     rndunix)
992          AC_DEFINE(USE_RNDUNIX,1, 
993                   [Defined if the default Unix RNG should be used.])
994          print_egd_warning=yes
995          use_rndunix=yes
996           ;;
997     rndegd)
998          AC_DEFINE(USE_RNDEGD,1, 
999                   [Defined if the EGD based RNG should be used.])
1000          use_rndegd=yes
1001          ;;
1002     rndw32)
1003          AC_DEFINE(USE_RNDW32,1, 
1004                   [Defined if the Windows specific RNG should be used.])
1005          use_rndw32=yes
1006         ;;
1007    esac
1008 done
1009
1010 AM_CONDITIONAL(USE_RNDLINUX, test "$use_rndlinux" = yes)
1011 AM_CONDITIONAL(USE_RNDUNIX,  test "$use_rndunix" = yes)
1012 AM_CONDITIONAL(USE_RNDEGD,   test "$use_rndegd" = yes)
1013 AM_CONDITIONAL(USE_RNDW32,   test "$use_rndw32" = yes)
1014
1015 dnl setup assembler stuff
1016 AC_MSG_CHECKING(for mpi assembler functions)
1017 if test -f $srcdir/mpi/config.links ; then
1018     . $srcdir/mpi/config.links
1019     AC_CONFIG_LINKS("$mpi_ln_list")
1020     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
1021     ac_cv_mpi_sflags="$mpi_sflags"
1022     ac_cv_mpi_config_done="yes"
1023     AC_MSG_RESULT(done)
1024 else
1025     AC_MSG_RESULT(failed)
1026     AC_MSG_ERROR([mpi/config.links missing!])
1027 fi
1028 MPI_EXTRA_ASM_OBJS=""
1029 show_extraasm=""
1030 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
1031 for i in $ac_cv_mpi_extra_asm_modules; do
1032     show_extraasm="$show_extraasm $i"
1033     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
1034 done
1035 fi
1036 AC_SUBST(MPI_EXTRA_ASM_OBJS)
1037 MPI_SFLAGS="$ac_cv_mpi_sflags"
1038 AC_SUBST(MPI_SFLAGS)
1039
1040 # Sanity check regex.  Tests adapted from mutt.
1041
1042 AC_MSG_CHECKING([whether regular expression support is requested])
1043 AC_ARG_ENABLE(regex,
1044   AC_HELP_STRING([--disable-regex],
1045     [do not handle regular expressions in trust signatures]),
1046   use_regex=$enableval, use_regex=yes)
1047 AC_MSG_RESULT($use_regex)
1048
1049 if test "$use_regex" = yes ; then
1050   AC_MSG_CHECKING([whether the included regex lib is requested])
1051   AC_ARG_WITH(included-regex,
1052       [  --with-included-regex   use the included GNU regex library],
1053       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1054   AC_MSG_RESULT($gnupg_cv_included_regex)
1055
1056   if test $gnupg_cv_included_regex = no ; then
1057      # Does the system have regex functions at all?
1058      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1059                            gnupg_cv_included_regex=yes)
1060   fi
1061
1062   if test $gnupg_cv_included_regex = no ; then
1063      AC_CACHE_CHECK([whether your system's regexp library is broken],
1064        [gnupg_cv_regex_broken],
1065        AC_TRY_RUN([
1066 #include <unistd.h>
1067 #include <regex.h>
1068 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1069        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1070
1071      if test $gnupg_cv_regex_broken = yes ; then
1072       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1073       gnupg_cv_included_regex=yes
1074      fi
1075   fi
1076
1077   if test $gnupg_cv_included_regex = yes; then
1078      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1079   fi
1080 else
1081   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1082 fi
1083
1084 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1085
1086 dnl Do we have zlib? Must do it here because Solaris failed
1087 dnl when compiling a conftest (due to the "-lz" from LIBS).
1088 use_local_zlib=yes
1089 if test "$g10_force_zlib" = "yes"; then
1090   :
1091 else
1092   _cppflags="${CPPFLAGS}"
1093   _ldflags="${LDFLAGS}"
1094
1095   AC_ARG_WITH(zlib,
1096   [  --with-zlib=DIR         use libz in DIR],[
1097     if test -d "$withval"; then
1098       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1099       LDFLAGS="${LDFLAGS} -L$withval/lib"
1100     fi
1101   ])
1102
1103   AC_CHECK_HEADER(zlib.h,
1104       AC_CHECK_LIB(z, deflateInit2_,
1105        use_local_zlib=no
1106        ZLIBS="-lz",
1107        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1108        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1109 fi
1110
1111 if test "$use_local_zlib" = yes ; then
1112     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1113     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1114     ZLIBS="../zlib/libzlib.a"
1115 else
1116     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1117 fi
1118
1119 if test "$use_bzip2" = yes ; then
1120   _cppflags="${CPPFLAGS}"
1121   _ldflags="${LDFLAGS}"
1122   AC_ARG_WITH(bzip2,
1123      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1124       [
1125       if test -d "$withval" ; then
1126         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1127         LDFLAGS="${LDFLAGS} -L$withval/lib"
1128       fi
1129       ],withval="")
1130
1131 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1132 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1133 # woefully out of date.
1134
1135   if test "$withval" != no ; then
1136      AC_CHECK_HEADER(bzlib.h,
1137         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1138           [
1139           have_bz2=yes
1140           ZLIBS="$ZLIBS -lbz2"
1141           AC_DEFINE(HAVE_BZIP2,1,
1142                   [Defined if the bz2 compression library is available])
1143           ],
1144           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1145           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1146   fi
1147 fi
1148
1149 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1150 AC_SUBST(ZLIBS)
1151
1152 # libusb allows us to use the integrated CCID smartcard reader driver.
1153 GNUPG_CHECK_LIBUSB
1154
1155 # Check for readline support
1156 GNUPG_CHECK_READLINE
1157
1158 # Allow users to append something to the version string without
1159 # flagging it as development version.  The user version parts is
1160 # considered everything after a dash. 
1161 if test "$development_version" != yes; then
1162   changequote(,)dnl
1163   tmp_pat='[a-zA-Z]'
1164   changequote([,])dnl
1165   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1166     development_version=yes
1167   fi
1168 fi
1169 if test "$development_version" = yes; then
1170     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1171             [Defined if this is not a regular release])
1172 fi
1173
1174 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1175
1176
1177 # add some extra libs here so that previous tests don't fail for
1178 # mysterious reasons - the final link step should bail out. 
1179 case "${host}" in
1180     *-mingw32*)
1181 dnl      NETLIBS="$NETLIBS -lwsock32"
1182         W32LIBS="-lwsock32"
1183         ;;
1184     *)
1185        ;;
1186 esac
1187
1188 AC_SUBST(NETLIBS)
1189 AC_SUBST(W32LIBS)
1190
1191 # Special options used with gcc.
1192 if test "$GCC" = yes; then
1193     # Note that it is okay to use CFLAGS here because this are just
1194     # warning options and the user should have a chance of overriding
1195     #them.
1196     if test "$USE_MAINTAINER_MODE" = "yes"; then
1197         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1198         CFLAGS="$CFLAGS -Wformat-nonliteral"
1199     else
1200         CFLAGS="$CFLAGS -Wall"
1201     fi
1202
1203     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1204
1205     _gcc_cflags_save=$CFLAGS
1206     CFLAGS="-Wno-pointer-sign"
1207
1208     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1209     AC_MSG_RESULT($_gcc_psign)
1210
1211     CFLAGS=$_gcc_cflags_save;
1212
1213     if test x"$_gcc_psign" = xyes ; then
1214        CFLAGS="$CFLAGS -Wno-pointer-sign"
1215     fi
1216
1217     # Non exec stack hack.  Fixme: Write a test to check whether as
1218     # can cope with it and use the enable-noexecstack option only to
1219     # disable it in case it is required on sime platforms.
1220     if test "$noexecstack_support" = yes; then
1221         NOEXECSTACK_FLAGS="-Wa,--noexecstack"
1222     fi
1223 fi
1224 AC_SUBST(NOEXECSTACK_FLAGS)
1225
1226
1227 if test "$print_egd_warning" = yes; then
1228   AC_MSG_WARN([[
1229 ***
1230 *** The performance of the UNIX random gatherer module is not very good
1231 *** and it does not keep the entropy pool over multiple invocations of
1232 *** GnuPG.  The suggested way to overcome this problem is to use the
1233 ***
1234 ***               Entropy Gathering Daemon (EGD)
1235 ***
1236 *** which provides a entropy source for the whole system.  It is written
1237 *** in Perl and available at the GnuPG FTP servers.  For more information
1238 *** consult the GnuPG webpages:
1239 ***
1240 ***           http://www.gnupg.org/download/#EGD
1241 ***
1242 *** You may want to run ./configure with --enable-static-rnd=egd or
1243 *** --enable-static-rnd=auto to use it.
1244 ***]])
1245 fi
1246
1247 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1248
1249 AC_CONFIG_COMMANDS(g10defs.h,[[
1250 cat >g10defs.tmp <<G10EOF
1251 /* Generated automatically by configure */
1252 #ifdef HAVE_DRIVE_LETTERS
1253 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1254 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1255 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1256 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1257 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1258 #else
1259 #define G10_LOCALEDIR     "${datadir}/locale"
1260 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1261 #define GNUPG_DATADIR     "${datadir}/gnupg"
1262 #ifdef __VMS
1263 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1264 #else
1265 #define GNUPG_HOMEDIR "~/.gnupg" 
1266 #endif
1267 #endif
1268 /* those are here to be redefined by handcrafted g10defs.h.
1269    Please note that the string version must not contain more
1270    than one character because the using code assumes strlen()==1 */
1271 #ifdef HAVE_DOSISH_SYSTEM
1272 #define DIRSEP_C '\\\\'
1273 #define EXTSEP_C '.'
1274 #define DIRSEP_S "\\\\"
1275 #define EXTSEP_S "."
1276 #define PATHSEP_C ';'
1277 #define PATHSEP_S ";"
1278 #else
1279 #define DIRSEP_C '/'
1280 #define EXTSEP_C '.'
1281 #define DIRSEP_S "/"
1282 #define EXTSEP_S "."
1283 #define PATHSEP_C ':'
1284 #define PATHSEP_S ":"
1285 #endif
1286 /* This is the same as VERSION, but should be overridden if the
1287    platform cannot handle things like dots'.' in filenames.  Set
1288    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1289    uses for dots and dashes. */
1290 #define SAFE_VERSION      VERSION
1291 #define SAFE_VERSION_DOT  '.'
1292 #define SAFE_VERSION_DASH '-'
1293 G10EOF
1294 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1295 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1296     echo "g10defs.h is unchanged"
1297     rm -f g10defs.tmp
1298 else
1299     rm -f g10defs.h
1300     mv g10defs.tmp g10defs.h
1301     echo "g10defs.h created"
1302 fi
1303 ]],[[
1304 prefix=$prefix
1305 exec_prefix=$exec_prefix
1306 libdir=$libdir
1307 libexecdir=$libexecdir
1308 datadir=$datadir
1309 DATADIRNAME=$DATADIRNAME
1310 ]])
1311
1312
1313 AC_CONFIG_FILES([
1314 Makefile
1315 m4/Makefile
1316 intl/Makefile
1317 po/Makefile.in
1318 util/Makefile
1319 mpi/Makefile
1320 cipher/Makefile
1321 g10/Makefile
1322 keyserver/Makefile
1323 keyserver/gpgkeys_mailto
1324 keyserver/gpgkeys_test
1325 doc/Makefile
1326 tools/Makefile
1327 tools/gpg-zip
1328 zlib/Makefile
1329 checks/Makefile
1330 ])
1331 AC_OUTPUT
1332
1333 # Give some feedback
1334 echo
1335 echo   "                Configured for: $PRINTABLE_OS_NAME ($host)"
1336 if test -n "$show_extraasm"; then
1337   echo "  Extra cpu specific functions:$show_extraasm"
1338 fi
1339 echo