cc151d52f528b854aadda32b0b90011c9b4c0d79
[gpg4win.git] / src / inst-gpg4win.nsi
1 # inst-gpg4win.nsi - Hidden section for common files. -*- coding: latin-1; -*-
2 # Copyright (C) 2006 g10 Code GmbH
3 #
4 # This file is part of GPG4Win.
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20
21 # This is the very first section installed.
22 Section "-gpg4win" SEC_gpg4win
23 !ifdef SOURCES
24   SetOutPath "$INSTDIR"
25   File "${BUILD_DIR}/../gpg4win-${VERSION}.tar.bz2"
26 !else
27 # Start the slideshow.
28   SetDetailsPrint none
29
30   SetOutPath "$PLUGINSDIR\Slides"
31   File "${BUILD_DIR}/slideshow/01.png"
32 #  File "${BUILD_DIR}/slideshow/02.png"
33 #  File "${BUILD_DIR}/slideshow/03.png"
34   File "${BUILD_DIR}/slideshow/slides.dat"
35   g4wihelp::slide_show /NOUNLOAD /CCOLOR=0x0000FF "/auto=$PLUGINSDIR\Slides\slides.dat"
36   SetDetailsPrint both
37   SetOutPath "$INSTDIR"
38
39 # Uninstall an old version if found.
40   ClearErrors
41   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "DisplayVersion"
42   IfErrors skip_uninst 0
43   StrCmp $0 "" skip_uninst
44   DetailPrint  "$(T_UninstallingOldVersion)$0"
45   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "UninstallString"
46   IfErrors skip_uninst 0
47   ReadRegStr $1 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "InstallLocation"
48   IfErrors skip_uninst 0
49
50   ExecWait '$0 /S _?=$1'
51 # Deleting here does not work?
52   Delete /REBOOTOK "$1\gpg4win-uninstall.exe"
53   RmDir "$1"
54
55 skip_uninst:
56   SetOutPath "$INSTDIR\share\gpg4win"
57
58   File "${BUILD_DIR}/README.en.txt"
59   File "${BUILD_DIR}/README.de.txt"
60   File /oname=README.ar.txt "${BUILD_DIR}/README.en.txt"
61   File /oname=README.cz.txt "${BUILD_DIR}/README.en.txt"
62   File /oname=README.es.txt "${BUILD_DIR}/README.en.txt"
63   File /oname=README.fr.txt "${BUILD_DIR}/README.en.txt"
64   File /oname=README.it.txt "${BUILD_DIR}/README.en.txt"
65   File /oname=README.pt.txt "${BUILD_DIR}/README.en.txt"
66   File /oname=README.ru.txt "${BUILD_DIR}/README.en.txt"
67   File "${BUILD_DIR}/HOWTO-SMIME.en.txt"
68   File "${BUILD_DIR}/HOWTO-SMIME.de.txt"
69
70   File "${BUILD_DIR}/versioninfo.txt"
71
72   # Write a version file.
73   DetailPrint "Opening VERSION file for writing"
74   FileOpen $0 "$INSTDIR\VERSION" w
75   FileWrite $0 "${PACKAGE}$\r$\n"
76   FileWrite $0 "${VERSION}$\r$\n"
77   FileClose $0
78   DetailPrint "VERSION closed"
79
80   # Register the install directory for Gpg4win suite.
81   WriteRegStr HKLM "Software\${PRETTY_PACKAGE_SHORT}" "Install Directory" $INSTDIR
82   DetailPrint "Saved install directory in the registry"
83
84   # We used to determine the language using a Registry entry.
85   # Although we don't want to delete the user's Lang Registry Setting
86   # because he might have have selected a different language than his
87   # default.  We delete the global Lang of the installation.
88   DeleteRegValue HKLM "Software\GNU\GnuPG" "Lang"
89   DetailPrint "Deleted obsolete Lang entry"
90
91   # This old key is required for GPGee.  Please do not use in new
92   # applications.
93   # Note: We don't use it anymore so that gpgme decides what gpg to use
94   #       For the new gpg4win we actually use gpg2.exe.
95   #       To cope with old installations we actually remove this value.
96   #       However we can only remove the HKLM version not those set by
97   #       the user under HKCU.
98   #WriteRegStr HKLM "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
99   DeleteRegValue HKLM "Software\GNU\GnuPG" "gpgProgram"
100   DetailPrint "Deleted obsolete gpgProgram value"
101
102   # Install gpg4win included tools
103   SetOutPath "$INSTDIR\bin"
104   File "${BUILD_DIR}/sha1sum.exe"
105   File "${BUILD_DIR}/sha256sum.exe"
106   File "${BUILD_DIR}/md5sum.exe"
107   File "${BUILD_DIR}/mkportable.exe"
108
109   # Install the mingw32 runtime libraries.  They are stored in the
110   # build directory with a different suffix, so that makensis does not
111   # list symbol names.
112   File /oname=libstdc++-6.dll     "${BUILD_DIR}/libstdc++-6.dll-x"
113   File /oname=libgcc_s_sjlj-1.dll "${BUILD_DIR}/libgcc_s_sjlj-1.dll-x"
114   File /oname=libwinpthread-1.dll "${BUILD_DIR}/libwinpthread-1.dll-x"
115
116 !endif
117
118 SectionEnd
119
120 LangString DESC_Menu_gpg4win_readme ${LANG_ENGLISH} \
121    "General information on Gpg4win"
122
123 LangString DESC_Menu_gpg4win_howtosmime ${LANG_ENGLISH} \
124    "Instruction to configure S/MIME"
125
126 LangString DESC_Menu_gnupg_faq ${LANG_ENGLISH} \
127    "Show the Frequently Asked Questions document for GnuPG"