See ChangeLog: Wed Feb 24 11:07:27 CET 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_INIT(g10/g10.c)
11 AC_CONFIG_AUX_DIR(scripts)
12 AM_CONFIG_HEADER(config.h)
13
14
15 VERSION=`cat $srcdir/VERSION`
16 PACKAGE=gnupg
17 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
18 static_modules="sha1 md5 rmd160"
19 AC_SUBST(VERSION)
20 AC_SUBST(PACKAGE)
21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
23
24 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
25                                                 $srcdir/cipher/Makefile.am`
26
27 dnl
28 dnl  Check for random module options
29 dnl
30 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
31 dnl         and check agiants this list
32
33 AC_MSG_CHECKING([which static random module to use])
34 AC_ARG_ENABLE(static-rnd,
35     [  --enable-static-rnd=[egd|unix|linux|nonde]  ],
36 [use_static_rnd=$enableval], [use_static_rnd=default] )
37
38 if test "$use_static_rnd" = no; then
39     use_static_rnd=default
40 fi
41
42 case "$use_static_rnd" in
43     egd | linux | unix | none | default )
44       AC_MSG_RESULT($use_static_rnd)
45       ;;
46     * )
47       AC_MSG_RESULT(invalid argument)
48       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
49       ;;
50 esac
51
52 dnl
53 dnl See whether the user wants to disable checking for 7dev/random
54
55 AC_MSG_CHECKING([whether use of /dev/random is requested])
56 AC_ARG_ENABLE(dev-random,
57 [  --disable-dev-random    disable the use of dev random],
58     try_dev_random=$enableval, try_dev_random=yes)
59 AC_MSG_RESULT($try_dev_random)
60
61
62 dnl
63 dnl  Check other options
64 dnl
65
66 AC_MSG_CHECKING([whether use of extensions is requested])
67 AC_ARG_ENABLE(dynload,
68 [  --disable-dynload       disable use of extensions],
69     try_dynload=$enableval, try_dynload=yes)
70 AC_MSG_RESULT($try_dynload)
71
72 AC_MSG_CHECKING([whether assembler modules are requested])
73 AC_ARG_ENABLE(asm,
74 [  --disable-asm           do not use assembler modules],
75      try_asm_modules=$enableval, try_asm_modules=yes)
76 AC_MSG_RESULT($try_asm_modules)
77
78 AC_MSG_CHECKING([whether memory debugging is requested])
79 AC_ARG_ENABLE(m-debug,
80 [  --enable-m-debug        enable debugging of memory allocation],
81 use_m_debug=$enableval, use_m_debug=no)
82 AC_MSG_RESULT($use_m_debug)
83 if test "$use_m_debug" = yes; then
84     AC_DEFINE(M_DEBUG)
85     use_m_guard=yes
86 else
87     AC_MSG_CHECKING([whether memory guard is requested])
88     AC_ARG_ENABLE(m-guard,
89     [  --enable-m-guard        enable memory guard facility],
90     use_m_guard=$enableval, use_m_guard=no)
91     AC_MSG_RESULT($use_m_guard)
92 fi
93 if test "$use_m_guard" = yes ; then
94     AC_DEFINE(M_GUARD)
95 fi
96
97
98 AC_MSG_CHECKING([whether included zlib is requested])
99 AC_ARG_WITH(included-zlib,
100     [  --with-included-zlib    use the zlib code included here],
101 [g10_force_zlib=yes], [g10_force_zlib=no] )
102 AC_MSG_RESULT($g10_force_zlib)
103
104
105 dnl Checks for programs.
106
107 AC_CANONICAL_SYSTEM
108 AC_ARG_PROGRAM
109 AC_PROG_MAKE_SET
110 AM_SANITY_CHECK
111 missing_dir=`cd $ac_aux_dir && pwd`
112 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
113 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
114 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
115 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
116 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
117 AC_PROG_CC
118 AC_PROG_CPP
119 AC_ISC_POSIX
120 AC_PROG_RANLIB
121 AC_PROG_INSTALL
122 dnl AC_CYGWIN32
123 dnl AM_PROG_LIBTOOL
124
125 MPI_OPT_FLAGS=""
126 if test "$GCC" = yes; then
127     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
128 fi
129
130
131 try_gettext=yes
132 try_gdbm=yes
133 case "${target}" in
134     i386--mingw32)
135         # special stuff for Windoze NT
136         cross_compiling=yes
137         CC="i386--mingw32-gcc"
138         CPP="i386--mingw32-gcc -E"
139         RANLIB="i386--mingw32-ranlib"
140         ac_cv_have_dev_random=no
141         AC_DEFINE(USE_ONLY_8DOT3)
142         AC_DEFINE(HAVE_DRIVE_LETTERS)
143         AC_DEFINE(HAVE_DOSISH_SYSTEM)
144         try_gettext="no"
145         try_gdbm="no"
146         ;;
147     i386-emx-os2)
148         # OS/2 with the EMX environment
149         ac_cv_have_dev_random=no
150         AC_DEFINE(HAVE_DRIVE_LETTERS)
151         AC_DEFINE(HAVE_DOSISH_SYSTEM)
152         try_gettext="no"
153         try_gdbm="no"
154         ;;
155     *-*-hpux*)
156         if test -z "$GCC" ; then
157             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
158         fi
159         ;;
160     *-dec-osf4*)
161         if test -z "$GCC" ; then
162             # Suppress all warnings
163             # to get rid of the unsigned/signed char mismatch warnings.
164             CFLAGS="$CFLAGS -w"
165         fi
166         ;;
167     m68k-atari-mint)
168         ;;
169     *)
170        ;;
171 esac
172
173 AC_SUBST(MPI_OPT_FLAGS)
174
175 GNUPG_CHECK_PIC
176 GNUPG_CHECK_RDYNAMIC
177 if test "$NO_PIC" = yes; then
178     try_dynload=no
179 fi
180
181
182 case "${target}" in
183     i386--mingw32)
184         PRINTABLE_OS_NAME="MingW32"
185         ;;
186     i386-emx-os2)
187         PRINTABLE_OS_NAME="OS/2"
188         ;;
189     *-linux*)
190         PRINTABLE_OS_NAME="GNU/Linux"
191         ;;
192     *)
193         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
194         ;;
195 esac
196 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
197
198 dnl  Fixme: Are these the best flags for OpenBSD????
199 case "${target}" in
200     *-openbsd*)
201         NAME_OF_DEV_RANDOM="/dev/srandom"
202         NAME_OF_DEV_URANDOM="/dev/urandom"
203         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
204         ;;
205     *)
206         NAME_OF_DEV_RANDOM="/dev/random"
207         NAME_OF_DEV_URANDOM="/dev/urandom"
208         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC -lc"
209         ;;
210 esac
211 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
212 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
213 AC_SUBST(MPI_OPT_FLAGS)
214
215
216 dnl Checks for libraries.
217
218 if test "$try_gettext" = yes; then
219 AM_GNU_GETTEXT
220 fi
221
222 if test "$try_gdbm" = yes; then
223 AC_CHECK_LIB(gdbm,gdbm_firstkey)
224 fi
225
226 dnl Solaris needs -lsocket and -lnsl
227 AC_CHECK_LIB(socket, socket)
228 AC_CHECK_LIB(nsl, gethostbyname)
229
230
231 if test "$try_dynload" = yes ; then
232   AC_CHECK_LIB(dl,dlopen)
233   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
234     AC_DEFINE(USE_DYNAMIC_LINKING)
235     AC_DEFINE(HAVE_DL_DLOPEN)
236     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
237     use_gnupg_extensions=yes
238   else
239     AC_CHECK_LIB(c,dlopen)
240     if test "$ac_cv_lib_c_dlopen" = "yes"; then
241       AC_DEFINE(USE_DYNAMIC_LINKING)
242       AC_DEFINE(HAVE_DL_DLOPEN)
243       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
244       dnl fixme: this is probably false but it should
245       dnl work for freebsd
246       AC_DEFINE(DLSYM_NEEDS_UNDERSCORE)
247       use_gnupg_extensions=yes
248     else
249       AC_CHECK_LIB(dld,dld_link)
250       if test "$ac_cv_lib_dld_dld_link" = "yes"; then
251         AC_DEFINE(USE_DYNAMIC_LINKING)
252         AC_DEFINE(HAVE_DLD_DLD_LINK)
253         DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
254         use_gnupg_extensions=yes
255       fi
256     fi
257   fi
258 else
259   AC_MSG_CHECKING(for dynamic loading)
260   DYNLINK_LDFLAGS=
261   DYNLINK_MOD_CFLAGS=
262   use_gnupg_extensions=no
263   AC_MSG_RESULT(has been disabled)
264 fi
265
266 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
267 AC_SUBST(DYNLINK_LDFLAGS)
268 AC_SUBST(DYNLINK_MOD_CFLAGS)
269
270
271 dnl Checks for header files.
272 AC_HEADER_STDC
273 AC_CHECK_HEADERS(unistd.h)
274
275
276 dnl Checks for typedefs, structures, and compiler characteristics.
277 AC_C_CONST
278 AC_C_INLINE
279 AC_TYPE_SIZE_T
280 AC_TYPE_SIGNAL
281 AC_DECL_SYS_SIGLIST
282
283 GNUPG_CHECK_ENDIAN
284
285
286 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
287 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
288 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
289 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
290 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
291
292 AC_CHECK_SIZEOF(unsigned short, 2)
293 AC_CHECK_SIZEOF(unsigned int, 4)
294 AC_CHECK_SIZEOF(unsigned long, 4)
295
296 if test "$ac_cv_sizeof_unsigned_short" = "0" \
297    || test "$ac_cv_sizeof_unsigned_int" = "0" \
298    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
299     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
300 fi
301
302
303
304 dnl Checks for library functions.
305 AC_FUNC_VPRINTF
306 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
307 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
308 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime)
309
310 GNUPG_CHECK_MLOCK
311
312 GNUPG_CHECK_IPC
313 if test "$ac_cv_header_sys_shm_h" = "yes"; then
314   AC_DEFINE(USE_SHM_COPROCESSING)
315 fi
316
317 dnl check whether we have a random device
318 if test "$try_dev_random" = yes ; then
319 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
320 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
321   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
322 if test "$ac_cv_have_dev_random" = yes; then
323     AC_DEFINE(HAVE_DEV_RANDOM)
324 fi
325 else
326     AC_MSG_CHECKING(for random device)
327     ac_cv_have_dev_random=no
328     AC_MSG_RESULT(has been disabled)
329 fi
330
331
332 dnl
333 dnl Figure out the default linkage mode for cipher modules
334 dnl
335 dnl (We always need a static rmd160)
336 static_modules="$static_modules rmd160"
337 if test "$use_static_rnd" = default; then
338   if test "$ac_cv_have_dev_random" = yes; then
339       static_modules="$static_modules rndlinux"
340   else
341       case "${target}" in
342           i386--mingw32)
343               static_modules="$static_modules rndw32"
344               ;;
345           i386-emx-os2)
346               static_modules="$static_modules rndos2"
347               ;;
348           m68k-atari-mint)
349               static_modules="$static_modules rndatari"
350               ;;
351           *)
352               static_modules="$static_modules rndunix"
353              ;;
354       esac
355   fi
356 else
357   if test "$use_static_rnd" = none; then
358     :
359   else
360     static_modules="$static_modules rnd$use_static_rnd"
361   fi
362 fi
363
364 dnl
365 dnl Parse the modules list and build the list
366 dnl of static and dymically linked modules
367 dnl
368 STATIC_CIPHER_NAMES=""
369 STATIC_CIPHER_OBJS=""
370 DYNAMIC_CIPHER_MODS=""
371 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
372 for name in $MODULES_IN_CIPHER; do
373     x="no"
374     for i in $static_modules; do
375         if test "$name" = "$i" ; then
376             x="yes"
377         fi
378     done;
379     if test $x = yes; then
380         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
381         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
382     else
383         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
384         GNUPG_MSG_PRINT([$name])
385     fi
386 done
387 AC_MSG_RESULT()
388 AC_SUBST(STATIC_CIPHER_OBJS)
389 AC_SUBST(STATIC_CIPHER_NAMES)
390 AC_SUBST(DYNAMIC_CIPHER_MODS)
391
392 dnl
393 dnl And build the constructor file
394 dnl
395
396 test -d cipher || mkdir cipher
397 cat <<EOF >cipher/construct.c
398 /* automatically generated by configure - do not edit */
399
400 EOF
401 GNUPG_MSG_PRINT([statically linked cipher modules:])
402 for name in $STATIC_CIPHER_NAMES; do
403     echo "void ${name}_constructor(void);" >>cipher/construct.c
404     GNUPG_MSG_PRINT([$name])
405 done
406 AC_MSG_RESULT()
407 cat <<EOF >>cipher/construct.c
408
409 void
410 cipher_modules_constructor(void)
411 {
412     static int done = 0;
413     if( done )
414         return;
415     done = 1;
416
417 EOF
418 for name in $STATIC_CIPHER_NAMES; do
419     echo "   ${name}_constructor();" >>cipher/construct.c
420 done
421 echo '}' >>cipher/construct.c
422
423
424
425
426 dnl
427 dnl Figure how to link the cipher modules
428 dnl
429 dnl (form now these are only dynamic)
430 AC_SUBST(STATIC_CIPHER_OBJS)
431 AC_SUBST(DYNAMIC_CIPHER_MODS)
432
433
434
435 dnl setup assembler stuff
436 AC_MSG_CHECKING(for mpi assembler functions)
437 if test -f $srcdir/mpi/config.links ; then
438     . $srcdir/mpi/config.links
439     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
440     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
441     ac_cv_mpi_sflags="$mpi_sflags"
442     ac_cv_mpi_config_done="yes"
443     AC_MSG_RESULT(done)
444 else
445     AC_MSG_RESULT(failed)
446     AC_MSG_ERROR([mpi/config.links missing!])
447 fi
448 MPI_EXTRA_ASM_OBJS=""
449 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
450 GNUPG_MSG_PRINT([mpi extra asm functions:])
451 for i in $ac_cv_mpi_extra_asm_modules; do
452     GNUPG_MSG_PRINT([$i])
453     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
454 done
455 AC_MSG_RESULT()
456 fi
457 AC_SUBST(MPI_EXTRA_ASM_OBJS)
458 MPI_SFLAGS="$ac_cv_mpi_sflags"
459 AC_SUBST(MPI_SFLAGS)
460
461 dnl Do we have zlib? Must do it here because Solaris failed
462 dnl when compiling a conftest (due to the "-lz" from LIBS).
463 if test "$g10_force_zlib" = "yes"; then
464     ZLIBS="../zlib/libzlib.a"
465     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
466     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
467     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
468 else
469 AC_CHECK_HEADERS(zlib.h)
470 if test "$ac_cv_header_zlib_h" = yes ; then
471     LIBS="$LIBS -lz"
472     ZLIBS=
473     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
474 else
475     ZLIBS="../zlib/libzlib.a"
476     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
477     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
478     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
479 fi
480 fi
481 AC_SUBST(ZLIBS)
482
483 if echo "$VERSION" | grep '[a-zA-Z]' >/dev/null ; then
484     AC_DEFINE(IS_DEVELOPMENT_VERSION)
485 fi
486
487 GNUPG_DO_LINK_FILES
488
489
490 AC_OUTPUT([
491 Makefile
492 intl/Makefile
493 po/Makefile.in
494 util/Makefile
495 mpi/Makefile
496 cipher/Makefile
497 g10/Makefile
498 doc/Makefile
499 tools/Makefile
500 zlib/Makefile
501 checks/Makefile
502 ])
503
504 dnl *-*wedit:notab*-*  Please keep this as the last line.