dcbaa223f491b8a752e79af4541d731c695ddc4b
[gpg4win.git] / src / installer.nsi
1 # installer.nsi - Installer for GnuPG 4 Windows.    -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2007 g10 Code GmbH
3
4 # This file is part of GPG4Win.
5
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 # No servicable parts beyond this line.  Stay clear :)
21
22 !ifdef REQUIRE_W32_NSIS
23 !ifdef PACKAGE_LIBRARY
24 !include "Library.nsh"
25 !endif
26 !else
27 !macro InstallLib libtype shared install localfile destfile tempbasedir
28   File "${localfile}"
29 !macroend
30 !endif
31
32 !include "WinMessages.nsh"
33
34 # Define for the registry key to change the environment.  The
35 # commented one may be used if the setting should affect only the
36 # current user.
37 !define Regkey_for_Env \
38     'HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"'
39 # !define Regkey_for_Env 'HKCU "Environment"'
40
41
42 # We use Memento to remember past installation choices.
43 !include Memento.nsh
44 !define MEMENTO_REGISTRY_ROOT HKLM
45 !define MEMENTO_REGISTRY_KEY \
46   Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRETTY_PACKAGE_SHORT}
47
48
49 # We use the modern UI.
50 !include "MUI.nsh"
51
52 # Set the package name.  Note that this name should not be sufficed
53 #  with the version because this would get displayed in the start menu.
54 Name "${PRETTY_PACKAGE}"
55
56
57 # Set the output filename.
58 !ifdef GPG4WIN_LIGHT
59 OutFile "${PACKAGE}-light-${VERSION}.exe"
60 !else
61 OutFile "${PACKAGE}-${VERSION}.exe"
62 !endif
63
64 Icon "${TOP_SRCDIR}/doc/logo/gpg4win-logo-icon.ico"
65 UninstallIcon "${TOP_SRCDIR}/doc/logo/gpg4win-logo-icon.ico"
66
67 # Set the installation directory.
68 !ifndef INSTALL_DIR
69 !define INSTALL_DIR "${PACKAGE}"
70 !endif
71 InstallDir "$PROGRAMFILES\GNU\${INSTALL_DIR}" 
72
73
74 InstallDirRegKey HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
75         "Install Directory"
76
77
78 # Add version information to the file properties.
79 VIProductVersion "${PROD_VERSION}"
80 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
81 !ifdef LICENSE_GPL
82 VIAddVersionKey "Comments" \
83    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
84     and/or modify it under the terms of the GNU General Public License.  \
85     You should have received a copy of the GNU General Public License  \
86     along with this software; if not, write to the Free Software  \
87     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
88     MA 02110-1301, USA"
89 !else
90 VIAddVersionKey "Comments" \
91    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
92     and/or modify it under the terms of the GNU Lesser General Public  \
93     License. You should have received a copy of the GNU Lesser General  \
94     Public License along with this software; if not, write to the Free  \
95     Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
96     MA 02110-1301, USA"
97 !endif
98 VIAddVersionKey "CompanyName" "${COMPANY}"
99 VIAddVersionKey "LegalTrademarks" ""
100 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
101 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
102 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
103
104 # Set to the name of another GnuPG installation if one has been detected
105 Var OtherGnuPGDetected
106
107 # Interface Settings
108
109 # !define MUI_ABORTWARNING
110 !define MUI_FINISHPAGE_NOAUTOCLOSE
111 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
112
113 #!define MUI_HEADERIMAGE
114 #!define MUI_HEADERIMAGE_BITMAP \
115 #               "${TOP_SRCDIR}/doc/logo/gpg4win-logo-150x57.bmp"
116 !define MUI_WELCOMEFINISHPAGE_BITMAP \
117                "${TOP_SRCDIR}/doc/logo/gpg4win-logo-164x314.bmp"
118
119 # Remember the installer language
120
121 #!define MUI_LANGDLL_REGISTRY_ROOT "HKCU" 
122 #!define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}" 
123 #!define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
124
125 # The list of wizard pages.
126
127 !define MUI_WELCOMEPAGE_TITLE "${WELCOME_TITLE_STR}"
128 !define MUI_WELCOMEPAGE_TEXT "${ABOUT_STR}"
129
130 !insertmacro MUI_PAGE_WELCOME
131
132 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
133 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
134 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
135 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
136
137 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
138 !insertmacro MUI_PAGE_COMPONENTS
139
140 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckExistingVersion
141 !insertmacro MUI_PAGE_DIRECTORY
142
143 !ifdef HAVE_STARTMENU
144
145 Page custom CustomPageOptions
146
147 Var STARTMENU_FOLDER
148
149 !define MUI_PAGE_CUSTOMFUNCTION_PRE CheckIfStartMenuWanted
150 !define MUI_STARTMENUPAGE_NODISABLE
151 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
152 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}"
153 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
154
155 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
156
157 !endif
158
159 !define MUI_PAGE_CUSTOMFUNCTION_PRE PrintCloseOtherApps
160 !insertmacro MUI_PAGE_INSTFILES
161
162 !define MUI_PAGE_CUSTOMFUNCTION_PRE ShowFinalWarnings
163 !define MUI_FINISHPAGE_SHOWREADME "share\gpg4win\README.$(T_LangCode).txt"
164 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
165 #!define MUI_FINISHPAGE_RUN
166 #!define MUI_FINISHPAGE_RUN_FUNCTION RunOnFinish
167 #!define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
168 #!define MUI_FINISHPAGE_RUN_NOTCHECKED
169 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
170 !define MUI_FINISHPAGE_LINK_LOCATION "$(T_MoreInfoURL)"
171 !insertmacro MUI_PAGE_FINISH
172
173
174 # Uninstaller pages.
175
176 !insertmacro MUI_UNPAGE_CONFIRM
177 !insertmacro MUI_UNPAGE_INSTFILES
178
179
180 #Page license
181 #Page components
182 #Page directory
183 #Page instfiles
184 #UninstPage uninstConfirm
185 #UninstPage instfiles
186
187
188 # Language support.  This has to be done after defining the pages, but
189 # before defining the translation strings.  Confusing.
190
191 !insertmacro MUI_LANGUAGE "English"
192
193 #!insertmacro MUI_RESERVEFILE_LANGDLL
194 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
195 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
196 !ifdef SOURCES
197 ReserveFile "${TOP_SRCDIR}\doc\logo\gpg4win-logo-400px.bmp"
198 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.wav"
199 !endif
200 ReserveFile "${TOP_SRCDIR}\COPYING"
201 ReserveFile "installer-options.ini"
202 ReserveFile "${TOP_SRCDIR}\doc\logo\gpg4win-logo-164x314.bmp"
203
204 # Language support
205
206 LangString T_LangCode ${LANG_ENGLISH} "en"
207
208 # Startup page
209 LangString T_GPLHeader ${LANG_ENGLISH} \
210   "This software is licensed under the terms of the GNU General Public \
211    License (GPL) which guarantees your freedom to share and change Free \
212    Software."
213
214 LangString T_GPLShort ${LANG_ENGLISH} \
215   "In short: You are allowed to run this software for any purpose. \
216    You may distribute it as long as you give the recipients the same \
217    rights you have received."
218
219 LangString T_RunKeyManager ${LANG_ENGLISH} \
220    "Run the key manager"
221
222 LangString T_MoreInfo ${LANG_ENGLISH} \
223    "Click here for the project's homepage"
224 LangString T_MoreInfoURL ${LANG_ENGLISH} "http://www.gpg4win.org"
225
226 LangString T_ShowReadme ${LANG_ENGLISH} \
227    "Show the README file"
228
229 LangString T_NoKeyManager ${LANG_ENGLISH} \
230    "No key manager has been installed, thus we can't run one now."
231
232 # Used as subdirectory name in Start Menu.
233
234 LangString DESC_Menu_manuals ${LANG_ENGLISH} \
235    "Documentation"
236
237 # Used as subdirectory name on Desktop.
238 LangString DESC_Desktop_manuals ${LANG_ENGLISH} \
239    "Gpg4win Documentation"
240
241
242 # Functions
243
244 # Custom functions and macros for gpg4win. 
245 !include "g4wihelp.nsi"
246
247 #
248 # Control function for the Custom page to select special
249 # install options.
250 #
251 Function CustomPageOptions
252   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_InstallOptLinks)"
253
254   # Note that the default selection is done in the ini file.
255   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
256         "Field 1" "Text"  "$(T_InstOptLabelA)"
257   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
258         "Field 2" "Text"  "$(T_InstOptFieldA)"
259   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
260         "Field 3" "Text"  "$(T_InstOptFieldB)"
261   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
262         "Field 4" "Text"  "$(T_InstOptFieldC)"
263   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
264         "Field 5" "Text"  "$(T_InstOptLabelB)"
265
266   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "installer-options.ini"
267 FunctionEnd
268
269
270 # Display a warning if GnuPP has been detected and allow the user to abort
271 # the installation.
272 Function PrintGnuPPWarning
273    MessageBox MB_YESNO "$(T_FoundOldGnuPP)" IDYES cont
274      Abort
275  cont:
276    StrCpy $OtherGnuPGDetected "GnuPP"
277 FunctionEnd
278
279 # Display a warning if GnuPT has been detected and allow the user to abort
280 # the installation.
281 Function PrintGnuPTWarning
282    MessageBox MB_YESNO "$(T_FoundOldGnuPT)" IDYES cont
283      Abort
284  cont:
285    StrCpy $OtherGnuPGDetected "GnuPT"
286 FunctionEnd
287
288 # Display a warning if the Sourceforge WinPT has been detected and
289 # allow the user to abort the installation.
290 Function PrintWinPTSFWarning
291    MessageBox MB_YESNO "$(T_FoundOldWinPTSF)" IDYES cont
292      Abort
293  cont:
294    StrCpy $OtherGnuPGDetected "WinPT-SF"
295 FunctionEnd
296
297 # Display a warning if GnuPG Pack has been detected and abort the
298 # the installation.  This one clobbers our own Registry space.
299 Function PrintGnuPackWarning
300    MessageBox MB_OK "$(T_FoundOldGnuPack)"
301    Abort
302 FunctionEnd
303
304
305 # Check whether one of the other GnuPG systems has already been
306 # installed.  We do this by looking at the registry.
307 Function CheckOtherGnuPGApps
308   StrCpy $OtherGnuPGDetected ""
309   ClearErrors
310   ReadRegStr $0 HKLM "Software\GNU\GnuPP\Settings" "Path"
311   IfErrors +2 0
312     Call PrintGnuPPWarning
313
314   EnumRegKey $0 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder\Start Menu\Programs\GnuPT" 0
315   StrCmp $0 "" +2
316     Call PrintGnuPTWarning
317
318   ClearErrors
319   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Windows Privacy Tools" "DisplayVersion"
320   IfErrors +2 0
321     Call PrintWinPTSFWarning
322
323   ReadRegStr $0 HKLM "Software\GNU\GnuPG" "Install Directory"
324   Push $0
325   Push "GnuPG-Pack"
326   Call StrStr
327   Pop $0
328   StrCmp $0 "" +2
329     Call PrintGnuPackWarning
330
331
332 FunctionEnd
333
334 # Check whether gpg4win has already been installed.  This is called as
335 # a leave function from the directory page.  A call to abort will get
336 # back to the directory selection.
337 Function CheckExistingVersion
338   ClearErrors
339   FileOpen $0 "$INSTDIR\VERSION" r
340   IfErrors nexttest
341   FileRead $0 $R0
342   FileRead $0 $R1
343   FileClose $0
344
345   Push $R1
346   Call TrimNewLines
347   Pop $R1
348
349   MessageBox MB_YESNO "$(T_FoundExistingVersion)" IDYES leave
350   Abort
351
352  nexttest:
353   ClearErrors
354   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "DisplayVersion"
355   IfErrors leave 0
356      MessageBox MB_YESNO "$(T_FoundExistingVersionB)" IDYES leave
357      Abort
358      
359  leave:
360 FunctionEnd
361
362
363
364 # PrintNonAdminWarning
365
366 # Check whether the current user is in the Administrator group or an
367 # OS version without the need for an Administrator is in use.  Print a
368 # diagnostic if this is not the case and abort installation.
369 Function PrintNonAdminWarning
370   ClearErrors
371   UserInfo::GetName
372   IfErrors leave
373   Pop $0
374   UserInfo::GetAccountType
375   Pop $1
376   StrCmp $1 "Admin" leave +1
377   MessageBox MB_OK "$(T_AdminNeeded)"
378   Quit
379
380  leave:
381 FunctionEnd
382
383
384 # Check whether the start menu is actually wanted.
385
386 Function CheckIfStartMenuWanted
387   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "installer-options.ini" \
388         "Field 2" "State"
389   IntCmp $R0 1 +2
390     Abort
391 FunctionEnd
392
393
394 # Check whether this is a reinstall and popup a message box to explain
395 # that it is better to close other apps before continuing
396 Function PrintCloseOtherApps
397     IfFileExists $INSTDIR\gnupg.exe print_warning
398     IfFileExists $INSTDIR\winpt.exe print_warning
399     IfFileExists $INSTDIR\gpa.exe   print_warning
400     IfFileExists $INSTDIR\gpgol.dll print_warning
401     IfFileExists $INSTDIR\gpgee.dll print_warning
402     IfFileExists $INSTDIR\dirmngr.exe print_warning
403     Return
404    print_warning:
405     MessageBox MB_OK|MB_ICONEXCLAMATION "$(T_CloseOtherApps)"
406     IfFileExists $INSTDIR\winpt.exe 0 +3
407       MessageBox MB_OK "$(T_ShuttingDownWinPT)"
408       ExecWait '"$INSTDIR\winpt.exe" --stop'
409     IfFileExists $INSTDIR\dirmngr.exe 0 +3
410       MessageBox MB_OK "$(T_ShuttingDownDirMngr)"
411       g4wihelp::service_stop "DirMngr"
412    leave:
413 FunctionEnd
414
415 # Called right before the final page to show more warnings.
416 Function ShowFinalWarnings
417    StrCmp $OtherGnupgDetected "" +2
418      MessageBox MB_OK "$(T_FoundOldSeeManual)"
419    leave:
420 FunctionEnd
421
422 #-----------------------------------------------
423 # Strings pertaining to the install options page
424 #-----------------------------------------------
425
426 # Installation options title
427 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
428
429 # Installation options subtitle 1
430 LangString T_InstallOptLinks ${LANG_ENGLISH} "Start links"
431
432 LangString T_InstOptLabelA  ${LANG_ENGLISH} \
433      "Please select where Gpg4win shall install links:"
434
435 LangString T_InstOptLabelB  ${LANG_ENGLISH} \
436      "(Only programs will be linked into the quick launch bar.)"
437
438 LangString T_InstOptFieldA  ${LANG_ENGLISH} \
439      "Start Menu"
440
441 LangString T_InstOptFieldB  ${LANG_ENGLISH} \
442      "Desktop"
443
444 LangString T_InstOptFieldC  ${LANG_ENGLISH} \
445      "Quick Launch Bar"
446
447 #------------------------------------------------
448 # String pertaining to the existing version check
449 #------------------------------------------------
450 LangString T_FoundExistingVersion ${LANG_ENGLISH} \
451      "Version $R1 has already been installed.  $\r$\n\
452       Do you want to overwrite it with version ${VERSION}?"
453 LangString T_FoundExistingVersionB ${LANG_ENGLISH} \
454      "A version of Gpg4Win has already been installed on the system. \
455       There will be no problem installing and thus overwriting this \
456       Version. $\r$\n\
457        $\r$\n\
458       Do you want to continue installing Gpg4win?"
459
460
461 #---------------------------------------------
462 # From the old installation checking functions
463 #---------------------------------------------
464 LangString T_FoundOldSeeManual ${LANG_ENGLISH} \
465      "Please see the Gpg4win user manual to learn how to migrate existing \
466       keys from other GnuPG based installations to Gpg4win."
467
468 #---------
469 LangString T_FoundOldGnuPP ${LANG_ENGLISH} \
470      "An old installation of GnuPP (GNU Privacy Project) has been been \
471       detected.  That software is not maintained anymore and thus should \
472       be removed. $\r$\n\
473           $\r$\n\
474       Do you want to continue installing Gpg4win and take care of the old \
475       installation later?"
476
477 #---------
478 LangString T_FoundOldGnuPT ${LANG_ENGLISH} \
479      "An installation of GnuPT has been been detected.  This may cause \
480       problems when used along with Gpg4win. $\r$\n\
481           $\r$\n\
482       Do you want to continue installing Gpg4win?"
483
484 #---------
485 LangString T_FoundOldWinPTSF ${LANG_ENGLISH} \
486      "An old installation of the Sourceforge hosted WinPT has been been \
487       detected.  That software is not maintained anymore and should \
488       be removed. $\r$\n\
489           $\r$\n\
490       Do you want to continue installing Gpg4win and take care of the old \
491       installation later?"
492
493
494 #--------
495 LangString T_FoundOldGnuPack ${LANG_ENGLISH} \
496      "An installation of GnuPG-Pack has been been detected. You need to \
497       uninstall it before you can continue with Gpg4win installation. $\r$\n\
498         $\r$\n\
499       The installation will be aborted now!"
500
501
502
503 # From Function PrintNonAdminWarning
504 LangString T_AdminNeeded ${LANG_ENGLISH} \
505    "Warning: Administrator permissions required for a successful installation"
506
507 # From Function PrintCloseOtherApps
508 LangString T_CloseOtherApps ${LANG_ENGLISH} \
509    "Please make sure that other applications are not running. \
510     In particular you should close Outlook and all Explorer \
511     windows.  Gpg4Win will try to install anyway but a reboot \
512     will be required then."
513 LangString T_ShuttingDownWinPT ${LANG_ENGLISH} \
514    "Trying to shutdown a possible running instance of WinPT."
515 LangString T_ShuttingDownDirMngr ${LANG_ENGLISH} \
516    "Trying to shutdown a possible running instance of DirMngr."
517
518
519 # FIXME: The GetAfterChar function comes from the NSIS wiki.
520 Function un.GetAfterChar
521   Exch $0 ; chop char
522   Exch
523   Exch $1 ; input string
524   Push $2
525   Push $3
526   StrCpy $2 0
527   loop:
528     IntOp $2 $2 - 1
529     StrCpy $3 $1 1 $2
530     StrCmp $3 "" 0 +3
531       StrCpy $0 ""
532       Goto exit2
533     StrCmp $3 $0 exit1
534     Goto loop
535   exit1:
536     IntOp $2 $2 + 1
537     StrCpy $0 $1 "" $2
538   exit2:
539     Pop $3
540     Pop $2
541     Pop $1
542     Exch $0 ; output
543 FunctionEnd
544
545
546 Function un.SourceDelete
547   Push "/"
548   Call un.GetAfterChar
549   Pop $R0
550   Delete "$INSTDIR\$R0"
551 FunctionEnd
552
553
554 # StrStr  - taken from the NSIS reference
555 # input, top of stack = string to search for
556 #        top of stack-1 = string to search in
557 # output, top of stack (replaces with the portion of the string remaining)
558 # modifies no other variables.
559 #
560 # Usage:
561 #   Push "this is a long ass string"
562 #   Push "ass"
563 #   Call StrStr
564 #   Pop $R0
565 #  ($R0 at this point is "ass string")
566 #
567 !macro StrStr un
568 Function ${un}StrStr
569    Exch $R1 # st=haystack,old$R1, $R1=needle
570    Exch     # st=old$R1,haystack
571    Exch $R2 # st=old$R1,old$R2, $R2=haystack
572    Push $R3
573    Push $R4
574    Push $R5
575    StrLen $R3 $R1
576    StrCpy $R4 0
577    # $R1=needle
578    # $R2=haystack
579    # $R3=len(needle)
580    # $R4=cnt
581    # $R5=tmp
582    loop:
583      StrCpy $R5 $R2 $R3 $R4
584      StrCmp $R5 $R1 done
585      StrCmp $R5 "" done
586      IntOp $R4 $R4 + 1
587      Goto loop
588  done:
589    StrCpy $R1 $R2 "" $R4
590    Pop $R5
591    Pop $R4
592    Pop $R3
593    Pop $R2
594    Exch $R1
595 FunctionEnd
596 !macroend
597 !insertmacro StrStr ""
598 !insertmacro StrStr "un."
599
600
601 # TrimNewlines  - taken from the NSIS reference
602 # input, top of stack  (e.g. whatever$\r$\n)
603 # output, top of stack (replaces, with e.g. whatever)
604 # modifies no other variables.
605 Function TrimNewlines
606    Exch $R0
607    Push $R1
608    Push $R2
609    StrCpy $R1 0
610  
611  loop:
612    IntOp $R1 $R1 - 1
613    StrCpy $R2 $R0 1 $R1
614    StrCmp $R2 "$\r" loop
615    StrCmp $R2 "$\n" loop
616    IntOp $R1 $R1 + 1
617    IntCmp $R1 0 no_trim_needed
618    StrCpy $R0 $R0 $R1
619  
620  no_trim_needed:
621    Pop $R2
622    Pop $R1
623    Exch $R0
624 FunctionEnd
625
626
627 # AddToPath - Adds the given dir to the search path.
628 #        Input - head of the stack
629 Function AddToPath
630   Exch $0
631   g4wihelp::path_add "$0"
632   StrCmp $R5 "0" add_to_path_done
633   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
634   add_to_path_done:
635   Pop $0
636 FunctionEnd
637  
638 # RemoveFromPath - Remove a given dir from the path
639 #     Input: head of the stack
640 Function un.RemoveFromPath
641   Exch $0
642   g4wihelp::path_remove "$0"
643   StrCmp $R5 "0" remove_from_path_done
644   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
645   remove_from_path_done:
646   Pop $0
647 FunctionEnd
648  
649