9f2ed1929158c88bdf9f6eea11e2e8373ae8cb17
[gpg4win.git] / src / installer.nsi
1 # installer.nsi - Installer for GnuPG 4 Windows.    -*- coding: latin-1; -*-
2 # Copyright (C) 2005 g10 Code GmbH
3
4 # This file is part of GPG4Win.
5
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 # No servicable parts beyond this line.  Stay clear :)
21
22 !ifdef REQUIRE_W32_NSIS
23 !ifdef PACKAGE_LIBRARY
24 !include "Library.nsh"
25 !endif
26 !else
27 !macro InstallLib libtype shared install localfile destfile tempbasedir
28   File "${localfile}"
29 !macroend
30 !endif
31
32
33 # We use the modern UI.
34 !include "MUI.nsh"
35
36
37 # Set the package name.  Note that this name should not be sufficed
38 #  with the version because this would get displayed in the start menu.
39 Name "${PRETTY_PACKAGE}"
40
41
42 # Set the output filename.
43 OutFile "${PACKAGE}-${VERSION}.exe"
44
45
46 # Set the installation directory.
47 !ifndef INSTALL_DIR
48 !define INSTALL_DIR "${PACKAGE}"
49 !endif
50 InstallDir "$PROGRAMFILES\GNU\${INSTALL_DIR}\\" 
51
52
53 InstallDirRegKey HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
54         "Install Directory"
55
56
57 # Add version information to the file properties.
58 VIProductVersion "${PROD_VERSION}"
59 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
60 !ifdef LICENSE_GPL
61 VIAddVersionKey "Comments" \
62    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
63     and/or modify it under the terms of the GNU General Public License.  \
64     You should have received a copy of the GNU General Public License  \
65     along with this software; if not, write to the Free Software  \
66     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
67     MA 02110-1301, USA"
68 !else
69 VIAddVersionKey "Comments" \
70    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
71     and/or modify it under the terms of the GNU Lesser General Public  \
72     License. You should have received a copy of the GNU Lesser General  \
73     Public License along with this software; if not, write to the Free  \
74     Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
75     MA 02110-1301, USA"
76 !endif
77 VIAddVersionKey "CompanyName" "${COMPANY}"
78 VIAddVersionKey "LegalTrademarks" ""
79 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
80 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
81 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
82
83
84 # Interface Settings
85
86 # !define MUI_ABORTWARNING
87 !define MUI_FINISHPAGE_NOAUTOCLOSE
88 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
89
90 # Remember the installer language
91
92 #!define MUI_LANGDLL_REGISTRY_ROOT "HKCU" 
93 #!define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}" 
94 #!define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
95
96
97 # The list of wizard pages.
98
99 !define MUI_WELCOMEPAGE_TITLE "$(T_WelcomeTitle)"
100 !define MUI_WELCOMEPAGE_TEXT  "$(T_About)"
101 !insertmacro MUI_PAGE_WELCOME
102
103 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
104 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
105 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
106 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
107
108 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
109 !insertmacro MUI_PAGE_COMPONENTS
110
111 !ifdef HAVE_STARTMENU
112 Var STARTMENU_FOLDER
113 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
114 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}"
115 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
116
117 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
118 !endif
119
120 !insertmacro MUI_PAGE_INSTFILES
121
122 !define MUI_FINISHPAGE_RUN "$INSTDIR\gpa.exe"
123 !define MUI_FINISHPAGE_RUN_PARAMETERS "--keyring"
124 !define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
125 !define MUI_FINISHPAGE_RUN_NOTCHECKED
126 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
127 !define MUI_FINISHPAGE_LINK_LOCATION http://www.gpg4win.org
128 !insertmacro MUI_PAGE_FINISH
129
130
131 # Uninstaller pages.
132
133 !insertmacro MUI_UNPAGE_CONFIRM
134 !insertmacro MUI_UNPAGE_INSTFILES
135
136
137 #Page license
138 #Page components
139 #Page directory
140 #Page instfiles
141 #UninstPage uninstConfirm
142 #UninstPage instfiles
143
144
145 # Language support.  This has to be done after defining the pages, but
146 # before defining the translation strings.  Confusing.
147
148 !insertmacro MUI_LANGUAGE "English"
149 !insertmacro MUI_LANGUAGE "German"
150
151 !insertmacro MUI_RESERVEFILE_LANGDLL
152 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
153 ReserveFile "${NSISDIR}\Plugins\advsplash.dll"
154 #ReserveFile "${NSISDIR}\Plugins\System.dll"
155 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.bmp"
156 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.wav"
157 ReserveFile "${TOP_SRCDIR}\COPYING"
158
159 # Language support
160
161 # The WelcomeTitle is displayed on the first page.
162 LangString T_WelcomeTitle ${LANG_ENGLISH} "${WELCOME_TITLE_ENGLISH}"
163 LangString T_WelcomeTitle ${LANG_GERMAN} "${WELCOME_TITLE_GERMAN}"
164
165 # The About string as displayed on the first page.
166 LangString T_About ${LANG_ENGLISH} "${ABOUT_ENGLISH}"
167 LangString T_About ${LANG_GERMAN} "${ABOUT_GERMAN}"
168
169 # Startup page
170 LangString T_GPLHeader ${LANG_ENGLISH} \
171   "This software is licensed under the terms of the GNU General Public \
172    License (GPL) which guarantees your freedom to share and change Free \
173    Software."
174 LangString T_GPLHeader ${LANG_GERMAN}} \
175   "Diese Software ist unter der GNU General Public License \
176    (GPL) lizensiert; dies gibt Ihnen die Freiheit, sie \
177    zu ändern und weiterzugeben."
178
179 LangString T_GPLShort ${LANG_ENGLISH} \
180   "In short: You are allowed to run this software for any purpose. \
181    You may distribute it as long as you give the recipients the same \
182    rights you have received."
183 LangString T_GPLShort ${LANG_GERMAN} \
184   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
185    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
186    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
187
188 LangString T_RunKeyManager ${LANG_ENGLISH} \
189    "Run the key manager"
190 LangString T_RunKeyManager ${LANG_GERMAN} \
191    "Die Schlüsselverwaltung aufrufen"
192
193 LangString T_MoreInfo ${LANG_ENGLISH} \
194    "Click here for the project's homepage"
195 LangString T_MoreInfo ${LANG_GERMAN} \
196    "Hier klicken um zur Homepage des Projekts zu gelangen"
197
198
199 # Functions
200
201 # PrintNonAdminWarning
202
203 # Check whether the current user is in the Administrator group or an
204 # OS version without the need for an Administrator is in use.  Print a
205 # warning if this is not the case.
206
207 Function PrintNonAdminWarning
208   ClearErrors
209   UserInfo::GetName
210   IfErrors leave
211   Pop $0
212   UserInfo::GetAccountType
213   Pop $1
214   StrCmp $1 "Admin" leave +1
215   MessageBox MB_OK "$(T_AdminNeeded)"
216
217  leave:
218 FunctionEnd
219
220 # From Function PrintNonAdminWarning
221 LangString T_AdminNeeded ${LANG_ENGLISH} \
222    "Warning: Administrator permissions required for a successful installation"
223 LangString T_AdminNeeded ${LANG_GERMAN} \
224    "Warnung: Für eine erfolgreiche Installation werden \
225     Administratorrechte benötigt."
226
227
228 # FIXME: The GetAfterChar function comes from the NSIS wiki.
229 Function un.GetAfterChar
230   Exch $0 ; chop char
231   Exch
232   Exch $1 ; input string
233   Push $2
234   Push $3
235   StrCpy $2 0
236   loop:
237     IntOp $2 $2 - 1
238     StrCpy $3 $1 1 $2
239     StrCmp $3 "" 0 +3
240       StrCpy $0 ""
241       Goto exit2
242     StrCmp $3 $0 exit1
243     Goto loop
244   exit1:
245     IntOp $2 $2 + 1
246     StrCpy $0 $1 "" $2
247   exit2:
248     Pop $3
249     Pop $2
250     Pop $1
251     Exch $0 ; output
252 FunctionEnd
253
254
255 Function un.SourceDelete
256   Push "/"
257   Call un.GetAfterChar
258   Pop $R0
259   Delete "$INSTDIR\$R0"
260 FunctionEnd