Merge branch 'master' into ECC-INTEGRATION-2-1
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
3 #               2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 AC_INIT([gnupg], 
35         [my_version[]m4_if(my_issvn,[yes],
36         [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])],
37         [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.8
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.4.6
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.0.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.1.0
53
54
55 PACKAGE=$PACKAGE_NAME
56 PACKAGE_GT=${PACKAGE_NAME}2
57 VERSION=$PACKAGE_VERSION
58
59 AC_CONFIG_AUX_DIR(scripts)
60 AC_CONFIG_SRCDIR(sm/gpgsm.c)
61 AM_CONFIG_HEADER(config.h)
62 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
63 AC_CANONICAL_HOST
64 AB_INIT
65
66 AC_GNU_SOURCE
67
68 # Some status variables.
69 have_gpg_error=no
70 have_libgcrypt=no 
71 have_libassuan=no
72 have_ksba=no
73 have_pth=no
74 have_libusb=no
75 have_adns=no
76
77 use_zip=yes
78 use_bzip2=yes
79 use_exec=yes
80 disable_keyserver_path=no
81 use_ccid_driver=yes
82 use_standard_socket=yes
83 dirmngr_auto_start=no
84
85 try_ks_ldap=no
86
87 GNUPG_BUILD_PROGRAM(gpg, yes)
88 GNUPG_BUILD_PROGRAM(gpgsm, yes)
89 GNUPG_BUILD_PROGRAM(agent, yes)
90 GNUPG_BUILD_PROGRAM(scdaemon, yes)
91 GNUPG_BUILD_PROGRAM(g13, yes)
92 GNUPG_BUILD_PROGRAM(dirmngr, yes)
93 GNUPG_BUILD_PROGRAM(tools, yes)
94 GNUPG_BUILD_PROGRAM(doc, yes)
95 GNUPG_BUILD_PROGRAM(symcryptrun, no)
96 GNUPG_BUILD_PROGRAM(gpgtar, no)
97
98 AC_SUBST(PACKAGE)
99 AC_SUBST(PACKAGE_GT)
100 AC_SUBST(VERSION)
101 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
102 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
103                                 [Name of this package for gettext])
104 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
105 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
106                                         [Bug report address])
107 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
108                                        [Required version of Libgcrypt])
109 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
110                                        [Required version of Libksba])
111
112
113
114 # The default is to use the modules from this package and the few
115 # other packages in a standard place; i.e where this package gets
116 # installed.  With these options it is possible to override these
117 # ${prefix} depended values with fixed paths, which can't be replaced
118 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
119 AC_ARG_WITH(agent-pgm,
120     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
121           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
122 AC_SUBST(GNUPG_AGENT_PGM)
123 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
124 show_gnupg_agent_pgm="(default)"
125 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
126
127 AC_ARG_WITH(pinentry-pgm,
128     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
129           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
130 AC_SUBST(GNUPG_PINENTRY_PGM)
131 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
132 show_gnupg_pinentry_pgm="(default)"
133 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
134
135
136 AC_ARG_WITH(scdaemon-pgm,
137     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
138           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
139 AC_SUBST(GNUPG_SCDAEMON_PGM)
140 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
141 show_gnupg_scdaemon_pgm="(default)"
142 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
143
144
145 AC_ARG_WITH(dirmngr-pgm,
146     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
147           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
148 AC_SUBST(GNUPG_DIRMNGR_PGM)
149 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
150 show_gnupg_dirmngr_pgm="(default)"
151 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
152
153 AC_ARG_WITH(protect-tool-pgm,
154     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
155           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
156 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
157 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
158 show_gnupg_protect_tool_pgm="(default)"
159 test -n "$GNUPG_PROTECT_TOOL_PGM" \
160       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
161
162 AC_ARG_WITH(dirmngr-ldap-pgm,
163     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
164           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
165 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
166 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
167 show_gnupg_dirmngr_ldap_pgm="(default)"
168 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
169       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
170
171
172 # On some platforms gpg2 is usually installed as gpg without using a
173 # symlink.  For correct operation of gpgconf it needs to know the
174 # installed name of gpg.  This option sets "gpg2"'s installed name to
175 # just "gpg".  Note that it might be required to rename gpg2 to gpg
176 # manually after the build process.
177
178 AC_ARG_ENABLE(gpg2-is-gpg,
179     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
180     gpg2_is_gpg=$enableval)
181 if test "$gpg2_is_gpg" = "yes"; then
182    name_of_installed_gpg=gpg
183 else
184    name_of_installed_gpg=gpg2
185 fi
186 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
187                    [The name of the installed GPG tool])
188
189
190 # Some folks want to use only the agent from this packet.  Make it
191 # easier for them by providing the configure option
192 # --enable-only-agent.
193 AC_ARG_ENABLE(agent-only,
194     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
195     build_agent_only=$enableval)
196
197 # SELinux support includes tracking of sensitive files to avoid
198 # leaking their contents through processing these files by gpg itself
199 AC_MSG_CHECKING([whether SELinux support is requested])
200 AC_ARG_ENABLE(selinux-support,
201               AC_HELP_STRING([--enable-selinux-support],
202                              [enable SELinux support]),
203               selinux_support=$enableval, selinux_support=no)
204 AC_MSG_RESULT($selinux_support)
205
206 # Allow disabling of zip support.
207 # This is in general not a good idea because according to rfc4880 OpenPGP
208 # implementations SHOULD support ZLIB.
209 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
210 AC_ARG_ENABLE(zip,
211    AC_HELP_STRING([--disable-zip],
212                   [disable the ZIP and ZLIB compression algorithm]),
213    use_zip=$enableval)
214 AC_MSG_RESULT($use_zip)
215
216 # Allow disabling of bzib2 support.
217 # It is defined only after we confirm the library is available later
218 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
219 AC_ARG_ENABLE(bzip2,
220    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
221    use_bzip2=$enableval)
222 AC_MSG_RESULT($use_bzip2)
223
224 # Configure option to allow or disallow execution of external
225 # programs, like a photo viewer.
226 AC_MSG_CHECKING([whether to enable external program execution])
227 AC_ARG_ENABLE(exec,
228     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
229     use_exec=$enableval)
230 AC_MSG_RESULT($use_exec)
231 if test "$use_exec" = no ; then
232     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
233 fi
234
235 if test "$use_exec" = yes ; then
236   AC_MSG_CHECKING([whether to enable photo ID viewing])
237   AC_ARG_ENABLE(photo-viewers,
238       [  --disable-photo-viewers disable photo ID viewers],
239       [if test "$enableval" = no ; then
240          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
241       fi],enableval=yes)
242   gnupg_cv_enable_photo_viewers=$enableval
243   AC_MSG_RESULT($enableval)
244
245   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
246     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
247     AC_ARG_WITH(photo-viewer,
248         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
249         [if test "$withval" = yes ; then
250            withval=no
251         elif test "$withval" != no ; then
252            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
253                             [if set, restrict photo-viewer to this])
254         fi],withval=no)
255     AC_MSG_RESULT($withval)
256   fi
257
258   AC_MSG_CHECKING([whether to enable external keyserver helpers])
259   AC_ARG_ENABLE(keyserver-helpers,
260       [  --disable-keyserver-helpers  disable all external keyserver support],
261       [if test "$enableval" = no ; then
262          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
263                   [define to disable keyserver helpers])
264       fi],enableval=yes)
265   gnupg_cv_enable_keyserver_helpers=$enableval
266   AC_MSG_RESULT($enableval)
267
268   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
269     # LDAP is defined only after we confirm the library is available later
270     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
271     AC_ARG_ENABLE(ldap,
272       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
273       try_ks_ldap=$enableval, try_ks_ldap=yes)
274     AC_MSG_RESULT($try_ks_ldap)
275
276     AC_MSG_CHECKING([whether HKP keyserver support is requested])
277     AC_ARG_ENABLE(hkp,
278       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
279       try_hkp=$enableval, try_hkp=yes)
280     AC_MSG_RESULT($try_hkp)
281
282     AC_MSG_CHECKING([whether finger key fetching support is requested])
283     AC_ARG_ENABLE(finger,
284       AC_HELP_STRING([--disable-finger],
285         [disable finger key fetching interface only]),
286       try_finger=$enableval, try_finger=yes)
287     AC_MSG_RESULT($try_finger)
288
289     AC_MSG_CHECKING([whether generic object key fetching support is requested])
290     AC_ARG_ENABLE(generic,
291       AC_HELP_STRING([--disable-generic],
292         [disable generic object key fetching interface only]),
293       try_generic=$enableval, try_generic=yes)
294     AC_MSG_RESULT($try_generic)
295
296     AC_MSG_CHECKING([whether email keyserver support is requested])
297     AC_ARG_ENABLE(mailto,
298       AC_HELP_STRING([--enable-mailto],
299         [enable email keyserver interface only]),
300       try_mailto=$enableval, try_mailto=no)
301     AC_MSG_RESULT($try_mailto)
302   fi
303
304   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
305   AC_ARG_ENABLE(keyserver-path,
306       AC_HELP_STRING([--disable-keyserver-path],
307         [disable the exec-path option for keyserver helpers]),
308       [if test "$enableval" = no ; then
309          disable_keyserver_path=yes
310       fi],enableval=yes)
311   AC_MSG_RESULT($enableval)
312 fi
313
314
315 #
316 # Check for the key/uid cache size.  This can't be zero, but can be
317 # pretty small on embedded systems.  This is used for the gpg part.
318 #
319 AC_MSG_CHECKING([for the size of the key and uid cache])
320 AC_ARG_ENABLE(key-cache,
321         AC_HELP_STRING([--enable-key-cache=SIZE],
322                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
323 if test "$enableval" = "no"; then
324    enableval=5
325 elif test "$enableval" = "yes" || test "$enableval" = ""; then
326    enableval=4096
327 fi
328 changequote(,)dnl
329 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
330 changequote([,])dnl
331 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
332    AC_MSG_ERROR([invalid key-cache size])
333 fi
334 AC_MSG_RESULT($key_cache_size)
335 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
336                   [Size of the key and UID caches])
337
338
339
340 #
341 # Check whether we want to use Linux capabilities
342 #
343 AC_MSG_CHECKING([whether use of capabilities is requested])
344 AC_ARG_WITH(capabilities,
345     [  --with-capabilities     use linux capabilities [default=no]],
346 [use_capabilities="$withval"],[use_capabilities=no])
347 AC_MSG_RESULT($use_capabilities)
348
349
350 #
351 # Allow disabling of internal CCID support.
352 # It is defined only after we confirm the library is available later
353 #
354 AC_MSG_CHECKING([whether to enable the internal CCID driver])
355 AC_ARG_ENABLE(ccid-driver,
356               AC_HELP_STRING([--disable-ccid-driver],
357                              [disable the internal CCID driver]),
358               use_ccid_driver=$enableval)
359 AC_MSG_RESULT($use_ccid_driver)
360
361
362 # Dirmngr is nowadays a system service and thus it usually does no
363 # make sense to start it as needed.  However on some systems this is
364 # possible; this option enable the feature.
365 #
366 AC_MSG_CHECKING([whether to auto start dirmngr])
367 AC_ARG_ENABLE(dirmngr-auto-start,
368               AC_HELP_STRING([--enable-dirmngr-auto-start],
369                              [enable auto starting of the dirmngr]),
370               dirmngr_auto_start=$enableval)
371 AC_MSG_RESULT($dirmngr_auto_start)
372 if test "$dirmngr_auto_start" = yes ; then
373     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
374               [Define to enable auto starting of the dirmngr])
375 fi
376
377
378 #
379 # To avoid double inclusion of config.h which might happen at some
380 # places, we add the usual double inclusion protection at the top of
381 # config.h.
382 #
383 AH_TOP([
384 #ifndef GNUPG_CONFIG_H_INCLUDED
385 #define GNUPG_CONFIG_H_INCLUDED
386 ])
387
388 #
389 # Stuff which goes at the bottom of config.h.
390 #
391 AH_BOTTOM([
392 /* This is the major version number of GnuPG so that
393    source included files can test for this.  Note, that
394    we use 2 here even for GnuPG 1.9.x. */
395 #define GNUPG_MAJOR_VERSION 2
396
397 /* Now to separate file name parts.
398    Please note that the string version must not contain more
399    than one character because the code assumes strlen()==1 */
400 #ifdef HAVE_DOSISH_SYSTEM
401 #define DIRSEP_C '\\'
402 #define DIRSEP_S "\\"
403 #define EXTSEP_C '.'
404 #define EXTSEP_S "."
405 #define PATHSEP_C ';'
406 #define PATHSEP_S ";"
407 #define EXEEXT_S ".exe"
408 #else
409 #define DIRSEP_C '/'
410 #define DIRSEP_S "/"
411 #define EXTSEP_C '.'
412 #define EXTSEP_S "."
413 #define PATHSEP_C ':'
414 #define PATHSEP_S ":"
415 #define EXEEXT_S ""
416 #endif
417
418 /* This is the same as VERSION, but should be overridden if the
419    platform cannot handle things like dots '.' in filenames. Set
420    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
421    uses for dots and dashes. */
422 #define SAFE_VERSION VERSION
423 #define SAFE_VERSION_DOT  '.'
424 #define SAFE_VERSION_DASH '-'
425
426 /* Some global constants. */
427 #ifdef HAVE_DOSISH_SYSTEM
428 # ifdef HAVE_DRIVE_LETTERS
429 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
430 # else
431 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
432 # endif
433 #elif defined(__VMS)
434 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg" 
435 #else
436 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
437 #endif 
438 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
439
440 /* For some systems (DOS currently), we hardcode the path here.  For
441    POSIX systems the values are constructed by the Makefiles, so that
442    the values may be overridden by the make invocations; this is to
443    comply with the GNU coding standards.  Note that these values are
444    only defaults.  */
445 #ifdef HAVE_DOSISH_SYSTEM
446 # ifdef HAVE_DRIVE_LETTERS
447 #  define GNUPG_BINDIR      "c:\\gnupg"
448 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
449 #  define GNUPG_LIBDIR      "c:\\gnupg"
450 #  define GNUPG_DATADIR     "c:\\gnupg"
451 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
452 # else
453 #  define GNUPG_BINDIR      "\\gnupg"
454 #  define GNUPG_LIBEXECDIR  "\\gnupg"
455 #  define GNUPG_LIBDIR      "\\gnupg"
456 #  define GNUPG_DATADIR     "\\gnupg"
457 #  define GNUPG_SYSCONFDIR  "\\gnupg"
458 # endif
459 #endif
460
461 /* Derive some other constants. */
462 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
463 #define EXEC_TEMPFILE_ONLY
464 #endif
465
466
467 /* We didn't define endianness above, so get it from OS macros.  This
468    is intended for making fat binary builds on OS X. */
469 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
470 #if defined(__BIG_ENDIAN__)
471 #define BIG_ENDIAN_HOST 1
472 #elif defined(__LITTLE_ENDIAN__)
473 #define LITTLE_ENDIAN_HOST 1
474 #else
475 #error "No endianness found"
476 #endif
477 #endif
478
479
480 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
481    ldap_start_tls_s because that is the actual symbol used in the
482    library.  winldap.h redefines it to our commonly used value,
483    thus we define our usual macro here.  */
484 #ifdef HAVE_LDAP_START_TLS_SA
485 # ifndef HAVE_LDAP_START_TLS_S
486 #  define HAVE_LDAP_START_TLS_S 1
487 # endif
488 #endif
489
490
491 /* Tell libgcrypt not to use its own libgpg-error implementation. */
492 #define USE_LIBGPG_ERROR 1
493
494 /* We use jnlib, so tell other modules about it.  */
495 #define HAVE_JNLIB_LOGGING 1
496
497 /* Our HTTP code is used in estream mode.  */
498 #define HTTP_USE_ESTREAM 1
499
500 /* Under W32 we do an explicit socket initialization, thus we need to
501    avoid the on-demand initialization which would also install an atexit
502    handler.  */
503 #define HTTP_NO_WSASTARTUP
504
505 /* We always include support for the OpenPGP card.  */
506 #define ENABLE_CARD_SUPPORT 1
507
508 /* We explicitly need to disable PTH's soft mapping as Debian
509    currently enables it by default for no reason. */
510 #define PTH_SYSCALL_SOFT 0
511
512 /* We want to use the libgcrypt provided memory allocation for
513    asprintf.  */
514 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
515 #define _ESTREAM_PRINTF_FREE          gcry_free
516 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
517
518 /* Under Windows we use the gettext code from libgpg-error.  */
519 #define GPG_ERR_ENABLE_GETTEXT_MACROS
520
521 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
522 #define GPG_ERR_ENABLE_ERRNO_MACROS
523
524 #endif /*GNUPG_CONFIG_H_INCLUDED*/
525 ])
526
527
528 AM_MAINTAINER_MODE
529
530 # Checks for programs.
531 AC_MSG_NOTICE([checking for programs])
532 AC_PROG_MAKE_SET
533 AM_SANITY_CHECK
534 missing_dir=`cd $ac_aux_dir && pwd`
535 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
536 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
537 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
538 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
539 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
540 AC_PROG_AWK
541 AC_PROG_CC
542 AC_PROG_CPP
543 AM_PROG_CC_C_O
544 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
545   AC_MSG_ERROR([[No C-89 compiler found]])
546 fi
547 AC_PROG_INSTALL
548 AC_PROG_LN_S
549 AC_PROG_RANLIB
550 AC_CHECK_TOOL(AR, ar, :)
551 AC_PATH_PROG(PERL,"perl")
552 AC_CHECK_TOOL(WINDRES, windres, :)
553 AC_ISC_POSIX
554 gl_EARLY
555 AC_SYS_LARGEFILE
556 GNUPG_CHECK_USTAR
557
558 # We need to compile and run a program on the build machine.  A
559 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
560 # the AC archive is broken for autoconf 2.57.  Given that there is no
561 # newer version of that macro, we assume that it is also broken for
562 # autoconf 2.61 and thus we use a simple but usually sufficient
563 # approach.
564 AC_MSG_CHECKING(for cc for build)
565 if test "$cross_compiling" = "yes"; then
566   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
567 else
568   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
569 fi
570 AC_MSG_RESULT($CC_FOR_BUILD)
571 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
572
573
574
575 try_gettext=yes
576 have_dosish_system=no
577 have_w32_system=no
578 have_w32ce_system=no
579 use_simple_gettext=no
580 use_ldapwrapper=yes
581 mmap_needed=yes
582 case "${host}" in
583     *-mingw32*)
584         # special stuff for Windoze NT
585         ac_cv_have_dev_random=no
586         AC_DEFINE(USE_ONLY_8DOT3,1,
587                   [Set this to limit filenames to the 8.3 format])
588         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
589                   [Because the Unix gettext has too much overhead on
590                    MingW32 systems and these systems lack Posix functions,
591                    we use a simplified version of gettext])
592         disable_keyserver_path=yes
593         have_dosish_system=yes
594         have_w32_system=yes
595         use_ldapwrapper=no  # Fixme: Do this only for CE.
596         case "${host}" in 
597           *-mingw32ce*)
598             have_w32ce_system=yes
599             ;;
600           *)
601             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
602                       [Defined if the OS supports drive letters.])
603             ;;
604         esac
605         try_gettext="no"
606         use_simple_gettext=yes
607         mmap_needed=no
608         ;;
609     i?86-emx-os2 | i?86-*-os2*emx )
610         # OS/2 with the EMX environment
611         ac_cv_have_dev_random=no
612         AC_DEFINE(HAVE_DRIVE_LETTERS)
613         have_dosish_system=yes
614         try_gettext="no"
615         ;;
616
617     i?86-*-msdosdjgpp*)
618         # DOS with the DJGPP environment
619         ac_cv_have_dev_random=no
620         AC_DEFINE(HAVE_DRIVE_LETTERS)
621         have_dosish_system=yes
622         try_gettext="no"
623         ;;
624
625     *-*-freebsd*)
626        # FreeBSD
627        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
628        LDFLAGS="$LDFLAGS -L/usr/local/lib"
629        ;;
630
631     *-*-hpux*)
632         if test -z "$GCC" ; then
633             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
634         fi
635         ;;
636     *-dec-osf4*)
637         if test -z "$GCC" ; then
638             # Suppress all warnings
639             # to get rid of the unsigned/signed char mismatch warnings.
640             CFLAGS="$CFLAGS -w"
641         fi
642         ;;
643     *-dec-osf5*)
644         if test -z "$GCC" ; then
645             # Use the newer compiler `-msg_disable ptrmismatch1' to
646             # get rid of the unsigned/signed char mismatch warnings.
647             # Using this may hide other pointer mismatch warnings, but
648             # it at least lets other warning classes through
649             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
650         fi
651         ;;
652     m68k-atari-mint)
653         ;;
654     *)
655        ;;
656 esac
657
658 if test "$have_dosish_system" = yes; then
659    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
660              [Defined if we run on some of the PCDOS like systems 
661               (DOS, Windoze. OS/2) with special properties like
662               no file modes, case insensitive file names and preferred
663               use of backslashes as directory name separators.])
664 fi
665 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
666
667 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
668
669 if test "$have_w32_system" = yes; then
670    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
671    if test "$have_w32ce_system" = yes; then
672       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
673    fi
674 fi
675 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
676 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
677
678 if test "$use_ldapwrapper" = yes; then
679    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
680 fi
681 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
682
683 if test "$disable_keyserver_path" = yes; then
684     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
685               [Defined to disable exec-path for keyserver helpers])
686 fi
687
688 #
689 # Allows enabling the use of a standard socket by default This is
690 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
691 # the use of this.
692 #
693 AC_MSG_CHECKING([whether to use a standard socket by default])
694 AC_ARG_ENABLE(standard-socket,
695               AC_HELP_STRING([--disable-standard-socket],
696                              [don't use a standard socket by default]),
697               use_standard_socket=$enableval)
698 tmp=""
699 if test "$use_standard_socket" != yes; then
700   if test "$have_w32_system" = yes; then
701     use_standard_socket=yes
702     tmp=" (forced)"
703   fi
704 fi
705 AC_MSG_RESULT($use_standard_socket$tmp)
706 if test "$use_standard_socket" = yes; then
707   AC_DEFINE(USE_STANDARD_SOCKET,1,
708             [Use the standard socket for the agent by default])
709 fi
710
711
712 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
713 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
714
715 if test x"$try_hkp" = xyes ; then
716   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
717 fi
718
719 if test x"$try_finger" = xyes ; then
720   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
721 fi
722
723
724
725 #
726 # Checks for libraries.
727 #
728 AC_MSG_NOTICE([checking for libraries])
729
730
731 #
732 # libgpg-error is a library with error codes shared between GnuPG
733 # related projects.
734 #
735 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
736                   have_gpg_error=yes,have_gpg_error=no)
737
738
739 #
740 # Libgcrypt is our generic crypto library
741 #
742 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
743         have_libgcrypt=yes,have_libgcrypt=no)
744
745 AC_CACHE_CHECK([whether Libgcrypt support ECDH], gnupg_cv_gcry_pk_ecdh,
746                [ _gnupg_gcry_save_cflags=$CFLAGS
747                  CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
748                  AC_TRY_COMPILE(
749                    [#include <gcrypt>],
750                    [ return GCRY_PK_ECDH; ],
751                    gnupg_cv_gcry_pk_ecdh=yes,
752                    gnupg_cv_gcry_pk_ecdh=no)
753                  CFLAGS=$_gnupg_gcry_save_cflags])
754 if test "$gnupg_cv_gcry_pk_ecdh" = yes; then
755   AC_DEFINE([HAVE_GCRY_PK_ECDH], 1,
756             [Define if gcrypt.h has the enum value for ECDH.])
757 fi
758
759
760 #
761 # libassuan is used for IPC
762 #
763 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
764                   have_libassuan=yes,have_libassuan=no)
765 if test "$have_libassuan" = "yes"; then
766   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
767                      [version of the libassuan library])
768 fi
769
770
771
772 #
773 # libksba is our X.509 support library
774 #
775 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
776
777
778 #
779 # libusb allows us to use the integrated CCID smartcard reader driver.
780 #
781 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
782 if test "$use_ccid_driver" = yes ; then
783   AC_CHECK_LIB(usb, usb_bulk_write,
784                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
785                   AC_DEFINE(HAVE_LIBUSB,1,
786                            [defined if libusb is available])
787                   have_libusb=yes
788                ])
789   AC_CHECK_FUNCS(usb_create_match)
790 fi
791 AC_SUBST(LIBUSB_LIBS)
792
793 #
794 # Check wether it is necessary to link against libdl.
795 #
796 gnupg_dlopen_save_libs="$LIBS"
797 LIBS=""
798 AC_SEARCH_LIBS(dlopen, c dl,,,)
799 DL_LIBS=$LIBS
800 AC_SUBST(DL_LIBS)
801 LIBS="$gnupg_dlopen_save_libs"
802
803 # Checks for g13
804
805 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
806 AC_DEFINE_UNQUOTED(ENCFS,
807         "${ENCFS}", [defines the filename of the encfs program])
808
809 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
810 AC_DEFINE_UNQUOTED(FUSERMOUNT,
811         "${FUSERMOUNT}", [defines the filename of the fusermount program])
812
813
814 # Checks for dirmngr
815
816
817 #
818 # Checks for symcryptrun:
819 #
820
821 # libutil has openpty() and login_tty().
822 AC_CHECK_LIB(util, openpty,
823               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
824                 AC_DEFINE(HAVE_LIBUTIL,1,
825                          [defined if libutil is available])
826              ])
827 AC_SUBST(LIBUTIL_LIBS)
828
829 # shred is used to clean temporary plain text files.
830 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
831 AC_DEFINE_UNQUOTED(SHRED,
832         "${SHRED}", [defines the filename of the shred program])
833
834
835 #
836 # Check whether the GNU Pth library is available
837 # Note, that we include a Pth emulation for W32.
838 #
839 if test "$have_w32_system" = yes; then
840   GNUPG_PATH_PTH([2.0.4])
841 else
842   GNUPG_PATH_PTH
843 fi
844 if test "$have_pth" = "yes"; then
845   AC_DEFINE(USE_GNU_PTH, 1,
846               [Defined if the GNU Portable Thread Library should be used])
847 else
848   AC_MSG_WARN([[
849 ***
850 *** To support concurrent access to the gpg-agent and the SCdaemon
851 *** we need the support of the GNU Portable Threads Library.
852 *** Download it from ftp://ftp.gnu.org/gnu/pth/
853 *** On a Debian GNU/Linux system you might want to try 
854 ***   apt-get install libpth-dev
855 ***]])
856 fi
857
858
859 AC_MSG_NOTICE([checking for networking options])
860
861 #
862 # Must check for network library requirements before doing link tests
863 # for ldap, for example. If ldap libs are static (or dynamic and without
864 # ELF runtime link paths), then link will fail and LDAP support won't
865 # be detected.
866 #
867 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
868         [NETLIBS="-lnsl $NETLIBS"]))
869 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
870         [NETLIBS="-lsocket $NETLIBS"]))
871
872
873 #
874 # Check for ADNS.
875 #
876 _cppflags="${CPPFLAGS}"
877 _ldflags="${LDFLAGS}"
878 AC_ARG_WITH(adns,
879             AC_HELP_STRING([--with-adns=DIR],
880                            [look for the adns library in DIR]),
881             [if test -d "$withval"; then
882                CPPFLAGS="${CPPFLAGS} -I$withval/include"
883                LDFLAGS="${LDFLAGS} -L$withval/lib"
884              fi])
885 if test "$with_adns" != "no"; then
886   AC_CHECK_HEADERS(adns.h,
887                 AC_CHECK_LIB(adns, adns_init,
888                              [have_adns=yes],
889                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
890                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
891 fi
892 if test "$have_adns" = "yes"; then
893   ADNSLIBS="-ladns" 
894 fi
895 AC_SUBST(ADNSLIBS)
896 # Newer adns versions feature a free function to be used under W32.
897 AC_CHECK_FUNCS(adns_free)
898
899
900
901 #
902 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
903 #
904 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
905   AC_ARG_ENABLE(dns-srv,
906      AC_HELP_STRING([--disable-dns-srv],
907                     [disable the use of DNS SRV in HKP and HTTP]),
908                 use_dns_srv=$enableval,use_dns_srv=yes)
909 fi
910
911 AC_ARG_ENABLE(dns-pka,
912    AC_HELP_STRING([--disable-dns-pka],
913         [disable the use of PKA records in DNS]),
914    use_dns_pka=$enableval,use_dns_pka=yes)
915
916 AC_ARG_ENABLE(dns-cert,
917    AC_HELP_STRING([--disable-dns-cert],
918         [disable the use of CERT records in DNS]),
919    use_dns_cert=$enableval,use_dns_cert=yes)
920
921 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
922    || test x"$use_dns_cert" = xyes; then
923   _dns_save_libs=$LIBS
924   LIBS=""
925   # the double underscore thing is a glibc-ism?
926   AC_SEARCH_LIBS(res_query,resolv bind,,
927                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
928   AC_SEARCH_LIBS(dn_expand,resolv bind,,
929                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
930   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
931                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
932
933   if test x"$have_resolver" != xno ; then
934
935     # Make sure that the BIND 4 resolver interface is workable before
936     # enabling any code that calls it.  At some point I'll rewrite the
937     # code to use the BIND 8 resolver API.
938     # We might also want to use adns instead.  Problem with ADNS is that
939     # it does not support v6.
940
941     AC_MSG_CHECKING([whether the resolver is usable])
942     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
943 #include <netinet/in.h>
944 #include <arpa/nameser.h>
945 #include <resolv.h>],
946 [[unsigned char answer[PACKETSZ];
947   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
948   dn_skipname(0,0); 
949   dn_expand(0,0,0,0,0);
950 ]])],have_resolver=yes,have_resolver=no)
951     AC_MSG_RESULT($have_resolver)
952
953     # This is Apple-specific and somewhat bizarre as they changed the
954     # define in bind 8 for some reason.
955
956     if test x"$have_resolver" != xyes ; then
957        AC_MSG_CHECKING(
958              [whether I can make the resolver usable with BIND_8_COMPAT])
959        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
960 #include <sys/types.h>
961 #include <netinet/in.h>
962 #include <arpa/nameser.h>
963 #include <resolv.h>],
964 [[unsigned char answer[PACKETSZ];
965   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
966   dn_skipname(0,0); dn_expand(0,0,0,0,0);
967 ]])],[have_resolver=yes ; need_compat=yes])
968        AC_MSG_RESULT($have_resolver)
969     fi
970   fi
971
972   if test x"$have_resolver" = xyes ; then
973      DNSLIBS=$LIBS
974
975      if test x"$use_dns_srv" = xyes ; then
976         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
977      fi
978
979      if test x"$use_dns_pka" = xyes ; then
980         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
981      fi
982
983      if test x"$use_dns_cert" = xyes ; then
984         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
985      fi
986
987      if test x"$need_compat" = xyes ; then
988         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
989      fi
990   else
991      # If we have no resolver library but ADNS (e.g. under W32) enable the
992      # code parts which can be used with ADNS.
993      if test x"$have_adns" = xyes ; then
994         DNSLIBS="$ADNSLIBS"
995         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
996
997         if test x"$use_dns_srv" = xyes ; then
998            AC_DEFINE(USE_DNS_SRV,1)
999         fi
1000
1001         if test x"$use_dns_pka" = xyes ; then
1002            AC_DEFINE(USE_DNS_PKA,1)
1003         fi
1004
1005         if test x"$use_dns_cert" = xyes ; then
1006            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1007         fi
1008      else
1009         use_dns_srv=no
1010         use_dns_pka=no
1011         use_dns_cert=no
1012      fi
1013   fi
1014
1015   LIBS=$_dns_save_libs
1016 fi
1017
1018 AC_SUBST(DNSLIBS)
1019
1020 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1021
1022
1023 #
1024 # Check for LDAP
1025 #
1026 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1027    GNUPG_CHECK_LDAP($NETLIBS)
1028 fi
1029
1030 #
1031 # Check for curl.  We fake the curl API if libcurl isn't installed.
1032 # We require 7.10 or later as we use curl_version_info().
1033 #
1034 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1035 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1036
1037 # Generic, for us, means curl
1038
1039 if test x"$try_generic" = xyes ; then
1040    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1041 fi
1042
1043 #
1044 # Check for sendmail
1045 #
1046 # This isn't necessarily sendmail itself, but anything that gives a
1047 # sendmail-ish interface to the outside world.  That includes Exim,
1048 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1049 if test "$try_mailto" = yes ; then
1050   AC_ARG_WITH(mailprog,
1051       AC_HELP_STRING([--with-mailprog=NAME],
1052                      [use "NAME -t" for mail transport]),
1053              ,with_mailprog=yes)
1054
1055   if test x"$with_mailprog" = xyes ; then
1056     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1057     if test "$ac_cv_path_SENDMAIL" ; then
1058       GPGKEYS_MAILTO="gpg2keys_mailto"
1059     fi
1060   elif test x"$with_mailprog" != xno ; then
1061     AC_MSG_CHECKING([for a mail transport program])
1062     AC_SUBST(SENDMAIL,$with_mailprog)
1063     AC_MSG_RESULT($with_mailprog)
1064     GPGKEYS_MAILTO="gpg2keys_mailto"
1065   fi
1066 fi
1067
1068 AC_SUBST(GPGKEYS_MAILTO)
1069
1070 #
1071 # Construct a printable name of the OS
1072 #
1073 case "${host}" in
1074     *-mingw32ce*)
1075         PRINTABLE_OS_NAME="W32CE"
1076         ;;
1077     *-mingw32*)
1078         PRINTABLE_OS_NAME="MingW32"
1079         ;;
1080     *-*-cygwin*)
1081         PRINTABLE_OS_NAME="Cygwin"
1082         ;;
1083     i?86-emx-os2 | i?86-*-os2*emx )
1084         PRINTABLE_OS_NAME="OS/2"
1085         ;;
1086     i?86-*-msdosdjgpp*)
1087         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1088         try_dynload=no
1089         ;;
1090     *-linux*)
1091         PRINTABLE_OS_NAME="GNU/Linux"
1092         ;;
1093     *)
1094         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1095         ;;
1096 esac
1097 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1098                    [A human readable text with the name of the OS])
1099
1100
1101 #
1102 # Checking for iconv
1103 #
1104 AM_ICONV
1105
1106
1107 #
1108 # Check for gettext
1109 #
1110 # This is "GNU gnupg" - The project-id script from gettext
1111 #                       needs this string
1112 #
1113 AC_MSG_NOTICE([checking for gettext])
1114 AM_PO_SUBDIRS
1115 AM_GNU_GETTEXT_VERSION([0.17])
1116 if test "$try_gettext" = yes; then
1117   AM_GNU_GETTEXT([external],[need-ngettext])
1118
1119   # gettext requires some extra checks.  These really should be part of
1120   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1121   # function checks to here.
1122
1123   AC_CHECK_FUNCS(strchr)
1124 else
1125   USE_NLS=no
1126   USE_INCLUDED_LIBINTL=no
1127   BUILD_INCLUDED_LIBINTL=no
1128   POSUB=po
1129   AC_SUBST(USE_NLS)
1130   AC_SUBST(USE_INCLUDED_LIBINTL)
1131   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1132   AC_SUBST(POSUB)
1133 fi
1134
1135 # We use HAVE_LANGINFO_CODESET in a couple of places.
1136 AM_LANGINFO_CODESET
1137
1138 # Checks required for our use locales
1139 gt_LC_MESSAGES
1140
1141
1142 #
1143 # SELinux support
1144 #
1145 if test "$selinux_support" = yes ; then
1146   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1147 fi
1148
1149
1150 #
1151 # Checks for header files.
1152 #
1153 AC_MSG_NOTICE([checking for header files])
1154 AC_HEADER_STDC
1155 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1156                   pty.h pwd.h inttypes.h signal.h])
1157 AC_HEADER_TIME
1158
1159
1160 #
1161 # Checks for typedefs, structures, and compiler characteristics.
1162 #
1163 AC_MSG_NOTICE([checking for system characteristics])
1164 AC_C_CONST
1165 AC_C_INLINE
1166 AC_C_VOLATILE
1167 AC_TYPE_SIZE_T
1168 AC_TYPE_MODE_T
1169 AC_TYPE_SIGNAL
1170 AC_DECL_SYS_SIGLIST
1171
1172 gl_HEADER_SYS_SOCKET
1173 gl_TYPE_SOCKLEN_T
1174
1175 AC_ARG_ENABLE(endian-check,
1176               AC_HELP_STRING([--disable-endian-check],
1177               [disable the endian check and trust the OS provided macros]),
1178               endiancheck=$enableval,endiancheck=yes)
1179
1180 if test x"$endiancheck" = xyes ; then
1181   GNUPG_CHECK_ENDIAN
1182 fi
1183
1184 # fixme: we should get rid of the byte type
1185 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1186 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1187 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1188 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1189 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1190
1191 AC_CHECK_SIZEOF(unsigned short)
1192 AC_CHECK_SIZEOF(unsigned int)
1193 AC_CHECK_SIZEOF(unsigned long)
1194 AC_CHECK_SIZEOF(unsigned long long)
1195 AC_HEADER_TIME
1196 AC_CHECK_SIZEOF(time_t,,[[
1197 #include <stdio.h>
1198 #if TIME_WITH_SYS_TIME
1199 # include <sys/time.h>
1200 # include <time.h>
1201 #else
1202 # if HAVE_SYS_TIME_H
1203 #  include <sys/time.h>
1204 # else
1205 #  include <time.h>
1206 # endif
1207 #endif
1208 ]])
1209 GNUPG_TIME_T_UNSIGNED
1210
1211
1212 # Ensure that we have UINT64_C before we bother to check for uint64_t
1213 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1214 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1215    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1216        uint64_t foo=UINT64_C(42);]),
1217      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1218 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1219    AC_CHECK_SIZEOF(uint64_t)
1220 fi
1221
1222 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1223    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1224    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1225     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1226 fi
1227
1228
1229 #
1230 # Checks for library functions.
1231 #
1232 AC_MSG_NOTICE([checking for library functions])
1233 AC_CHECK_DECLS(getpagesize)
1234 AC_FUNC_FSEEKO
1235 AC_FUNC_VPRINTF
1236 AC_FUNC_FORK
1237 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1238 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1239 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1240 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1241 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1242 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1243 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1244
1245 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1246
1247 # Dirmngr requires mmap on Unix systems.
1248 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1249   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1250 fi
1251
1252 #
1253 # These are needed by the jnlib parts in common.
1254 # Note:  We already checked pwd.h.
1255 AC_CHECK_HEADERS([signal.h])
1256 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1257                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1258                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1259                 getenv inet_pton])
1260 # end jnlib checks.
1261
1262
1263
1264 #
1265 # gnulib checks
1266 #
1267 gl_SOURCE_BASE([gl])
1268 gl_M4_BASE([gl/m4])
1269 gl_MODULES([setenv mkdtemp xsize strpbrk])
1270 gl_INIT
1271
1272
1273 #
1274 # W32 specific test
1275 #
1276 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1277
1278 #
1279 # Sanity check regex.  Tests adapted from mutt.
1280 #
1281 AC_MSG_CHECKING([whether regular expression support is requested])
1282 AC_ARG_ENABLE(regex,
1283   AC_HELP_STRING([--disable-regex],
1284     [do not handle regular expressions in trust signatures]),
1285   use_regex=$enableval, use_regex=yes)
1286 AC_MSG_RESULT($use_regex)
1287
1288 if test "$use_regex" = yes ; then
1289   _cppflags="${CPPFLAGS}"
1290   _ldflags="${LDFLAGS}"
1291   AC_ARG_WITH(regex,
1292      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1293       [
1294       if test -d "$withval" ; then
1295         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1296         LDFLAGS="${LDFLAGS} -L$withval/lib"
1297       fi
1298       ],withval="")     
1299
1300   # Does the system have regex functions at all?
1301   AC_SEARCH_LIBS([regcomp], [regex])
1302   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1303
1304   if test $gnupg_cv_have_regex = no; then
1305     use_regex=no
1306   else
1307     if test x"$cross_compiling" = xyes; then
1308       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1309     else
1310       AC_CACHE_CHECK([whether your system's regexp library is broken],
1311        [gnupg_cv_regex_broken],
1312        AC_TRY_RUN([
1313 #include <unistd.h>
1314 #include <regex.h>
1315 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1316        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1317
1318       if test $gnupg_cv_regex_broken = yes; then
1319         AC_MSG_WARN([your regex is broken - disabling regex use])
1320         use_regex=no
1321       fi
1322     fi
1323   fi
1324   CPPFLAGS="${_cppflags}"
1325   LDFLAGS="${_ldflags}"
1326 fi
1327
1328 if test "$use_regex" != yes ; then
1329   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1330 fi
1331 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1332
1333
1334
1335 #
1336 # Do we have zlib? Must do it here because Solaris failed
1337 # when compiling a conftest (due to the "-lz" from LIBS).
1338 # Note that we combine zlib and bzlib2 in ZLIBS.
1339 #
1340 if test "$use_zip" = yes ; then
1341   _cppflags="${CPPFLAGS}"
1342   _ldflags="${LDFLAGS}"
1343   AC_ARG_WITH(zlib,
1344     [  --with-zlib=DIR         use libz in DIR],[
1345       if test -d "$withval"; then
1346         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1347         LDFLAGS="${LDFLAGS} -L$withval/lib"
1348       fi
1349     ])
1350   
1351   AC_CHECK_HEADER(zlib.h,
1352         AC_CHECK_LIB(z, deflateInit2_,
1353          ZLIBS="-lz",
1354          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1355          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1356          
1357   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1358 fi
1359
1360
1361 #
1362 # Check whether we can support bzip2
1363
1364 if test "$use_bzip2" = yes ; then
1365   _cppflags="${CPPFLAGS}"
1366   _ldflags="${LDFLAGS}"
1367   AC_ARG_WITH(bzip2,
1368      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1369       [
1370       if test -d "$withval" ; then
1371         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1372         LDFLAGS="${LDFLAGS} -L$withval/lib"
1373       fi
1374       ],withval="")
1375
1376   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1377   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1378   # woefully out of date.
1379   if test "$withval" != no ; then
1380      AC_CHECK_HEADER(bzlib.h,
1381         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1382           [
1383           have_bz2=yes
1384           ZLIBS="$ZLIBS -lbz2"
1385           AC_DEFINE(HAVE_BZIP2,1,
1386                   [Defined if the bz2 compression library is available])
1387           ],
1388           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1389           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1390   fi
1391 fi
1392 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1393 AC_SUBST(ZLIBS)
1394
1395
1396 # Check for readline support
1397 GNUPG_CHECK_READLINE
1398
1399 #
1400 # Allow users to append something to the version string without
1401 # flagging it as development version.  The user version parts is
1402 # considered everything after a dash. 
1403 #
1404 if test "$development_version" != yes; then
1405   changequote(,)dnl
1406   tmp_pat='[a-zA-Z]'
1407   changequote([,])dnl
1408   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1409     development_version=yes
1410   fi
1411 fi
1412 if test "$development_version" = yes; then
1413     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1414             [Defined if this is not a regular release])
1415 fi
1416
1417 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1418
1419 GNUPG_CHECK_GNUMAKE
1420
1421 # Add some extra libs here so that previous tests don't fail for
1422 # mysterious reasons - the final link step should bail out.
1423 # W32SOCKLIBS is also defined so that if can be used for tools not
1424 # requiring any network stuff but linking to code in libcommon which
1425 # tracks in winsock stuff (e.g. init_common_subsystems).
1426 if test "$have_w32_system" = yes; then
1427    if test "$have_w32ce_system" = yes; then
1428      W32SOCKLIBS="-lws2"
1429    else
1430      W32SOCKLIBS="-lws2_32"
1431    fi
1432    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1433 fi
1434
1435 AC_SUBST(NETLIBS)
1436 AC_SUBST(W32SOCKLIBS)
1437
1438 #
1439 # Setup gcc specific options
1440 #
1441 AC_MSG_NOTICE([checking for cc features])
1442 if test "$GCC" = yes; then
1443     # Note that it is okay to use CFLAGS here because this are just
1444     # warning options and the user should have a chance of overriding
1445     # them.
1446     if test "$USE_MAINTAINER_MODE" = "yes"; then
1447         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1448         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1449         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1450         _gcc_cflags_save=$CFLAGS
1451         CFLAGS="-Wno-missing-field-initializers"
1452         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1453         AC_MSG_RESULT($_gcc_wopt)
1454         CFLAGS=$_gcc_cflags_save;
1455         if test x"$_gcc_wopt" = xyes ; then
1456           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1457         fi
1458         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1459         _gcc_cflags_save=$CFLAGS
1460         CFLAGS="-Wdeclaration-after-statement"
1461         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1462         AC_MSG_RESULT($_gcc_wopt)
1463         CFLAGS=$_gcc_cflags_save;
1464         if test x"$_gcc_wopt" = xyes ; then
1465           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1466         fi
1467     else
1468         CFLAGS="$CFLAGS -Wall"
1469     fi
1470
1471     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1472     _gcc_cflags_save=$CFLAGS
1473     CFLAGS="-Wno-pointer-sign"
1474     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1475     AC_MSG_RESULT($_gcc_psign)
1476     CFLAGS=$_gcc_cflags_save;
1477     if test x"$_gcc_psign" = xyes ; then
1478        CFLAGS="$CFLAGS -Wno-pointer-sign"
1479     fi
1480
1481     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1482     _gcc_cflags_save=$CFLAGS
1483     CFLAGS="-Wpointer-arith"
1484     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1485     AC_MSG_RESULT($_gcc_psign)
1486     CFLAGS=$_gcc_cflags_save;
1487     if test x"$_gcc_psign" = xyes ; then
1488        CFLAGS="$CFLAGS -Wpointer-arith"
1489     fi
1490 fi
1491
1492
1493 #
1494 # This is handy for debugging so the compiler doesn't rearrange
1495 # things and eliminate variables.
1496 #
1497 AC_ARG_ENABLE(optimization,
1498    AC_HELP_STRING([--disable-optimization],
1499                   [disable compiler optimization]),
1500                   [if test $enableval = no ; then
1501                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1502                    fi])
1503
1504 #
1505 # Prepare building of estream
1506 #
1507 estream_INIT
1508
1509
1510 #
1511 # Decide what to build
1512 #
1513 if test "$have_adns" = "yes"; then
1514   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1515 fi
1516
1517
1518 missing_pth=no
1519 if test $have_ksba = no; then
1520   build_gpgsm=no
1521   build_scdaemon=no
1522 fi
1523
1524 build_agent_threaded=""
1525 if test "$build_agent" = "yes"; then
1526   if test $have_pth = no; then
1527      build_agent_threaded="(not multi-threaded)"
1528      missing_pth=yes
1529   fi
1530 fi
1531
1532 build_scdaemon_extra=""
1533 if test "$build_scdaemon" = "yes"; then
1534   tmp=""
1535   if test $have_pth = no; then
1536      build_scdaemon_extra="not multi-threaded"
1537      tmp=", "
1538      missing_pth=yes
1539   fi
1540   if test $have_libusb = no; then
1541      build_scdaemon_extra="${tmp}without internal CCID driver"
1542      tmp=", "
1543   fi
1544   if test -n "$build_scdaemon_extra"; then
1545      build_scdaemon_extra="(${build_scdaemon_extra})"
1546   fi
1547 fi
1548
1549
1550 if test "$build_agent_only" = "yes" ; then
1551   build_gpg=no
1552   build_gpgsm=no
1553   build_scdaemon=no
1554   build_tools=no
1555   build_doc=no
1556 fi
1557
1558 #
1559 # Set variables for use by th automake makefile.
1560 #
1561 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1562 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1563 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1564 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1565 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1566 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1567 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1568 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1569 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1570 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1571
1572 AM_CONDITIONAL(RUN_GPG_TESTS,
1573                test x$cross_compiling = xno -a "$build_gpg" = yes )
1574
1575
1576 # Set some defines for use gpgconf.
1577 #
1578 if test "$build_gpg" = yes ; then
1579     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1580 fi
1581 if test "$build_gpgsm" = yes ; then
1582     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1583 fi
1584 if test "$build_agent" = yes ; then
1585     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1586 fi
1587 if test "$build_scdaemon" = yes ; then
1588     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1589 fi
1590 if test "$build_dirmngr" = yes ; then
1591     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1592 fi
1593 if test "$build_g13" = yes ; then
1594     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1595 fi
1596
1597
1598
1599 #
1600 # Print errors here so that they are visible all
1601 # together and the user can acquire them all together.
1602 #
1603 die=no
1604 if test "$have_gpg_error" = "no"; then
1605    die=yes
1606    AC_MSG_NOTICE([[
1607 ***  
1608 *** You need libgpg-error to build this program.
1609 **  This library is for example available at
1610 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1611 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1612 ***]])
1613 fi
1614 if test "$have_libgcrypt" = "no"; then
1615    die=yes
1616    AC_MSG_NOTICE([[
1617 ***  
1618 *** You need libgcrypt to build this program.
1619 **  This library is for example available at
1620 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1621 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1622 ***]])
1623 fi
1624 if test "$have_libassuan" = "no"; then
1625    die=yes
1626    AC_MSG_NOTICE([[
1627 ***
1628 *** You need libassuan to build this program.
1629 *** This library is for example available at
1630 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1631 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1632 ***]])
1633 fi
1634 if test "$have_ksba" = "no"; then
1635     AC_MSG_NOTICE([[
1636 ***
1637 *** You need libksba to build this program.
1638 *** This library is for example available at
1639 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1640 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1641 ***]])
1642 fi
1643 if test "$gnupg_have_ldap" = "no"; then
1644     die=yes
1645     AC_MSG_NOTICE([[
1646 ***
1647 *** You need a LDAP library to build this program.
1648 *** Check out 
1649 ***    http://www.openldap.org 
1650 *** for a suitable implementation.
1651 ***]])
1652    if test "$have_w32ce_system" = yes; then
1653     AC_MSG_NOTICE([[
1654 *** Note that CeGCC might be broken, a package fixing this is:
1655 ***    http://files.kolab.org/local/windows-ce/ 
1656 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1657 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1658 ***]])
1659    fi
1660 fi
1661 if test "$missing_pth" = "yes"; then
1662     AC_MSG_NOTICE([[
1663 ***
1664 *** It is now required to build with support for the
1665 *** GNU Portable Threads Library (Pth). Please install this
1666 *** library first.  The library is for example available at
1667 ***   ftp://ftp.gnu.org/gnu/pth/
1668 *** On a Debian GNU/Linux system you can install it using 
1669 ***   apt-get install libpth-dev
1670 *** To build GnuPG for Windows you need to use the W32PTH
1671 *** package; available at:
1672 ***   ftp://ftp.g10code.com/g10code/w32pth/
1673 ***]])
1674    die=yes
1675 fi
1676
1677 if test "$die" = "yes"; then
1678     AC_MSG_ERROR([[
1679 ***
1680 *** Required libraries not found. Please consult the above messages
1681 *** and install them before running configure again.
1682 ***]])
1683 fi
1684
1685
1686
1687 AC_CONFIG_FILES([ m4/Makefile 
1688 Makefile
1689 po/Makefile.in
1690 gl/Makefile
1691 include/Makefile
1692 common/Makefile
1693 kbx/Makefile
1694 g10/Makefile
1695 sm/Makefile
1696 agent/Makefile
1697 scd/Makefile
1698 g13/Makefile
1699 dirmngr/Makefile
1700 tools/gpg-zip
1701 tools/Makefile
1702 doc/Makefile
1703 tests/Makefile
1704 tests/openpgp/Makefile
1705 tests/pkits/Makefile
1706 ])
1707 #keyserver/Makefile
1708 #keyserver/gpg2keys_mailto
1709 #keyserver/gpg2keys_test
1710
1711
1712 AC_OUTPUT
1713
1714
1715 echo "
1716         GnuPG v${VERSION} has been configured as follows:
1717         
1718         Platform:  $PRINTABLE_OS_NAME ($host)
1719
1720         OpenPGP:   $build_gpg
1721         S/MIME:    $build_gpgsm
1722         Agent:     $build_agent $build_agent_threaded
1723         Smartcard: $build_scdaemon $build_scdaemon_extra
1724         G13:       $build_g13
1725         Dirmngr:   $build_dirmngr
1726         Gpgtar:    $build_gpgtar
1727
1728         Protect tool:      $show_gnupg_protect_tool_pgm
1729         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1730         Default agent:     $show_gnupg_agent_pgm
1731         Default pinentry:  $show_gnupg_pinentry_pgm
1732         Default scdaemon:  $show_gnupg_scdaemon_pgm
1733         Default dirmngr:   $show_gnupg_dirmngr_pgm
1734
1735         Use standard socket: $use_standard_socket
1736         Dirmngr auto start:  $dirmngr_auto_start
1737 "
1738 if test x"$use_regex" != xyes ; then
1739 echo "
1740         Warning: No regular expression support available.
1741                  OpenPGP trust signatures won't work.
1742                  gpg-check-pattern will not be build.
1743 "
1744 fi