2003-01-29 Marcus Brinkmann <marcus@g10code.de>
[gpgme.git] / configure.ac
1 # configure.in  for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 # Version number: Remember to change it immediately *after* a release.
24 AC_INIT(gpgme, 0.4.1, [bug-gpgme@gnupg.org])
25 # LT Version numbers, remember to change them just *before* a release.
26 #   (Code changed:                      REVISION++)
27 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
28 #   (Interfaces added:                  AGE++)
29 #   (Interfaces removed:                AGE=0)
30 #
31 LIBGPGME_LT_CURRENT=10
32 LIBGPGME_LT_AGE=0
33 LIBGPGME_LT_REVISION=0
34 NEED_GPG_VERSION=1.2.0
35 NEED_GPGSM_VERSION=0.9.0
36 ##############################################
37 AC_PREREQ(2.52)
38 AC_REVISION($Revision$)
39
40 PACKAGE=$PACKAGE_NAME
41 VERSION=$PACKAGE_VERSION
42
43 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
44 AM_CONFIG_HEADER(config.h)
45 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
46 AM_MAINTAINER_MODE
47
48 AH_VERBATIM([_GNU_SOURCE],
49 [/* Enable GNU extensions on systems that have them.  */
50 #ifndef _GNU_SOURCE
51 # define _GNU_SOURCE
52 #endif])
53
54 AH_VERBATIM([_REENTRANT],
55 [/* To allow the use of GPGME in multithreaded programs we have to use
56   special features from the library.
57   IMPORTANT: gpgme is not yet fully reentrant and you should use it
58   only from one thread.  */
59 #ifndef _REENTRANT
60 # define _REENTRANT 1
61 #endif])
62
63
64 AC_PROG_CC
65
66
67 AC_SUBST(LIBGPGME_LT_CURRENT)
68 AC_SUBST(LIBGPGME_LT_AGE)
69 AC_SUBST(LIBGPGME_LT_REVISION)
70 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
71                                      [Min. needed GnuPG version.])
72 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
73                                        [Min. needed GPGSM version.])
74
75 AC_SUBST(PACKAGE)
76 AC_SUBST(VERSION)
77 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
78 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
79
80 dnl Don't default to build static libs.
81 dnl AC_DISABLE_STATIC
82 AC_PROG_LIBTOOL
83
84 AC_CANONICAL_HOST
85 # For now we hardcode the use of version scripts.  It would be better
86 # to write a test for this or even implement this within libtool.
87 have_ld_version_script=no
88 case "${host}" in
89     *-*-linux*)
90         have_ld_version_script=yes
91         ;;
92     *-*-gnu*)
93         have_ld_version_script=yes
94         ;;
95 esac
96 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
97
98 GPG_DEFAULT=no
99 GPGSM_DEFAULT=no
100 component_system=None
101 case "${host}" in
102     *-*-mingw32* | i?86-emx-os2 | i?86-*-os2*emx | i?86-*-msdosdjgpp* )
103         # special stuff for Windoze NT
104         # OS/2 with the EMX environment
105         # DOS with the DJGPP environment
106         AC_DEFINE(HAVE_DRIVE_LETTERS, ,
107                   [Defined if we run on some of the PCDOS like systems (DOS,
108                    Windoze, OS/2) with special properties like no file modes.])
109         AC_DEFINE(HAVE_DOSISH_SYSTEM, ,
110                   [Defined if the filesystem uses driver letters.])
111         have_dosish_system=yes
112         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
113         # XXX Assuan is not supported in this configuration.
114         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
115         #component_system='COM+'
116         ;;
117     *)
118         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
119         if test "$have_pth" = yes; then
120           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
121           CFLAGS="$CFLAGS $PTH_CFLAGS"
122         fi
123         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
124         if test "$have_pthread" = yes; then
125           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
126         fi
127
128 dnl     # XXX: Probably use exec-prefix here?
129 dnl     GPG_DEFAULT='/usr/bin/gpg'
130 dnl     GPGSM_DEFAULT='/usr/bin/gpgsm'
131         ;;
132 esac
133 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = "yes")
134 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
135 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
136
137 dnl
138 dnl Checks for header files.
139 dnl
140 AC_CHECK_HEADERS(sys/select.h)
141
142 dnl
143 dnl Type checks.
144 dnl
145
146 AC_CHECK_SIZEOF(unsigned int)
147
148 dnl
149 dnl Checks for compiler features.
150 dnl
151
152 if test "$GCC" = yes; then
153     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
154 fi
155
156 dnl
157 dnl Checks for library functions.
158 dnl
159
160 AC_REPLACE_FUNCS(stpcpy)
161
162 AC_REPLACE_FUNCS(vasprintf)
163 if test "$ac_cv_func_vasprintf" != yes; then
164   GNUPG_CHECK_VA_COPY
165 fi
166
167
168
169 # Note: fopencokie is only a dummy stub and not used.  
170 #       However some code in assuan/ links against it.
171 AC_REPLACE_FUNCS(fopencookie)
172
173
174
175 dnl
176 dnl Checks for system services
177 dnl
178
179 NO_OVERRIDE=no
180 AC_ARG_WITH(gpg,
181             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
182             GPG=$withval, NO_OVERRIDE=yes)
183 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
184   GPG=
185   NO_OVERRIDE=yes
186   if test "$cross_compiling" != "yes"; then
187     AC_PATH_PROG(GPG, gpg)
188   fi
189   if test -z "$GPG"; then
190     GPG="$GPG_DEFAULT"
191   fi
192 fi
193 if test "$GPG" = no; then
194   if test "$NO_OVERRIDE" = "yes"; then
195     if test "$cross_compiling" != "yes"; then
196       AC_MSG_WARN([Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it])
197     else
198       AC_MSG_ERROR([Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH])
199     fi
200   fi
201 else
202   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
203   AC_SUBST(GPG)
204 fi
205 AM_CONDITIONAL(RUN_GPG_TESTS,
206   [test "$cross_compiling" != "yes" && test -n "$GPG" && test -r "$GPG"])
207 AC_SUBST(GPG_PATH)
208
209 NO_OVERRIDE=no
210 AC_ARG_WITH(gpgsm,
211             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
212             GPGSM=$withval, NO_OVERRIDE=yes)
213 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
214   GPGSM=
215   NO_OVERRIDE=yes
216   if test "$cross_compiling" != "yes"; then
217     AC_PATH_PROG(GPGSM, gpgsm)
218   fi
219   if test -z "$GPGSM"; then
220     GPGSM="$GPGSM_DEFAULT"
221   fi
222 fi
223 if test "$GPGSM" = no; then
224   if test "$NO_OVERRIDE" = "yes"; then
225     if test "$cross_compiling" != "yes"; then
226       AC_MSG_WARN([Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it])
227     else
228       AC_MSG_ERROR([Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH])
229     fi
230   fi
231 else
232   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
233   AC_SUBST(GPGSM)
234 fi
235 AM_CONDITIONAL(HAVE_GPGSM, [test -n "$GPGSM" && test -r "$GPGSM"])
236 AM_CONDITIONAL(RUN_GPGSM_TESTS,
237   [test "$cross_compiling" != "yes" && test -n "$GPGSM" && test -r "$GPGSM"])
238
239 dnl FIXME: Only build if supported.
240 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
241
242 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
243
244 dnl Make the version number in gpgme/gpgme.h the same as the one here.
245 dnl (this is easier than to have a *.in file just for one substitution)
246 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
247
248 dnl Substitution used for gpgme-config 
249 GPGME_CONFIG_LIBS="-lgpgme"
250 GPGME_CONFIG_CFLAGS=""
251 AC_SUBST(GPGME_CONFIG_LIBS)
252 AC_SUBST(GPGME_CONFIG_CFLAGS)
253
254 dnl Frob'da Variables
255 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
256            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
257 AC_SUBST(LTLIBOBJS)
258
259 dnl
260 dnl Create config files 
261 dnl
262
263 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
264                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
265                 doc/Makefile complus/Makefile)
266 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
267 AC_OUTPUT
268
269 echo "
270         GPGME v${VERSION} has been configured as follows:
271
272         GnuPG version: min. $NEED_GPG_VERSION
273         GnuPG path:    $GPG
274
275         GpgSM version: min. $NEED_GPGSM_VERSION
276         GpgSM path:    $GPGSM
277 "