note: previous commit 6e46862 fixes another minor doc issue fix.
[gnupg.git] / m4 / npth.m4
1 # npth.m4 - autoconf macro to detect NPTH.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 AC_DEFUN([_AM_PATH_NPTH_CONFIG],
13 [ AC_ARG_WITH(npth-prefix,
14             AC_HELP_STRING([--with-npth-prefix=PFX],
15                            [prefix where NPTH is installed (optional)]),
16      npth_config_prefix="$withval", npth_config_prefix="")
17   if test "x$npth_config_prefix" != x ; then
18       NPTH_CONFIG="$npth_config_prefix/bin/npth-config"
19   fi
20
21   use_gpgrt_config=""
22   if test x"$NPTH_CONFIG" = x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
23     if $GPGRT_CONFIG npth --exists; then
24       NPTH_CONFIG="$GPGRT_CONFIG npth"
25       AC_MSG_NOTICE([Use gpgrt-config as npth-config])
26       use_gpgrt_config=yes
27     fi
28   fi
29   if test -z "$use_gpgrt_config"; then
30     AC_PATH_PROG(NPTH_CONFIG, npth-config, no)
31   fi
32
33   if test "$NPTH_CONFIG" != "no" ; then
34     if test -z "$use_gpgrt_config"; then
35       npth_version=`$NPTH_CONFIG --version`
36     else
37       npth_version=`$NPTH_CONFIG --modversion`
38     fi
39   fi
40   npth_version_major=`echo $npth_version | \
41                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
42   npth_version_minor=`echo $npth_version | \
43                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
44 ])
45
46 dnl AM_PATH_NPTH([MINIMUM-VERSION,
47 dnl               [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
48 dnl Test for libnpth and define NPTH_CFLAGS and NPTH_LIBS.
49 dnl
50 AC_DEFUN([AM_PATH_NPTH],
51 [ AC_REQUIRE([_AM_PATH_NPTH_CONFIG])dnl
52   tmp=ifelse([$1], ,1:0.91,$1)
53   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
54      req_npth_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
55      min_npth_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
56   else
57      req_npth_api=1
58      min_npth_version="$tmp"
59   fi
60
61   AC_MSG_CHECKING(for NPTH - version >= $min_npth_version)
62   ok=no
63   if test "$NPTH_CONFIG" != "no" ; then
64     req_major=`echo $min_npth_version | \
65                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
66     req_minor=`echo $min_npth_version | \
67                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
68     if test "$npth_version_major" -gt "$req_major"; then
69         ok=yes
70     else
71         if test "$npth_version_major" -eq "$req_major"; then
72             if test "$npth_version_minor" -gt "$req_minor"; then
73                ok=yes
74             else
75                if test "$npth_version_minor" -eq "$req_minor"; then
76                   ok=yes
77                fi
78             fi
79         fi
80     fi
81   fi
82   if test $ok = yes; then
83     AC_MSG_RESULT([yes ($npth_version)])
84   else
85     AC_MSG_RESULT(no)
86   fi
87   if test $ok = yes; then
88     # If we have a recent NPTH, we should also check that the
89     # API is compatible.
90     if test "$req_npth_api" -gt 0 ; then
91       if test -z "$use_gpgrt_config"; then
92         tmp=`$NPTH_CONFIG --api-version 2>/dev/null || echo 0`
93       else
94         tmp=`$NPTH_CONFIG --variable=api_version 2>/dev/null || echo 0`
95       fi
96       if test "$tmp" -gt 0 ; then
97         AC_MSG_CHECKING([NPTH API version])
98         if test "$req_npth_api" -eq "$tmp" ; then
99           AC_MSG_RESULT([okay])
100         else
101           ok=no
102           AC_MSG_RESULT([does not match. want=$req_npth_api got=$tmp])
103         fi
104       fi
105     fi
106   fi
107   if test $ok = yes; then
108     NPTH_CFLAGS=`$NPTH_CONFIG --cflags`
109     NPTH_LIBS=`$NPTH_CONFIG --libs`
110     ifelse([$2], , :, [$2])
111     if test -z "$use_gpgrt_config"; then
112       npth_config_host=`$NPTH_CONFIG --host 2>/dev/null || echo none`
113     else
114       npth_config_host=`$NPTH_CONFIG --variable=host 2>/dev/null || echo none`
115     fi
116     if test x"$npth_config_host" != xnone ; then
117       if test x"$npth_config_host" != x"$host" ; then
118         AC_MSG_WARN([[
119 ***
120 *** The config script "$NPTH_CONFIG" was
121 *** built for $npth_config_host and thus may not match the
122 *** used host $host.
123 *** You may want to use the configure option --with-npth-prefix
124 *** to specify a matching config script.
125 ***]])
126       fi
127     fi
128   else
129     NPTH_CFLAGS=""
130     NPTH_LIBS=""
131     ifelse([$3], , :, [$3])
132   fi
133   AC_SUBST(NPTH_CFLAGS)
134   AC_SUBST(NPTH_LIBS)
135 ])