Ignore final installer files.
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006, 2007, 2008, 2010 g10 Code GmbH
3 #
4 # This file is part of GPG4Win
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18
19 # (Process this file with autoconf to produce a configure script.)
20
21 AC_PREREQ(2.59)
22 min_automake_version="1.9.3"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_isgit to "yes" for non-released code.
26 # Right after a release the make target "copy-news" is to be called!
27 m4_define([my_version], [2.1.1])
28 m4_define([my_isgit], [yes])
29
30 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
31           | awk '/^\* / {printf "%s",$3}']))
32 m4_define([my_full_version],
33           [my_version[]m4_if(my_isgit,[yes],[-git[]git_revision])])
34 AC_INIT([gpg4win],[my_full_version],[gpg4win-devel@wald.intevation.org])
35
36 # Remember to update these version numbers also in the NEWS file.
37 MANUALVERSION_EINSTEIGER="2.0.2"
38 MANUALDATE_EINSTEIGER="30. Mai 2006"
39 MANUALVERSION_DURCHBLICKER="2.0.2"
40 MANUALDATE_DURCHBLICKER="30. Mai 2006"
41 MANUALVERSION_NOVICES="1.0.0"
42 MANUALDATE_NOVICES="Nov. 30, 2006"
43 MANUALVERSION_ADVANCED="0.0.0"
44 MANUALDATE_ADVANCED="Nov. 30, 2006"
45 COMPENDIUM_VERSION_DE="3.0.0"
46 COMPENDIUM_DATE_DE="21. Mai 2010"
47 COMPENDIUMINPROGRESS_DE="zuletzt geringfügig korrigiert am 4. Januar 2012"
48 COMPENDIUM_VERSION_EN="3.0.0-beta1"
49 COMPENDIUM_DATE_EN="31. August 2010"
50 COMPENDIUMINPROGRESS_EN="last minor changes from 4. January 2012"
51
52 MANUALINPROGRESS_DE=m4_if(my_isgit,[yes],["~und evtl. seitdem weiter bearbeitet"])
53 MANUALINPROGRESS_EN=m4_if(my_isgit,[yes],["~and may have been further edited"])
54 PACKAGE=$PACKAGE_NAME
55 VERSION=$PACKAGE_VERSION
56 GIT_REVISION=git_revision
57 GIT_REVISION_DEC="$((0x$(echo git_revision | head -c 4)))"
58
59
60 AC_CONFIG_SRCDIR(include/config.nsi.in)
61 AC_CONFIG_MACRO_DIR(m4)
62
63 AM_INIT_AUTOMAKE([tar-ustar])
64 AM_MAINTAINER_MODE
65 AC_CANONICAL_HOST
66 AM_CONFIG_HEADER(config.h)
67
68 # Language support
69 AM_PO_SUBDIRS
70
71
72 AC_SUBST(PACKAGE)
73 AC_SUBST(VERSION)
74 AC_SUBST(MANUALVERSION_EINSTEIGER)
75 AC_SUBST(MANUALDATE_EINSTEIGER)
76 AC_SUBST(MANUALVERSION_DURCHBLICKER)
77 AC_SUBST(MANUALDATE_DURCHBLICKER)
78 AC_SUBST(MANUALINPROGRESS_DE)
79 AC_SUBST(MANUALVERSION_NOVICES)
80 AC_SUBST(MANUALDATE_NOVICES)
81 AC_SUBST(MANUALVERSION_ADVANCED)
82 AC_SUBST(MANUALDATE_ADVANCED)
83 AC_SUBST(MANUALINPROGRESS_EN)
84 AC_SUBST(COMPENDIUM_VERSION_DE)
85 AC_SUBST(COMPENDIUM_DATE_DE)
86 AC_SUBST(COMPENDIUMINPROGRESS_DE)
87 AC_SUBST(COMPENDIUM_VERSION_EN)
88 AC_SUBST(COMPENDIUM_DATE_EN)
89 AC_SUBST(COMPENDIUMINPROGRESS_EN)
90
91 if echo "${PACKAGE_VERSION}" | egrep 'svn|rc|beta|git' >/dev/null ; then
92   IS_BETA_BUILD=yes
93 else
94   IS_BETA_BUILD=no
95 fi
96 AC_SUBST(IS_BETA_BUILD)
97
98 # Generate extended version information.  Note, that for NSIS use we
99 # must not translate the dots to commas in the BUILD_FILEVERSION.
100 BUILD_TIMESTAMP=`date --iso-8601=minutes`
101 BUILD_ISODATE=`date --iso-8601`
102 changequote(,)dnl
103 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
104 changequote([,])dnl
105 BUILD_FILEVERSION="${BUILD_FILEVERSION}${GIT_REVISION_DEC}"
106 AC_SUBST(BUILD_TIMESTAMP)
107 AC_SUBST(BUILD_ISODATE)
108 AC_SUBST(BUILD_FILEVERSION)
109
110 # To test the manuals using an actual web server, the preview target
111 # may be used in doc/manuals.  The default is my (wk) test environment
112 # but may be overriden using another preview variable.  PREVIEWHOST is
113 # expected to be the target for an rsync command.
114 if test -z "$PREVIEWHOST" ; then
115    PREVIEWHOST="vigenere:/var/www/all/preview.gpg4win.org/htdocs/"
116 fi
117 AC_SUBST(PREVIEWHOST)
118
119 # The final release is copied to an archive server.  The default
120 # location may be changed by setting the RELEASEHOST envvar.
121 if test -z "$RELEASEHOST" ; then
122    RELEASEHOST="vigenere:tarballs/gpg4win"
123    if test "${IS_BETA_BUILD}" = yes ; then
124       RELEASEHOST="${RELEASEHOST}/Beta"
125    fi
126 fi
127 AC_SUBST(RELEASEHOST)
128
129 # For development of this package it is useful to build without
130 # creating the source installer (takes a long time).  This option may
131 # be used to suppress creation of the source installer.
132 AC_ARG_ENABLE(source-installer,
133     AC_HELP_STRING([--disable-source-installer],
134                    [Do not create the Source installer]),
135                     build_source_installer=$enableval,
136                     build_source_installer=yes)
137 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
138
139
140 # You can build a light version of the installer in addition to the
141 # regular version.  This one does not contain the manuals.
142 AC_ARG_ENABLE(light-installer,
143     AC_HELP_STRING([--disable-light-installer],
144                    [Do not create the light version of the installer]),
145                     build_light_installer=$enableval,
146                     build_light_installer=yes)
147 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
148
149 # You can build a vanilla version of the installer, featuring only
150 # GnuPG, a pinentry and GPGME, in addition to the regular version.
151 # This one does not contain the manuals.
152 AC_ARG_ENABLE(vanilla-installer,
153     AC_HELP_STRING([--disable-vanilla-installer],
154                    [Do not create the vanilla version of the installer]),
155                     build_vanilla_installer=$enableval,
156                     build_vanilla_installer=yes)
157 AM_CONDITIONAL(BUILD_VANILLA_INSTALLER, test "$build_vanilla_installer" = yes)
158
159 # If you want to build only the light or vanilla installer, you may
160 # disable building of the full installer.
161 AC_ARG_ENABLE(full-installer,
162     AC_HELP_STRING([--disable-full-installer],
163                    [Do not create the full version of the installer]),
164                     build_full_installer=$enableval,
165                     build_full_installer=yes)
166 AM_CONDITIONAL(BUILD_FULL_INSTALLER, test "$build_full_installer" = yes)
167
168 # For development it is often faster to build without manuals.
169 AC_ARG_ENABLE(manuals,
170     AC_HELP_STRING([--disable-manuals],
171                    [Do not build the manuals (for debugging)]),
172                     build_manuals=$enableval,
173                     build_manuals=yes)
174 AM_CONDITIONAL(BUILD_MANUALS, test "$build_manuals" = yes)
175
176
177 AC_ARG_ENABLE(fast-makensis,
178     AC_HELP_STRING([--enable-fast-makensis],
179                    [Use a less efficient compressor to speed up building]),
180                     use_fast_makensis=$enableval,
181                     use_fast_makensis=no)
182 if test "$use_fast_makensis" = yes; then
183   EXTRA_MAKENSIS_FLAGS="${EXTRA_MAKENSIS_FLAGS} -DDISABLE_LZMA=1"
184 fi
185 AC_SUBST(EXTRA_MAKENSIS_FLAGS)
186
187
188 # Required tools.
189 AC_PROG_CC
190 AC_PROG_CPP
191 AC_PROG_RANLIB
192 AC_CHECK_TOOL(AR, ar, :)
193 AC_CHECK_TOOLS(STRIP, strip)
194 AC_CHECK_TOOLS(DLLTOOL, dlltool)
195 AC_CHECK_PROGS(MAKE, make)
196 AC_CHECK_PROGS(UNZIP, unzip)
197 AC_CHECK_PROGS(TAR, tar)
198 AC_CHECK_PROGS(MKDIR, mkdir)
199 AC_CHECK_PROGS(CP, cp)
200 AC_CHECK_PROGS(RM, rm)
201 AC_CHECK_PROGS(STOW, stow)
202 AC_CHECK_PROGS(MAKENSIS, makensis)
203 AC_CHECK_PROGS(ZCAT, zcat)
204 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
205 AC_CHECK_PROGS(DVIPDF, dvipdf)
206 AC_CHECK_PROGS(CONVERT, convert)
207 AC_CHECK_PROGS(SHA1SUM, sha1sum)
208 AC_CHECK_PROGS(MSGFMT, msgfmt)
209 AC_PROG_INSTALL
210
211 missing_tools=
212 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
213          DVIPDF CONVERT SHA1SUM MSGFMT ; do
214    eval tmp='$'$i
215    if test -z "$tmp"; then
216       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
217    fi
218 done
219
220
221
222 # Optional tools.
223
224 AC_CHECK_PROGS(WGET, wget)
225
226
227 # Packages.
228 gpg4win_dup_sources=""
229
230 GPG4WIN_BPKG_GNU([libiconv])
231 GPG4WIN_BPKG_GNU([gettext], [libiconv])
232
233 GPG4WIN_SPKG([zlib])
234 GPG4WIN_BPKG_GNUWIN32([bsfilter])
235
236 GPG4WIN_BPKG_GTK([pkgconfig])
237 # We build our own version of glib, because we need to apply a few patches.
238 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
239 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
240 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
241 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
242 GPG4WIN_BPKG_GTK_DEV([cairo], [glib pkgconfig])
243 GPG4WIN_BPKG_GTK_DEV([expat])
244 GPG4WIN_BPKG_GTK_DEV([freetype], [pkgconfig zlib])
245 GPG4WIN_BPKG_GTK_DEV([fontconfig], [pkgconfig zlib expat])
246 GPG4WIN_BPKG_GTK_DEV([gtk+], [libiconv gettext pkgconfig atk pango glib cairo])
247 GPG4WIN_SPKG([libpng], [pkgconfig])
248 GPG4WIN_SPKG([enchant], [pkgconfig glib])
249
250 GPG4WIN_SPKG([bzip2])
251 GPG4WIN_SPKG([adns])
252 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
253 GPG4WIN_SPKG([libgcrypt], [libgpg-error])
254 GPG4WIN_SPKG([libksba], [libgpg-error])
255 GPG4WIN_SPKG([w32pth])
256 GPG4WIN_SPKG([libassuan], [libgpg-error w32pth])
257 GPG4WIN_SPKG([dirmngr], [libgpg-error libgcrypt libassuan libksba w32pth])
258 GPG4WIN_SPKG([pinentry], [libiconv gtk+])
259 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg2 glib])
260 GPG4WIN_SPKG([curl], [zlib gnutls])
261 GPG4WIN_SPKG([gnupg2], [libiconv libgcrypt libksba libassuan libgpg-error dnl
262                         w32pth zlib bzip2 adns pinentry])
263 GPG4WIN_SPKG([pthreads-w32])
264 GPG4WIN_SPKG([gpgol], [gpgme libassuan])
265 GPG4WIN_SPKG([gpgex], [libassuan])
266 GPG4WIN_SPKG([scute], [libgpg-error libassuan])
267 GPG4WIN_SPKG([paperkey])
268 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
269 GPG4WIN_SPKG([libgsasl])
270 GPG4WIN_SPKG([libtasn1])
271 GPG4WIN_SPKG([gnutls], [libgsasl libtasn1 libgcrypt])
272 GPG4WIN_SPKG([libetpan], [pthreads-w32 gnutls])
273 GPG4WIN_SPKG([libxml2], [zlib])
274 GPG4WIN_SPKG([regex])
275 GPG4WIN_SPKG([crypt])
276 GPG4WIN_SPKG([claws-mail], [libiconv gettext zlib gtk+ libpng enchant glib dnl
277                             gpgme pthreads-w32 crypt regex libetpan gnutls])
278 GPG4WIN_SPKG([notification_plugin], [claws-mail])
279 GPG4WIN_SPKG([gtkhtml2_viewer], [curl claws-mail libxml2])
280 GPG4WIN_SPKG([vcalendar], [curl claws-mail])
281 GPG4WIN_SPKG([rssyl], [curl claws-mail])
282 GPG4WIN_SPKG([tnef_parse], [claws-mail])
283 GPG4WIN_SPKG([attachwarner], [claws-mail])
284 GPG4WIN_SPKG([bsfilter_plugin], [claws-mail])
285 GPG4WIN_IPKG([compendium])
286
287 # Qt related stuff.
288 GPG4WIN_BPKG_GNUWIN32([kdesupport])
289 GPG4WIN_BPKG_BINSRC([oxygen-icons])
290 GPG4WIN_BPKG_GNUWIN32([qt], [kdesupport])
291 GPG4WIN_BPKG_GNUWIN32([kdelibs], [qt oxygen-icons])
292 GPG4WIN_BPKG_BINSRC([kleopatra], [gpgme gnupg2 kdelibs])
293 #GPG4WIN_BPKG_GNUWIN32([kleopatra], [gpgme gnupg2 kdelibs])
294
295 GPG4WIN_FINALIZE
296
297 # Qt is compiled with -mthreads, and thus requires the mingwm10.dll.
298 mingwm_dll=no
299 AC_ARG_WITH([mingwm-dll],
300             AC_HELP_STRING([--with-mingwm-dll=FILE], [use the mingwm DLL]),
301             [mingwm_dll=$withval])
302 if test "$mingwm_dll" = "no"; then
303   file="/usr/share/doc/mingw32-runtime/mingwm10.dll.gz"
304   if test -r "$file"; then
305     mingwm_dll="$file"
306   fi
307 fi
308 if test "$mingwm_dll" = "no"; then
309   missing_tools="mingwm10.dll $missing_tools"
310 fi
311 # To make things simple, we just install a copy of the file in the
312 # source directory.  No need to make this ugly hack any uglier by
313 # messing around with the build system.
314 case "$mingwm_dll" in
315     *.gz)
316       $ZCAT $mingwm_dll > src/mingwm10.dll
317       ;;
318     *)
319       cp $mingwm_dll src/mingwm10.dll
320       ;;
321 esac
322
323
324 # Throw an error if required tools are missing
325 if test -n "$missing_tools"; then
326     for i in $missing_tools; do
327       AC_MSG_NOTICE([$i is missing])
328     done
329     AC_MSG_ERROR([[
330 ***
331 *** Required tools not found. Please consult the above messages
332 *** and install them before running configure again.
333 ***]])
334 fi
335
336 # Throw an error if any duplicate source packages have been found
337 if test -n "$gpg4win_dup_sources"; then
338     tmp=
339     for i in $gpg4win_dup_sources; do
340       tmp="$tmp
341 $i"
342     done
343     AC_MSG_ERROR([Packages with more that one source version:$tmp])
344 fi
345
346
347 # Finalize.
348
349 AC_CONFIG_COMMANDS([gpg4win-conf],[[
350 chmod +x patches/gnupg2/01-version.patch
351 ]])
352
353 AC_CONFIG_FILES(Makefile)
354 AC_CONFIG_FILES(packages/Makefile include/Makefile src/Makefile po/Makefile.in)
355 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
356 AC_CONFIG_FILES(doc/Makefile)
357 AC_CONFIG_FILES(doc/logo/Makefile)
358 AC_CONFIG_FILES(doc/manual/Makefile doc/manual/version.tex)
359 AC_CONFIG_FILES(doc/website/Makefile)
360 AC_CONFIG_FILES(src/dictionaries/Makefile)
361 AC_CONFIG_FILES(patches/gnupg2/01-version.patch)
362 AC_OUTPUT