Remove obsolete w32-qt code
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=3
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 # If the API is changed in an incompatible way: increment the next counter.
69 GPGME_CONFIG_API_VERSION=1
70 ##############################################
71
72 NEED_GPG_ERROR_VERSION=1.11
73 NEED_LIBASSUAN_API=2
74 NEED_LIBASSUAN_VERSION=2.0.2
75
76
77 PACKAGE=$PACKAGE_NAME
78 VERSION=$PACKAGE_VERSION
79
80 AC_CONFIG_AUX_DIR([build-aux])
81 AC_CONFIG_MACRO_DIR([m4])
82 AC_CONFIG_SRCDIR(src/gpgme.h.in)
83 AC_CONFIG_HEADER(config.h)
84 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
85 AM_MAINTAINER_MODE
86 AC_CANONICAL_HOST
87 AM_SILENT_RULES
88 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
89
90 # Enable GNU extensions on systems that have them.
91 AC_GNU_SOURCE
92
93 AH_VERBATIM([_REENTRANT],
94 [/* To allow the use of GPGME in multithreaded programs we have to use
95   special features from the library.
96   IMPORTANT: gpgme is not yet fully reentrant and you should use it
97   only from one thread.  */
98 #ifndef _REENTRANT
99 # define _REENTRANT 1
100 #endif])
101
102 AC_PROG_CC
103 AC_PROG_CXX
104
105 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
106 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
107
108 AC_SUBST(LIBGPGME_LT_CURRENT)
109 AC_SUBST(LIBGPGME_LT_AGE)
110 AC_SUBST(LIBGPGME_LT_REVISION)
111 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
112 AC_SUBST(LIBGPGMEPP_LT_AGE)
113 AC_SUBST(LIBGPGMEPP_LT_REVISION)
114
115 AC_SUBST(PACKAGE)
116 AC_SUBST(VERSION)
117 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
118 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
119 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
120                           mym4_version_minor mym4_version_micro)
121 AC_SUBST(VERSION_NUMBER)
122
123 # Don't default to build static libs.
124 LT_PREREQ([2.2.6])
125 LT_INIT([win32-dll disable-static])
126 LT_LANG([Windows Resource])
127
128 # For now we hardcode the use of version scripts.  It would be better
129 # to write a test for this or even implement this within libtool.
130 have_ld_version_script=no
131 case "${host}" in
132     *-*-linux*)
133         have_ld_version_script=yes
134         ;;
135     *-*-gnu*)
136         have_ld_version_script=yes
137         ;;
138     *-apple-darwin*)
139         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
140         ;;
141 esac
142
143 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
144
145 GPG_DEFAULT=no
146 GPGSM_DEFAULT=no
147 GPGCONF_DEFAULT=no
148 G13_DEFAULT=no
149 component_system=None
150 have_dosish_system=no
151 have_android_system=no
152 have_w32_system=no
153 have_w64_system=no
154 build_w32_glib=no
155 build_w32_qt=no
156 available_languages="cpp cl"
157 default_languages="cpp cl"
158 case "${host}" in
159     x86_64-*mingw32*)
160         have_w64_system=yes
161         ;;
162     *-mingw32ce*)
163         have_w32ce_system=yes
164         ;;
165     *-linux-androideabi)
166         have_android_system=yes
167         ;;
168 esac
169 case "${host}" in
170     *-mingw32ce*|*-mingw32*)
171         have_dosish_system=yes
172         have_w32_system=yes
173         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
174         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
175         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
176         G13_DEFAULT='c:\\gnupg\\g13.exe'
177         #component_system='COM+'
178
179         AM_PATH_GLIB_2_0
180         AC_ARG_ENABLE(w32-glib,
181             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
182                            build_w32_glib=$enableval)
183        ;;
184     *)
185
186         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
187         if test "$have_pthread" = yes; then
188           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
189         fi
190
191         # XXX: Probably use exec-prefix here?
192 #       GPG_DEFAULT='/usr/bin/gpg'
193 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
194 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
195 #       G13_DEFAULT='/usr/bin/g13'
196         ;;
197 esac
198
199 if test "$have_dosish_system" = yes; then
200    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
201              [Defined if we run on some of the PCDOS like systems
202               (DOS, Windoze. OS/2) with special properties like
203               no file modes])
204 fi
205 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
206
207 if test "$have_w32_system" = yes; then
208    AC_DEFINE(HAVE_W32_SYSTEM,1,
209              [Defined if we run on any kind of W32 API based system])
210 fi
211 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
212
213 if test "$have_w64_system" = yes; then
214    AC_DEFINE(HAVE_W64_SYSTEM,1,
215              [Defined if we run on a 64 bit W32 API based system])
216 fi
217 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
218
219 if test "$have_w32ce_system" = yes; then
220    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
221              [Defined if we run on a W32 CE API based system])
222 fi
223 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
224
225 if test "$have_android_system" = yes; then
226    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
227 fi
228 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
229
230 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
231
232 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
233
234
235 AC_ARG_ENABLE([fixed-path],
236               AC_HELP_STRING([--enable-fixed-path=PATH],
237                              [locate binaries only via this PATH]),
238               [fixed_search_path="$enableval"],
239               [fixed_search_path=""])
240 if test x$fixed_search_path != x ; then
241   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
242                     [Locate binaries only via this PATH])
243 fi
244
245 AC_ARG_ENABLE([languages],
246               AC_HELP_STRING([--enable-languages=languages],
247                              [enable only specific language bindings]),
248                              [enabled_languages=`echo $enableval | \
249                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
250                              sed 's/c++/cpp/'`],
251                              [enabled_languages="$default_languages"])
252 if test "x$enabled_languages" = "x" \
253    -o "$enabled_languages" = "no"; then
254    enabled_languages=
255 fi
256 for language in $enabled_languages; do
257     LIST_MEMBER($language, $available_languages)
258     if test "$found" = "0"; then
259        AC_MSG_ERROR([unsupported language binding specified])
260     fi
261 done
262 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
263
264 #
265 # Provide information about the build.
266 #
267 BUILD_REVISION="mym4_revision"
268 AC_SUBST(BUILD_REVISION)
269 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
270                    [GIT commit id revision used to build this package])
271
272 changequote(,)dnl
273 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
274 changequote([,])dnl
275 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
276 AC_SUBST(BUILD_FILEVERSION)
277
278 AC_ARG_ENABLE([build-timestamp],
279   AC_HELP_STRING([--enable-build-timestamp],
280                  [set an explicit build timestamp for reproducibility.
281                   (default is the current time in ISO-8601 format)]),
282      [if test "$enableval" = "yes"; then
283         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
284       else
285         BUILD_TIMESTAMP="$enableval"
286       fi],
287      [BUILD_TIMESTAMP="<none>"])
288 AC_SUBST(BUILD_TIMESTAMP)
289 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
290                    [The time this package was configured for a build])
291
292
293 #
294 # Options to disable some regression tests
295 #
296 run_gpgconf_test="yes"
297 AC_ARG_ENABLE(gpgconf-test,
298   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
299          run_gpgconf_test=$enableval)
300 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
301
302 run_gpg_test="yes"
303 AC_ARG_ENABLE(gpg-test,
304   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
305          run_gpg_test=$enableval)
306 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
307
308 run_gpgsm_test="yes"
309 AC_ARG_ENABLE(gpgsm-test,
310   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
311          run_gpgsm_test=$enableval)
312 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
313
314 run_g13_test="yes"
315 AC_ARG_ENABLE(g13-test,
316   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
317          run_g13_test=$enableval)
318 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
319
320
321 # Checks for header files.
322 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
323                        unistd.h sys/time.h sys/types.h sys/stat.h])
324
325
326 # Type checks.
327 AC_C_INLINE
328 AC_CHECK_SIZEOF(unsigned int)
329 AC_SYS_LARGEFILE
330 AC_TYPE_OFF_T
331 AC_TYPE_UINTPTR_T
332
333 # A simple compile time check in gpgme.h for GNU/Linux systems that
334 # prevents a file offset bits mismatch between gpgme and the application.
335 NEED__FILE_OFFSET_BITS=0
336 if test "$have_w32_system" != yes; then
337   case "$ac_cv_sys_file_offset_bits" in
338     "" | no | unknown) ;;
339     *)
340     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
341     ;;
342   esac
343 fi
344 AC_SUBST(NEED__FILE_OFFSET_BITS)
345
346 # Figure out platform dependent typedefs for gpgme.h
347 if test "$have_w32_system" = yes; then
348     INSERT__TYPEDEFS_FOR_GPGME_H="
349 #ifdef _WIN64
350 # include <stdint.h>
351   typedef int64_t gpgme_off_t;
352   typedef int64_t gpgme_ssize_t;
353 #else /* _WIN32 */
354   typedef long gpgme_off_t;
355   typedef long gpgme_ssize_t;
356 #endif /* _WIN32 */"
357     API__OFF_T="gpgme_off_t"
358     API__SSIZE_T="gpgme_ssize_t"
359 else
360     INSERT__TYPEDEFS_FOR_GPGME_H="
361 #include <sys/types.h>
362 typedef off_t   gpgme_off_t;
363 typedef ssize_t gpgme_ssize_t;"
364     API__OFF_T="off_t"
365     API__SSIZE_T="ssize_t"
366 fi
367 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
368 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
369 AC_SUBST(API__OFF_T)
370 AM_SUBST_NOTMAKE(API__OFF_T)
371 AC_SUBST(API__SSIZE_T)
372 AM_SUBST_NOTMAKE(API__SSIZE_T)
373
374 # Checks for compiler features.
375 if test "$GCC" = yes; then
376     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
377     if test "$have_w32_system" = yes; then
378        CFLAGS="$CFLAGS -mms-bitfields"
379     fi
380 fi
381
382 # Only used for debugging, so no serious test needed (for actual
383 # functionality you have to test libc as well, this only tests the
384 # compiler).
385 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
386    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
387                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
388 if test "$gpgme_cv_tls_works" = yes; then
389   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
390 fi
391
392
393 # Checks for library functions.
394 AC_MSG_NOTICE([checking for libraries])
395
396 AC_FUNC_FSEEKO
397
398 AC_REPLACE_FUNCS(vasprintf)
399 if test "$ac_cv_func_vasprintf" != yes; then
400   GNUPG_CHECK_VA_COPY
401 fi
402
403 # Try to find a thread-safe version of ttyname().
404 gnupg_REPLACE_TTYNAME_R
405 if test "$ac_cv_func_ttyname_r" != yes; then
406   AC_MSG_WARN([
407 ***
408 *** ttyname() is not thread-safe and ttyname_r() does not exist
409 ***])
410 fi
411
412 # Try to find a thread-safe version of getenv().
413 have_thread_safe_getenv=no
414 jm_GLIBC21
415 if test $GLIBC21 = yes; then
416   have_thread_safe_getenv=yes
417 fi
418 if test $have_thread_safe_getenv = yes; then
419   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
420 fi
421 have_getenv_r=no
422 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
423 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
424   AC_MSG_WARN([
425 ***
426 *** getenv() is not thread-safe and getenv_r() does not exist
427 ***])
428 fi
429
430 # For converting time strings to seconds since Epoch, we need the timegm
431 # function.
432 AC_CHECK_FUNCS(timegm)
433 if test "$ac_cv_func_timegm" != yes; then
434   AC_MSG_WARN([
435 ***
436 *** timegm() not available - a non-thread-safe kludge will be used
437 *** and the TZ variable might be changed at runtime.
438 ***])
439 fi
440
441 AC_CHECK_FUNCS(setlocale)
442
443 # Checking for libgpg-error.
444 have_gpg_error=no
445 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
446                   have_gpg_error=yes, have_gpg_error=no)
447 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
448           [The default error source for GPGME.])
449
450 # And for libassuan.
451 have_libassuan=no
452 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
453                   have_libassuan=yes, have_libassuan=no)
454 if test "$have_libassuan" = "yes"; then
455   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
456                      [version of the libassuan library])
457 fi
458
459
460 #
461 # Other checks
462 #
463
464 # Check for funopen
465 AC_CHECK_FUNCS(funopen)
466 if test $ac_cv_func_funopen != yes; then
467     # No funopen but we can implement that in terms of fopencookie.
468     AC_CHECK_FUNCS(fopencookie)
469     if test $ac_cv_func_fopencookie = yes; then
470         AC_REPLACE_FUNCS(funopen)
471     else
472         AC_MSG_WARN([
473 ***
474 *** No implementation of fopencookie or funopen available
475 ***])
476     fi
477 fi
478
479 # Check for getgid etc
480 AC_CHECK_FUNCS(getgid getegid)
481
482
483 # Replacement functions.
484 AC_REPLACE_FUNCS(stpcpy)
485 AC_REPLACE_FUNCS(setenv)
486
487 # Assuan check for descriptor passing.
488 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
489                 [supports_descriptor_passing=yes],
490                 [supports_descriptor_passing=no
491                  AC_MSG_WARN([
492 ***
493 *** Data structure for sending ancillary data missing.
494 *** Descriptor passing won't work.
495 ***])],[
496 #include <stdlib.h>
497 #include <stddef.h>
498 #include <stdio.h>
499 #include <sys/types.h>
500 #include <sys/socket.h>
501 #include <sys/un.h>
502 #if HAVE_SYS_UIO_H
503 #include <sys/uio.h>
504 #endif
505 #include <unistd.h>
506        ])
507
508
509 dnl There seems to be a problem with Apple and decriptor passing.
510 dnl Until we found a solution we change the default to no.
511 dnl See bug 1483.
512 case "${host}" in
513     *-apple-darwin*)
514       use_descriptor_passing=no
515       ;;
516     *)
517       use_descriptor_passing=yes
518       ;;
519 esac
520 AC_ARG_ENABLE(fd-passing,
521   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
522   use_descriptor_passing=$enableval)
523
524 if test "$supports_descriptor_passing" != "yes"; then
525   use_descriptor_passing=no
526 fi
527
528 if test "$use_descriptor_passing" = "yes"; then
529 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
530           [Defined if descriptor passing is enabled and supported])
531 fi
532
533 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
534
535
536 uiserver=no
537 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
538   uiserver=yes
539 fi
540 if test "$uiserver" != "no"; then
541   AC_DEFINE(ENABLE_UISERVER, 1,
542             [Defined if we are building with uiserver support.])
543 fi
544 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
545
546
547 # Add a few constants to help porting to W32
548 AH_VERBATIM([SEPCONSTANTS],
549 [
550 /* Separators as used in $PATH and file name.  */
551 #ifdef HAVE_DOSISH_SYSTEM
552 #define PATHSEP_C ';'
553 #define DIRSEP_C '\\'
554 #define DIRSEP_S "\\"
555 #else
556 #define PATHSEP_C ':'
557 #define DIRSEP_C '/'
558 #define DIRSEP_S "/"
559 #endif
560 ])
561
562 AH_BOTTOM([
563 /* Definition of GCC specific attributes.  */
564 #if __GNUC__ > 2
565 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
566 #else
567 # define GPGME_GCC_A_PURE
568 #endif
569
570 /* Under WindowsCE we need gpg-error's strerror macro.  */
571 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
572
573 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
574                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
575 ])
576
577
578 # Substitution used for gpgme-config
579 GPGME_CONFIG_LIBS="-lgpgme"
580 GPGME_CONFIG_CFLAGS=""
581 GPGME_CONFIG_HOST="$host"
582 AC_SUBST(GPGME_CONFIG_API_VERSION)
583 AC_SUBST(GPGME_CONFIG_LIBS)
584 AC_SUBST(GPGME_CONFIG_CFLAGS)
585 AC_SUBST(GPGME_CONFIG_HOST)
586
587 # Frob'da Variables
588 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
589            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
590 AC_SUBST(LTLIBOBJS)
591
592 # Some checks for gpgme-tool
593 # Done at top: AC_CHECK_HEADER([argp.h])
594 AC_CHECK_TYPES([error_t], [],
595    [AC_DEFINE([error_t], [int],
596    [Define to a type to use for `error_t' if it is not otherwise available.])],
597    [#include <errno.h>])
598
599
600 # A substitution to set generated files in a Emacs buffer to read-only.
601 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
602 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
603 AC_SUBST(emacs_local_vars_end, ['End:'])
604
605
606 # Last check.
607 die=no
608 if test "$have_gpg_error" = "no"; then
609    die=yes
610    AC_MSG_NOTICE([[
611 ***
612 *** You need libgpg-error to build this program.
613 **  This library is for example available at
614 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
615 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
616 ***]])
617 fi
618 if test "$have_libassuan" = "no"; then
619    die=yes
620    AC_MSG_NOTICE([[
621 ***
622 *** You need libassuan to build this program.
623 *** This library is for example available at
624 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
625 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
626 ***]])
627 fi
628
629 if test "$die" = "yes"; then
630     AC_MSG_ERROR([[
631 ***
632 *** Required libraries not found. Please consult the above messages
633 *** and install them before running configure again.
634 ***]])
635 fi
636
637
638 #
639 # Create config files
640
641 AC_CONFIG_FILES(Makefile src/Makefile
642                 tests/Makefile
643                 tests/gpg/Makefile
644                 tests/gpgsm/Makefile
645                 tests/opassuan/Makefile
646                 doc/Makefile
647                 src/versioninfo.rc
648                 src/gpgme.h)
649 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
650 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
651 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
652 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
653 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
654 AC_OUTPUT
655
656 echo "
657         GPGME v${VERSION} has been configured as follows:
658
659         Revision:          mym4_revision  (mym4_revision_dec)
660         Platform:          $host
661
662         UI Server:         $uiserver
663         FD Passing:        $use_descriptor_passing
664         GPGME Pthread:     $have_pthread
665
666         Language bindings: $enabled_languages
667 "
668 if test "x${gpg_config_script_warn}" != x; then
669 cat <<G10EOF
670         Mismatches between the target platform and the to
671         be used libraries have been been detected for:
672          ${gpg_config_script_warn}
673         Please check above for warning messages.
674
675 G10EOF
676 fi