Make use of internal iospawn flags more flexible.
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.11"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [5])
32 m4_define(mym4_version_micro, [0])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=22
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=11
62 LIBGPGME_LT_REVISION=0
63
64 # If the API is changed in an incompatible way: increment the next counter.
65 GPGME_CONFIG_API_VERSION=1
66 ##############################################
67
68 NEED_GPG_ERROR_VERSION=1.11
69 NEED_LIBASSUAN_API=2
70 NEED_LIBASSUAN_VERSION=2.0.2
71
72
73 PACKAGE=$PACKAGE_NAME
74 VERSION=$PACKAGE_VERSION
75
76 AC_CONFIG_AUX_DIR([build-aux])
77 AC_CONFIG_MACRO_DIR([m4])
78 AC_CONFIG_SRCDIR(src/gpgme.h.in)
79 AC_CONFIG_HEADER(config.h)
80 # Note: For automake 1.13 add the option
81 #          serial-tests
82 AM_INIT_AUTOMAKE
83 AM_MAINTAINER_MODE
84 AC_CANONICAL_HOST
85 AM_SILENT_RULES
86
87 # Enable GNU extensions on systems that have them.
88 AC_GNU_SOURCE
89
90 AH_VERBATIM([_REENTRANT],
91 [/* To allow the use of GPGME in multithreaded programs we have to use
92   special features from the library.
93   IMPORTANT: gpgme is not yet fully reentrant and you should use it
94   only from one thread.  */
95 #ifndef _REENTRANT
96 # define _REENTRANT 1
97 #endif])
98
99 AC_PROG_CC
100 AC_PROG_CXX
101
102 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
103 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
104
105 AC_SUBST(LIBGPGME_LT_CURRENT)
106 AC_SUBST(LIBGPGME_LT_AGE)
107 AC_SUBST(LIBGPGME_LT_REVISION)
108
109 AC_SUBST(PACKAGE)
110 AC_SUBST(VERSION)
111 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
112 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
113 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
114                           mym4_version_minor mym4_version_micro)
115 AC_SUBST(VERSION_NUMBER)
116
117 # Don't default to build static libs.
118 LT_PREREQ([2.2.6])
119 LT_INIT([win32-dll disable-static])
120 LT_LANG([Windows Resource])
121
122 # For now we hardcode the use of version scripts.  It would be better
123 # to write a test for this or even implement this within libtool.
124 have_ld_version_script=no
125 case "${host}" in
126     *-*-linux*)
127         have_ld_version_script=yes
128         ;;
129     *-*-gnu*)
130         have_ld_version_script=yes
131         ;;
132     *-apple-darwin*)
133         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
134         ;;
135 esac
136
137 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
138
139 GPG_DEFAULT=no
140 GPGSM_DEFAULT=no
141 GPGCONF_DEFAULT=no
142 G13_DEFAULT=no
143 component_system=None
144 have_dosish_system=no
145 have_android_system=no
146 have_w32_system=no
147 have_w64_system=no
148 build_w32_glib=no
149 build_w32_qt=no
150 case "${host}" in
151     x86_64-*mingw32*)
152         have_w64_system=yes
153         ;;
154     *-mingw32ce*)
155         have_w32ce_system=yes
156         ;;
157     *-linux-androideabi)
158         have_android_system=yes
159         ;;
160 esac
161 case "${host}" in
162     *-mingw32ce*|*-mingw32*)
163         have_dosish_system=yes
164         have_w32_system=yes
165         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
166         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
167         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
168         G13_DEFAULT='c:\\gnupg\\g13.exe'
169         #component_system='COM+'
170
171         AM_PATH_GLIB_2_0
172         AC_ARG_ENABLE(w32-glib,
173             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
174                            build_w32_glib=$enableval)
175
176         # Check disabled, because the qt-dev packages in gpg4win do
177         # not provide any support for cross compilation.
178         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
179
180         # Use it like this:
181         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
182         AC_SUBST(QT4_CORE_CFLAGS)
183         AC_SUBST(QT4_CORE_LIBS)
184         AC_ARG_ENABLE(w32-qt,
185             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
186                            build_w32_qt=$enableval)
187         ;;
188     *)
189         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
190         if test "$have_pthread" = yes; then
191           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
192         fi
193
194         # XXX: Probably use exec-prefix here?
195 #       GPG_DEFAULT='/usr/bin/gpg'
196 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
197 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
198 #       G13_DEFAULT='/usr/bin/g13'
199         ;;
200 esac
201
202 if test "$have_dosish_system" = yes; then
203    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
204              [Defined if we run on some of the PCDOS like systems
205               (DOS, Windoze. OS/2) with special properties like
206               no file modes])
207 fi
208 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
209
210 if test "$have_w32_system" = yes; then
211    AC_DEFINE(HAVE_W32_SYSTEM,1,
212              [Defined if we run on any kind of W32 API based system])
213 fi
214 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
215
216 if test "$have_w64_system" = yes; then
217    AC_DEFINE(HAVE_W64_SYSTEM,1,
218              [Defined if we run on a 64 bit W32 API based system])
219 fi
220 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
221
222 if test "$have_w32ce_system" = yes; then
223    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
224              [Defined if we run on a W32 CE API based system])
225 fi
226 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
227
228 if test "$have_android_system" = yes; then
229    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
230 fi
231 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
232
233 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
234 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
235
236 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
237
238
239 AC_ARG_ENABLE([fixed-path],
240               AC_HELP_STRING([--enable-fixed-path=PATH],
241                              [locate binaries only via this PATH]),
242               [fixed_search_path="$enableval"],
243               [fixed_search_path=""])
244 if test x$fixed_search_path != x ; then
245   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
246                     [Locate binaries only via this PATH])
247 fi
248
249
250 #
251 # Provide information about the build.
252 #
253 BUILD_REVISION="mym4_revision"
254 AC_SUBST(BUILD_REVISION)
255 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
256                    [GIT commit id revision used to build this package])
257
258 changequote(,)dnl
259 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
260 changequote([,])dnl
261 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
262 AC_SUBST(BUILD_FILEVERSION)
263
264 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
265 AC_SUBST(BUILD_TIMESTAMP)
266 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
267                    [The time this package was configured for a build])
268
269 #
270 # Options to disable some regression tests
271 #
272 run_gpgconf_test="yes"
273 AC_ARG_ENABLE(gpgconf-test,
274   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
275          run_gpgconf_test=$enableval)
276 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
277
278 run_gpg_test="yes"
279 AC_ARG_ENABLE(gpg-test,
280   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
281          run_gpg_test=$enableval)
282 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
283
284 run_gpgsm_test="yes"
285 AC_ARG_ENABLE(gpgsm-test,
286   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
287          run_gpgsm_test=$enableval)
288 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
289
290 run_g13_test="yes"
291 AC_ARG_ENABLE(g13-test,
292   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
293          run_g13_test=$enableval)
294 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
295
296
297 # Checks for header files.
298 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
299                        unistd.h sys/time.h sys/types.h sys/stat.h])
300
301
302 # Type checks.
303 AC_C_INLINE
304 AC_CHECK_SIZEOF(unsigned int)
305 AC_SYS_LARGEFILE
306 AC_TYPE_OFF_T
307 AC_TYPE_UINTPTR_T
308
309 # A simple compile time check in gpgme.h for GNU/Linux systems that
310 # prevents a file offset bits mismatch between gpgme and the application.
311 NEED__FILE_OFFSET_BITS=0
312 if test "$have_w32_system" != yes; then
313   case "$ac_cv_sys_file_offset_bits" in
314     "" | no | unknown) ;;
315     *)
316     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
317     ;;
318   esac
319 fi
320 AC_SUBST(NEED__FILE_OFFSET_BITS)
321
322 # Figure out platform dependent typedefs for gpgme.h
323 if test "$have_w32_system" = yes; then
324     INSERT__TYPEDEFS_FOR_GPGME_H="
325 #ifdef _WIN64
326 # include <stdint.h>
327   typedef int64_t gpgme_off_t;
328   typedef int64_t gpgme_ssize_t;
329 #else /* _WIN32 */
330   typedef long gpgme_off_t;
331   typedef long gpgme_ssize_t;
332 #endif /* _WIN32 */"
333     API__OFF_T="gpgme_off_t"
334     API__SSIZE_T="gpgme_ssize_t"
335 else
336     INSERT__TYPEDEFS_FOR_GPGME_H="
337 #include <sys/types.h>
338 typedef off_t   gpgme_off_t;
339 typedef ssize_t gpgme_ssize_t;"
340     API__OFF_T="off_t"
341     API__SSIZE_T="ssize_t"
342 fi
343 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
344 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
345 AC_SUBST(API__OFF_T)
346 AM_SUBST_NOTMAKE(API__OFF_T)
347 AC_SUBST(API__SSIZE_T)
348 AM_SUBST_NOTMAKE(API__SSIZE_T)
349
350 # Checks for compiler features.
351 if test "$GCC" = yes; then
352     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
353     if test "$have_w32_system" = yes; then
354        CFLAGS="$CFLAGS -mms-bitfields"
355     fi
356 fi
357
358 # Only used for debugging, so no serious test needed (for actual
359 # functionality you have to test libc as well, this only tests the
360 # compiler).
361 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
362    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
363                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
364 if test "$gpgme_cv_tls_works" = yes; then
365   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
366 fi
367
368
369 # Checks for library functions.
370 AC_MSG_NOTICE([checking for libraries])
371
372 AC_FUNC_FSEEKO
373
374 AC_REPLACE_FUNCS(vasprintf)
375 if test "$ac_cv_func_vasprintf" != yes; then
376   GNUPG_CHECK_VA_COPY
377 fi
378
379 # Try to find a thread-safe version of ttyname().
380 gnupg_REPLACE_TTYNAME_R
381 if test "$ac_cv_func_ttyname_r" != yes; then
382   AC_MSG_WARN([
383 ***
384 *** ttyname() is not thread-safe and ttyname_r() does not exist
385 ***])
386 fi
387
388 # Try to find a thread-safe version of getenv().
389 have_thread_safe_getenv=no
390 jm_GLIBC21
391 if test $GLIBC21 = yes; then
392   have_thread_safe_getenv=yes
393 fi
394 if test $have_thread_safe_getenv = yes; then
395   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
396 fi
397 have_getenv_r=no
398 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
399 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
400   AC_MSG_WARN([
401 ***
402 *** getenv() is not thread-safe and getenv_r() does not exist
403 ***])
404 fi
405
406 # For converting time strings to seconds since Epoch, we need the timegm
407 # function.
408 AC_CHECK_FUNCS(timegm)
409 if test "$ac_cv_func_timegm" != yes; then
410   AC_MSG_WARN([
411 ***
412 *** timegm() not available - a non-thread-safe kludge will be used
413 *** and the TZ variable might be changed at runtime.
414 ***])
415 fi
416
417 AC_CHECK_FUNCS(setlocale)
418
419 # Checking for libgpg-error.
420 have_gpg_error=no
421 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
422                   have_gpg_error=yes, have_gpg_error=no)
423 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
424           [The default error source for GPGME.])
425
426 # And for libassuan.
427 have_libassuan=no
428 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
429                   have_libassuan=yes, have_libassuan=no)
430 if test "$have_libassuan" = "yes"; then
431   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
432                      [version of the libassuan library])
433 fi
434
435
436 #
437 # Other checks
438 #
439
440 # Check for funopen
441 AC_CHECK_FUNCS(funopen)
442 if test $ac_cv_func_funopen != yes; then
443     # No funopen but we can implement that in terms of fopencookie.
444     AC_CHECK_FUNCS(fopencookie)
445     if test $ac_cv_func_fopencookie = yes; then
446         AC_REPLACE_FUNCS(funopen)
447     else
448         AC_MSG_WARN([
449 ***
450 *** No implementation of fopencookie or funopen available
451 ***])
452     fi
453 fi
454
455 # Check for getgid etc
456 AC_CHECK_FUNCS(getgid getegid)
457
458
459 # Replacement functions.
460 AC_REPLACE_FUNCS(stpcpy)
461 AC_REPLACE_FUNCS(setenv)
462
463 # Assuan check for descriptor passing.
464 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
465                 [supports_descriptor_passing=yes],
466                 [supports_descriptor_passing=no
467                  AC_MSG_WARN([
468 ***
469 *** Data structure for sending ancillary data missing.
470 *** Descriptor passing won't work.
471 ***])],[
472 #include <stdlib.h>
473 #include <stddef.h>
474 #include <stdio.h>
475 #include <sys/types.h>
476 #include <sys/socket.h>
477 #include <sys/un.h>
478 #if HAVE_SYS_UIO_H
479 #include <sys/uio.h>
480 #endif
481 #include <unistd.h>
482        ])
483
484
485 dnl There seems to be a problem with Apple and decriptor passing.
486 dnl Until we found a solution we change the default to no.
487 dnl See bug 1483.
488 case "${host}" in
489     *-apple-darwin*)
490       use_descriptor_passing=no
491       ;;
492     *)
493       use_descriptor_passing=yes
494       ;;
495 esac
496 AC_ARG_ENABLE(fd-passing,
497   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
498   use_descriptor_passing=$enableval)
499
500 if test "$supports_descriptor_passing" != "yes"; then
501   use_descriptor_passing=no
502 fi
503
504 if test "$use_descriptor_passing" = "yes"; then
505 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
506           [Defined if descriptor passing is enabled and supported])
507 fi
508
509 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
510
511
512 uiserver=no
513 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
514   uiserver=yes
515 fi
516 if test "$uiserver" != "no"; then
517   AC_DEFINE(ENABLE_UISERVER, 1,
518             [Defined if we are building with uiserver support.])
519 fi
520 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
521
522
523 # Add a few constants to help porting to W32
524 AH_VERBATIM([SEPCONSTANTS],
525 [
526 /* Separators as used in $PATH and file name.  */
527 #ifdef HAVE_DOSISH_SYSTEM
528 #define PATHSEP_C ';'
529 #define DIRSEP_C '\\'
530 #define DIRSEP_S "\\"
531 #else
532 #define PATHSEP_C ':'
533 #define DIRSEP_C '/'
534 #define DIRSEP_S "/"
535 #endif
536 ])
537
538 AH_BOTTOM([
539 /* Definition of GCC specific attributes.  */
540 #if __GNUC__ > 2
541 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
542 #else
543 # define GPGME_GCC_A_PURE
544 #endif
545
546 /* Under WindowsCE we need gpg-error's strerror macro.  */
547 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
548
549 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
550                     "Copyright (C) 2001--2013 g10 Code GmbH\n"
551 ])
552
553
554 # Substitution used for gpgme-config
555 GPGME_CONFIG_LIBS="-lgpgme"
556 GPGME_CONFIG_CFLAGS=""
557 GPGME_CONFIG_HOST="$host"
558 AC_SUBST(GPGME_CONFIG_API_VERSION)
559 AC_SUBST(GPGME_CONFIG_LIBS)
560 AC_SUBST(GPGME_CONFIG_CFLAGS)
561 AC_SUBST(GPGME_CONFIG_HOST)
562
563 # Frob'da Variables
564 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
565            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
566 AC_SUBST(LTLIBOBJS)
567
568 # Some checks for gpgme-tool
569 # Done at top: AC_CHECK_HEADER([argp.h])
570 AC_CHECK_TYPES([error_t], [],
571    [AC_DEFINE([error_t], [int],
572    [Define to a type to use for `error_t' if it is not otherwise available.])],
573    [#include <errno.h>])
574
575
576 # A substitution to set generated files in a Emacs buffer to read-only.
577 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
578 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
579 AC_SUBST(emacs_local_vars_end, ['End:'])
580
581
582 # Last check.
583 die=no
584 if test "$have_gpg_error" = "no"; then
585    die=yes
586    AC_MSG_NOTICE([[
587 ***
588 *** You need libgpg-error to build this program.
589 **  This library is for example available at
590 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
591 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
592 ***]])
593 fi
594 if test "$have_libassuan" = "no"; then
595    die=yes
596    AC_MSG_NOTICE([[
597 ***
598 *** You need libassuan to build this program.
599 *** This library is for example available at
600 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
601 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
602 ***]])
603 fi
604
605 if test "$die" = "yes"; then
606     AC_MSG_ERROR([[
607 ***
608 *** Required libraries not found. Please consult the above messages
609 *** and install them before running configure again.
610 ***]])
611 fi
612
613
614 #
615 # Create config files
616
617 AC_CONFIG_FILES(Makefile src/Makefile
618                 tests/Makefile
619                 tests/gpg/Makefile
620                 tests/gpgsm/Makefile
621                 tests/opassuan/Makefile
622                 doc/Makefile
623                 src/versioninfo.rc
624                 src/gpgme.h)
625 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
626 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
627 AC_OUTPUT
628
629 echo "
630         GPGME v${VERSION} has been configured as follows:
631
632         Revision:        mym4_revision  (mym4_revision_dec)
633         Platform:        $host
634
635         UI Server:       $uiserver
636         FD Passing:      $use_descriptor_passing
637         GPGME Pthread:   $have_pthread
638 "