See ChangeLog: Wed May 26 14:36:29 CEST 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105
106 dnl Checks for programs.
107
108 AC_CANONICAL_SYSTEM
109 AC_ARG_PROGRAM
110 AC_PROG_MAKE_SET
111 AM_SANITY_CHECK
112 missing_dir=`cd $ac_aux_dir && pwd`
113 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
114 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
115 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
116 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
117 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
118 AC_PROG_CC
119 AC_PROG_CPP
120 AC_ISC_POSIX
121 AC_PROG_INSTALL
122 AC_PROG_RANLIB
123
124 MPI_OPT_FLAGS=""
125 if test "$GCC" = yes; then
126     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
127 fi
128
129
130 try_gettext=yes
131 try_gdbm=yes
132 case "${target}" in
133     i386--mingw32)
134         # special stuff for Windoze NT
135         cross_compiling=yes
136         CC="i386--mingw32-gcc"
137         CPP="i386--mingw32-gcc -E"
138         RANLIB="i386--mingw32-ranlib"
139         ac_cv_have_dev_random=no
140         AC_DEFINE(USE_ONLY_8DOT3)
141         AC_DEFINE(HAVE_DRIVE_LETTERS)
142         AC_DEFINE(HAVE_DOSISH_SYSTEM)
143         try_gettext="no"
144         try_gdbm="no"
145         ;;
146     i386-emx-os2 | i[3456]86-pc-os2emx )
147         # OS/2 with the EMX environment
148         ac_cv_have_dev_random=no
149         AC_DEFINE(HAVE_DRIVE_LETTERS)
150         AC_DEFINE(HAVE_DOSISH_SYSTEM)
151         try_gettext="no"
152         try_gdbm="no"
153         ;;
154     *-*-hpux*)
155         if test -z "$GCC" ; then
156             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
157         fi
158         ;;
159     *-dec-osf4*)
160         if test -z "$GCC" ; then
161             # Suppress all warnings
162             # to get rid of the unsigned/signed char mismatch warnings.
163             CFLAGS="$CFLAGS -w"
164         fi
165         ;;
166     m68k-atari-mint)
167         ;;
168     *)
169        ;;
170 esac
171
172 AC_SUBST(MPI_OPT_FLAGS)
173 GNUPG_SYS_SYMBOL_UNDERSCORE
174 GNUPG_CHECK_PIC
175 GNUPG_CHECK_RDYNAMIC
176 if test "$NO_PIC" = yes; then
177     try_dynload=no
178 fi
179
180
181 case "${target}" in
182     i386--mingw32)
183         PRINTABLE_OS_NAME="MingW32"
184         ;;
185     i386-emx-os2 | i[3456]86-pc-os2emx)
186         PRINTABLE_OS_NAME="OS/2"
187         ;;
188     *-linux*)
189         PRINTABLE_OS_NAME="GNU/Linux"
190         ;;
191     *)
192         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
193         ;;
194 esac
195 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
196
197 dnl  Fixme: Are these the best flags for OpenBSD????
198 dnl (I have removed the -lc from * ...CFLAGS for test purposes.)
199 case "${target}" in
200     *-openbsd*)
201         NAME_OF_DEV_RANDOM="/dev/srandom"
202         NAME_OF_DEV_URANDOM="/dev/urandom"
203         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
204         ;;
205     *)
206         NAME_OF_DEV_RANDOM="/dev/random"
207         NAME_OF_DEV_URANDOM="/dev/urandom"
208         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
209         ;;
210 esac
211 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
212 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
213 AC_SUBST(MPI_OPT_FLAGS)
214
215
216 dnl Checks for libraries.
217
218 if test "$try_gettext" = yes; then
219 AM_GNU_GETTEXT
220 else
221 USE_NLS=no
222 USE_INCLUDED_LIBINTL=no
223 AC_SUBST(USE_NLS)
224 AC_SUBST(USE_INCLUDED_LIBINTL)
225 fi
226
227 if test "$try_gdbm" = yes; then
228 AC_CHECK_LIB(gdbm,gdbm_firstkey)
229 fi
230
231 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
232 dnl gethostbyname in libsocket but needs libnsl for socket.
233 AC_CHECK_LIB(nsl, gethostbyname)
234 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
235 if test x$ac_need_libsocket = x1; then
236     LIBS="$LIBS -lsocket"
237 fi
238 if test x$ac_try_nsl = x1; then
239     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
240     if test x$ac_need_libnsl = x1
241     then
242         LIBS="$LIBS -lnsl"
243     fi
244 fi
245
246
247 if test "$try_dynload" = yes ; then
248   AC_CHECK_LIB(dl,dlopen)
249   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
250     AC_DEFINE(USE_DYNAMIC_LINKING)
251     AC_DEFINE(HAVE_DL_DLOPEN)
252     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
253     use_gnupg_extensions=yes
254   else
255     AC_CHECK_LIB(c,dlopen)
256     if test "$ac_cv_lib_c_dlopen" = "yes"; then
257       AC_DEFINE(USE_DYNAMIC_LINKING)
258       AC_DEFINE(HAVE_DL_DLOPEN)
259       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
260       use_gnupg_extensions=yes
261 dnl else
262 dnl
263 dnl  DLD is not ready for use. So I better disable this test
264 dnl
265 dnl    AC_CHECK_LIB(dld,dld_link)
266 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
267 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
268 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
269 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
270 dnl      use_gnupg_extensions=yes
271 dnl    fi
272     fi
273   fi
274 else
275   AC_MSG_CHECKING(for dynamic loading)
276   DYNLINK_LDFLAGS=
277   DYNLINK_MOD_CFLAGS=
278   use_gnupg_extensions=no
279   AC_MSG_RESULT(has been disabled)
280 fi
281
282 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
283 AC_SUBST(DYNLINK_LDFLAGS)
284 AC_SUBST(DYNLINK_MOD_CFLAGS)
285
286
287 dnl Checks for header files.
288 AC_HEADER_STDC
289 AC_CHECK_HEADERS(unistd.h langinfo.h)
290
291
292 dnl Checks for typedefs, structures, and compiler characteristics.
293 AC_C_CONST
294 AC_C_INLINE
295 AC_TYPE_SIZE_T
296 AC_TYPE_SIGNAL
297 AC_DECL_SYS_SIGLIST
298
299 GNUPG_CHECK_ENDIAN
300
301
302 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
303 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
304 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
305 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
306 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
307
308 AC_CHECK_SIZEOF(unsigned short, 2)
309 AC_CHECK_SIZEOF(unsigned int, 4)
310 AC_CHECK_SIZEOF(unsigned long, 4)
311
312 if test "$ac_cv_sizeof_unsigned_short" = "0" \
313    || test "$ac_cv_sizeof_unsigned_int" = "0" \
314    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
315     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
316 fi
317
318
319
320 dnl Checks for library functions.
321 AC_FUNC_VPRINTF
322 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
323 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
324 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
325
326 GNUPG_CHECK_MLOCK
327
328 GNUPG_CHECK_IPC
329 if test "$ac_cv_header_sys_shm_h" = "yes"; then
330   AC_DEFINE(USE_SHM_COPROCESSING)
331 fi
332
333 dnl check whether we have a random device
334 if test "$try_dev_random" = yes ; then
335 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
336 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
337   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
338 if test "$ac_cv_have_dev_random" = yes; then
339     AC_DEFINE(HAVE_DEV_RANDOM)
340 fi
341 else
342     AC_MSG_CHECKING(for random device)
343     ac_cv_have_dev_random=no
344     AC_MSG_RESULT(has been disabled)
345 fi
346
347
348 dnl
349 dnl Figure out the default linkage mode for cipher modules
350 dnl
351 dnl (We always need a static rmd160)
352 static_modules="$static_modules rmd160"
353 if test "$use_static_rnd" = default; then
354   if test "$ac_cv_have_dev_random" = yes; then
355       static_modules="$static_modules rndlinux"
356   else
357       case "${target}" in
358           i386--mingw32)
359               static_modules="$static_modules rndw32"
360               ;;
361           i386-emx-os2|i[3456]86-pc-os2emx)
362               static_modules="$static_modules rndos2"
363               ;;
364           m68k-atari-mint)
365               static_modules="$static_modules rndatari"
366               ;;
367           *)
368               static_modules="$static_modules rndunix"
369              ;;
370       esac
371   fi
372 else
373   if test "$use_static_rnd" = none; then
374     :
375   else
376     static_modules="$static_modules rnd$use_static_rnd"
377   fi
378 fi
379
380 dnl
381 dnl Parse the modules list and build the list
382 dnl of static and dymically linked modules
383 dnl
384 STATIC_CIPHER_NAMES=""
385 STATIC_CIPHER_OBJS=""
386 DYNAMIC_CIPHER_MODS=""
387 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
388 for name in $MODULES_IN_CIPHER; do
389     x="no"
390     for i in $static_modules; do
391         if test "$name" = "$i" ; then
392             x="yes"
393         fi
394     done;
395     if test $x = yes; then
396         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
397         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
398     else
399         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
400         GNUPG_MSG_PRINT([$name])
401     fi
402 done
403 AC_MSG_RESULT()
404 AC_SUBST(STATIC_CIPHER_OBJS)
405 AC_SUBST(STATIC_CIPHER_NAMES)
406 AC_SUBST(DYNAMIC_CIPHER_MODS)
407
408 dnl
409 dnl And build the constructor file
410 dnl
411
412 test -d cipher || mkdir cipher
413 cat <<G10EOF >cipher/construct.c
414 /* automatically generated by configure - do not edit */
415
416 G10EOF
417 GNUPG_MSG_PRINT([statically linked cipher modules:])
418 for name in $STATIC_CIPHER_NAMES; do
419     echo "void ${name}_constructor(void);" >>cipher/construct.c
420     GNUPG_MSG_PRINT([$name])
421 done
422 AC_MSG_RESULT()
423 cat <<G10EOF >>cipher/construct.c
424
425 void
426 cipher_modules_constructor(void)
427 {
428     static int done = 0;
429     if( done )
430         return;
431     done = 1;
432
433 G10EOF
434 for name in $STATIC_CIPHER_NAMES; do
435     echo "   ${name}_constructor();" >>cipher/construct.c
436 done
437 echo '}' >>cipher/construct.c
438
439
440
441
442 dnl
443 dnl Figure how to link the cipher modules
444 dnl
445 AC_SUBST(STATIC_CIPHER_OBJS)
446 AC_SUBST(DYNAMIC_CIPHER_MODS)
447
448
449 dnl setup assembler stuff
450 AC_MSG_CHECKING(for mpi assembler functions)
451 if test -f $srcdir/mpi/config.links ; then
452     . $srcdir/mpi/config.links
453     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
454     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
455     ac_cv_mpi_sflags="$mpi_sflags"
456     ac_cv_mpi_config_done="yes"
457     AC_MSG_RESULT(done)
458 else
459     AC_MSG_RESULT(failed)
460     AC_MSG_ERROR([mpi/config.links missing!])
461 fi
462 MPI_EXTRA_ASM_OBJS=""
463 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
464 GNUPG_MSG_PRINT([mpi extra asm functions:])
465 for i in $ac_cv_mpi_extra_asm_modules; do
466     GNUPG_MSG_PRINT([$i])
467     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
468 done
469 AC_MSG_RESULT()
470 fi
471 AC_SUBST(MPI_EXTRA_ASM_OBJS)
472 MPI_SFLAGS="$ac_cv_mpi_sflags"
473 AC_SUBST(MPI_SFLAGS)
474
475 dnl Do we have zlib? Must do it here because Solaris failed
476 dnl when compiling a conftest (due to the "-lz" from LIBS).
477 if test "$g10_force_zlib" = "yes"; then
478     ZLIBS="../zlib/libzlib.a"
479     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
480     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
481     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
482 else
483 AC_CHECK_HEADERS(zlib.h)
484 if test "$ac_cv_header_zlib_h" = yes ; then
485     LIBS="$LIBS -lz"
486     ZLIBS=
487     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
488 else
489     ZLIBS="../zlib/libzlib.a"
490     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
491     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
492     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
493 fi
494 fi
495 AC_SUBST(ZLIBS)
496
497 changequote(,)dnl
498 tmp_pat='[a-zA-Z]'
499 changequote([,])dnl
500 if echo "$VERSION" | grep $tmp_pat >/dev/null ; then
501     AC_DEFINE(IS_DEVELOPMENT_VERSION)
502 fi
503
504 GNUPG_DO_LINK_FILES
505
506
507 AC_OUTPUT_COMMANDS([
508 cat >g10defs.tmp <<G10EOF
509 /* Generated automatically by configure */
510 #ifdef HAVE_DRIVE_LETTERS
511   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
512   #define GNUPG_LIBDIR  "c:/lib/gnupg"
513   #define GNUPG_DATADIR "c:/lib/gnupg"
514 #else
515   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
516   #define GNUPG_LIBDIR  "${libdir}/gnupg"
517   #define GNUPG_DATADIR "${datadir}/gnupg"
518 #endif
519 G10EOF
520 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
521     echo "g10defs.h is unchanged"
522     rm -f g10defs.tmp
523 else
524     rm -f g10defs.h
525     mv g10defs.tmp g10defs.h
526     echo "g10defs.h created"
527 fi
528 ],[
529 prefix=$prefix
530 exec_prefix=$exec_prefix
531 libdir=$libdir
532 datadir=$datadir
533 DATADIRNAME=$DATADIRNAME
534 ])
535
536
537 AC_OUTPUT([
538 Makefile
539 intl/Makefile
540 po/Makefile.in
541 util/Makefile
542 mpi/Makefile
543 cipher/Makefile
544 g10/Makefile
545 doc/Makefile
546 tools/Makefile
547 zlib/Makefile
548 checks/Makefile
549 ])
550
551 dnl *-*wedit:notab*-*  Please keep this as the last line.