scd: Migrate to new API of libusb 1.0.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [12])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.21
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.1
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=yes
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132
133 AC_SUBST(PACKAGE)
134 AC_SUBST(PACKAGE_GT)
135 AC_SUBST(VERSION)
136 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
137 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
138                                 [Name of this package for gettext])
139 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
141                                         [Bug report address])
142 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
143                                        [Required version of Libgcrypt])
144 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
145                                        [Required version of Libksba])
146 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
147                                        [Required version of NTBTLS])
148
149
150
151 # The default is to use the modules from this package and the few
152 # other packages in a standard place; i.e where this package gets
153 # installed.  With these options it is possible to override these
154 # ${prefix} depended values with fixed paths, which can't be replaced
155 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
156 AC_ARG_WITH(agent-pgm,
157     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
158           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
159 AC_SUBST(GNUPG_AGENT_PGM)
160 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
161 show_gnupg_agent_pgm="(default)"
162 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
163
164 AC_ARG_WITH(pinentry-pgm,
165     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
166           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
167 AC_SUBST(GNUPG_PINENTRY_PGM)
168 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
169 show_gnupg_pinentry_pgm="(default)"
170 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
171
172
173 AC_ARG_WITH(scdaemon-pgm,
174     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
175           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
176 AC_SUBST(GNUPG_SCDAEMON_PGM)
177 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
178 show_gnupg_scdaemon_pgm="(default)"
179 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
180
181
182 AC_ARG_WITH(dirmngr-pgm,
183     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
184           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
185 AC_SUBST(GNUPG_DIRMNGR_PGM)
186 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
187 show_gnupg_dirmngr_pgm="(default)"
188 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
189
190 AC_ARG_WITH(protect-tool-pgm,
191     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
192           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
193 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
194 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
195 show_gnupg_protect_tool_pgm="(default)"
196 test -n "$GNUPG_PROTECT_TOOL_PGM" \
197       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
198
199 AC_ARG_WITH(dirmngr-ldap-pgm,
200     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
201           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
202 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
203 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
204 show_gnupg_dirmngr_ldap_pgm="(default)"
205 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
206       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
207
208 #
209 # On some platforms gpg2 is usually installed as gpg without using a
210 # symlink.  For correct operation of gpgconf it needs to know the
211 # installed name of gpg.  This option sets "gpg2"'s installed name to
212 # just "gpg".  Note that it might be required to rename gpg2 to gpg
213 # manually after the build process.
214 #
215 AC_ARG_ENABLE(gpg2-is-gpg,
216     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
217     gpg2_is_gpg=$enableval)
218 if test "$gpg2_is_gpg" = "yes"; then
219    name_of_installed_gpg=gpg
220 else
221    name_of_installed_gpg=gpg2
222 fi
223 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
224                    [The name of the installed GPG tool])
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=yes)
267 AC_MSG_RESULT($use_tofu)
268
269
270
271 #
272 # Options to disable algorithm
273 #
274
275 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
276 # Elgamal is a MUST algorithm
277 # DSA is a MUST algorithm
278 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
279 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
280 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
281
282 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
283 # 3DES is a MUST algorithm
284 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
285 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
286 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
287 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
288 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
289 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
290 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
291 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
292 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
293
294 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
295 # SHA1 is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
297 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
298 # SHA256 is a MUST algorithm for GnuPG.
299 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
301
302
303 # Allow disabling of zip support.
304 # This is in general not a good idea because according to rfc4880 OpenPGP
305 # implementations SHOULD support ZLIB.
306 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
307 AC_ARG_ENABLE(zip,
308    AC_HELP_STRING([--disable-zip],
309                   [disable the ZIP and ZLIB compression algorithm]),
310    use_zip=$enableval)
311 AC_MSG_RESULT($use_zip)
312
313 # Allow disabling of bzib2 support.
314 # It is defined only after we confirm the library is available later
315 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
316 AC_ARG_ENABLE(bzip2,
317    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
318    use_bzip2=$enableval)
319 AC_MSG_RESULT($use_bzip2)
320
321 # Configure option to allow or disallow execution of external
322 # programs, like a photo viewer.
323 AC_MSG_CHECKING([whether to enable external program execution])
324 AC_ARG_ENABLE(exec,
325     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
326     use_exec=$enableval)
327 AC_MSG_RESULT($use_exec)
328 if test "$use_exec" = no ; then
329     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
330 fi
331
332 if test "$use_exec" = yes ; then
333   AC_MSG_CHECKING([whether to enable photo ID viewing])
334   AC_ARG_ENABLE(photo-viewers,
335       [  --disable-photo-viewers disable photo ID viewers],
336       [if test "$enableval" = no ; then
337          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
338       fi],enableval=yes)
339   gnupg_cv_enable_photo_viewers=$enableval
340   AC_MSG_RESULT($enableval)
341
342   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
343     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
344     AC_ARG_WITH(photo-viewer,
345         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
346         [if test "$withval" = yes ; then
347            withval=no
348         elif test "$withval" != no ; then
349            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
350                             [if set, restrict photo-viewer to this])
351         fi],withval=no)
352     AC_MSG_RESULT($withval)
353   fi
354 fi
355
356
357 #
358 # Check for the key/uid cache size.  This can't be zero, but can be
359 # pretty small on embedded systems.  This is used for the gpg part.
360 #
361 AC_MSG_CHECKING([for the size of the key and uid cache])
362 AC_ARG_ENABLE(key-cache,
363         AC_HELP_STRING([--enable-key-cache=SIZE],
364                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
365 if test "$enableval" = "no"; then
366    enableval=5
367 elif test "$enableval" = "yes" || test "$enableval" = ""; then
368    enableval=4096
369 fi
370 changequote(,)dnl
371 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
372 changequote([,])dnl
373 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
374    AC_MSG_ERROR([invalid key-cache size])
375 fi
376 AC_MSG_RESULT($key_cache_size)
377 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
378                   [Size of the key and UID caches])
379
380
381
382 #
383 # Check whether we want to use Linux capabilities
384 #
385 AC_MSG_CHECKING([whether use of capabilities is requested])
386 AC_ARG_WITH(capabilities,
387     [  --with-capabilities     use linux capabilities [default=no]],
388 [use_capabilities="$withval"],[use_capabilities=no])
389 AC_MSG_RESULT($use_capabilities)
390
391 #
392 # Check whether to disable the card support
393 AC_MSG_CHECKING([whether smartcard support is requested])
394 AC_ARG_ENABLE(card-support,
395               AC_HELP_STRING([--disable-card-support],
396                              [disable smartcard support]),
397               card_support=$enableval)
398 AC_MSG_RESULT($card_support)
399 if test "$card_support" = yes ; then
400   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
401 else
402   build_scdaemon=no
403 fi
404
405 #
406 # Allow disabling of internal CCID support.
407 # It is defined only after we confirm the library is available later
408 #
409 AC_MSG_CHECKING([whether to enable the internal CCID driver])
410 AC_ARG_ENABLE(ccid-driver,
411               AC_HELP_STRING([--disable-ccid-driver],
412                              [disable the internal CCID driver]),
413               use_ccid_driver=$enableval)
414 AC_MSG_RESULT($use_ccid_driver)
415
416 AC_MSG_CHECKING([whether to auto start dirmngr])
417 AC_ARG_ENABLE(dirmngr-auto-start,
418               AC_HELP_STRING([--disable-dirmngr-auto-start],
419                              [disable auto starting of the dirmngr]),
420               dirmngr_auto_start=$enableval)
421 AC_MSG_RESULT($dirmngr_auto_start)
422 if test "$dirmngr_auto_start" = yes ; then
423     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
424               [Define to enable auto starting of the dirmngr])
425 fi
426
427
428 #
429 # To avoid double inclusion of config.h which might happen at some
430 # places, we add the usual double inclusion protection at the top of
431 # config.h.
432 #
433 AH_TOP([
434 #ifndef GNUPG_CONFIG_H_INCLUDED
435 #define GNUPG_CONFIG_H_INCLUDED
436 ])
437
438 #
439 # Stuff which goes at the bottom of config.h.
440 #
441 AH_BOTTOM([
442 /* This is the major version number of GnuPG so that
443    source included files can test for this.  Note, that
444    we use 2 here even for GnuPG 1.9.x. */
445 #define GNUPG_MAJOR_VERSION 2
446
447 /* Now to separate file name parts.
448    Please note that the string version must not contain more
449    than one character because the code assumes strlen()==1 */
450 #ifdef HAVE_DOSISH_SYSTEM
451 #define DIRSEP_C '\\'
452 #define DIRSEP_S "\\"
453 #define EXTSEP_C '.'
454 #define EXTSEP_S "."
455 #define PATHSEP_C ';'
456 #define PATHSEP_S ";"
457 #define EXEEXT_S ".exe"
458 #else
459 #define DIRSEP_C '/'
460 #define DIRSEP_S "/"
461 #define EXTSEP_C '.'
462 #define EXTSEP_S "."
463 #define PATHSEP_C ':'
464 #define PATHSEP_S ":"
465 #define EXEEXT_S ""
466 #endif
467
468 /* This is the same as VERSION, but should be overridden if the
469    platform cannot handle things like dots '.' in filenames. Set
470    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
471    uses for dots and dashes. */
472 #define SAFE_VERSION VERSION
473 #define SAFE_VERSION_DOT  '.'
474 #define SAFE_VERSION_DASH '-'
475
476 /* Some global constants. */
477 #ifdef HAVE_DOSISH_SYSTEM
478 # ifdef HAVE_DRIVE_LETTERS
479 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
480 # else
481 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
482 # endif
483 #elif defined(__VMS)
484 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
485 #else
486 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
487 #endif
488 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
489 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
490
491 /* For some systems (DOS currently), we hardcode the path here.  For
492    POSIX systems the values are constructed by the Makefiles, so that
493    the values may be overridden by the make invocations; this is to
494    comply with the GNU coding standards.  Note that these values are
495    only defaults.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_BINDIR      "c:\\gnupg"
499 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
500 #  define GNUPG_LIBDIR      "c:\\gnupg"
501 #  define GNUPG_DATADIR     "c:\\gnupg"
502 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
503 # else
504 #  define GNUPG_BINDIR      "\\gnupg"
505 #  define GNUPG_LIBEXECDIR  "\\gnupg"
506 #  define GNUPG_LIBDIR      "\\gnupg"
507 #  define GNUPG_DATADIR     "\\gnupg"
508 #  define GNUPG_SYSCONFDIR  "\\gnupg"
509 # endif
510 #endif
511
512 /* Derive some other constants. */
513 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
514 #define EXEC_TEMPFILE_ONLY
515 #endif
516
517
518 /* We didn't define endianness above, so get it from OS macros.  This
519    is intended for making fat binary builds on OS X. */
520 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
521 #if defined(__BIG_ENDIAN__)
522 #define BIG_ENDIAN_HOST 1
523 #elif defined(__LITTLE_ENDIAN__)
524 #define LITTLE_ENDIAN_HOST 1
525 #else
526 #error "No endianness found"
527 #endif
528 #endif
529
530
531 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
532    ldap_start_tls_s because that is the actual symbol used in the
533    library.  winldap.h redefines it to our commonly used value,
534    thus we define our usual macro here.  */
535 #ifdef HAVE_LDAP_START_TLS_SA
536 # ifndef HAVE_LDAP_START_TLS_S
537 #  define HAVE_LDAP_START_TLS_S 1
538 # endif
539 #endif
540
541 /* Provide the es_ macro for estream.  */
542 #define GPGRT_ENABLE_ES_MACROS 1
543
544 /* Tell libgcrypt not to use its own libgpg-error implementation. */
545 #define USE_LIBGPG_ERROR 1
546
547 /* Tell Libgcrypt not to include deprecated definitions.  */
548 #define GCRYPT_NO_DEPRECATED 1
549
550 /* Our HTTP code is used in estream mode.  */
551 #define HTTP_USE_ESTREAM 1
552
553 /* Under W32 we do an explicit socket initialization, thus we need to
554    avoid the on-demand initialization which would also install an atexit
555    handler.  */
556 #define HTTP_NO_WSASTARTUP
557
558 /* Under Windows we use the gettext code from libgpg-error.  */
559 #define GPG_ERR_ENABLE_GETTEXT_MACROS
560
561 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
562 #define GPG_ERR_ENABLE_ERRNO_MACROS
563
564 #endif /*GNUPG_CONFIG_H_INCLUDED*/
565 ])
566
567
568 AM_MAINTAINER_MODE
569 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
570
571 # Checks for programs.
572 AC_MSG_NOTICE([checking for programs])
573 AC_PROG_MAKE_SET
574 AM_SANITY_CHECK
575 missing_dir=`cd $ac_aux_dir && pwd`
576 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
577 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
578 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
579 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
580 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
581 AM_SILENT_RULES
582 AC_PROG_AWK
583 AC_PROG_CC
584 AC_PROG_CPP
585 AM_PROG_CC_C_O
586 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
587   AC_MSG_ERROR([[No C-89 compiler found]])
588 fi
589 AC_PROG_INSTALL
590 AC_PROG_LN_S
591 AC_PROG_RANLIB
592 AC_CHECK_TOOL(AR, ar, :)
593 AC_PATH_PROG(PERL,"perl")
594 AC_CHECK_TOOL(WINDRES, windres, :)
595 AC_ISC_POSIX
596 AC_SYS_LARGEFILE
597 GNUPG_CHECK_USTAR
598
599
600 # We need to compile and run a program on the build machine.  A
601 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
602 # the AC archive is broken for autoconf 2.57.  Given that there is no
603 # newer version of that macro, we assume that it is also broken for
604 # autoconf 2.61 and thus we use a simple but usually sufficient
605 # approach.
606 AC_MSG_CHECKING(for cc for build)
607 if test "$cross_compiling" = "yes"; then
608   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
609 else
610   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
611 fi
612 AC_MSG_RESULT($CC_FOR_BUILD)
613 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
614
615 # We need to call this macro because other pkg-config macros are
616 # not always used.
617 PKG_PROG_PKG_CONFIG
618
619
620 try_gettext=yes
621 require_iconv=yes
622 have_dosish_system=no
623 have_w32_system=no
624 have_w32ce_system=no
625 have_android_system=no
626 run_tests=yes
627 use_simple_gettext=no
628 use_ldapwrapper=yes
629 mmap_needed=yes
630 case "${host}" in
631     *-mingw32*)
632         # special stuff for Windoze NT
633         ac_cv_have_dev_random=no
634         AC_DEFINE(USE_ONLY_8DOT3,1,
635                   [Set this to limit filenames to the 8.3 format])
636         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
637                   [Because the Unix gettext has too much overhead on
638                    MingW32 systems and these systems lack Posix functions,
639                    we use a simplified version of gettext])
640         have_dosish_system=yes
641         have_w32_system=yes
642         run_tests=no
643         use_ldapwrapper=no  # Fixme: Do this only for CE.
644         case "${host}" in
645           *-mingw32ce*)
646             have_w32ce_system=yes
647             ;;
648           *)
649             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
650                       [Defined if the OS supports drive letters.])
651             ;;
652         esac
653         try_gettext="no"
654         use_simple_gettext=yes
655         mmap_needed=no
656         ;;
657     i?86-emx-os2 | i?86-*-os2*emx )
658         # OS/2 with the EMX environment
659         ac_cv_have_dev_random=no
660         AC_DEFINE(HAVE_DRIVE_LETTERS)
661         have_dosish_system=yes
662         try_gettext="no"
663         ;;
664
665     i?86-*-msdosdjgpp*)
666         # DOS with the DJGPP environment
667         ac_cv_have_dev_random=no
668         AC_DEFINE(HAVE_DRIVE_LETTERS)
669         have_dosish_system=yes
670         try_gettext="no"
671         ;;
672
673     *-*-hpux*)
674         if test -z "$GCC" ; then
675             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
676         fi
677         ;;
678     *-dec-osf4*)
679         if test -z "$GCC" ; then
680             # Suppress all warnings
681             # to get rid of the unsigned/signed char mismatch warnings.
682             CFLAGS="-w $CFLAGS"
683         fi
684         ;;
685     *-dec-osf5*)
686         if test -z "$GCC" ; then
687             # Use the newer compiler `-msg_disable ptrmismatch1' to
688             # get rid of the unsigned/signed char mismatch warnings.
689             # Using this may hide other pointer mismatch warnings, but
690             # it at least lets other warning classes through
691             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
692         fi
693         ;;
694     m68k-atari-mint)
695         ;;
696     *-linux-androideabi)
697         have_android_system=yes
698         # Android is fully utf-8 and we do not want to use iconv to
699         # keeps things simple
700         require_iconv=no
701         run_tests=no
702         ;;
703     *)
704        ;;
705 esac
706
707 if test "$have_dosish_system" = yes; then
708    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
709              [Defined if we run on some of the PCDOS like systems
710               (DOS, Windoze. OS/2) with special properties like
711               no file modes, case insensitive file names and preferred
712               use of backslashes as directory name separators.])
713 fi
714 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
715
716 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
717
718 if test "$have_w32_system" = yes; then
719    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
720    if test "$have_w32ce_system" = yes; then
721       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
722    fi
723 fi
724 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
725 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
726
727 if test "$have_android_system" = yes; then
728    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
729 fi
730 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
731
732 if test "$run_tests" = yes; then
733    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
734 fi
735 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
736
737
738 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
739 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
740
741
742 #
743 # Checks for libraries.
744 #
745 AC_MSG_NOTICE([checking for libraries])
746
747
748 #
749 # libgpg-error is a library with error codes shared between GnuPG
750 # related projects.
751 #
752 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
753                   have_gpg_error=yes,have_gpg_error=no)
754
755
756 #
757 # Libgcrypt is our generic crypto library
758 #
759 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
760         have_libgcrypt=yes,have_libgcrypt=no)
761
762
763 #
764 # libassuan is used for IPC
765 #
766 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
767                   have_libassuan=yes,have_libassuan=no)
768 if test "$have_libassuan" = "yes"; then
769   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
770                      [version of the libassuan library])
771   show_tor_support="only .onion"
772 fi
773
774
775 #
776 # libksba is our X.509 support library
777 #
778 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
779
780
781 #
782 # libusb allows us to use the integrated CCID smartcard reader driver.
783 #
784 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
785 if test "$use_ccid_driver" = yes ; then
786    case $target in
787      *-*-darwin*)
788        LIBUSB_LIBS="-lusb-1.0 -Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
789        ;;
790      *-*-freebsd*)
791        # FreeBSD has a native 1.0 compatible library by -lusb.
792        LIBUSB_LIBS="-lusb"
793        ;;
794      *)
795        LIBUSB_LIBS="-lusb-1.0"
796        ;;
797    esac
798    AC_CHECK_LIB(usb-1.0, libusb_init,
799                 [ LIBUSB_LIBS="$LIBUSB_LIBS"
800                   AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
801                   have_libusb=yes
802                ])
803    AC_DEFINE([HAVE_LIBUSB])
804    AC_MSG_CHECKING([libusb include dir])
805    usb_incdir_found="no"
806    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
807      _libusb_save_cppflags=$CPPFLAGS
808      if test -n "${_incdir}"; then
809        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
810      fi
811      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
812      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
813      CPPFLAGS=${_libusb_save_cppflags}
814      if test "$usb_incdir_found" = "yes"; then
815        break
816      fi
817    done
818    if test "$usb_incdir_found" = "yes"; then
819      AC_MSG_RESULT([${usb_incdir}])
820    else
821      AC_MSG_RESULT([not found])
822      use_ccid_driver=no
823    fi
824    if test "$usb_incdir" = ""; then
825      LIBUSB_CPPFLAGS=""
826    else
827      LIBUSB_CPPFLAGS="-I${usb_incdir}"
828    fi
829 fi
830 AC_SUBST(LIBUSB_LIBS)
831 AC_SUBST(LIBUSB_CPPFLAGS)
832
833 #
834 # Check wether it is necessary to link against libdl.
835 # (For example to load libpcsclite)
836 #
837 gnupg_dlopen_save_libs="$LIBS"
838 LIBS=""
839 AC_SEARCH_LIBS(dlopen, c dl,,,)
840 DL_LIBS=$LIBS
841 AC_SUBST(DL_LIBS)
842 LIBS="$gnupg_dlopen_save_libs"
843
844
845 # Checks for g10
846
847 AC_ARG_ENABLE(sqlite,
848                 AC_HELP_STRING([--disable-sqlite],
849                                [disable the use of SQLITE]),
850               try_sqlite=$enableval, try_sqlite=yes)
851
852 if test x"$use_tofu" = xyes ; then
853   if test x"$try_sqlite" = xyes ; then
854     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
855                                  [have_sqlite=yes],
856                                  [have_sqlite=no])
857   fi
858   if test "$have_sqlite" = "yes"; then
859     :
860     AC_SUBST([SQLITE3_CFLAGS])
861     AC_SUBST([SQLITE3_LIBS])
862   else
863     use_tofu=no
864     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
865     AC_MSG_WARN([[
866 ***
867 *** Building without SQLite support - TOFU disabled
868 ***
869 *** $tmp]])
870   fi
871 fi
872
873 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
874
875 if test x"$use_tofu" = xyes ; then
876     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
877 fi
878
879
880 # Checks for g13
881
882 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
883 AC_DEFINE_UNQUOTED(ENCFS,
884         "${ENCFS}", [defines the filename of the encfs program])
885
886 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
887 AC_DEFINE_UNQUOTED(FUSERMOUNT,
888         "${FUSERMOUNT}", [defines the filename of the fusermount program])
889
890
891 # Checks for dirmngr
892
893
894 #
895 # Checks for symcryptrun:
896 #
897
898 # libutil has openpty() and login_tty().
899 AC_CHECK_LIB(util, openpty,
900               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
901                 AC_DEFINE(HAVE_LIBUTIL,1,
902                          [defined if libutil is available])
903              ])
904 AC_SUBST(LIBUTIL_LIBS)
905
906 # shred is used to clean temporary plain text files.
907 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
908 AC_DEFINE_UNQUOTED(SHRED,
909         "${SHRED}", [defines the filename of the shred program])
910
911
912 #
913 # Check whether the nPth library is available
914 #
915 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
916 if test "$have_npth" = "yes"; then
917   AC_DEFINE(HAVE_NPTH, 1,
918               [Defined if the New Portable Thread Library is available])
919   AC_DEFINE(USE_NPTH, 1,
920               [Defined if support for nPth is requested and nPth is available])
921 else
922   AC_MSG_WARN([[
923 ***
924 *** To support concurrent access for example in gpg-agent and the SCdaemon
925 *** we need the support of the New Portable Threads Library.
926 ***]])
927 fi
928
929
930 #
931 # NTBTLS is our TLS library.  If it is not available fallback to
932 # GNUTLS.
933 #
934 AC_ARG_ENABLE(ntbtls,
935               AC_HELP_STRING([--disable-ntbtls],
936                              [disable the use of NTBTLS as TLS library]),
937               try_ntbtls=$enableval, try_ntbtls=yes)
938 if test x"$try_ntbtls" = xyes ; then
939   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
940                  [have_ntbtls=yes],[have_ntbtls=no])
941 fi
942 if test "$have_ntbtls" = yes ; then
943    use_tls_library=ntbtls
944    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
945 else
946   AC_ARG_ENABLE(gnutls,
947                 AC_HELP_STRING([--disable-gnutls],
948                                [disable GNUTLS as fallback TLS library]),
949                 try_gnutls=$enableval, try_gnutls=yes)
950   if test x"$try_gnutls" = xyes ; then
951     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
952                                    [have_gnutls=yes],
953                                    [have_gnutls=no])
954   fi
955   if test "$have_gnutls" = "yes"; then
956     AC_SUBST([LIBGNUTLS_CFLAGS])
957     AC_SUBST([LIBGNUTLS_LIBS])
958     use_tls_library=gnutls
959     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
960   else
961     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
962     AC_MSG_WARN([[
963 ***
964 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
965 ***
966 *** $tmp]])
967   fi
968 fi
969
970
971 AC_MSG_NOTICE([checking for networking options])
972
973 #
974 # Must check for network library requirements before doing link tests
975 # for ldap, for example. If ldap libs are static (or dynamic and without
976 # ELF runtime link paths), then link will fail and LDAP support won't
977 # be detected.
978 #
979 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
980         [NETLIBS="-lnsl $NETLIBS"]))
981 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
982         [NETLIBS="-lsocket $NETLIBS"]))
983
984
985 #
986 # Check for ADNS.
987 #
988 _cppflags="${CPPFLAGS}"
989 _ldflags="${LDFLAGS}"
990 AC_ARG_WITH(adns,
991             AC_HELP_STRING([--with-adns=DIR],
992                            [look for the adns library in DIR]),
993             [if test -d "$withval"; then
994                CPPFLAGS="${CPPFLAGS} -I$withval/include"
995                LDFLAGS="${LDFLAGS} -L$withval/lib"
996              fi])
997 if test "$with_adns" != "no"; then
998   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
999   AC_CHECK_FUNCS(adns_free)
1000   AC_MSG_CHECKING([if adns supports adns_if_tormode])
1001   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1002     #include <adns.h>
1003     adns_initflags flags = adns_if_tormode;
1004   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
1005   AC_MSG_RESULT($adns_if_tormode)
1006   if test x"$adns_if_tormode" = xyes; then
1007     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
1008     if test "$show_tor_support" != "no"; then
1009       show_tor_support=yes
1010     fi
1011   fi
1012 fi
1013 CPPFLAGS=${_cppflags}
1014 LDFLAGS=${_ldflags}
1015 if test "$have_adns" = "yes"; then
1016   ADNSLIBS="-ladns"
1017 fi
1018
1019
1020 #
1021 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
1022 #
1023 AC_ARG_ENABLE(dns-srv,
1024               AC_HELP_STRING([--disable-dns-srv],
1025                              [disable the use of DNS SRV in HKP and HTTP]),
1026               use_dns_srv=$enableval,use_dns_srv=yes)
1027
1028 AC_ARG_ENABLE(dns-cert,
1029    AC_HELP_STRING([--disable-dns-cert],
1030         [disable the use of CERT records in DNS]),
1031    use_dns_cert=$enableval,use_dns_cert=yes)
1032
1033 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
1034   _dns_save_libs=$LIBS
1035   LIBS=""
1036
1037   if test x"$have_adns" = xyes ; then
1038     # We prefer ADNS.
1039     DNSLIBS="$ADNSLIBS"
1040     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1041
1042     if test x"$use_dns_srv" = xyes ; then
1043         AC_DEFINE(USE_DNS_SRV,1)
1044     fi
1045
1046     if test x"$use_dns_cert" = xyes ; then
1047         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1048     fi
1049   else
1050     # With no ADNS find the system resolver.
1051
1052     # the double underscore thing is a glibc-ism?
1053     AC_SEARCH_LIBS(res_query,resolv bind,,
1054                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1055     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1056                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1057     AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1058                    AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
1059
1060     if test x"$have_resolver" != xno ; then
1061
1062       # Make sure that the BIND 4 resolver interface is workable before
1063       # enabling any code that calls it.  At some point I'll rewrite the
1064       # code to use the BIND 8 resolver API.
1065       # We might also want to use adns instead.  Problem with ADNS is that
1066       # it does not support v6.
1067
1068       AC_MSG_CHECKING([whether the resolver is usable])
1069       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1070 #include <netinet/in.h>
1071 #include <arpa/nameser.h>
1072 #include <resolv.h>]],
1073 [[unsigned char answer[PACKETSZ];
1074   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1075   dn_skipname(0,0);
1076   dn_expand(0,0,0,0,0);
1077 ]])],have_resolver=yes,have_resolver=no)
1078       AC_MSG_RESULT($have_resolver)
1079
1080       # This is Apple-specific and somewhat bizarre as they changed the
1081       # define in bind 8 for some reason.
1082
1083       if test x"$have_resolver" != xyes ; then
1084          AC_MSG_CHECKING(
1085              [whether I can make the resolver usable with BIND_8_COMPAT])
1086         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1087 #include <sys/types.h>
1088 #include <netinet/in.h>
1089 #include <arpa/nameser.h>
1090 #include <resolv.h>]],
1091 [[unsigned char answer[PACKETSZ];
1092   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1093   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1094 ]])],[have_resolver=yes ; need_compat=yes])
1095          AC_MSG_RESULT($have_resolver)
1096       fi
1097     fi
1098
1099     if test x"$have_resolver" = xyes ; then
1100       DNSLIBS=$LIBS
1101
1102       if test x"$use_dns_srv" = xyes ; then
1103          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1104       fi
1105
1106       if test x"$use_dns_cert" = xyes ; then
1107         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1108       fi
1109
1110       if test x"$need_compat" = xyes ; then
1111         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1112       fi
1113     else
1114       use_dns_srv=no
1115       use_dns_cert=no
1116     fi
1117   fi
1118
1119   LIBS=$_dns_save_libs
1120 fi
1121
1122 AC_SUBST(DNSLIBS)
1123
1124 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1125
1126
1127 #
1128 # Check for LDAP
1129 #
1130 # Note that running the check changes the variable
1131 # gnupg_have_ldap from "n/a" to "no" or "yes".
1132
1133 AC_ARG_ENABLE(ldap,
1134     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1135     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1136
1137 if test "$gnupg_have_ldap" != "no" ; then
1138   if test "$build_dirmngr" = "yes" ; then
1139      GNUPG_CHECK_LDAP($NETLIBS)
1140      AC_CHECK_LIB(lber, ber_free,
1141                   [ LBER_LIBS="$LBER_LIBS -llber"
1142                     AC_DEFINE(HAVE_LBER,1,
1143                              [defined if liblber is available])
1144                     have_lber=yes
1145                  ])
1146   fi
1147 fi
1148 AC_SUBST(LBER_LIBS)
1149 if test "$gnupg_have_ldap" = "no"; then
1150     AC_MSG_WARN([[
1151 ***
1152 *** Building without LDAP support.
1153 *** No CRL access or X.509 certificate search available.
1154 ***]])
1155 fi
1156
1157 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1158 if test "$gnupg_have_ldap" = yes ; then
1159   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1160 else
1161  use_ldapwrapper=no
1162 fi
1163
1164 if test "$use_ldapwrapper" = yes; then
1165    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1166 fi
1167 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1168
1169
1170
1171
1172 #
1173 # Check for sendmail
1174 #
1175 # This isn't necessarily sendmail itself, but anything that gives a
1176 # sendmail-ish interface to the outside world.  That includes Exim,
1177 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1178 AC_ARG_WITH(mailprog,
1179       AC_HELP_STRING([--with-mailprog=NAME],
1180                      [use "NAME -t" for mail transport]),
1181              ,with_mailprog=yes)
1182 if test x"$with_mailprog" = xyes ; then
1183     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1184 elif test x"$with_mailprog" != xno ; then
1185     AC_MSG_CHECKING([for a mail transport program])
1186     AC_SUBST(SENDMAIL,$with_mailprog)
1187     AC_MSG_RESULT($with_mailprog)
1188 fi
1189
1190
1191 #
1192 # Construct a printable name of the OS
1193 #
1194 case "${host}" in
1195     *-mingw32ce*)
1196         PRINTABLE_OS_NAME="W32CE"
1197         ;;
1198     *-mingw32*)
1199         PRINTABLE_OS_NAME="MingW32"
1200         ;;
1201     *-*-cygwin*)
1202         PRINTABLE_OS_NAME="Cygwin"
1203         ;;
1204     i?86-emx-os2 | i?86-*-os2*emx )
1205         PRINTABLE_OS_NAME="OS/2"
1206         ;;
1207     i?86-*-msdosdjgpp*)
1208         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1209         try_dynload=no
1210         ;;
1211     *-linux*)
1212         PRINTABLE_OS_NAME="GNU/Linux"
1213         ;;
1214     *)
1215         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1216         ;;
1217 esac
1218 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1219                    [A human readable text with the name of the OS])
1220
1221
1222 #
1223 # Checking for iconv
1224 #
1225 if test "$require_iconv" = yes; then
1226   AM_ICONV
1227 else
1228   LIBICONV=
1229   LTLIBICONV=
1230   AC_SUBST(LIBICONV)
1231   AC_SUBST(LTLIBICONV)
1232 fi
1233
1234
1235 #
1236 # Check for gettext
1237 #
1238 # This is "GNU gnupg" - The project-id script from gettext
1239 #                       needs this string
1240 #
1241 AC_MSG_NOTICE([checking for gettext])
1242 AM_PO_SUBDIRS
1243 AM_GNU_GETTEXT_VERSION([0.17])
1244 if test "$try_gettext" = yes; then
1245   AM_GNU_GETTEXT([external],[need-ngettext])
1246
1247   # gettext requires some extra checks.  These really should be part of
1248   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1249   # function checks to here.
1250
1251   AC_CHECK_FUNCS(strchr)
1252 else
1253   USE_NLS=no
1254   USE_INCLUDED_LIBINTL=no
1255   BUILD_INCLUDED_LIBINTL=no
1256   POSUB=po
1257   AC_SUBST(USE_NLS)
1258   AC_SUBST(USE_INCLUDED_LIBINTL)
1259   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1260   AC_SUBST(POSUB)
1261 fi
1262
1263 # We use HAVE_LANGINFO_CODESET in a couple of places.
1264 AM_LANGINFO_CODESET
1265
1266 # Checks required for our use of locales
1267 gt_LC_MESSAGES
1268
1269
1270 #
1271 # SELinux support
1272 #
1273 if test "$selinux_support" = yes ; then
1274   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1275 fi
1276
1277
1278 #
1279 # Checks for header files.
1280 #
1281 AC_MSG_NOTICE([checking for header files])
1282 AC_HEADER_STDC
1283 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1284                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1285                   signal.h])
1286 AC_HEADER_TIME
1287
1288
1289 #
1290 # Checks for typedefs, structures, and compiler characteristics.
1291 #
1292 AC_MSG_NOTICE([checking for system characteristics])
1293 AC_C_CONST
1294 AC_C_INLINE
1295 AC_C_VOLATILE
1296 AC_TYPE_SIZE_T
1297 AC_TYPE_MODE_T
1298 AC_TYPE_SIGNAL
1299 AC_DECL_SYS_SIGLIST
1300
1301 gl_HEADER_SYS_SOCKET
1302 gl_TYPE_SOCKLEN_T
1303
1304 AC_SEARCH_LIBS([inet_addr], [nsl])
1305
1306 AC_ARG_ENABLE(endian-check,
1307               AC_HELP_STRING([--disable-endian-check],
1308               [disable the endian check and trust the OS provided macros]),
1309               endiancheck=$enableval,endiancheck=yes)
1310
1311 if test x"$endiancheck" = xyes ; then
1312   GNUPG_CHECK_ENDIAN
1313 fi
1314
1315 # fixme: we should get rid of the byte type
1316 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1317 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1318 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1319 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1320 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1321
1322 AC_CHECK_SIZEOF(unsigned short)
1323 AC_CHECK_SIZEOF(unsigned int)
1324 AC_CHECK_SIZEOF(unsigned long)
1325 AC_CHECK_SIZEOF(unsigned long long)
1326 AC_HEADER_TIME
1327 AC_CHECK_SIZEOF(time_t,,[[
1328 #include <stdio.h>
1329 #if TIME_WITH_SYS_TIME
1330 # include <sys/time.h>
1331 # include <time.h>
1332 #else
1333 # if HAVE_SYS_TIME_H
1334 #  include <sys/time.h>
1335 # else
1336 #  include <time.h>
1337 # endif
1338 #endif
1339 ]])
1340 GNUPG_TIME_T_UNSIGNED
1341
1342
1343 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1344    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1345    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1346     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1347 fi
1348
1349
1350 #
1351 # Checks for library functions.
1352 #
1353 AC_MSG_NOTICE([checking for library functions])
1354 AC_CHECK_DECLS(getpagesize)
1355 AC_FUNC_FSEEKO
1356 AC_FUNC_VPRINTF
1357 AC_FUNC_FORK
1358 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1359 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1360 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1361 AC_CHECK_FUNCS([canonicalize_file_name])
1362 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1363 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1364 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1365 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1366 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1367                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1368                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1369                 getenv inet_pton strpbrk])
1370
1371 if test "$have_android_system" = yes; then
1372    # On Android ttyname is a stub but prints an error message.
1373    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1374              [Defined if ttyname does not work properly])
1375 fi
1376
1377 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1378
1379 # Dirmngr requires mmap on Unix systems.
1380 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1381   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1382 fi
1383
1384 #
1385 # W32 specific test
1386 #
1387 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1388
1389 #
1390 # Sanity check regex.  Tests adapted from mutt.
1391 #
1392 AC_MSG_CHECKING([whether regular expression support is requested])
1393 AC_ARG_ENABLE(regex,
1394   AC_HELP_STRING([--disable-regex],
1395     [do not handle regular expressions in trust signatures]),
1396   use_regex=$enableval, use_regex=yes)
1397 AC_MSG_RESULT($use_regex)
1398
1399 if test "$use_regex" = yes ; then
1400   _cppflags="${CPPFLAGS}"
1401   _ldflags="${LDFLAGS}"
1402   AC_ARG_WITH(regex,
1403      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1404       [
1405       if test -d "$withval" ; then
1406         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1407         LDFLAGS="${LDFLAGS} -L$withval/lib"
1408       fi
1409       ],withval="")
1410
1411   # Does the system have regex functions at all?
1412   AC_SEARCH_LIBS([regcomp], [regex])
1413   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1414
1415   if test $gnupg_cv_have_regex = no; then
1416     use_regex=no
1417   else
1418     if test x"$cross_compiling" = xyes; then
1419       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1420     else
1421       AC_CACHE_CHECK([whether your system's regexp library is broken],
1422        [gnupg_cv_regex_broken],
1423        AC_TRY_RUN([
1424 #include <unistd.h>
1425 #include <regex.h>
1426 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1427        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1428
1429       if test $gnupg_cv_regex_broken = yes; then
1430         AC_MSG_WARN([your regex is broken - disabling regex use])
1431         use_regex=no
1432       fi
1433     fi
1434   fi
1435   CPPFLAGS="${_cppflags}"
1436   LDFLAGS="${_ldflags}"
1437 fi
1438
1439 if test "$use_regex" != yes ; then
1440   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1441 fi
1442 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1443
1444
1445
1446 #
1447 # Do we have zlib? Must do it here because Solaris failed
1448 # when compiling a conftest (due to the "-lz" from LIBS).
1449 # Note that we combine zlib and bzlib2 in ZLIBS.
1450 #
1451 if test "$use_zip" = yes ; then
1452   _cppflags="${CPPFLAGS}"
1453   _ldflags="${LDFLAGS}"
1454   AC_ARG_WITH(zlib,
1455     [  --with-zlib=DIR         use libz in DIR],[
1456       if test -d "$withval"; then
1457         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1458         LDFLAGS="${LDFLAGS} -L$withval/lib"
1459       fi
1460     ])
1461
1462   AC_CHECK_HEADER(zlib.h,
1463      AC_CHECK_LIB(z, deflateInit2_,
1464        [
1465        ZLIBS="-lz"
1466        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1467        ],
1468        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1469        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1470 fi
1471
1472
1473 #
1474 # Check whether we can support bzip2
1475 #
1476 if test "$use_bzip2" = yes ; then
1477   _cppflags="${CPPFLAGS}"
1478   _ldflags="${LDFLAGS}"
1479   AC_ARG_WITH(bzip2,
1480      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1481       [
1482       if test -d "$withval" ; then
1483         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1484         LDFLAGS="${LDFLAGS} -L$withval/lib"
1485       fi
1486       ],withval="")
1487
1488   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1489   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1490   # woefully out of date.
1491   if test "$withval" != no ; then
1492      AC_CHECK_HEADER(bzlib.h,
1493         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1494           [
1495           have_bz2=yes
1496           ZLIBS="$ZLIBS -lbz2"
1497           AC_DEFINE(HAVE_BZIP2,1,
1498                   [Defined if the bz2 compression library is available])
1499           ],
1500           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1501           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1502   fi
1503 fi
1504 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1505 AC_SUBST(ZLIBS)
1506
1507
1508 # Check for readline support
1509 GNUPG_CHECK_READLINE
1510
1511
1512 if test "$development_version" = yes; then
1513     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1514             [Defined if this is not a regular release])
1515 fi
1516
1517 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1518
1519 GNUPG_CHECK_GNUMAKE
1520
1521 # Add some extra libs here so that previous tests don't fail for
1522 # mysterious reasons - the final link step should bail out.
1523 # W32SOCKLIBS is also defined so that if can be used for tools not
1524 # requiring any network stuff but linking to code in libcommon which
1525 # tracks in winsock stuff (e.g. init_common_subsystems).
1526 if test "$have_w32_system" = yes; then
1527    if test "$have_w32ce_system" = yes; then
1528      W32SOCKLIBS="-lws2"
1529    else
1530      W32SOCKLIBS="-lws2_32"
1531    fi
1532    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1533 fi
1534
1535 AC_SUBST(NETLIBS)
1536 AC_SUBST(W32SOCKLIBS)
1537
1538 #
1539 # Setup gcc specific options
1540 #
1541 AC_MSG_NOTICE([checking for cc features])
1542 if test "$GCC" = yes; then
1543     mycflags=
1544     mycflags_save=$CFLAGS
1545
1546     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1547     # options.  This is the case for gcc >= 4.6
1548     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1549     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1550 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1551 #kickerror
1552 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1553     AC_MSG_RESULT($_gcc_silent_wno)
1554
1555     # Note that it is okay to use CFLAGS here because these are just
1556     # warning options and the user should have a chance of overriding
1557     # them.
1558     if test "$USE_MAINTAINER_MODE" = "yes"; then
1559         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1560         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1561         if test x"$_gcc_silent_wno" = xyes ; then
1562           _gcc_wopt=yes
1563         else
1564           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1565           CFLAGS="-Wno-missing-field-initializers"
1566           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1567                             [_gcc_wopt=yes],[_gcc_wopt=no])
1568           AC_MSG_RESULT($_gcc_wopt)
1569         fi
1570         if test x"$_gcc_wopt" = xyes ; then
1571           mycflags="$mycflags -W -Wno-sign-compare"
1572           mycflags="$mycflags -Wno-missing-field-initializers"
1573         fi
1574
1575         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1576         CFLAGS="-Wdeclaration-after-statement"
1577         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1578         AC_MSG_RESULT($_gcc_wopt)
1579         if test x"$_gcc_wopt" = xyes ; then
1580           mycflags="$mycflags -Wdeclaration-after-statement"
1581         fi
1582     else
1583         mycflags="$mycflags -Wall"
1584     fi
1585
1586     if test x"$_gcc_silent_wno" = xyes ; then
1587       _gcc_psign=yes
1588     else
1589       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1590       CFLAGS="-Wno-pointer-sign"
1591       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1592                         [_gcc_psign=yes],[_gcc_psign=no])
1593       AC_MSG_RESULT($_gcc_psign)
1594     fi
1595     if test x"$_gcc_psign" = xyes ; then
1596        mycflags="$mycflags -Wno-pointer-sign"
1597     fi
1598
1599     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1600     CFLAGS="-Wpointer-arith"
1601     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1602     AC_MSG_RESULT($_gcc_psign)
1603     if test x"$_gcc_psign" = xyes ; then
1604        mycflags="$mycflags -Wpointer-arith"
1605     fi
1606
1607     CFLAGS="$mycflags $mycflags_save"
1608 fi
1609
1610
1611 #
1612 # This is handy for debugging so the compiler doesn't rearrange
1613 # things and eliminate variables.
1614 #
1615 AC_ARG_ENABLE(optimization,
1616    AC_HELP_STRING([--disable-optimization],
1617                   [disable compiler optimization]),
1618                   [if test $enableval = no ; then
1619                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1620                    fi])
1621
1622 #
1623 # Add user CFLAGS.
1624 #
1625 CFLAGS="$CFLAGS $CFLAGS_orig"
1626
1627 #
1628 # Decide what to build
1629 #
1630
1631 build_scdaemon_extra=""
1632 if test "$build_scdaemon" = "yes"; then
1633   if test $have_libusb = no; then
1634      build_scdaemon_extra="without internal CCID driver"
1635   fi
1636   if test -n "$build_scdaemon_extra"; then
1637      build_scdaemon_extra="(${build_scdaemon_extra})"
1638   fi
1639 fi
1640
1641
1642 #
1643 # Set variables for use by automake makefiles.
1644 #
1645 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1646 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1647 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1648 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1649 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1650 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1651 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1652 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1653 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1654 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1655
1656 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1657 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1658 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1659
1660 AM_CONDITIONAL(RUN_GPG_TESTS,
1661                test x$cross_compiling = xno -a "$build_gpg" = yes )
1662
1663 #
1664 # Set some defines for use gpgconf.
1665 #
1666 if test "$build_gpg" = yes ; then
1667     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1668 fi
1669 if test "$build_gpgsm" = yes ; then
1670     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1671 fi
1672 if test "$build_agent" = yes ; then
1673     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1674 fi
1675 if test "$build_scdaemon" = yes ; then
1676     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1677 fi
1678 if test "$build_dirmngr" = yes ; then
1679     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1680 fi
1681 if test "$build_g13" = yes ; then
1682     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1683 fi
1684
1685
1686 #
1687 # Define Name strings
1688 #
1689 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1690
1691 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1692 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1693
1694 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1695 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1696
1697 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1698 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1699                                         [The displayed name of gpg-agent])
1700
1701 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1702 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1703                                        [The displayed name of scdaemon])
1704
1705 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1706 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1707                                       [The displayed name of dirmngr])
1708
1709 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1710 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1711
1712 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1713 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1714                                       [The displayed name of gpgconf])
1715
1716 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1717
1718 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1719                    [The name of the agent socket])
1720 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1721                    [The name of the agent socket for ssh])
1722 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1723                    [The name of the dirmngr info envvar])
1724 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1725                    [The name of the SCdaemon socket])
1726 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1727                    [The name of the dirmngr socket])
1728
1729 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1730
1731 if test "$have_w32_system" = yes; then
1732   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1733                      [The directory part of the W32 registry keys])
1734 fi
1735
1736
1737 #
1738 # Provide information about the build.
1739 #
1740 BUILD_REVISION="mym4_revision"
1741 AC_SUBST(BUILD_REVISION)
1742 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1743                    [GIT commit id revision used to build this package])
1744
1745 changequote(,)dnl
1746 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1747 changequote([,])dnl
1748 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1749 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1750 AC_SUBST(BUILD_VERSION)
1751 AC_SUBST(BUILD_FILEVERSION)
1752
1753 AC_ARG_ENABLE([build-timestamp],
1754   AC_HELP_STRING([--enable-build-timestamp],
1755                  [set an explicit build timestamp for reproducibility.
1756                   (default is the current time in ISO-8601 format)]),
1757      [if test "$enableval" = "yes"; then
1758         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1759       else
1760         BUILD_TIMESTAMP="$enableval"
1761       fi],
1762      [BUILD_TIMESTAMP="<none>"])
1763 AC_SUBST(BUILD_TIMESTAMP)
1764 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1765                    [The time this package was configured for a build])
1766 BUILD_HOSTNAME="$ac_hostname"
1767 AC_SUBST(BUILD_HOSTNAME)
1768
1769
1770 #
1771 # Print errors here so that they are visible all
1772 # together and the user can acquire them all together.
1773 #
1774 die=no
1775 if test "$have_gpg_error" = "no"; then
1776    die=yes
1777    AC_MSG_NOTICE([[
1778 ***
1779 *** You need libgpg-error to build this program.
1780 **  This library is for example available at
1781 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1782 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1783 ***]])
1784 fi
1785 if test "$have_libgcrypt" = "no"; then
1786    die=yes
1787    AC_MSG_NOTICE([[
1788 ***
1789 *** You need libgcrypt to build this program.
1790 **  This library is for example available at
1791 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1792 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1793 ***]])
1794 fi
1795 if test "$have_libassuan" = "no"; then
1796    die=yes
1797    AC_MSG_NOTICE([[
1798 ***
1799 *** You need libassuan to build this program.
1800 *** This library is for example available at
1801 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1802 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1803 ***]])
1804 fi
1805 if test "$have_ksba" = "no"; then
1806     die=yes
1807     AC_MSG_NOTICE([[
1808 ***
1809 *** You need libksba to build this program.
1810 *** This library is for example available at
1811 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1812 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1813 ***]])
1814 fi
1815 if test "$gnupg_have_ldap" = yes; then
1816   if test "$have_w32ce_system" = yes; then
1817     AC_MSG_NOTICE([[
1818 *** Note that CeGCC might be broken, a package fixing this is:
1819 ***    http://files.kolab.org/local/windows-ce/
1820 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1821 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1822 ***]])
1823    fi
1824 fi
1825 if test "$have_npth" = "no"; then
1826     die=yes
1827     AC_MSG_NOTICE([[
1828 ***
1829 *** It is now required to build with support for the
1830 *** New Portable Threads Library (nPth). Please install this
1831 *** library first.  The library is for example available at
1832 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1833 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1834 ***]])
1835 fi
1836
1837 if test "$require_iconv" = yes; then
1838   if test "$am_func_iconv" != yes; then
1839     die=yes
1840     AC_MSG_NOTICE([[
1841 ***
1842 *** The system does not provide a working iconv function.  Please
1843 *** install a suitable library; for example GNU Libiconv which is
1844 *** available at:
1845 ***   http://ftp.gnu.org/gnu/libiconv/
1846 ***]])
1847   fi
1848 fi
1849
1850 if test "$die" = "yes"; then
1851     AC_MSG_ERROR([[
1852 ***
1853 *** Required libraries not found. Please consult the above messages
1854 *** and install them before running configure again.
1855 ***]])
1856 fi
1857
1858
1859
1860 AC_CONFIG_FILES([ m4/Makefile
1861 Makefile
1862 po/Makefile.in
1863 common/Makefile
1864 common/w32info-rc.h
1865 kbx/Makefile
1866 g10/Makefile
1867 sm/Makefile
1868 agent/Makefile
1869 scd/Makefile
1870 g13/Makefile
1871 dirmngr/Makefile
1872 tools/gpg-zip
1873 tools/Makefile
1874 doc/Makefile
1875 tests/Makefile
1876 tests/openpgp/Makefile
1877 tests/pkits/Makefile
1878 g10/gpg.w32-manifest
1879 ])
1880
1881
1882 AC_OUTPUT
1883
1884
1885 echo "
1886         GnuPG v${VERSION} has been configured as follows:
1887
1888         Revision:  mym4_revision  (mym4_revision_dec)
1889         Platform:  $PRINTABLE_OS_NAME ($host)
1890
1891         OpenPGP:   $build_gpg
1892         S/MIME:    $build_gpgsm
1893         Agent:     $build_agent
1894         Smartcard: $build_scdaemon $build_scdaemon_extra
1895         G13:       $build_g13
1896         Dirmngr:   $build_dirmngr
1897         Gpgtar:    $build_gpgtar
1898
1899         Protect tool:      $show_gnupg_protect_tool_pgm
1900         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1901         Default agent:     $show_gnupg_agent_pgm
1902         Default pinentry:  $show_gnupg_pinentry_pgm
1903         Default scdaemon:  $show_gnupg_scdaemon_pgm
1904         Default dirmngr:   $show_gnupg_dirmngr_pgm
1905
1906         Dirmngr auto start:  $dirmngr_auto_start
1907         Readline support:    $gnupg_cv_have_readline
1908         LDAP support:        $gnupg_have_ldap
1909         DNS SRV support:     $use_dns_srv
1910         TLS support:         $use_tls_library
1911         TOFU support:        $use_tofu
1912         Tor support:         $show_tor_support
1913 "
1914 if test x"$use_regex" != xyes ; then
1915 echo "
1916         Warning: No regular expression support available.
1917                  OpenPGP trust signatures won't work.
1918                  gpg-check-pattern will not be built.
1919 "
1920 fi
1921 if test "x${gpg_config_script_warn}" != x; then
1922 cat <<G10EOF
1923         Warning: Mismatches between the target platform and the
1924                  to be used libraries have been detected for:
1925                   ${gpg_config_script_warn}
1926                  Please check above for more warning messages.
1927
1928 G10EOF
1929 fi