getting ready for a release
[gpg4win.git] / src / installer-finish.nsi
1 # installer-finish.nsi - Installer for GPG4Win.      -*- coding: latin-1; -*-
2 # Copyright (C) 2005 g10 Code GmbH
3
4 # This file is part of GPG4Win.
5
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 Var MYTMP
21
22 # Last section is a hidden one.
23 Section
24   WriteUninstaller "$INSTDIR\${PACKAGE}-uninstall.exe"
25
26   # Windows Add/Remove Programs support
27   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRETTY_PACKAGE_SHORT}"
28   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\${PACKAGE}-uninstall.exe"'
29   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
30   WriteRegStr       HKLM $MYTMP "DisplayName"     "${PRETTY_PACKAGE}"
31   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\gpg.exe,0"
32   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
33   WriteRegStr       HKLM $MYTMP "Publisher"       "g10 Code GmbH"
34   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "http://www.gpg4win.org/"
35   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
36   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
37 SectionEnd
38
39
40 Section Uninstall
41
42 !ifdef HAVE_STARTMENU
43   # Make sure that the context of the automatic variables has been set to
44   # the "all users" shell folder.  This guarantees that the menu gets written
45   # for all users.  We have already checked that we are running as Admin; or
46   # we printed a warning that installation will not succeed.
47   SetShellVarContext all
48
49   #---------------------------------------------------
50   # Delete the menu entries and any empty parent menus
51   #---------------------------------------------------
52   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
53   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
54   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
55   startMenuDeleteLoop:
56     ClearErrors
57     RMDir $MYTMP
58     GetFullPathName $MYTMP "$MYTMP\.."
59     IfErrors startMenuDeleteLoopDone
60     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
61   startMenuDeleteLoopDone:
62
63   DeleteRegValue HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
64         "Start Menu Folder"
65
66   # Delete Desktop links.
67 !ifdef HAVE_PKG_WINPT
68   Delete "$DESKTOP\WinPT.lnk"
69 !endif
70 !ifdef HAVE_PKG_GPA
71   Delete "$DESKTOP\GPA.lnk"
72 !endif
73 !ifdef HAVE_PKG_SYLPHEED_CLAWS
74   Delete "$DESKTOP\Sylpheed-Claws.lnk"
75   Delete "$DESKTOP\Sylpheed-Claws Manual.lnk" \
76   # We better delete also the name we used prior to 1.0.3
77   Delete "$DESKTOP\Sylpheed.lnk"
78 !endif
79 !ifdef HAVE_PKG_MAN_NOVICE_DE
80   Delete "$DESKTOP\$(DESC_Name_man_novice_de).lnk"
81 !endif
82 !ifdef HAVE_PKG_MAN_ADVANCED_DE
83   Delete "$DESKTOP\$(DESC_Name_man_advanced_de).lnk"
84 !endif
85 !ifdef HAVE_PKG_GPGEE
86   Delete "$DESKTOP\GPGee Manual.lnk"
87 !endif
88   Delete "$DESKTOP\GnuPG FAQ.lnk"
89   Delete "$DESKTOP\Gpg4Win README.lnk"
90
91   # Delete Quick Launch Bar links.
92   StrCmp $QUICKLAUNCH $TEMP no_quick_launch_uninstall
93 !ifdef HAVE_PKG_WINPT
94   Delete "$QUICKLAUNCH\WinPT.lnk"
95 !endif
96 !ifdef HAVE_PKG_GPA
97   Delete "$QUICKLAUNCH\GPA.lnk"
98 !endif
99 !ifdef HAVE_PKG_SYLPHEED_CLAWS
100   Delete "$QUICKLAUNCH\Sylpheed-Claws.lnk"
101   # We better delete also the name we used prior to 1.0.3
102   Delete "$QUICKLAUNCH\Sylpheed.lnk"
103 !endif
104 !ifdef HAVE_PKG_MAN_NOVICE_DE
105   Delete "$QUICKLAUNCH\$(DESC_Name_man_novice_de).lnk"
106 !endif
107 !ifdef HAVE_PKG_MAN_ADVANCED_DE
108   Delete "$QUICKLAUNCH\$(DESC_Name_man_advanced_de).lnk"
109 !endif
110 !ifdef HAVE_PKG_GPGEE
111   Delete "$QUICKLAUNCH\GPGee Manual.lnk"
112 !endif
113   Delete "$QUICKLAUNCH\GnuPG FAQ.lnk"
114   Delete "$QUICKLAUNCH\Gpg4Win README.lnk"
115 no_quick_launch_uninstall:
116
117 !endif
118
119
120   Delete "$INSTDIR\${PACKAGE}-uninstall.exe"
121   RMDir "$INSTDIR"
122
123   # Clean the registry.
124   DeleteRegValue HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
125         "Install Directory"
126   DeleteRegKey /ifempty HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
127   # Remove Windows Add/Remove Programs support.
128   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRETTY_PACKAGE_SHORT}"
129 SectionEnd