Add custom plugin DLL
[gpg4win.git] / src / installer.nsi
1 # installer.nsi - Installer for GnuPG 4 Windows.    -*- coding: latin-1; -*-
2 # Copyright (C) 2005 g10 Code GmbH
3
4 # This file is part of GPG4Win.
5
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 # No servicable parts beyond this line.  Stay clear :)
21
22 !ifdef REQUIRE_W32_NSIS
23 !ifdef PACKAGE_LIBRARY
24 !include "Library.nsh"
25 !endif
26 !else
27 !macro InstallLib libtype shared install localfile destfile tempbasedir
28   File "${localfile}"
29 !macroend
30 !endif
31
32
33 # We use the modern UI.
34 !include "MUI.nsh"
35
36 # Customj functions and macros for gpg4win. 
37 !include "g4wihelp.nsi"
38
39 # Set the package name.  Note that this name should not be sufficed
40 #  with the version because this would get displayed in the start menu.
41 Name "${PRETTY_PACKAGE}"
42
43
44 # Set the output filename.
45 OutFile "${PACKAGE}-${VERSION}.exe"
46
47
48 # Set the installation directory.
49 !ifndef INSTALL_DIR
50 !define INSTALL_DIR "${PACKAGE}"
51 !endif
52 InstallDir "$PROGRAMFILES\GNU\${INSTALL_DIR}\\" 
53
54
55 InstallDirRegKey HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
56         "Install Directory"
57
58
59 # Add version information to the file properties.
60 VIProductVersion "${PROD_VERSION}"
61 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
62 !ifdef LICENSE_GPL
63 VIAddVersionKey "Comments" \
64    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
65     and/or modify it under the terms of the GNU General Public License.  \
66     You should have received a copy of the GNU General Public License  \
67     along with this software; if not, write to the Free Software  \
68     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
69     MA 02110-1301, USA"
70 !else
71 VIAddVersionKey "Comments" \
72    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
73     and/or modify it under the terms of the GNU Lesser General Public  \
74     License. You should have received a copy of the GNU Lesser General  \
75     Public License along with this software; if not, write to the Free  \
76     Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
77     MA 02110-1301, USA"
78 !endif
79 VIAddVersionKey "CompanyName" "${COMPANY}"
80 VIAddVersionKey "LegalTrademarks" ""
81 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
82 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
83 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
84
85
86 # Interface Settings
87
88 # !define MUI_ABORTWARNING
89 !define MUI_FINISHPAGE_NOAUTOCLOSE
90 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
91
92 # Remember the installer language
93
94 #!define MUI_LANGDLL_REGISTRY_ROOT "HKCU" 
95 #!define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}" 
96 #!define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
97
98
99 # The list of wizard pages.
100
101 !define MUI_WELCOMEPAGE_TITLE "$(T_WelcomeTitle)"
102 !define MUI_WELCOMEPAGE_TEXT  "$(T_About)"
103 !insertmacro MUI_PAGE_WELCOME
104
105 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
106 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
107 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
108 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
109
110 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
111 !insertmacro MUI_PAGE_COMPONENTS
112
113 !ifdef HAVE_STARTMENU
114 Var STARTMENU_FOLDER
115 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
116 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}"
117 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
118
119 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
120 !endif
121
122 !insertmacro MUI_PAGE_INSTFILES
123
124 !define MUI_FINISHPAGE_RUN "$INSTDIR\gpa.exe"
125 !define MUI_FINISHPAGE_RUN_PARAMETERS "--keyring"
126 !define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
127 !define MUI_FINISHPAGE_RUN_NOTCHECKED
128 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
129 !define MUI_FINISHPAGE_LINK_LOCATION http://www.gpg4win.org
130 !insertmacro MUI_PAGE_FINISH
131
132
133 # Uninstaller pages.
134
135 !insertmacro MUI_UNPAGE_CONFIRM
136 !insertmacro MUI_UNPAGE_INSTFILES
137
138
139 #Page license
140 #Page components
141 #Page directory
142 #Page instfiles
143 #UninstPage uninstConfirm
144 #UninstPage instfiles
145
146
147 # Language support.  This has to be done after defining the pages, but
148 # before defining the translation strings.  Confusing.
149
150 !insertmacro MUI_LANGUAGE "English"
151 !insertmacro MUI_LANGUAGE "German"
152
153 !insertmacro MUI_RESERVEFILE_LANGDLL
154 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
155 ReserveFile "${NSISDIR}\Plugins\advsplash.dll"
156 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
157 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.bmp"
158 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.wav"
159 ReserveFile "${TOP_SRCDIR}\COPYING"
160
161 # Language support
162
163 # The WelcomeTitle is displayed on the first page.
164 LangString T_WelcomeTitle ${LANG_ENGLISH} "${WELCOME_TITLE_ENGLISH}"
165 LangString T_WelcomeTitle ${LANG_GERMAN} "${WELCOME_TITLE_GERMAN}"
166
167 # The About string as displayed on the first page.
168 LangString T_About ${LANG_ENGLISH} "${ABOUT_ENGLISH}"
169 LangString T_About ${LANG_GERMAN} "${ABOUT_GERMAN}"
170
171 # Startup page
172 LangString T_GPLHeader ${LANG_ENGLISH} \
173   "This software is licensed under the terms of the GNU General Public \
174    License (GPL) which guarantees your freedom to share and change Free \
175    Software."
176 LangString T_GPLHeader ${LANG_GERMAN}} \
177   "Diese Software ist unter der GNU General Public License \
178    (GPL) lizensiert; dies gibt Ihnen die Freiheit, sie \
179    zu ändern und weiterzugeben."
180
181 LangString T_GPLShort ${LANG_ENGLISH} \
182   "In short: You are allowed to run this software for any purpose. \
183    You may distribute it as long as you give the recipients the same \
184    rights you have received."
185 LangString T_GPLShort ${LANG_GERMAN} \
186   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
187    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
188    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
189
190 LangString T_RunKeyManager ${LANG_ENGLISH} \
191    "Run the key manager"
192 LangString T_RunKeyManager ${LANG_GERMAN} \
193    "Die Schlüsselverwaltung aufrufen"
194
195 LangString T_MoreInfo ${LANG_ENGLISH} \
196    "Click here for the project's homepage"
197 LangString T_MoreInfo ${LANG_GERMAN} \
198    "Hier klicken um zur Homepage des Projekts zu gelangen"
199
200
201 # Functions
202
203 # PrintNonAdminWarning
204
205 # Check whether the current user is in the Administrator group or an
206 # OS version without the need for an Administrator is in use.  Print a
207 # warning if this is not the case.
208
209 Function PrintNonAdminWarning
210   ClearErrors
211   UserInfo::GetName
212   IfErrors leave
213   Pop $0
214   UserInfo::GetAccountType
215   Pop $1
216   StrCmp $1 "Admin" leave +1
217   MessageBox MB_OK "$(T_AdminNeeded)"
218
219  leave:
220 FunctionEnd
221
222 # From Function PrintNonAdminWarning
223 LangString T_AdminNeeded ${LANG_ENGLISH} \
224    "Warning: Administrator permissions required for a successful installation"
225 LangString T_AdminNeeded ${LANG_GERMAN} \
226    "Warnung: Für eine erfolgreiche Installation werden \
227     Administratorrechte benötigt."
228
229
230 # FIXME: The GetAfterChar function comes from the NSIS wiki.
231 Function un.GetAfterChar
232   Exch $0 ; chop char
233   Exch
234   Exch $1 ; input string
235   Push $2
236   Push $3
237   StrCpy $2 0
238   loop:
239     IntOp $2 $2 - 1
240     StrCpy $3 $1 1 $2
241     StrCmp $3 "" 0 +3
242       StrCpy $0 ""
243       Goto exit2
244     StrCmp $3 $0 exit1
245     Goto loop
246   exit1:
247     IntOp $2 $2 + 1
248     StrCpy $0 $1 "" $2
249   exit2:
250     Pop $3
251     Pop $2
252     Pop $1
253     Exch $0 ; output
254 FunctionEnd
255
256
257 Function un.SourceDelete
258   Push "/"
259   Call un.GetAfterChar
260   Pop $R0
261   Delete "$INSTDIR\$R0"
262 FunctionEnd