tests: Disable 'pkits' test suite.
[gnupg.git] / tests / openpgp / defs.scm
1 ;; Common definitions for the OpenPGP test scripts.
2 ;;
3 ;; Copyright (C) 2016, 2017 g10 Code GmbH
4 ;;
5 ;; This file is part of GnuPG.
6 ;;
7 ;; GnuPG is free software; you can redistribute it and/or modify
8 ;; it under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation; either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; GnuPG is distributed in the hope that it will be useful,
13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 ;; GNU General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 ;;
21 ;; Constants.
22 ;;
23
24 (define usrname1 "one@example.com")
25 (define usrpass1 "def")
26 (define usrname2 "two@example.com")
27 (define usrpass2 "")
28 (define usrname3 "three@example.com")
29 (define usrpass3 "")
30
31 (define dsa-usrname1 "pgp5")
32 ;; we use the sub key because we do not yet have the logic to derive
33 ;; the first encryption key from a keyblock (I guess) (Well of course
34 ;; we have this by now and the notation below will lookup the primary
35 ;; first and then search for the encryption subkey.)
36 (define dsa-usrname2 "0xCB879DE9")
37
38 (define keys
39   (package
40    (define (new fpr grip uids subkeys)
41      (package))
42    (define (subkey fpr grip)
43      (package))
44    (define alfa (new "A0FF4590BB6122EDEF6E3C542D727CC768697734"
45                      "76F7E2B35832976B50A27A282D9B87E44577EB66"
46                      '("alfa@example.net" "alpha@example.net")
47                      (list
48                       (subkey "3B3FBC948FE59301ED629EFB6AE6D7EE46A871F8"
49                               "A0747D5F9425E6664F4FFBEED20FBCA79FDED2BD"))))
50    (define one (new "289B0EF1D105E124B6F626020EF77096D74C5F22"
51                     "50B2D4FA4122C212611048BC5FC31BD44393626E"
52                     '("one@example.com")
53                     (list
54                      (subkey "EB467DCA4AD7676A6A62B2ABABAB28A247BE2775"
55                              "7E201E28B6FEB2927B321F443205F4724EBE637E"))))
56    (define two (new "C1DEBB34EA8B71009EAFA474973D50E1C40FDECF"
57                     "343D8AF79796EE107D645A2787A9D9252F924E6F"
58                     '("two@example.com")
59                     (list
60                      (subkey "CD3D0F5701CBFCACB2A4907305A37887B27907AA"
61                              "8B5ABF3EF9EB8D96B91A0B8C2C4401C91C834C34"))))))
62
63 (define key-file1 "samplekeys/rsa-rsa-sample-1.asc")
64 (define key-file2 "samplekeys/ed25519-cv25519-sample-1.asc")
65
66 (define plain-files '("plain-1" "plain-2" "plain-3" "plain-large"))
67 (define data-files '("data-500" "data-9000" "data-32000" "data-80000"))
68 (define exp-files '())
69 (define all-files (append plain-files data-files))
70
71 (let ((verbose (string->number (getenv "verbose"))))
72   (if (number? verbose)
73       (*set-verbose!* verbose)))
74
75 (define (qualify executable)
76   (string-append executable (getenv "EXEEXT")))
77
78 (define (getenv' key default)
79   (let ((value (getenv key)))
80     (if (string=? "" value)
81         default
82         value)))
83
84 (define (percent-decode s)
85   (define (decode c)
86     (if (and (> (length c) 2) (char=? #\% (car c)))
87         (integer->char (string->number (string #\# #\x (cadr c) (caddr c))))
88         #f))
89   (let loop ((i 0) (c (string->list s)) (r (make-string (string-length s))))
90     (if (null? c)
91         (substring r 0 i)
92         (let ((decoded (decode c)))
93           (string-set! r i (if decoded decoded (car c)))
94           (loop (+ 1 i) (if decoded (cdddr c) (cdr c)) r)))))
95 (assert (equal? (percent-decode "") ""))
96 (assert (equal? (percent-decode "%61") "a"))
97 (assert (equal? (percent-decode "foob%61r") "foobar"))
98
99 (define (percent-encode s)
100   (define (encode c)
101     `(#\% ,@(string->list (number->string (char->integer c) 16))))
102   (let loop ((acc '()) (cs (reverse (string->list s))))
103     (if (null? cs)
104         (list->string acc)
105         (case (car cs)
106           ((#\: #\%)
107            (loop (append (encode (car cs)) acc) (cdr cs)))
108           (else
109            (loop (cons (car cs) acc) (cdr cs)))))))
110 (assert (equal? (percent-encode "") ""))
111 (assert (equal? (percent-encode "%61") "%2561"))
112 (assert (equal? (percent-encode "foob%61r") "foob%2561r"))
113
114 (define tools
115   '((gpgv "GPGV" "g10/gpgv")
116     (gpg-connect-agent "GPG_CONNECT_AGENT" "tools/gpg-connect-agent")
117     (gpgconf "GPGCONF" "tools/gpgconf")
118     (gpg-preset-passphrase "GPG_PRESET_PASSPHRASE"
119                            "agent/gpg-preset-passphrase")
120     (gpgtar "GPGTAR" "tools/gpgtar")
121     (gpg-zip "GPGZIP" "tools/gpg-zip")
122     (pinentry "PINENTRY" "tests/openpgp/fake-pinentry")))
123
124 (define bin-prefix (getenv "BIN_PREFIX"))
125 (define installed? (not (string=? "" bin-prefix)))
126
127 (define (tool-hardcoded which)
128   (let ((t (assoc which tools)))
129     (getenv' (cadr t)
130              (qualify (if installed?
131                           (string-append bin-prefix "/" (basename (caddr t)))
132                           (string-append (getenv "objdir") "/" (caddr t)))))))
133
134 ;; You can splice VALGRIND into your argument vector to run programs
135 ;; under valgrind.  For example, to run valgrind on gpg, you may want
136 ;; to redefine gpg:
137 ;;
138 ;; (set! gpg `(,@valgrind ,@gpg))
139 ;;
140 (define valgrind
141   '("/usr/bin/valgrind" --leak-check=full --error-exitcode=154))
142
143 (unless installed?
144         (setenv "GNUPG_BUILDDIR" (getenv "objdir") #t))
145
146 (define (gpg-conf . args)
147   (gpg-conf' "" args))
148 (define (gpg-conf' input args)
149   (let ((s (call-popen `(,(tool-hardcoded 'gpgconf)
150                          ,@(if installed? '()
151                                (list '--build-prefix (getenv "objdir")))
152                          ,@args) input)))
153     (map (lambda (line) (map percent-decode (string-split line #\:)))
154          (string-split-newlines s))))
155 (define :gc:c:name car)
156 (define :gc:c:description cadr)
157 (define :gc:c:pgmname caddr)
158 (define (:gc:o:name x)             (list-ref x 0))
159 (define (:gc:o:flags x)            (string->number (list-ref x 1)))
160 (define (:gc:o:level x)            (string->number (list-ref x 2)))
161 (define (:gc:o:description x)      (list-ref x 3))
162 (define (:gc:o:type x)             (string->number (list-ref x 4)))
163 (define (:gc:o:alternate-type x)   (string->number (list-ref x 5)))
164 (define (:gc:o:argument-name x)    (list-ref x 6))
165 (define (:gc:o:default-value x)    (list-ref x 7))
166 (define (:gc:o:default-argument x) (list-ref x 8))
167 (define (:gc:o:value x)            (if (< (length x) 10) "" (list-ref x 9)))
168
169 (define (gpg-config component key)
170   (package
171    (define (value)
172      (let* ((conf (assoc key (gpg-conf '--list-options component)))
173             (type (:gc:o:type conf))
174             (value (:gc:o:value conf)))
175        (case type
176          ((0 2 3) (string->number value))
177          ((1 32) (substring value 1 (string-length value))))))
178    (define (update value)
179      (let ((value' (cond
180                     ((string? value) (string-append "\"" value))
181                     ((number? value) (number->string value))
182                     (else (throw "Unsupported value" value)))))
183        (gpg-conf' (string-append key ":0:" (percent-encode value'))
184                   `(--change-options ,component))))
185    (define (clear)
186      (gpg-conf' (string-append key ":16:")
187                 `(--change-options ,component)))))
188
189 (define gpg-components (apply gpg-conf '(--list-components)))
190
191 (define (tool which)
192   (case which
193     ((gpg gpg-agent scdaemon gpgsm dirmngr)
194      (:gc:c:pgmname (assoc (symbol->string which) gpg-components)))
195     (else
196      (tool-hardcoded which))))
197
198 (define (gpg-has-option? option)
199   (string-contains? (call-popen `(,(tool 'gpg) --dump-options) "")
200                     option))
201
202 (define have-opt-always-trust
203   (catch #f
204          (call-check `(,(tool 'gpg) --gpgconf-test --always-trust))
205          #t))
206
207 (define GPG `(,(tool 'gpg) --no-permission-warning
208               ,@(if have-opt-always-trust '(--always-trust) '())))
209 (define GPGV `(,(tool 'gpgv)))
210 (define PINENTRY (tool 'pinentry))
211
212 (define (tr:gpg input args)
213   (tr:spawn input `(,@GPG --output **out** ,@args **in**)))
214
215 (define (pipe:gpg args)
216   (pipe:spawn `(,@GPG --output - ,@args -)))
217
218 (define (gpg-with-colons args)
219   (let ((s (call-popen `(,@GPG --with-colons ,@args) "")))
220     (map (lambda (line) (string-split line #\:))
221          (string-split-newlines s))))
222
223 ;; Convenient accessors for the colon output.
224 (define (:type x)   (string->symbol (list-ref x 0)))
225 (define (:length x) (string->number (list-ref x 2)))
226 (define (:alg x) (string->number (list-ref x 3)))
227 (define (:expire x) (list-ref x 6))
228 (define (:fpr x) (list-ref x 9))
229 (define (:cap x) (list-ref x 11))
230
231 (define (have-public-key? key)
232   (catch #f
233          (pair? (filter (lambda (l) (and (equal? 'fpr (:type l))
234                                          (equal? key::fpr (:fpr l))))
235                         (gpg-with-colons `(--list-keys ,key::fpr))))))
236
237 (define (have-secret-key? key)
238   (catch #f
239          (pair? (filter (lambda (l) (and (equal? 'fpr (:type l))
240                                          (equal? key::fpr (:fpr l))))
241                         (gpg-with-colons `(--list-secret-keys ,key::fpr))))))
242
243 (define (have-secret-key-file? key)
244   (file-exists? (path-join (getenv "GNUPGHOME") "private-keys-v1.d"
245                            (string-append key::grip ".key"))))
246
247 (define (get-config what)
248   (string-split (caddar (gpg-with-colons `(--list-config ,what))) #\;))
249
250 (define all-pubkey-algos (delay (get-config "pubkeyname")))
251 (define all-hash-algos (delay (get-config "digestname")))
252 (define all-cipher-algos (delay (get-config "ciphername")))
253 (define all-compression-algos (delay (get-config "compressname")))
254
255 (define (have-pubkey-algo? x)
256   (not (not (member x (force all-pubkey-algos)))))
257 (define (have-hash-algo? x)
258   (not (not (member x (force all-hash-algos)))))
259 (define (have-cipher-algo? x)
260   (not (not (member x (force all-cipher-algos)))))
261 (define (have-compression-algo? x)
262   (not (not (member x (force all-compression-algos)))))
263
264 (define (gpg-pipe args0 args1 errfd)
265   (lambda (source sink)
266     (let* ((p (pipe))
267            (task0 (spawn-process-fd `(,@GPG ,@args0)
268                    source (:write-end p) errfd))
269            (_ (close (:write-end p)))
270            (task1 (spawn-process-fd `(,@GPG ,@args1)
271                    (:read-end p) sink errfd)))
272       (close (:read-end p))
273       (wait-processes (list GPG GPG) (list task0 task1) #t))))
274
275 (setenv "GPG_AGENT_INFO" "" #t)
276 (setenv "GNUPGHOME" (getcwd) #t)
277 (define GNUPGHOME (getcwd))
278
279 ;;
280 ;; GnuPG helper.
281 ;;
282
283 ;; Evaluate a sequence of expressions with the given home directory.
284 (define-macro (with-home-directory gnupghome . expressions)
285   (let ((original-home-directory (gensym)))
286     `(let ((,original-home-directory (getenv "GNUPGHOME")))
287        (dynamic-wind
288            (lambda () (setenv "GNUPGHOME" ,gnupghome #t))
289            (lambda () ,@expressions)
290            (lambda () (setenv "GNUPGHOME" ,original-home-directory #t))))))
291
292 ;; Evaluate a sequence of expressions with an ephemeral home
293 ;; directory.
294 (define-macro (with-ephemeral-home-directory setup-fn . expressions)
295   (let ((original-home-directory (gensym))
296         (ephemeral-home-directory (gensym))
297         (setup (gensym)))
298     `(let ((,original-home-directory (getenv "GNUPGHOME"))
299            (,ephemeral-home-directory (mkdtemp))
300            (,setup (delay (,setup-fn))))
301        (finally (unlink-recursively ,ephemeral-home-directory)
302          (dynamic-wind
303              (lambda ()
304                (setenv "GNUPGHOME" ,ephemeral-home-directory #t)
305                (with-working-directory ,ephemeral-home-directory (force ,setup)))
306              (lambda () ,@expressions)
307              (lambda () (setenv "GNUPGHOME" ,original-home-directory #t)))))))
308
309 ;; Call GPG to obtain the hash sums.  Either specify an input file in
310 ;; ARGS, or an string in INPUT.  Returns a list of (<algo>
311 ;; "<hashsum>") lists.
312 (define (gpg-hash-string args input)
313   (map
314    (lambda (line)
315      (let ((p (string-split line #\:)))
316        (list (string->number (cadr p)) (caddr p))))
317    (string-split-newlines
318     (call-popen `(,@GPG --with-colons ,@args) input))))
319
320 ;; Dearmor a file.
321 (define (dearmor source-name sink-name)
322   (pipe:do
323    (pipe:open source-name (logior O_RDONLY O_BINARY))
324    (pipe:spawn `(,@GPG --dearmor))
325    (pipe:write-to sink-name (logior O_WRONLY O_CREAT O_BINARY) #o600)))
326
327 ;;
328 ;; Support for test environment creation and teardown.
329 ;;
330
331 (define (make-test-data filename size)
332   (call-with-binary-output-file
333    filename
334    (lambda (port)
335      (display (make-random-string size) port))))
336
337 (define (create-gpghome)
338   (log "Creating test environment...")
339
340   (srandom (getpid))
341   (make-test-data "random_seed" 600)
342
343   (log "Creating configuration files")
344   (for-each
345    (lambda (name)
346      (file-copy (in-srcdir (string-append name ".tmpl")) name)
347      (let ((p (open-input-output-file name)))
348        (cond
349         ((string=? "gpg.conf" name)
350          (if have-opt-always-trust
351              (display "no-auto-check-trustdb\n" p))
352          (display (string-append "agent-program "
353                                  (tool 'gpg-agent)
354                                  "|--debug-quick-random\n") p)
355          (display "allow-weak-digest-algos\n" p))
356         ((string=? "gpg-agent.conf" name)
357          (display (string-append "pinentry-program " PINENTRY "\n") p)))))
358    '("gpg.conf" "gpg-agent.conf")))
359
360 ;; Initialize the test environment, install appropriate configuration
361 ;; and start the agent, without any keys.
362 (define (setup-environment)
363   (create-gpghome)
364   (start-agent))
365
366 (define (create-sample-files)
367   (log "Creating sample data files")
368   (for-each
369    (lambda (size)
370      (make-test-data (string-append "data-" (number->string size))
371                      size))
372    '(500 9000 32000 80000))
373
374   (log "Unpacking samples")
375   (for-each
376    (lambda (name)
377      (dearmor (in-srcdir ".." "openpgp" (string-append name "o.asc")) name))
378    plain-files))
379
380 (define (create-legacy-gpghome)
381   (create-sample-files)
382
383   (log "Storing private keys")
384   (for-each
385    (lambda (name)
386      (dearmor (in-srcdir (string-append "/privkeys/" name ".asc"))
387               (string-append "private-keys-v1.d/" name ".key")))
388    '("50B2D4FA4122C212611048BC5FC31BD44393626E"
389      "7E201E28B6FEB2927B321F443205F4724EBE637E"
390      "13FDB8809B17C5547779F9D205C45F47CE0217CE"
391      "343D8AF79796EE107D645A2787A9D9252F924E6F"
392      "8B5ABF3EF9EB8D96B91A0B8C2C4401C91C834C34"
393      "0D6F6AD4C4C803B25470F9104E9F4E6A4CA64255"
394      "FD692BD59D6640A84C8422573D469F84F3B98E53"
395      "76F7E2B35832976B50A27A282D9B87E44577EB66"
396      "A0747D5F9425E6664F4FFBEED20FBCA79FDED2BD"
397      "00FE67F28A52A8AA08FFAED20AF832DA916D1985"
398      "1DF48228FEFF3EC2481B106E0ACA8C465C662CC5"
399      "A2832820DC9F40751BDCD375BB0945BA33EC6B4C"
400      "ADE710D74409777B7729A7653373D820F67892E0"
401      "CEFC51AF91F68A2904FBFF62C4F075A4785B803F"
402      "1E28F20E41B54C2D1234D896096495FF57E08D18"
403      "EB33B687EB8581AB64D04852A54453E85F3DF62D"
404      "C6A6390E9388CDBAD71EAEA698233FE5E04F001E"
405      "D69102E0F5AC6B6DB8E4D16DA8E18CF46D88CAE3"))
406
407   (log "Importing public demo and test keys")
408   (for-each
409    (lambda (file)
410      (call-check `(,@GPG --yes --import ,(in-srcdir file))))
411    (list "pubdemo.asc" "pubring.asc" key-file1))
412
413   (pipe:do
414    (pipe:open (in-srcdir "pubring.pkr.asc") (logior O_RDONLY O_BINARY))
415    (pipe:spawn `(,@GPG --dearmor))
416    (pipe:spawn `(,@GPG --yes --import))))
417
418 (define (preset-passphrases)
419   (log "Presetting passphrases")
420   ;; one@example.com
421   (call-check `(,(tool 'gpg-preset-passphrase)
422                 --preset --passphrase def
423                 "50B2D4FA4122C212611048BC5FC31BD44393626E"))
424   (call-check `(,(tool 'gpg-preset-passphrase)
425                 --preset --passphrase def
426                 "7E201E28B6FEB2927B321F443205F4724EBE637E"))
427   ;; alpha@example.net
428   (call-check `(,(tool 'gpg-preset-passphrase)
429                 --preset --passphrase abc
430                 "76F7E2B35832976B50A27A282D9B87E44577EB66"))
431   (call-check `(,(tool 'gpg-preset-passphrase)
432                 --preset --passphrase abc
433                 "A0747D5F9425E6664F4FFBEED20FBCA79FDED2BD")))
434
435 ;; Initialize the test environment, install appropriate configuration
436 ;; and start the agent, with the keys from the legacy test suite.
437 (define (setup-legacy-environment)
438   (create-gpghome)
439   (if (member "--unpack-tarball" *args*)
440       (begin
441         (call-check `(,(tool 'gpgtar) --extract --directory=. ,(cadr *args*)))
442         (start-agent))
443       (begin
444         (start-agent)
445         (create-legacy-gpghome)))
446   (preset-passphrases))
447
448 ;; Create the socket dir and start the agent.
449 (define (start-agent)
450   (log "Starting gpg-agent...")
451   (let ((gnupghome (getenv "GNUPGHOME")))
452     (atexit (lambda ()
453               (with-home-directory gnupghome
454                                    (stop-agent)))))
455   (catch (log "Warning: Creating socket directory failed:" (car *error*))
456          (call-popen `(,(tool 'gpgconf) --create-socketdir) ""))
457   (call-check `(,(tool 'gpg-connect-agent) --verbose
458                 ,(string-append "--agent-program=" (tool 'gpg-agent)
459                                 "|--debug-quick-random")
460                 /bye)))
461
462 ;; Stop the agent and other daemons and remove the socket dir.
463 (define (stop-agent)
464   (log "Stopping gpg-agent...")
465   (call-check `(,(tool 'gpgconf) --kill all))
466   (catch (log "Warning: Removing socket directory failed.")
467          (call-popen `(,(tool 'gpgconf) --remove-socketdir) "")))
468
469
470 ;; end