add-key works
[gnupg.git] / mpi / i586 / mpih-sub1.S
1 /* i80586 sub_n -- Sub two limb vectors of the same length > 0 and store
2  *                 sum in a third limb vector.
3  *      Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
4  *      Copyright (C) 1998 Free Software Foundation, Inc.
5  *
6  * This file is part of GNUPG.
7  *
8  * GNUPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 2 of the License, or
11  * (at your option) any later version.
12  *
13  * GNUPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 #include "sysdep.h"
33 #include "asm-syntax.h"
34
35
36 /*******************
37  *  mpi_limb_t
38  *  mpihelp_sub_n( mpi_ptr_t res_ptr,   (sp + 4)
39  *                 mpi_ptr_t s1_ptr,    (sp + 8)
40  *                 mpi_ptr_t s2_ptr,    (sp + 12)
41  *                 mpi_size_t size)     (sp + 16)
42  */
43
44
45 .text
46         ALIGN (3)
47         .globl C_SYMBOL_NAME(mpihelp_sub_n)
48 C_SYMBOL_NAME(mpihelp_sub_n:)
49
50         pushl   %edi
51         pushl   %esi
52         pushl   %ebx
53         pushl   %ebp
54
55         movl    20(%esp),%edi           /* res_ptr */
56         movl    24(%esp),%esi           /* s1_ptr */
57         movl    28(%esp),%ebp           /* s2_ptr */
58         movl    32(%esp),%ecx           /* size */
59
60         movl    (%ebp),%ebx
61
62         decl    %ecx
63         movl    %ecx,%edx
64         shrl    $3,%ecx
65         andl    $7,%edx
66         testl   %ecx,%ecx               /* zero carry flag */
67         jz      Lend
68         pushl   %edx
69
70         ALIGN (3)
71 Loop:   movl    28(%edi),%eax           /* fetch destination cache line */
72         leal    32(%edi),%edi
73
74 L1:     movl    (%esi),%eax
75         movl    4(%esi),%edx
76         sbbl    %ebx,%eax
77         movl    4(%ebp),%ebx
78         sbbl    %ebx,%edx
79         movl    8(%ebp),%ebx
80         movl    %eax,-32(%edi)
81         movl    %edx,-28(%edi)
82
83 L2:     movl    8(%esi),%eax
84         movl    12(%esi),%edx
85         sbbl    %ebx,%eax
86         movl    12(%ebp),%ebx
87         sbbl    %ebx,%edx
88         movl    16(%ebp),%ebx
89         movl    %eax,-24(%edi)
90         movl    %edx,-20(%edi)
91
92 L3:     movl    16(%esi),%eax
93         movl    20(%esi),%edx
94         sbbl    %ebx,%eax
95         movl    20(%ebp),%ebx
96         sbbl    %ebx,%edx
97         movl    24(%ebp),%ebx
98         movl    %eax,-16(%edi)
99         movl    %edx,-12(%edi)
100
101 L4:     movl    24(%esi),%eax
102         movl    28(%esi),%edx
103         sbbl    %ebx,%eax
104         movl    28(%ebp),%ebx
105         sbbl    %ebx,%edx
106         movl    32(%ebp),%ebx
107         movl    %eax,-8(%edi)
108         movl    %edx,-4(%edi)
109
110         leal    32(%esi),%esi
111         leal    32(%ebp),%ebp
112         decl    %ecx
113         jnz     Loop
114
115         popl    %edx
116 Lend:
117         decl    %edx                    /* test %edx w/o clobbering carry */
118         js      Lend2
119         incl    %edx
120 Loop2:
121         leal    4(%edi),%edi
122         movl    (%esi),%eax
123         sbbl    %ebx,%eax
124         movl    4(%ebp),%ebx
125         movl    %eax,-4(%edi)
126         leal    4(%esi),%esi
127         leal    4(%ebp),%ebp
128         decl    %edx
129         jnz     Loop2
130 Lend2:
131         movl    (%esi),%eax
132         sbbl    %ebx,%eax
133         movl    %eax,(%edi)
134
135         sbbl    %eax,%eax
136         negl    %eax
137
138         popl    %ebp
139         popl    %ebx
140         popl    %esi
141         popl    %edi
142         ret
143