post release updates
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19  
20 # (Process this file with autoconf to produce a configure script.)
21
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Set my_issvn to "yes" for non-released code.  Remember to run an
27 # "svn up" and "autogen.sh" right before creating a distribution.
28 # Right after a release the make target "copy-news" is to be called!
29 m4_define([my_version], [1.0.9])
30 m4_define([my_issvn], [yes])
31
32 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
33           ||echo 'Revision: 0')|sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
34 AC_INIT([gpg4win], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
35         [gpg4win-devel@wald.intevation.org])
36
37 # Remember to update these version numbers also in the NEWS file.
38 MANUALVERSION_EINSTEIGER="2.0.2"
39 MANUALDATE_EINSTEIGER="30. Mai 2006"
40 MANUALVERSION_DURCHBLICKER="2.0.2"
41 MANUALDATE_DURCHBLICKER="30. Mai 2006"
42 MANUALVERSION_NOVICES="0.9.0"
43 MANUALDATE_NOVICES="Nov. 30, 2006"
44 MANUALVERSION_ADVANCED="0.0.0"
45 MANUALDATE_ADVANCED="Nov. 30, 2006"
46
47
48 MANUALINPROGRESS_DE=m4_if(my_issvn,[yes],["~und evtl. seitdem weiter bearbeitet"])
49 MANUALINPROGRESS_EN=m4_if(my_issvn,[yes],["~and may have been further edited"])
50 SVN_REVISION=svn_revision
51 PACKAGE=$PACKAGE_NAME
52 VERSION=$PACKAGE_VERSION
53
54
55 AC_CONFIG_SRCDIR(include/config.nsi.in)
56 AC_CONFIG_MACRO_DIR(m4)
57
58 AM_INIT_AUTOMAKE
59 AM_MAINTAINER_MODE
60 AC_CANONICAL_HOST
61
62 AC_SUBST(PACKAGE)
63 AC_SUBST(VERSION)
64 AC_SUBST(MANUALVERSION_EINSTEIGER)
65 AC_SUBST(MANUALDATE_EINSTEIGER)
66 AC_SUBST(MANUALVERSION_DURCHBLICKER)
67 AC_SUBST(MANUALDATE_DURCHBLICKER)
68 AC_SUBST(MANUALINPROGRESS_DE)
69 AC_SUBST(MANUALVERSION_NOVICES)
70 AC_SUBST(MANUALDATE_NOVICES)
71 AC_SUBST(MANUALVERSION_ADVANCED)
72 AC_SUBST(MANUALDATE_ADVANCED)
73 AC_SUBST(MANUALINPROGRESS_EN)
74
75
76 # Generate extended version information.  Note, that for NSIS use we
77 # must not translate the dots to commas in the BUILD_FILEVERSION.
78 BUILD_TIMESTAMP=`date --iso-8601=minutes`
79 BUILD_ISODATE=`date --iso-8601`
80 changequote(,)dnl
81 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
82 changequote([,])dnl
83 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
84 AC_SUBST(BUILD_TIMESTAMP)
85 AC_SUBST(BUILD_ISODATE)
86 AC_SUBST(BUILD_FILEVERSION)
87
88
89 # For development of this package it is useful to build without
90 # creatign the source installer (takes a long time).  This option may
91 # be used to suppress creation of the source installer.
92 AC_ARG_ENABLE(source-installer,
93     AC_HELP_STRING([--disable-source-installer],
94                    [Do not create the Source installer]),
95                     build_source_installer=$enableval,
96                     build_source_installer=yes)
97 AC_MSG_RESULT($source_installer)
98 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
99
100
101 # You can build a light version of the installer in addition to the
102 # regular version.  This one does not contain the manuals.
103 AC_ARG_ENABLE(light-installer,
104     AC_HELP_STRING([--disable-light-installer],
105                    [Do not create the light version of the installer]),
106                     build_light_installer=$enableval,
107                     build_light_installer=yes)
108 AC_MSG_RESULT($light_installer)
109 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
110
111
112 # Required tools.
113 AC_PROG_CC
114 AC_PROG_CPP
115 AC_CHECK_TOOLS(DLLTOOL, dlltool)
116 AC_CHECK_PROGS(MAKE, make)
117 AC_CHECK_PROGS(UNZIP, unzip)
118 AC_CHECK_PROGS(TAR, tar)
119 AC_CHECK_PROGS(MKDIR, mkdir)
120 AC_CHECK_PROGS(CP, cp)
121 AC_CHECK_PROGS(RM, rm)
122 AC_CHECK_PROGS(STOW, stow)
123 AC_CHECK_PROGS(MAKENSIS, makensis)
124 AC_CHECK_PROGS(ZCAT, zcat)
125 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
126 AC_CHECK_PROGS(DVIPDF, dvipdf)
127 AC_CHECK_PROGS(CONVERT, convert)
128 AC_CHECK_PROGS(SHA1SUM, sha1sum)
129 AC_PROG_INSTALL
130
131 missing_tools=
132 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
133          DVIPDF CONVERT SHA1SUM ; do
134    eval tmp='$'$i
135    if test -z "$tmp"; then 
136       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
137    fi
138 done
139
140
141 # Optional tools.
142
143 AC_CHECK_PROGS(WGET, wget)
144
145
146 # Packages.
147
148 GPG4WIN_BPKG_GNU([libiconv])
149 GPG4WIN_BPKG_GNU([gettext], [libiconv])
150
151 GPG4WIN_BPKG_GNUWIN32([zlib])
152 GPG4WIN_BPKG_GNUWIN32_LIB([crypt])
153 GPG4WIN_BPKG_GNUWIN32_LIB([regex])
154 GPG4WIN_BPKG_GNUWIN32([libpng], [pkgconfig])
155 GPG4WIN_BPKG_GNUWIN32([jpeg])
156
157 GPG4WIN_BPKG_GTK([pkgconfig])
158 # We build our own version of glib, because we need to patch giowin32.c.
159 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
160 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
161 GPG4WIN_BPKG_GTK_DEV([gtk+], [atk pango glib libiconv gettext pkgconfig])
162 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
163 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
164 GPG4WIN_BPKG_BINSRC([GPGee], [gnupg])
165
166 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
167 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg glib])
168 GPG4WIN_SPKG([gnupg], [libiconv])
169 GPG4WIN_SPKG([pthreads-w32])
170 GPG4WIN_SPKG([gpgol], [gpgme])
171 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
172 GPG4WIN_SPKG([winpt], [gpgme gnupg])
173 GPG4WIN_SPKG([sylpheed-claws], [libiconv gettext zlib gtk+ libpng jpeg glib dnl
174                                 gpgme pthreads-w32 crypt regex])
175 # The Eudora license (the one for thye EMS API) is still not acceptable.
176 #GPG4WIN_SPKG([eudoragpg])
177 GPG4WIN_IPKG([man_novice_de])
178 GPG4WIN_IPKG([man_advanced_de])
179 GPG4WIN_IPKG([man_novice_en])
180 GPG4WIN_IPKG([man_advanced_en])
181
182 GPG4WIN_FINALIZE
183
184 # Throw an error if required tools are missing
185 if test -n "$missing_tools"; then
186     for i in $missing_tools; do 
187       AC_MSG_NOTICE([$i is missing])
188     done
189     AC_MSG_ERROR([[
190 ***
191 *** Required tools not found. Please consult the above messages
192 *** and install them before running configure again.
193 ***]])
194 fi
195
196
197 # Finalize.
198
199 AC_CONFIG_FILES(Makefile packages/Makefile include/Makefile src/Makefile)
200 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
201 AC_CONFIG_FILES(doc/Makefile)
202 AC_CONFIG_FILES(doc/logo/Makefile)
203 AC_CONFIG_FILES(doc/manual/Makefile doc/manual/version.tex)
204 AC_CONFIG_FILES(doc/website/Makefile)
205 AC_OUTPUT