2010-11-21 Colin Leroy <colin@colino.net>
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006, 2007, 2008, 2010 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18  
19 # (Process this file with autoconf to produce a configure script.)
20
21 AC_PREREQ(2.59)
22 min_automake_version="1.9.3"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 # Right after a release the make target "copy-news" is to be called!
28 m4_define([my_version], [2.1.0-beta2])
29 m4_define([my_issvn], [yes])
30
31 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
32           ||echo 'Revision: 0')|sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
33 AC_INIT([gpg4win], 
34         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
35         [gpg4win-devel@wald.intevation.org])
36
37 # Remember to update these version numbers also in the NEWS file.
38 MANUALVERSION_EINSTEIGER="2.0.2"
39 MANUALDATE_EINSTEIGER="30. Mai 2006"
40 MANUALVERSION_DURCHBLICKER="2.0.2"
41 MANUALDATE_DURCHBLICKER="30. Mai 2006"
42 MANUALVERSION_NOVICES="1.0.0"
43 MANUALDATE_NOVICES="Nov. 30, 2006"
44 MANUALVERSION_ADVANCED="0.0.0"
45 MANUALDATE_ADVANCED="Nov. 30, 2006"
46 COMPENDIUM_VERSION_DE="3.0.0"
47 COMPENDIUM_DATE_DE="21. Mai 2010"
48 COMPENDIUMINPROGRESS_DE="zuletzt geringfügig korrigiert am 21. September 2010"
49 COMPENDIUM_VERSION_EN="3.0.0-beta1"
50 COMPENDIUM_DATE_EN="31. August 2010"
51 COMPENDIUMINPROGRESS_EN="last minor changes from 21. September 2010"
52
53 MANUALINPROGRESS_DE=m4_if(my_issvn,[yes],["~und evtl. seitdem weiter bearbeitet"])
54 MANUALINPROGRESS_EN=m4_if(my_issvn,[yes],["~and may have been further edited"])
55 SVN_REVISION=svn_revision
56 PACKAGE=$PACKAGE_NAME
57 VERSION=$PACKAGE_VERSION
58
59
60 AC_CONFIG_SRCDIR(include/config.nsi.in)
61 AC_CONFIG_MACRO_DIR(m4)
62
63 AM_INIT_AUTOMAKE
64 AM_MAINTAINER_MODE
65 AC_CANONICAL_HOST
66 AM_CONFIG_HEADER(config.h)
67
68 # Language support
69 AM_PO_SUBDIRS
70
71
72 AC_SUBST(PACKAGE)
73 AC_SUBST(VERSION)
74 AC_SUBST(MANUALVERSION_EINSTEIGER)
75 AC_SUBST(MANUALDATE_EINSTEIGER)
76 AC_SUBST(MANUALVERSION_DURCHBLICKER)
77 AC_SUBST(MANUALDATE_DURCHBLICKER)
78 AC_SUBST(MANUALINPROGRESS_DE)
79 AC_SUBST(MANUALVERSION_NOVICES)
80 AC_SUBST(MANUALDATE_NOVICES)
81 AC_SUBST(MANUALVERSION_ADVANCED)
82 AC_SUBST(MANUALDATE_ADVANCED)
83 AC_SUBST(MANUALINPROGRESS_EN)
84 AC_SUBST(COMPENDIUM_VERSION_DE)
85 AC_SUBST(COMPENDIUM_DATE_DE)
86 AC_SUBST(COMPENDIUMINPROGRESS_DE)
87 AC_SUBST(COMPENDIUM_VERSION_EN)
88 AC_SUBST(COMPENDIUM_DATE_EN)
89 AC_SUBST(COMPENDIUMINPROGRESS_EN)
90
91 if echo "${PACKAGE_VERSION}" | egrep 'svn|rc|beta|git' >/dev/null ; then 
92   IS_BETA_BUILD=yes
93 else
94   IS_BETA_BUILD=no
95 fi
96 AC_SUBST(IS_BETA_BUILD)
97
98 # Generate extended version information.  Note, that for NSIS use we
99 # must not translate the dots to commas in the BUILD_FILEVERSION.
100 BUILD_TIMESTAMP=`date --iso-8601=minutes`
101 BUILD_ISODATE=`date --iso-8601`
102 changequote(,)dnl
103 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
104 changequote([,])dnl
105 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
106 AC_SUBST(BUILD_TIMESTAMP)
107 AC_SUBST(BUILD_ISODATE)
108 AC_SUBST(BUILD_FILEVERSION)
109
110 # To test the manuals using an actual web server, the preview target
111 # may be used in doc/manuals.  The default is my (wk) test environment
112 # but may be overriden using another preview variable.  PREVIEWHOST is
113 # expected to be the target for an rsync command.
114 if test -z "$PREVIEWHOST" ; then
115    PREVIEWHOST="vigenere:/var/www/all/preview.gpg4win.org/htdocs/"
116 fi
117 AC_SUBST(PREVIEWHOST)
118
119 # The final release is copied to an archive server.  The default
120 # location may be changed by setting the RELEASEHOST envvar.
121 if test -z "$RELEASEHOST" ; then
122    RELEASEHOST="vigenere:tarballs/gpg4win"
123    if test "${IS_BETA_BUILD}" = yes ; then
124       RELEASEHOST="${RELEASEHOST}/Beta"
125    fi
126 fi
127 AC_SUBST(RELEASEHOST)
128
129 # For development of this package it is useful to build without
130 # creating the source installer (takes a long time).  This option may
131 # be used to suppress creation of the source installer.
132 AC_ARG_ENABLE(source-installer,
133     AC_HELP_STRING([--disable-source-installer],
134                    [Do not create the Source installer]),
135                     build_source_installer=$enableval,
136                     build_source_installer=yes)
137 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
138
139
140 # You can build a light version of the installer in addition to the
141 # regular version.  This one does not contain the manuals.
142 AC_ARG_ENABLE(light-installer,
143     AC_HELP_STRING([--disable-light-installer],
144                    [Do not create the light version of the installer]),
145                     build_light_installer=$enableval,
146                     build_light_installer=yes)
147 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
148
149 AC_ARG_ENABLE(fast-makensis,
150     AC_HELP_STRING([--enable-fast-makensis],
151                    [Use a less efficient compressor to speed up building]),
152                     use_fast_makensis=$enableval,
153                     use_fast_makensis=no)
154 if test "$use_fast_makensis" = yes; then
155   EXTRA_MAKENSIS_FLAGS="${EXTRA_MAKENSIS_FLAGS} -DDISABLE_LZMA=1"
156 fi
157 AC_SUBST(EXTRA_MAKENSIS_FLAGS)
158
159
160 # Required tools.
161 AC_PROG_CC
162 AC_PROG_CPP
163 AC_PROG_RANLIB
164 AC_CHECK_TOOL(AR, ar, :)
165 AC_CHECK_TOOLS(STRIP, strip)
166 AC_CHECK_TOOLS(DLLTOOL, dlltool)
167 AC_CHECK_PROGS(MAKE, make)
168 AC_CHECK_PROGS(UNZIP, unzip)
169 AC_CHECK_PROGS(TAR, tar)
170 AC_CHECK_PROGS(MKDIR, mkdir)
171 AC_CHECK_PROGS(CP, cp)
172 AC_CHECK_PROGS(RM, rm)
173 AC_CHECK_PROGS(STOW, stow)
174 AC_CHECK_PROGS(MAKENSIS, makensis)
175 AC_CHECK_PROGS(ZCAT, zcat)
176 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
177 AC_CHECK_PROGS(DVIPDF, dvipdf)
178 AC_CHECK_PROGS(CONVERT, convert)
179 AC_CHECK_PROGS(SHA1SUM, sha1sum)
180 AC_CHECK_PROGS(MSGFMT, msgfmt)
181 AC_PROG_INSTALL
182
183 missing_tools=
184 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
185          DVIPDF CONVERT SHA1SUM MSGFMT ; do
186    eval tmp='$'$i
187    if test -z "$tmp"; then 
188       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
189    fi
190 done
191
192
193
194 # Optional tools.
195
196 AC_CHECK_PROGS(WGET, wget)
197
198
199 # Packages.
200 gpg4win_dup_sources=""
201
202 GPG4WIN_BPKG_GNU([libiconv])
203 GPG4WIN_BPKG_GNU([gettext], [libiconv])
204
205 GPG4WIN_SPKG([zlib])
206 GPG4WIN_BPKG_GNUWIN32([bsfilter])
207
208 GPG4WIN_BPKG_GTK([pkgconfig])
209 # We build our own version of glib, because we need to apply a few patches.
210 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
211 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
212 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
213 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
214 GPG4WIN_BPKG_GTK_DEV([cairo], [glib pkgconfig])
215 GPG4WIN_BPKG_GTK_DEV([expat])
216 GPG4WIN_BPKG_GTK_DEV([freetype], [pkgconfig zlib])
217 GPG4WIN_BPKG_GTK_DEV([fontconfig], [pkgconfig zlib expat])
218 GPG4WIN_BPKG_GTK_DEV([gtk+], [libiconv gettext pkgconfig atk pango glib cairo])
219 GPG4WIN_SPKG([libpng], [pkgconfig])
220
221 GPG4WIN_SPKG([bzip2])
222 GPG4WIN_SPKG([adns])
223 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
224 GPG4WIN_SPKG([libgcrypt], [libgpg-error])
225 GPG4WIN_SPKG([libksba], [libgpg-error])
226 GPG4WIN_SPKG([w32pth])
227 GPG4WIN_SPKG([libassuan], [libgpg-error w32pth])
228 GPG4WIN_SPKG([dirmngr], [libgpg-error libgcrypt libassuan libksba w32pth])
229 GPG4WIN_SPKG([pinentry], [libiconv gtk+])
230 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg2 glib])
231 GPG4WIN_SPKG([curl], [zlib gnutls])
232 GPG4WIN_SPKG([gnupg2], [libiconv libgcrypt libksba libassuan libgpg-error dnl
233                         w32pth zlib bzip2 adns pinentry])
234 GPG4WIN_SPKG([pthreads-w32])
235 GPG4WIN_SPKG([gpgol], [gpgme libassuan])
236 GPG4WIN_SPKG([gpgex], [libassuan])
237 GPG4WIN_SPKG([scute], [libgpg-error libassuan])
238 GPG4WIN_SPKG([paperkey])
239 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
240 GPG4WIN_SPKG([libgsasl])
241 GPG4WIN_SPKG([libtasn1])
242 GPG4WIN_SPKG([gnutls], [libgsasl libtasn1 libgcrypt])
243 GPG4WIN_SPKG([libetpan], [pthreads-w32 gnutls])
244 GPG4WIN_SPKG([libxml2], [zlib])
245 GPG4WIN_SPKG([regex])
246 GPG4WIN_SPKG([crypt])
247 GPG4WIN_SPKG([claws-mail], [libiconv gettext zlib gtk+ libpng glib dnl
248                             gpgme pthreads-w32 crypt regex libetpan gnutls])
249 GPG4WIN_SPKG([notification_plugin], [claws-mail])
250 GPG4WIN_SPKG([gtkhtml2_viewer], [curl claws-mail libxml2])
251 GPG4WIN_SPKG([vcalendar], [curl claws-mail])
252 GPG4WIN_SPKG([rssyl], [curl claws-mail])
253 GPG4WIN_SPKG([tnef_parse], [claws-mail])
254 GPG4WIN_SPKG([attachwarner], [claws-mail])
255 GPG4WIN_SPKG([bsfilter_plugin], [claws-mail])
256 GPG4WIN_IPKG([compendium])
257
258 # Qt related stuff.
259 GPG4WIN_BPKG_GNUWIN32([kdesupport])
260 GPG4WIN_BPKG_BINSRC([oxygen-icons])
261 GPG4WIN_BPKG_GNUWIN32([qt], [kdesupport])
262 GPG4WIN_BPKG_GNUWIN32([kdelibs], [qt oxygen-icons])
263 GPG4WIN_BPKG_BINSRC([kleopatra], [gpgme gnupg2 kdelibs])
264 #GPG4WIN_BPKG_GNUWIN32([kleopatra], [gpgme gnupg2 kdelibs])
265
266 GPG4WIN_FINALIZE
267
268 # Qt is compiled with -mthreads, and thus requires the mingwm10.dll.
269 mingwm_dll=no
270 AC_ARG_WITH([mingwm-dll],
271             AC_HELP_STRING([--with-mingwm-dll=FILE], [use the mingwm DLL]),
272             [mingwm_dll=$withval])
273 if test "$mingwm_dll" = "no"; then
274   file="/usr/share/doc/mingw32-runtime/mingwm10.dll.gz"
275   if test -r "$file"; then
276     mingwm_dll="$file"
277   fi
278 fi
279 if test "$mingwm_dll" = "no"; then
280   missing_tools="mingwm10.dll $missing_tools"
281 fi
282 # To make things simple, we just install a copy of the file in the
283 # source directory.  No need to make this ugly hack any uglier by
284 # messing around with the build system.
285 case "$mingwm_dll" in
286     *.gz)
287       $ZCAT $mingwm_dll > src/mingwm10.dll
288       ;;
289     *)
290       cp $mingwm_dll src/mingwm10.dll
291       ;;
292 esac
293
294
295 # Throw an error if required tools are missing
296 if test -n "$missing_tools"; then
297     for i in $missing_tools; do 
298       AC_MSG_NOTICE([$i is missing])
299     done
300     AC_MSG_ERROR([[
301 ***
302 *** Required tools not found. Please consult the above messages
303 *** and install them before running configure again.
304 ***]])
305 fi
306
307 # Throw an error if any duplicate source packages have been found
308 if test -n "$gpg4win_dup_sources"; then
309     tmp=
310     for i in $gpg4win_dup_sources; do 
311       tmp="$tmp
312 $i"
313     done
314     AC_MSG_ERROR([Packages with more that one source version:$tmp])
315 fi
316
317
318 # Finalize.
319
320 AC_CONFIG_COMMANDS([gpg4win-conf],[[
321 chmod +x patches/gnupg2/01-version.patch
322 ]])
323
324 AC_CONFIG_FILES(Makefile)
325 AC_CONFIG_FILES(packages/Makefile include/Makefile src/Makefile po/Makefile.in)
326 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
327 AC_CONFIG_FILES(doc/Makefile)
328 AC_CONFIG_FILES(doc/logo/Makefile)
329 AC_CONFIG_FILES(doc/manual/Makefile doc/manual/version.tex)
330 AC_CONFIG_FILES(doc/website/Makefile)
331 AC_CONFIG_FILES(patches/gnupg2/01-version.patch)
332 AC_OUTPUT