2009-02-16 Marcus Brinkmann <marcus@g10code.de>
[gpg4win.git] / src / installer.nsi
1 # installer.nsi - Installer for GnuPG 4 Windows.    -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2007 g10 Code GmbH
3
4 # This file is part of GPG4Win.
5
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 # No servicable parts beyond this line.  Stay clear :)
21
22 !ifdef REQUIRE_W32_NSIS
23 !ifdef PACKAGE_LIBRARY
24 !include "Library.nsh"
25 !endif
26 !else
27 !macro InstallLib libtype shared install localfile destfile tempbasedir
28   File "${localfile}"
29 !macroend
30 !endif
31
32 !include "WinMessages.nsh"
33
34 # Define for the registry key to change the environment.  The
35 # commented one may be used if the setting should affect only the
36 # current user.
37 !define Regkey_for_Env \
38     'HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"'
39 # !define Regkey_for_Env 'HKCU "Environment"'
40
41
42 # We use Memento to remember past installation choices.
43 !include Memento.nsh
44 !define MEMENTO_REGISTRY_ROOT HKLM
45 !define MEMENTO_REGISTRY_KEY \
46   Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRETTY_PACKAGE_SHORT}
47
48
49 # We use the modern UI.
50 !include "MUI.nsh"
51
52 # Set the package name.  Note that this name should not be sufficed
53 #  with the version because this would get displayed in the start menu.
54 Name "${PRETTY_PACKAGE}"
55
56
57 # Set the output filename.
58 !ifdef GPG4WIN_LIGHT
59 OutFile "${PACKAGE}-light-${VERSION}.exe"
60 !else
61 OutFile "${PACKAGE}-${VERSION}.exe"
62 !endif
63
64 Icon "${TOP_SRCDIR}/doc/logo/gpg4win-logo-icon.ico"
65 UninstallIcon "${TOP_SRCDIR}/doc/logo/gpg4win-logo-icon.ico"
66
67 # Set the installation directory.
68 !ifndef INSTALL_DIR
69 !define INSTALL_DIR "${PACKAGE}"
70 !endif
71 InstallDir "$PROGRAMFILES\GNU\${INSTALL_DIR}" 
72
73
74 InstallDirRegKey HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" \
75         "Install Directory"
76
77
78 # Add version information to the file properties.
79 VIProductVersion "${PROD_VERSION}"
80 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
81 !ifdef LICENSE_GPL
82 VIAddVersionKey "Comments" \
83    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
84     and/or modify it under the terms of the GNU General Public License.  \
85     You should have received a copy of the GNU General Public License  \
86     along with this software; if not, write to the Free Software  \
87     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
88     MA 02110-1301, USA"
89 !else
90 VIAddVersionKey "Comments" \
91    "${PRETTY_PACKAGE_SHORT} is Free Software; you can redistribute it  \
92     and/or modify it under the terms of the GNU Lesser General Public  \
93     License. You should have received a copy of the GNU Lesser General  \
94     Public License along with this software; if not, write to the Free  \
95     Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
96     MA 02110-1301, USA"
97 !endif
98 VIAddVersionKey "CompanyName" "${COMPANY}"
99 VIAddVersionKey "LegalTrademarks" ""
100 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
101 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
102 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
103
104 # Set to the name of another GnuPG installation if one has been detected
105 Var OtherGnuPGDetected
106
107 # Interface Settings
108
109 # !define MUI_ABORTWARNING
110 !define MUI_FINISHPAGE_NOAUTOCLOSE
111 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
112
113 #!define MUI_HEADERIMAGE
114 #!define MUI_HEADERIMAGE_BITMAP \
115 #               "${TOP_SRCDIR}/doc/logo/gpg4win-logo-150x57.bmp"
116 !define MUI_WELCOMEFINISHPAGE_BITMAP \
117                "${TOP_SRCDIR}/doc/logo/gpg4win-logo-164x314.bmp"
118
119 # Remember the installer language
120
121 !define MUI_LANGDLL_REGISTRY_ROOT "HKLM"
122 !define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}" 
123 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
124
125 # No Umlaute, please!
126 !define MUI_LANGDLL_INFO "Please choose a language for the setup.$\r$\n\
127 Bitte die Sprache des Installations-Vorgangs angeben."
128
129 # The list of wizard pages.
130
131 !define MUI_WELCOMEPAGE_TITLE "${WELCOME_TITLE_STR}"
132 !define MUI_WELCOMEPAGE_TEXT "${ABOUT_STR}"
133
134 !insertmacro MUI_PAGE_WELCOME
135
136 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
137 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
138 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
139 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
140
141 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
142 !insertmacro MUI_PAGE_COMPONENTS
143
144 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckExistingVersion
145 !insertmacro MUI_PAGE_DIRECTORY
146
147 !ifdef HAVE_STARTMENU
148
149 Page custom CustomPageOptions
150
151 Var STARTMENU_FOLDER
152
153 !define MUI_PAGE_CUSTOMFUNCTION_PRE CheckIfStartMenuWanted
154 !define MUI_STARTMENUPAGE_NODISABLE
155 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKLM"
156 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\${PRETTY_PACKAGE_SHORT}"
157 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
158
159 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
160
161 !endif
162
163 !define MUI_PAGE_CUSTOMFUNCTION_PRE PrintCloseOtherApps
164 !insertmacro MUI_PAGE_INSTFILES
165
166 !define MUI_PAGE_CUSTOMFUNCTION_PRE ShowFinalWarnings
167 !define MUI_FINISHPAGE_SHOWREADME "share\gpg4win\README.$(T_LangCode).txt"
168 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
169 #!define MUI_FINISHPAGE_RUN
170 #!define MUI_FINISHPAGE_RUN_FUNCTION RunOnFinish
171 #!define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
172 #!define MUI_FINISHPAGE_RUN_NOTCHECKED
173 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
174 !define MUI_FINISHPAGE_LINK_LOCATION "$(T_MoreInfoURL)"
175 !insertmacro MUI_PAGE_FINISH
176
177
178 # Uninstaller pages.
179
180 !insertmacro MUI_UNPAGE_CONFIRM
181 !insertmacro MUI_UNPAGE_INSTFILES
182
183
184 #Page license
185 #Page components
186 #Page directory
187 #Page instfiles
188 #UninstPage uninstConfirm
189 #UninstPage instfiles
190
191
192 # Language support.  This has to be done after defining the pages, but
193 # before defining the translation strings.  Confusing.
194
195 # Enable this to not filter languages for the current code page.  Note
196 # that languages which are then not filtered out may not be displayed
197 # correctly in the Windows version the user is using.  Not recommended,
198 # but can be useful for testing.
199 !ifdef DEBUG
200 !define MUI_LANGDLL_ALLLANGUAGES
201 !endif
202
203 !insertmacro MUI_LANGUAGE "English"
204 !define PO_HEADER
205 !include "../po/catalogs.nsi"
206 !undef PO_HEADER
207
208 !insertmacro MUI_RESERVEFILE_LANGDLL
209 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
210 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
211 !ifdef SOURCES
212 ReserveFile "${TOP_SRCDIR}\doc\logo\gpg4win-logo-400px.bmp"
213 ReserveFile "${TOP_SRCDIR}\src\gpg4win-splash.wav"
214 !endif
215 ReserveFile "${TOP_SRCDIR}\COPYING"
216 ReserveFile "installer-options.ini"
217 ReserveFile "${TOP_SRCDIR}\doc\logo\gpg4win-logo-164x314.bmp"
218
219 # Language support
220
221 LangString T_LangCode ${LANG_ENGLISH} "en"
222
223 # Startup page
224 LangString T_GPLHeader ${LANG_ENGLISH} \
225   "This software is licensed under the terms of the GNU General Public \
226    License (GPL) which guarantees your freedom to share and change Free \
227    Software."
228
229 LangString T_GPLShort ${LANG_ENGLISH} \
230   "In short: You are allowed to run this software for any purpose. \
231    You may distribute it as long as you give the recipients the same \
232    rights you have received."
233
234 LangString T_RunKeyManager ${LANG_ENGLISH} \
235    "Run the key manager"
236
237 LangString T_MoreInfo ${LANG_ENGLISH} \
238    "Click here for the project's homepage"
239 LangString T_MoreInfoURL ${LANG_ENGLISH} "http://www.gpg4win.org"
240
241 LangString T_ShowReadme ${LANG_ENGLISH} \
242    "Show the README file"
243
244 LangString T_NoKeyManager ${LANG_ENGLISH} \
245    "No key manager has been installed, thus we can't run one now."
246
247 # Used as subdirectory name in Start Menu.
248
249 LangString DESC_Menu_manuals ${LANG_ENGLISH} \
250    "Documentation"
251
252 LangString DESC_Menu_uninstall ${LANG_ENGLISH} \
253    "Uninstall"
254
255 # Used as subdirectory name on Desktop.
256 LangString DESC_Desktop_manuals ${LANG_ENGLISH} \
257    "Gpg4win Documentation"
258
259
260 # Functions
261
262 # Custom functions and macros for gpg4win. 
263 !include "g4wihelp.nsi"
264
265 #
266 # Control function for the Custom page to select special
267 # install options.
268 #
269 Function CustomPageOptions
270   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_InstallOptLinks)"
271
272   # Note that the default selection is done in the ini file.
273   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
274         "Field 1" "Text"  "$(T_InstOptLabelA)"
275   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
276         "Field 2" "Text"  "$(T_InstOptFieldA)"
277   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
278         "Field 3" "Text"  "$(T_InstOptFieldB)"
279   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
280         "Field 4" "Text"  "$(T_InstOptFieldC)"
281   !insertmacro MUI_INSTALLOPTIONS_WRITE "installer-options.ini" \
282         "Field 5" "Text"  "$(T_InstOptLabelB)"
283
284   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "installer-options.ini"
285 FunctionEnd
286
287 # Display a warning if this is a Beta version.
288 Function PrintBetaWarning
289    MessageBox MB_OK "$(T_BetaWarning)"
290 FunctionEnd
291
292
293 # Display a warning if GnuPP has been detected and allow the user to abort
294 # the installation.
295 Function PrintGnuPPWarning
296    MessageBox MB_YESNO "$(T_FoundOldGnuPP)" IDYES cont
297      Abort
298  cont:
299    StrCpy $OtherGnuPGDetected "GnuPP"
300 FunctionEnd
301
302 # Display a warning if GnuPT has been detected and allow the user to abort
303 # the installation.
304 Function PrintGnuPTWarning
305    MessageBox MB_YESNO "$(T_FoundOldGnuPT)" IDYES cont
306      Abort
307  cont:
308    StrCpy $OtherGnuPGDetected "GnuPT"
309 FunctionEnd
310
311 # Display a warning if the Sourceforge WinPT has been detected and
312 # allow the user to abort the installation.
313 Function PrintWinPTSFWarning
314    MessageBox MB_YESNO "$(T_FoundOldWinPTSF)" IDYES cont
315      Abort
316  cont:
317    StrCpy $OtherGnuPGDetected "WinPT-SF"
318 FunctionEnd
319
320 # Display a warning if GnuPG Pack has been detected and abort the
321 # the installation.  This one clobbers our own Registry space.
322 Function PrintGnuPackWarning
323    MessageBox MB_OK "$(T_FoundOldGnuPack)"
324    Abort
325 FunctionEnd
326
327
328 # Check whether one of the other GnuPG systems has already been
329 # installed.  We do this by looking at the registry.
330 Function CheckOtherGnuPGApps
331   StrCpy $OtherGnuPGDetected ""
332   ClearErrors
333   ReadRegStr $0 HKLM "Software\GNU\GnuPP\Settings" "Path"
334   IfErrors +2 0
335     Call PrintGnuPPWarning
336
337   EnumRegKey $0 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder\Start Menu\Programs\GnuPT" 0
338   StrCmp $0 "" +2
339     Call PrintGnuPTWarning
340
341   ClearErrors
342   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Windows Privacy Tools" "DisplayVersion"
343   IfErrors +2 0
344     Call PrintWinPTSFWarning
345
346   ReadRegStr $0 HKLM "Software\GNU\GnuPG" "Install Directory"
347   Push $0
348   Push "GnuPG-Pack"
349   Call StrStr
350   Pop $0
351   StrCmp $0 "" +2
352     Call PrintGnuPackWarning
353
354
355 FunctionEnd
356
357 # Check whether gpg4win has already been installed.  This is called as
358 # a leave function from the directory page.  A call to abort will get
359 # back to the directory selection.
360 Function CheckExistingVersion
361   ClearErrors
362   FileOpen $0 "$INSTDIR\VERSION" r
363   IfErrors nexttest
364   FileRead $0 $R0
365   FileRead $0 $R1
366   FileClose $0
367
368   Push $R1
369   Call TrimNewLines
370   Pop $R1
371
372   # Extract major version.
373   StrCpy $0 $R1 2
374   StrCmp $0 "1." 0 secondtest
375     MessageBox MB_YESNO "$(T_FoundExistingOldVersion)" IDYES leave
376     Abort
377
378  secondtest:
379   MessageBox MB_YESNO "$(T_FoundExistingVersion)" IDYES leave
380   Abort
381
382  nexttest:
383   ClearErrors
384   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "DisplayVersion"
385   IfErrors leave 0
386      MessageBox MB_YESNO "$(T_FoundExistingVersionB)" IDYES leave
387      Abort
388      
389  leave:
390 FunctionEnd
391
392
393
394 # PrintNonAdminWarning
395
396 # Check whether the current user is in the Administrator group or an
397 # OS version without the need for an Administrator is in use.  Print a
398 # diagnostic if this is not the case and abort installation.
399 Function PrintNonAdminWarning
400
401   Call PrintBetaWarning
402
403   ClearErrors
404   UserInfo::GetName
405   IfErrors leave
406   Pop $0
407   UserInfo::GetAccountType
408   Pop $1
409   StrCmp $1 "Admin" leave +1
410   MessageBox MB_OK "$(T_AdminNeeded)"
411   Quit
412
413  leave:
414 FunctionEnd
415
416
417 # Check whether the start menu is actually wanted.
418
419 Function CheckIfStartMenuWanted
420   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "installer-options.ini" \
421         "Field 2" "State"
422   IntCmp $R0 1 +2
423     Abort
424 FunctionEnd
425
426
427 # Check whether this is a reinstall and popup a message box to explain
428 # that it is better to close other apps before continuing
429 Function PrintCloseOtherApps
430     IfFileExists $INSTDIR\gnupg.exe print_warning
431     IfFileExists $INSTDIR\winpt.exe print_warning
432     IfFileExists $INSTDIR\gpa.exe   print_warning
433     IfFileExists $INSTDIR\gpgol.dll print_warning
434     IfFileExists $INSTDIR\gpgee.dll print_warning
435     IfFileExists $INSTDIR\dirmngr.exe print_warning
436     Return
437    print_warning:
438     MessageBox MB_OK|MB_ICONEXCLAMATION "$(T_CloseOtherApps)"
439     IfFileExists $INSTDIR\winpt.exe 0 +3
440       MessageBox MB_OK "$(T_ShuttingDownWinPT)"
441       ExecWait '"$INSTDIR\winpt.exe" --stop'
442     IfFileExists $INSTDIR\dirmngr.exe 0 +3
443       MessageBox MB_OK "$(T_ShuttingDownDirMngr)"
444       g4wihelp::service_stop "DirMngr"
445    leave:
446 FunctionEnd
447
448 # Called right before the final page to show more warnings.
449 Function ShowFinalWarnings
450    StrCmp $OtherGnupgDetected "" +2
451      MessageBox MB_OK "$(T_FoundOldSeeManual)"
452    leave:
453 FunctionEnd
454
455 #-----------------------------------------------
456 # Strings pertaining to the install options page
457 #-----------------------------------------------
458
459 # Installation options title
460 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
461
462 # Installation options subtitle 1
463 LangString T_InstallOptLinks ${LANG_ENGLISH} "Start links"
464
465 LangString T_InstOptLabelA  ${LANG_ENGLISH} \
466      "Please select where Gpg4win shall install links:"
467
468 LangString T_InstOptLabelB  ${LANG_ENGLISH} \
469      "(Only programs will be linked into the quick launch bar.)"
470
471 LangString T_InstOptFieldA  ${LANG_ENGLISH} \
472      "Start Menu"
473
474 LangString T_InstOptFieldB  ${LANG_ENGLISH} \
475      "Desktop"
476
477 LangString T_InstOptFieldC  ${LANG_ENGLISH} \
478      "Quick Launch Bar"
479
480 #------------------------------------------------
481 # String pertaining to the existing version check
482 #------------------------------------------------
483 LangString T_FoundExistingVersion ${LANG_ENGLISH} \
484      "Version $R1 has already been installed.  $\r$\n\
485       Do you want to overwrite it with version ${VERSION}?"
486 LangString T_FoundExistingOldVersion ${LANG_ENGLISH} \
487      "An old version $R1 has already been installed.  It is \
488       strongly recommended to deinstall previous versions on \
489       major upgrades. $\r$\n\
490       Do you want to continue installing Gpg4win ${VERSION} anyway?"
491 LangString T_FoundExistingVersionB ${LANG_ENGLISH} \
492      "A version of Gpg4Win has already been installed on the system. \
493       There will be no problem installing and thus overwriting this \
494       Version. $\r$\n\
495        $\r$\n\
496       Do you want to continue installing Gpg4win?"
497
498
499 #---------------------------------------------
500 # From the old installation checking functions
501 #---------------------------------------------
502 LangString T_FoundOldSeeManual ${LANG_ENGLISH} \
503      "Please see the Gpg4win user manual to learn how to migrate existing \
504       keys from other GnuPG based installations to Gpg4win."
505
506 #---------
507 LangString T_FoundOldGnuPP ${LANG_ENGLISH} \
508      "An old installation of GnuPP (GNU Privacy Project) has been been \
509       detected.  That software is not maintained anymore and thus should \
510       be removed. $\r$\n\
511           $\r$\n\
512       Do you want to continue installing Gpg4win and take care of the old \
513       installation later?"
514
515 #---------
516 LangString T_FoundOldGnuPT ${LANG_ENGLISH} \
517      "An installation of GnuPT has been been detected.  This may cause \
518       problems when used along with Gpg4win. $\r$\n\
519           $\r$\n\
520       Do you want to continue installing Gpg4win?"
521
522 #---------
523 LangString T_FoundOldWinPTSF ${LANG_ENGLISH} \
524      "An old installation of the Sourceforge hosted WinPT has been been \
525       detected.  That software is not maintained anymore and should \
526       be removed. $\r$\n\
527           $\r$\n\
528       Do you want to continue installing Gpg4win and take care of the old \
529       installation later?"
530
531
532 #--------
533 LangString T_FoundOldGnuPack ${LANG_ENGLISH} \
534      "An installation of GnuPG-Pack has been been detected. You need to \
535       uninstall it before you can continue with Gpg4win installation. $\r$\n\
536         $\r$\n\
537       The installation will be aborted now!"
538
539
540
541 # From Function PrintBetaWarning
542 LangString T_BetaWarning ${LANG_ENGLISH} \
543    "Note: This is a BETA version of Gpg4win. $\r$\n\
544      $\r$\n\
545     Beta versions are only intended for testing and \
546     shall not be used in a production environment."
547
548 # From Function PrintNonAdminWarning
549 LangString T_AdminNeeded ${LANG_ENGLISH} \
550    "Warning: Administrator permissions required for a successful installation"
551
552 # From Function PrintCloseOtherApps
553 LangString T_CloseOtherApps ${LANG_ENGLISH} \
554    "Please make sure that other applications are not running. \
555     In particular you should close Outlook and all Explorer \
556     windows.  Gpg4win will try to install anyway but a reboot \
557     will be required then."
558 LangString T_ShuttingDownWinPT ${LANG_ENGLISH} \
559    "Trying to shutdown a possible running instance of WinPT."
560 LangString T_ShuttingDownDirMngr ${LANG_ENGLISH} \
561    "Trying to shutdown a possible running instance of DirMngr."
562
563
564 # FIXME: The GetAfterChar function comes from the NSIS wiki.
565 Function un.GetAfterChar
566   Exch $0 ; chop char
567   Exch
568   Exch $1 ; input string
569   Push $2
570   Push $3
571   StrCpy $2 0
572   loop:
573     IntOp $2 $2 - 1
574     StrCpy $3 $1 1 $2
575     StrCmp $3 "" 0 +3
576       StrCpy $0 ""
577       Goto exit2
578     StrCmp $3 $0 exit1
579     Goto loop
580   exit1:
581     IntOp $2 $2 + 1
582     StrCpy $0 $1 "" $2
583   exit2:
584     Pop $3
585     Pop $2
586     Pop $1
587     Exch $0 ; output
588 FunctionEnd
589
590
591 Function un.SourceDelete
592   Push "/"
593   Call un.GetAfterChar
594   Pop $R0
595   Delete "$INSTDIR\$R0"
596 FunctionEnd
597
598
599 # StrStr  - taken from the NSIS reference
600 # input, top of stack = string to search for
601 #        top of stack-1 = string to search in
602 # output, top of stack (replaces with the portion of the string remaining)
603 # modifies no other variables.
604 #
605 # Usage:
606 #   Push "this is a long ass string"
607 #   Push "ass"
608 #   Call StrStr
609 #   Pop $R0
610 #  ($R0 at this point is "ass string")
611 #
612 !macro StrStr un
613 Function ${un}StrStr
614    Exch $R1 # st=haystack,old$R1, $R1=needle
615    Exch     # st=old$R1,haystack
616    Exch $R2 # st=old$R1,old$R2, $R2=haystack
617    Push $R3
618    Push $R4
619    Push $R5
620    StrLen $R3 $R1
621    StrCpy $R4 0
622    # $R1=needle
623    # $R2=haystack
624    # $R3=len(needle)
625    # $R4=cnt
626    # $R5=tmp
627    loop:
628      StrCpy $R5 $R2 $R3 $R4
629      StrCmp $R5 $R1 done
630      StrCmp $R5 "" done
631      IntOp $R4 $R4 + 1
632      Goto loop
633  done:
634    StrCpy $R1 $R2 "" $R4
635    Pop $R5
636    Pop $R4
637    Pop $R3
638    Pop $R2
639    Exch $R1
640 FunctionEnd
641 !macroend
642 !insertmacro StrStr ""
643 !insertmacro StrStr "un."
644
645
646 # TrimNewlines  - taken from the NSIS reference
647 # input, top of stack  (e.g. whatever$\r$\n)
648 # output, top of stack (replaces, with e.g. whatever)
649 # modifies no other variables.
650 Function TrimNewlines
651    Exch $R0
652    Push $R1
653    Push $R2
654    StrCpy $R1 0
655  
656  loop:
657    IntOp $R1 $R1 - 1
658    StrCpy $R2 $R0 1 $R1
659    StrCmp $R2 "$\r" loop
660    StrCmp $R2 "$\n" loop
661    IntOp $R1 $R1 + 1
662    IntCmp $R1 0 no_trim_needed
663    StrCpy $R0 $R0 $R1
664  
665  no_trim_needed:
666    Pop $R2
667    Pop $R1
668    Exch $R0
669 FunctionEnd
670
671
672 # AddToPath - Adds the given dir to the search path.
673 #        Input - head of the stack
674 Function AddToPath
675   Exch $0
676   g4wihelp::path_add "$0"
677   StrCmp $R5 "0" add_to_path_done
678   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
679   add_to_path_done:
680   Pop $0
681 FunctionEnd
682  
683 # RemoveFromPath - Remove a given dir from the path
684 #     Input: head of the stack
685 Function un.RemoveFromPath
686   Exch $0
687   g4wihelp::path_remove "$0"
688   StrCmp $R5 "0" remove_from_path_done
689   SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
690   remove_from_path_done:
691   Pop $0
692 FunctionEnd
693  
694