core: Make sure FD_SET is not used with an out of range fd.
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=6
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 LIBQGPGME_LT_CURRENT=6
69 LIBQGPGME_LT_AGE=0
70 LIBQGPGME_LT_REVISION=1
71
72 # If the API is changed in an incompatible way: increment the next counter.
73 GPGME_CONFIG_API_VERSION=1
74 ##############################################
75
76 NEED_GPG_ERROR_VERSION=1.11
77 NEED_LIBASSUAN_API=2
78 NEED_LIBASSUAN_VERSION=2.0.2
79
80
81 PACKAGE=$PACKAGE_NAME
82 VERSION=$PACKAGE_VERSION
83
84 AC_CONFIG_AUX_DIR([build-aux])
85 AC_CONFIG_MACRO_DIR([m4])
86 AC_CONFIG_SRCDIR(src/gpgme.h.in)
87 AC_CONFIG_HEADER(config.h)
88 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
89 AM_MAINTAINER_MODE
90 AC_CANONICAL_HOST
91 AM_SILENT_RULES
92 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
93
94 # Enable GNU extensions on systems that have them.
95 AC_GNU_SOURCE
96
97 AH_VERBATIM([_REENTRANT],
98 [/* To allow the use of GPGME in multithreaded programs we have to use
99   special features from the library.
100   IMPORTANT: gpgme is not yet fully reentrant and you should use it
101   only from one thread.  */
102 #ifndef _REENTRANT
103 # define _REENTRANT 1
104 #endif])
105
106 AC_PROG_CC
107 AC_PROG_CXX
108
109 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
110 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
111
112 AC_SUBST(LIBGPGME_LT_CURRENT)
113 AC_SUBST(LIBGPGME_LT_AGE)
114 AC_SUBST(LIBGPGME_LT_REVISION)
115 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
116 AC_SUBST(LIBGPGMEPP_LT_AGE)
117 AC_SUBST(LIBGPGMEPP_LT_REVISION)
118 AC_SUBST(LIBQGPGME_LT_CURRENT)
119 AC_SUBST(LIBQGPGME_LT_AGE)
120 AC_SUBST(LIBQGPGME_LT_REVISION)
121
122 AC_SUBST(PACKAGE)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
126 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
127                           mym4_version_minor mym4_version_micro)
128 AC_SUBST(VERSION_NUMBER)
129
130 # Don't default to build static libs.
131 LT_PREREQ([2.2.6])
132 LT_INIT([win32-dll disable-static])
133 LT_LANG([Windows Resource])
134
135 # For now we hardcode the use of version scripts.  It would be better
136 # to write a test for this or even implement this within libtool.
137 have_ld_version_script=no
138 case "${host}" in
139     *-*-linux*)
140         have_ld_version_script=yes
141         ;;
142     *-*-gnu*)
143         have_ld_version_script=yes
144         ;;
145     *-apple-darwin*)
146         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
147         ;;
148 esac
149
150 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
151
152 GPG_DEFAULT=no
153 GPGSM_DEFAULT=no
154 GPGCONF_DEFAULT=no
155 G13_DEFAULT=no
156 component_system=None
157 have_dosish_system=no
158 have_android_system=no
159 have_w32_system=no
160 have_w64_system=no
161 build_w32_glib=no
162 build_w32_qt=no
163 available_languages="cl cpp python qt"
164 default_languages="cl cpp python qt"
165 case "${host}" in
166     x86_64-*mingw32*)
167         have_w64_system=yes
168         ;;
169     *-mingw32ce*)
170         have_w32ce_system=yes
171         ;;
172     *-linux-androideabi)
173         have_android_system=yes
174         ;;
175 esac
176 case "${host}" in
177     *-mingw32ce*|*-mingw32*)
178         have_dosish_system=yes
179         have_w32_system=yes
180         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
181         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
182         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
183         G13_DEFAULT='c:\\gnupg\\g13.exe'
184         #component_system='COM+'
185
186         AM_PATH_GLIB_2_0
187         AC_ARG_ENABLE(w32-glib,
188             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
189                            build_w32_glib=$enableval)
190        ;;
191     *)
192
193         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
194         if test "$have_pthread" = yes; then
195           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
196         fi
197
198         # XXX: Probably use exec-prefix here?
199 #       GPG_DEFAULT='/usr/bin/gpg'
200 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
201 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
202 #       G13_DEFAULT='/usr/bin/g13'
203         ;;
204 esac
205
206 if test "$have_dosish_system" = yes; then
207    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
208              [Defined if we run on some of the PCDOS like systems
209               (DOS, Windoze. OS/2) with special properties like
210               no file modes])
211 fi
212 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
213
214 if test "$have_w32_system" = yes; then
215    AC_DEFINE(HAVE_W32_SYSTEM,1,
216              [Defined if we run on any kind of W32 API based system])
217 fi
218 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
219
220 if test "$have_w64_system" = yes; then
221    AC_DEFINE(HAVE_W64_SYSTEM,1,
222              [Defined if we run on a 64 bit W32 API based system])
223 fi
224 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
225
226 if test "$have_w32ce_system" = yes; then
227    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
228              [Defined if we run on a W32 CE API based system])
229 fi
230 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
231
232 if test "$have_android_system" = yes; then
233    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
234 fi
235 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
236
237 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
238
239 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
240
241
242 AC_ARG_ENABLE([fixed-path],
243               AC_HELP_STRING([--enable-fixed-path=PATH],
244                              [locate binaries only via this PATH]),
245               [fixed_search_path="$enableval"],
246               [fixed_search_path=""])
247 if test x$fixed_search_path != x ; then
248   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
249                     [Locate binaries only via this PATH])
250 fi
251
252 AC_ARG_ENABLE([languages],
253               AC_HELP_STRING([--enable-languages=languages],
254                              [enable only specific language bindings]),
255                              [enabled_languages=`echo $enableval | \
256                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
257                              sed 's/c++/cpp/'`],
258                              [enabled_languages="maybe"])
259 if test "x$enabled_languages" = "x" \
260    -o "$enabled_languages" = "no"; then
261    enabled_languages=
262 fi
263
264 # If languages are explicitly set missing requirements
265 # for the languages are treated as errors otherwise
266 # there will be a warning.
267 explicit_languages=1
268 if test "x$enabled_languages" = "xmaybe"; then
269     explicit_languages=0
270     enabled_languages="$default_languages"
271 fi
272
273 for language in $enabled_languages; do
274     LIST_MEMBER($language, $available_languages)
275     if test "$found" = "0"; then
276        AC_MSG_ERROR([unsupported language binding specified])
277     fi
278 done
279
280
281
282 # Enable C++ 11 if cpp language is requested
283 LIST_MEMBER("cpp", $enabled_languages)
284 if test "$found" = "1"; then
285     AX_CXX_COMPILE_STDCXX(11, noext, optional)
286     if test "$HAVE_CXX11" != "1"; then
287         if test "$explicit_languages" = "1"; then
288             AC_MSG_ERROR([[
289 ***
290 *** A compiler with c++11 support is required for the c++ binding.
291 ***]])
292         else
293             enabled_languages=$(echo $enabled_languages | sed 's/cpp//')
294             enabled_languages=$(echo $enabled_languages | sed 's/qt//')
295             AC_MSG_WARN([[
296 ***
297 *** No c++11 support detected. C++ and Qt bindings will be disabled.
298 ***]])
299         fi
300     fi
301 fi
302
303 # Check that if qt is enabled cpp also is enabled
304 LIST_MEMBER("qt", $enabled_languages)
305 if test "$found" = "1"; then
306     # We need to ensure that in the langauge order qt comes after cpp
307     # so we remove qt first and explicitly add it as last list member.
308     enabled_languages=$(echo $enabled_languages | sed 's/qt//')
309     LIST_MEMBER("cpp", $enabled_languages)
310     if test "$found" = "0"; then
311         AC_MSG_ERROR([[
312 ***
313 *** Qt language binding depends on cpp binding.
314 ***]])
315     fi
316     FIND_QT
317     if test "$have_qt5_libs" != "yes"; then
318         if test "$explicit_languages" = "1"; then
319         AC_MSG_ERROR([[
320 ***
321 *** Qt5 (Qt5Core) is required for Qt binding.
322 ***]])
323         else
324            AC_MSG_WARN([[
325 ***
326 *** Qt5 (Qt5Core) not found Qt Binding will be disabled.
327 ***]])
328         fi
329     else
330         enabled_languages=`echo $enabled_languages qt`
331
332         AC_CHECK_PROGS([DOXYGEN], [doxygen])
333         if test -z "$DOXYGEN";
334             # This is not highlighted becase it's not really important.
335             then AC_MSG_WARN([Doxygen not found - Qt binding doc will not be built.])
336         fi
337         AC_CHECK_PROGS([GRAPHVIZ], [dot])
338         if test -z "$GRAPHVIZ";
339             then AC_MSG_WARN([Graphviz not found - Qt binding doc will not have diagrams.])
340         fi
341     fi
342 fi
343 AM_CONDITIONAL([HAVE_DOXYGEN],
344                [test -n "$DOXYGEN"])
345 if test -n "$GRAPHVIZ"; then
346     HAVE_DOT="YES"
347 else
348     HAVE_DOT="NO"
349 fi
350 AC_SUBST(HAVE_DOT)
351
352 # Python bindings.
353 LIST_MEMBER("python", $enabled_languages)
354 if test "$found" = "1"; then
355     AX_PKG_SWIG
356     if test -z "$SWIG"; then
357         if test "$explicit_languages" = "1"; then
358             AC_MSG_ERROR([[
359 ***
360 *** You need SWIG to build the Python bindings.
361 ***]])
362         else
363             enabled_languages=$(echo $enabled_languages | sed 's/python//')
364         fi
365     else
366         AM_PATH_PYTHON([3.3])
367         AX_SWIG_PYTHON
368         if test -z "$PYTHON_VERSION"; then
369            if test "$explicit_languages" = "1"; then
370               AC_MSG_ERROR([[
371 ***
372 *** Please install the python development packages.
373 ***]])
374             else
375                 enabled_languages=$(echo $enabled_languages | sed 's/python//')
376             fi
377         fi
378     fi
379 fi
380
381 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
382
383 #
384 # Provide information about the build.
385 #
386 BUILD_REVISION="mym4_revision"
387 AC_SUBST(BUILD_REVISION)
388 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
389                    [GIT commit id revision used to build this package])
390
391 changequote(,)dnl
392 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
393 changequote([,])dnl
394 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
395 AC_SUBST(BUILD_FILEVERSION)
396
397 AC_ARG_ENABLE([build-timestamp],
398   AC_HELP_STRING([--enable-build-timestamp],
399                  [set an explicit build timestamp for reproducibility.
400                   (default is the current time in ISO-8601 format)]),
401      [if test "$enableval" = "yes"; then
402         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
403       else
404         BUILD_TIMESTAMP="$enableval"
405       fi],
406      [BUILD_TIMESTAMP="<none>"])
407 AC_SUBST(BUILD_TIMESTAMP)
408 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
409                    [The time this package was configured for a build])
410
411
412 #
413 # Options to disable some regression tests
414 #
415 run_gpgconf_test="yes"
416 AC_ARG_ENABLE(gpgconf-test,
417   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
418          run_gpgconf_test=$enableval)
419 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
420
421 run_gpg_test="yes"
422 AC_ARG_ENABLE(gpg-test,
423   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
424          run_gpg_test=$enableval)
425 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
426
427 run_gpgsm_test="yes"
428 AC_ARG_ENABLE(gpgsm-test,
429   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
430          run_gpgsm_test=$enableval)
431 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
432
433 run_g13_test="yes"
434 AC_ARG_ENABLE(g13-test,
435   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
436          run_g13_test=$enableval)
437 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
438
439
440 # Checks for header files.
441 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
442                        unistd.h sys/time.h sys/types.h sys/stat.h])
443
444
445 # Type checks.
446 AC_C_INLINE
447 AC_CHECK_SIZEOF(unsigned int)
448 AC_SYS_LARGEFILE
449 AC_TYPE_OFF_T
450 AC_TYPE_UINTPTR_T
451
452 # A simple compile time check in gpgme.h for GNU/Linux systems that
453 # prevents a file offset bits mismatch between gpgme and the application.
454 NEED__FILE_OFFSET_BITS=0
455 if test "$have_w32_system" != yes; then
456   case "$ac_cv_sys_file_offset_bits" in
457     "" | no | unknown) ;;
458     *)
459     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
460     ;;
461   esac
462 fi
463 AC_SUBST(NEED__FILE_OFFSET_BITS)
464
465 # Figure out platform dependent typedefs for gpgme.h
466 if test "$have_w32_system" = yes; then
467     INSERT__TYPEDEFS_FOR_GPGME_H="
468 #ifdef _WIN64
469 # include <stdint.h>
470   typedef int64_t gpgme_off_t;
471   typedef int64_t gpgme_ssize_t;
472 #else /* _WIN32 */
473   typedef long gpgme_off_t;
474   typedef long gpgme_ssize_t;
475 #endif /* _WIN32 */"
476     API__OFF_T="gpgme_off_t"
477     API__SSIZE_T="gpgme_ssize_t"
478 else
479     INSERT__TYPEDEFS_FOR_GPGME_H="
480 #include <sys/types.h>
481 typedef off_t   gpgme_off_t;
482 typedef ssize_t gpgme_ssize_t;"
483     API__OFF_T="off_t"
484     API__SSIZE_T="ssize_t"
485 fi
486 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
487 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
488 AC_SUBST(API__OFF_T)
489 AM_SUBST_NOTMAKE(API__OFF_T)
490 AC_SUBST(API__SSIZE_T)
491 AM_SUBST_NOTMAKE(API__SSIZE_T)
492
493 # Checks for compiler features.
494 if test "$GCC" = yes; then
495     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
496     if test "$have_w32_system" = yes; then
497        CFLAGS="$CFLAGS -mms-bitfields"
498     fi
499 fi
500
501 # Only used for debugging, so no serious test needed (for actual
502 # functionality you have to test libc as well, this only tests the
503 # compiler).
504 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
505    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
506                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
507 if test "$gpgme_cv_tls_works" = yes; then
508   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
509 fi
510
511
512 # Checks for library functions.
513 AC_MSG_NOTICE([checking for libraries])
514
515 AC_FUNC_FSEEKO
516
517 AC_REPLACE_FUNCS(vasprintf)
518 if test "$ac_cv_func_vasprintf" != yes; then
519   GNUPG_CHECK_VA_COPY
520 fi
521
522 # Try to find a thread-safe version of ttyname().
523 gnupg_REPLACE_TTYNAME_R
524 if test "$ac_cv_func_ttyname_r" != yes; then
525   AC_MSG_WARN([
526 ***
527 *** ttyname() is not thread-safe and ttyname_r() does not exist
528 ***])
529 fi
530
531 # Try to find a thread-safe version of getenv().
532 have_thread_safe_getenv=no
533 jm_GLIBC21
534 if test $GLIBC21 = yes; then
535   have_thread_safe_getenv=yes
536 fi
537 if test $have_thread_safe_getenv = yes; then
538   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
539 fi
540 have_getenv_r=no
541 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
542 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
543   AC_MSG_WARN([
544 ***
545 *** getenv() is not thread-safe and getenv_r() does not exist
546 ***])
547 fi
548
549 # For converting time strings to seconds since Epoch, we need the timegm
550 # function.
551 AC_CHECK_FUNCS(timegm)
552 if test "$ac_cv_func_timegm" != yes; then
553   AC_MSG_WARN([
554 ***
555 *** timegm() not available - a non-thread-safe kludge will be used
556 *** and the TZ variable might be changed at runtime.
557 ***])
558 fi
559
560 AC_CHECK_FUNCS(setlocale)
561
562 # Checking for libgpg-error.
563 have_gpg_error=no
564 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
565                   have_gpg_error=yes, have_gpg_error=no)
566 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
567           [The default error source for GPGME.])
568
569 # And for libassuan.
570 have_libassuan=no
571 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
572                   have_libassuan=yes, have_libassuan=no)
573 if test "$have_libassuan" = "yes"; then
574   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
575                      [version of the libassuan library])
576 fi
577
578
579 #
580 # Other checks
581 #
582
583 # Check for funopen
584 AC_CHECK_FUNCS(funopen)
585 if test $ac_cv_func_funopen != yes; then
586     # No funopen but we can implement that in terms of fopencookie.
587     AC_CHECK_FUNCS(fopencookie)
588     if test $ac_cv_func_fopencookie = yes; then
589         AC_REPLACE_FUNCS(funopen)
590     else
591         AC_MSG_WARN([
592 ***
593 *** No implementation of fopencookie or funopen available
594 ***])
595     fi
596 fi
597
598 # Check for getgid etc
599 AC_CHECK_FUNCS(getgid getegid)
600
601
602 # Replacement functions.
603 AC_REPLACE_FUNCS(stpcpy)
604 AC_REPLACE_FUNCS(setenv)
605
606 # Assuan check for descriptor passing.
607 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
608                 [supports_descriptor_passing=yes],
609                 [supports_descriptor_passing=no
610                  AC_MSG_WARN([
611 ***
612 *** Data structure for sending ancillary data missing.
613 *** Descriptor passing won't work.
614 ***])],[
615 #include <stdlib.h>
616 #include <stddef.h>
617 #include <stdio.h>
618 #include <sys/types.h>
619 #include <sys/socket.h>
620 #include <sys/un.h>
621 #if HAVE_SYS_UIO_H
622 #include <sys/uio.h>
623 #endif
624 #include <unistd.h>
625        ])
626
627
628 dnl There seems to be a problem with Apple and decriptor passing.
629 dnl Until we found a solution we change the default to no.
630 dnl See bug 1483.
631 case "${host}" in
632     *-apple-darwin*)
633       use_descriptor_passing=no
634       ;;
635     *)
636       use_descriptor_passing=yes
637       ;;
638 esac
639 AC_ARG_ENABLE(fd-passing,
640   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
641   use_descriptor_passing=$enableval)
642
643 if test "$supports_descriptor_passing" != "yes"; then
644   use_descriptor_passing=no
645 fi
646
647 if test "$use_descriptor_passing" = "yes"; then
648 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
649           [Defined if descriptor passing is enabled and supported])
650 fi
651
652 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
653
654
655 uiserver=no
656 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
657   uiserver=yes
658 fi
659 if test "$uiserver" != "no"; then
660   AC_DEFINE(ENABLE_UISERVER, 1,
661             [Defined if we are building with uiserver support.])
662 fi
663 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
664
665
666 # Add a few constants to help porting to W32
667 AH_VERBATIM([SEPCONSTANTS],
668 [
669 /* Separators as used in $PATH and file name.  */
670 #ifdef HAVE_DOSISH_SYSTEM
671 #define PATHSEP_C ';'
672 #define DIRSEP_C '\\'
673 #define DIRSEP_S "\\"
674 #else
675 #define PATHSEP_C ':'
676 #define DIRSEP_C '/'
677 #define DIRSEP_S "/"
678 #endif
679 ])
680
681 AH_BOTTOM([
682 /* Definition of GCC specific attributes.  */
683 #if __GNUC__ > 2
684 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
685 #else
686 # define GPGME_GCC_A_PURE
687 #endif
688
689 /* Under WindowsCE we need gpg-error's strerror macro.  */
690 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
691
692 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
693                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
694 ])
695
696
697 # Substitution used for gpgme-config
698 GPGME_CONFIG_LIBS="-lgpgme"
699 GPGME_CONFIG_CFLAGS=""
700 GPGME_CONFIG_HOST="$host"
701 AC_SUBST(GPGME_CONFIG_API_VERSION)
702 AC_SUBST(GPGME_CONFIG_LIBS)
703 AC_SUBST(GPGME_CONFIG_CFLAGS)
704 AC_SUBST(GPGME_CONFIG_HOST)
705
706 # Frob'da Variables
707 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
708            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
709 AC_SUBST(LTLIBOBJS)
710
711 # Some checks for gpgme-tool
712 # Done at top: AC_CHECK_HEADER([argp.h])
713 AC_CHECK_TYPES([error_t], [],
714    [AC_DEFINE([error_t], [int],
715    [Define to a type to use for `error_t' if it is not otherwise available.])],
716    [#include <errno.h>])
717
718
719 # A substitution to set generated files in a Emacs buffer to read-only.
720 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
721 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
722 AC_SUBST(emacs_local_vars_end, ['End:'])
723
724 # Last check.
725 die=no
726 if test "$have_gpg_error" = "no"; then
727    die=yes
728    AC_MSG_NOTICE([[
729 ***
730 *** You need libgpg-error to build this program.
731 **  This library is for example available at
732 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
733 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
734 ***]])
735 fi
736 if test "$have_libassuan" = "no"; then
737    die=yes
738    AC_MSG_NOTICE([[
739 ***
740 *** You need libassuan to build this program.
741 *** This library is for example available at
742 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
743 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
744 ***]])
745 fi
746
747 if test "$die" = "yes"; then
748     AC_MSG_ERROR([[
749 ***
750 *** Required libraries not found. Please consult the above messages
751 *** and install them before running configure again.
752 ***]])
753 fi
754
755
756 #
757 # Create config files
758
759 AC_CONFIG_FILES(Makefile src/Makefile
760                 tests/Makefile
761                 tests/gpg/Makefile
762                 tests/gpgsm/Makefile
763                 tests/opassuan/Makefile
764                 doc/Makefile
765                 src/versioninfo.rc
766                 src/gpgme.h)
767 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
768 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
769 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
770 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
771 AC_CONFIG_FILES(lang/qt/Makefile lang/qt/src/Makefile)
772 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfig.cmake.in)
773 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfigVersion.cmake)
774 AC_CONFIG_FILES(lang/qt/tests/Makefile)
775 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
776 AM_COND_IF([HAVE_DOXYGEN], [AC_CONFIG_FILES([lang/qt/doc/Doxyfile])])
777 AC_CONFIG_FILES(lang/qt/doc/Makefile)
778 AC_CONFIG_FILES([lang/python/Makefile lang/python/tests/Makefile])
779 AC_OUTPUT
780
781 echo "
782         GPGME v${VERSION} has been configured as follows:
783
784         Revision:          mym4_revision  (mym4_revision_dec)
785         Platform:          $host
786
787         UI Server:         $uiserver
788         FD Passing:        $use_descriptor_passing
789         GPGME Pthread:     $have_pthread
790
791         Language bindings: $enabled_languages
792 "
793 if test "x${gpg_config_script_warn}" != x; then
794 cat <<G10EOF
795         Mismatches between the target platform and the to
796         be used libraries have been been detected for:
797          ${gpg_config_script_warn}
798         Please check above for warning messages.
799
800 G10EOF
801 fi