Set next version to 1.5.0
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.11"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [5])
32 m4_define(mym4_version_micro, [0])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=22
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=11
62 LIBGPGME_LT_REVISION=0
63
64 # If the API is changed in an incompatible way: increment the next counter.
65 GPGME_CONFIG_API_VERSION=1
66 ##############################################
67
68 NEED_GPG_ERROR_VERSION=1.11
69 NEED_LIBASSUAN_API=2
70 NEED_LIBASSUAN_VERSION=2.0.2
71
72
73 PACKAGE=$PACKAGE_NAME
74 VERSION=$PACKAGE_VERSION
75
76 AC_CONFIG_AUX_DIR([build-aux])
77 AC_CONFIG_MACRO_DIR([m4])
78 AC_CONFIG_SRCDIR(src/gpgme.h.in)
79 AC_CONFIG_HEADER(config.h)
80 # Note: For automake 1.13 add the option
81 #          serial-tests
82 AM_INIT_AUTOMAKE
83 AM_MAINTAINER_MODE
84 AC_CANONICAL_HOST
85
86 # Enable GNU extensions on systems that have them.
87 AC_GNU_SOURCE
88
89 AH_VERBATIM([_REENTRANT],
90 [/* To allow the use of GPGME in multithreaded programs we have to use
91   special features from the library.
92   IMPORTANT: gpgme is not yet fully reentrant and you should use it
93   only from one thread.  */
94 #ifndef _REENTRANT
95 # define _REENTRANT 1
96 #endif])
97
98 AC_PROG_CC
99 AC_PROG_CXX
100
101 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
102 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
103
104 AC_SUBST(LIBGPGME_LT_CURRENT)
105 AC_SUBST(LIBGPGME_LT_AGE)
106 AC_SUBST(LIBGPGME_LT_REVISION)
107
108 AC_SUBST(PACKAGE)
109 AC_SUBST(VERSION)
110 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
111 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
112 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
113                           mym4_version_minor mym4_version_micro)
114 AC_SUBST(VERSION_NUMBER)
115
116 # Don't default to build static libs.
117 LT_PREREQ([2.2.6])
118 LT_INIT([win32-dll disable-static])
119 LT_LANG([Windows Resource])
120
121 # For now we hardcode the use of version scripts.  It would be better
122 # to write a test for this or even implement this within libtool.
123 have_ld_version_script=no
124 case "${host}" in
125     *-*-linux*)
126         have_ld_version_script=yes
127         ;;
128     *-*-gnu*)
129         have_ld_version_script=yes
130         ;;
131     *-apple-darwin*)
132         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
133         ;;
134 esac
135
136 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
137
138 GPG_DEFAULT=no
139 GPGSM_DEFAULT=no
140 GPGCONF_DEFAULT=no
141 G13_DEFAULT=no
142 component_system=None
143 have_dosish_system=no
144 have_android_system=no
145 have_w32_system=no
146 have_w64_system=no
147 build_w32_glib=no
148 build_w32_qt=no
149 case "${host}" in
150     x86_64-*mingw32*)
151         have_w64_system=yes
152         ;;
153     *-mingw32ce*)
154         have_w32ce_system=yes
155         ;;
156     *-linux-androideabi)
157         have_android_system=yes
158         ;;
159 esac
160 case "${host}" in
161     *-mingw32ce*|*-mingw32*)
162         have_dosish_system=yes
163         have_w32_system=yes
164         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
165         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
166         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
167         G13_DEFAULT='c:\\gnupg\\g13.exe'
168         #component_system='COM+'
169
170         AM_PATH_GLIB_2_0
171         AC_ARG_ENABLE(w32-glib,
172             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
173                            build_w32_glib=$enableval)
174
175         # Check disabled, because the qt-dev packages in gpg4win do
176         # not provide any support for cross compilation.
177         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
178
179         # Use it like this:
180         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
181         AC_SUBST(QT4_CORE_CFLAGS)
182         AC_SUBST(QT4_CORE_LIBS)
183         AC_ARG_ENABLE(w32-qt,
184             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
185                            build_w32_qt=$enableval)
186         ;;
187     *)
188         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
189         if test "$have_pthread" = yes; then
190           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
191         fi
192
193         # XXX: Probably use exec-prefix here?
194 #       GPG_DEFAULT='/usr/bin/gpg'
195 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
196 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
197 #       G13_DEFAULT='/usr/bin/g13'
198         ;;
199 esac
200
201 if test "$have_dosish_system" = yes; then
202    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
203              [Defined if we run on some of the PCDOS like systems
204               (DOS, Windoze. OS/2) with special properties like
205               no file modes])
206 fi
207 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
208
209 if test "$have_w32_system" = yes; then
210    AC_DEFINE(HAVE_W32_SYSTEM,1,
211              [Defined if we run on any kind of W32 API based system])
212 fi
213 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
214
215 if test "$have_w64_system" = yes; then
216    AC_DEFINE(HAVE_W64_SYSTEM,1,
217              [Defined if we run on a 64 bit W32 API based system])
218 fi
219 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
220
221 if test "$have_w32ce_system" = yes; then
222    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
223              [Defined if we run on a W32 CE API based system])
224 fi
225 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
226
227 if test "$have_android_system" = yes; then
228    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
229 fi
230 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
231
232 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
233 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
234
235 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
236
237
238 #
239 # Provide information about the build.
240 #
241 BUILD_REVISION="mym4_revision"
242 AC_SUBST(BUILD_REVISION)
243 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
244                    [GIT commit id revision used to build this package])
245
246 changequote(,)dnl
247 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
248 changequote([,])dnl
249 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
250 AC_SUBST(BUILD_FILEVERSION)
251
252 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
253 AC_SUBST(BUILD_TIMESTAMP)
254 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
255                    [The time this package was configured for a build])
256
257 #
258 # Options to disable some regression tests
259 #
260 run_gpgconf_test="yes"
261 AC_ARG_ENABLE(gpgconf-test,
262   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
263          run_gpgconf_test=$enableval)
264 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
265
266 run_gpg_test="yes"
267 AC_ARG_ENABLE(gpg-test,
268   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
269          run_gpg_test=$enableval)
270 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
271
272 run_gpgsm_test="yes"
273 AC_ARG_ENABLE(gpgsm-test,
274   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
275          run_gpgsm_test=$enableval)
276 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
277
278 run_g13_test="yes"
279 AC_ARG_ENABLE(g13-test,
280   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
281          run_g13_test=$enableval)
282 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
283
284
285 # Checks for header files.
286 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
287                        unistd.h sys/time.h sys/types.h sys/stat.h])
288
289
290 # Type checks.
291 AC_C_INLINE
292 AC_CHECK_SIZEOF(unsigned int)
293 AC_SYS_LARGEFILE
294 AC_TYPE_OFF_T
295 AC_TYPE_UINTPTR_T
296
297 # A simple compile time check in gpgme.h for GNU/Linux systems that
298 # prevents a file offset bits mismatch between gpgme and the application.
299 NEED__FILE_OFFSET_BITS=0
300 if test "$have_w32_system" != yes; then
301   case "$ac_cv_sys_file_offset_bits" in
302     "" | no | unknown) ;;
303     *)
304     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
305     ;;
306   esac
307 fi
308 AC_SUBST(NEED__FILE_OFFSET_BITS)
309
310 # Figure out platform dependent typedefs for gpgme.h
311 if test "$have_w32_system" = yes; then
312     INSERT__TYPEDEFS_FOR_GPGME_H="
313 #ifdef _WIN64
314 # include <stdint.h>
315   typedef int64_t gpgme_off_t;
316   typedef int64_t gpgme_ssize_t;
317 #else /* _WIN32 */
318   typedef long gpgme_off_t;
319   typedef long gpgme_ssize_t;
320 #endif /* _WIN32 */"
321     API__OFF_T="gpgme_off_t"
322     API__SSIZE_T="gpgme_ssize_t"
323 else
324     INSERT__TYPEDEFS_FOR_GPGME_H="
325 #include <sys/types.h>
326 typedef off_t   gpgme_off_t;
327 typedef ssize_t gpgme_ssize_t;"
328     API__OFF_T="off_t"
329     API__SSIZE_T="ssize_t"
330 fi
331 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
332 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
333 AC_SUBST(API__OFF_T)
334 AM_SUBST_NOTMAKE(API__OFF_T)
335 AC_SUBST(API__SSIZE_T)
336 AM_SUBST_NOTMAKE(API__SSIZE_T)
337
338 # Checks for compiler features.
339 if test "$GCC" = yes; then
340     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
341     if test "$have_w32_system" = yes; then
342        CFLAGS="$CFLAGS -mms-bitfields"
343     fi
344 fi
345
346 # Only used for debugging, so no serious test needed (for actual
347 # functionality you have to test libc as well, this only tests the
348 # compiler).
349 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
350    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
351                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
352 if test "$gpgme_cv_tls_works" = yes; then
353   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
354 fi
355
356
357 # Checks for library functions.
358 AC_MSG_NOTICE([checking for libraries])
359
360 AC_FUNC_FSEEKO
361
362 AC_REPLACE_FUNCS(vasprintf)
363 if test "$ac_cv_func_vasprintf" != yes; then
364   GNUPG_CHECK_VA_COPY
365 fi
366
367 # Try to find a thread-safe version of ttyname().
368 gnupg_REPLACE_TTYNAME_R
369 if test "$ac_cv_func_ttyname_r" != yes; then
370   AC_MSG_WARN([
371 ***
372 *** ttyname() is not thread-safe and ttyname_r() does not exist
373 ***])
374 fi
375
376 # Try to find a thread-safe version of getenv().
377 have_thread_safe_getenv=no
378 jm_GLIBC21
379 if test $GLIBC21 = yes; then
380   have_thread_safe_getenv=yes
381 fi
382 if test $have_thread_safe_getenv = yes; then
383   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
384 fi
385 have_getenv_r=no
386 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
387 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
388   AC_MSG_WARN([
389 ***
390 *** getenv() is not thread-safe and getenv_r() does not exist
391 ***])
392 fi
393
394 # For converting time strings to seconds since Epoch, we need the timegm
395 # function.
396 AC_CHECK_FUNCS(timegm)
397 if test "$ac_cv_func_timegm" != yes; then
398   AC_MSG_WARN([
399 ***
400 *** timegm() not available - a non-thread-safe kludge will be used
401 *** and the TZ variable might be changed at runtime.
402 ***])
403 fi
404
405 AC_CHECK_FUNCS(setlocale)
406
407 # Checking for libgpg-error.
408 have_gpg_error=no
409 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
410                   have_gpg_error=yes, have_gpg_error=no)
411 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
412           [The default error source for GPGME.])
413
414 # And for libassuan.
415 have_libassuan=no
416 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
417                   have_libassuan=yes, have_libassuan=no)
418 if test "$have_libassuan" = "yes"; then
419   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
420                      [version of the libassuan library])
421 fi
422
423
424 #
425 # Other checks
426 #
427
428 # Check for funopen
429 AC_CHECK_FUNCS(funopen)
430 if test $ac_cv_func_funopen != yes; then
431     # No funopen but we can implement that in terms of fopencookie.
432     AC_CHECK_FUNCS(fopencookie)
433     if test $ac_cv_func_fopencookie = yes; then
434         AC_REPLACE_FUNCS(funopen)
435     else
436         AC_MSG_WARN([
437 ***
438 *** No implementation of fopencookie or funopen available
439 ***])
440     fi
441 fi
442
443 # Check for getgid etc
444 AC_CHECK_FUNCS(getgid getegid)
445
446
447 # Replacement functions.
448 AC_REPLACE_FUNCS(stpcpy)
449 AC_REPLACE_FUNCS(setenv)
450
451 # Assuan check for descriptor passing.
452 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
453                 [supports_descriptor_passing=yes],
454                 [supports_descriptor_passing=no
455                  AC_MSG_WARN([
456 ***
457 *** Data structure for sending ancillary data missing.
458 *** Descriptor passing won't work.
459 ***])],[
460 #include <stdlib.h>
461 #include <stddef.h>
462 #include <stdio.h>
463 #include <sys/types.h>
464 #include <sys/socket.h>
465 #include <sys/un.h>
466 #if HAVE_SYS_UIO_H
467 #include <sys/uio.h>
468 #endif
469 #include <unistd.h>
470        ])
471
472
473 dnl There seems to be a problem with Apple and decriptor passing.
474 dnl Until we found a solution we change the default to no.
475 dnl See bug 1483.
476 case "${host}" in
477     *-apple-darwin*)
478       use_descriptor_passing=no
479       ;;
480     *)
481       use_descriptor_passing=yes
482       ;;
483 esac
484 AC_ARG_ENABLE(fd-passing,
485   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
486   use_descriptor_passing=$enableval)
487
488 if test "$supports_descriptor_passing" != "yes"; then
489   use_descriptor_passing=no
490 fi
491
492 if test "$use_descriptor_passing" = "yes"; then
493 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
494           [Defined if descriptor passing is enabled and supported])
495 fi
496
497 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
498
499
500 uiserver=no
501 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
502   uiserver=yes
503 fi
504 if test "$uiserver" != "no"; then
505   AC_DEFINE(ENABLE_UISERVER, 1,
506             [Defined if we are building with uiserver support.])
507 fi
508 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
509
510
511 # Add a few constants to help porting to W32
512 AH_VERBATIM([SEPCONSTANTS],
513 [
514 /* Separators as used in $PATH and file name.  */
515 #ifdef HAVE_DOSISH_SYSTEM
516 #define PATHSEP_C ';'
517 #define DIRSEP_C '\\'
518 #define DIRSEP_S "\\"
519 #else
520 #define PATHSEP_C ':'
521 #define DIRSEP_C '/'
522 #define DIRSEP_S "/"
523 #endif
524 ])
525
526 AH_BOTTOM([
527 /* Definition of GCC specific attributes.  */
528 #if __GNUC__ > 2
529 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
530 #else
531 # define GPGME_GCC_A_PURE
532 #endif
533
534 /* Under WindowsCE we need gpg-error's strerror macro.  */
535 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
536
537 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
538                     "Copyright (C) 2001--2013 g10 Code GmbH\n"
539 ])
540
541
542 # Substitution used for gpgme-config
543 GPGME_CONFIG_LIBS="-lgpgme"
544 GPGME_CONFIG_CFLAGS=""
545 GPGME_CONFIG_HOST="$host"
546 AC_SUBST(GPGME_CONFIG_API_VERSION)
547 AC_SUBST(GPGME_CONFIG_LIBS)
548 AC_SUBST(GPGME_CONFIG_CFLAGS)
549 AC_SUBST(GPGME_CONFIG_HOST)
550
551 # Frob'da Variables
552 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
553            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
554 AC_SUBST(LTLIBOBJS)
555
556 # Some checks for gpgme-tool
557 # Done at top: AC_CHECK_HEADER([argp.h])
558 AC_CHECK_TYPES([error_t], [],
559    [AC_DEFINE([error_t], [int],
560    [Define to a type to use for `error_t' if it is not otherwise available.])],
561    [#include <errno.h>])
562
563
564 # A substitution to set generated files in a Emacs buffer to read-only.
565 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
566 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
567 AC_SUBST(emacs_local_vars_end, ['End:'])
568
569
570 # Last check.
571 die=no
572 if test "$have_gpg_error" = "no"; then
573    die=yes
574    AC_MSG_NOTICE([[
575 ***
576 *** You need libgpg-error to build this program.
577 **  This library is for example available at
578 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
579 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
580 ***]])
581 fi
582 if test "$have_libassuan" = "no"; then
583    die=yes
584    AC_MSG_NOTICE([[
585 ***
586 *** You need libassuan to build this program.
587 *** This library is for example available at
588 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
589 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
590 ***]])
591 fi
592
593 if test "$die" = "yes"; then
594     AC_MSG_ERROR([[
595 ***
596 *** Required libraries not found. Please consult the above messages
597 *** and install them before running configure again.
598 ***]])
599 fi
600
601
602 #
603 # Create config files
604
605 AC_CONFIG_FILES(Makefile src/Makefile
606                 tests/Makefile
607                 tests/gpg/Makefile
608                 tests/gpgsm/Makefile
609                 tests/opassuan/Makefile
610                 doc/Makefile
611                 src/versioninfo.rc
612                 src/gpgme.h)
613 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
614 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
615 AC_OUTPUT
616
617 echo "
618         GPGME v${VERSION} has been configured as follows:
619
620         Revision:        mym4_revision  (mym4_revision_dec)
621         Platform:        $host
622
623         UI Server:       $uiserver
624         FD Passing:      $use_descriptor_passing
625         GPGME Pthread:   $have_pthread
626 "