Add enable-languages build option
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 # If the API is changed in an incompatible way: increment the next counter.
65 GPGME_CONFIG_API_VERSION=1
66 ##############################################
67
68 NEED_GPG_ERROR_VERSION=1.11
69 NEED_LIBASSUAN_API=2
70 NEED_LIBASSUAN_VERSION=2.0.2
71
72
73 PACKAGE=$PACKAGE_NAME
74 VERSION=$PACKAGE_VERSION
75
76 AC_CONFIG_AUX_DIR([build-aux])
77 AC_CONFIG_MACRO_DIR([m4])
78 AC_CONFIG_SRCDIR(src/gpgme.h.in)
79 AC_CONFIG_HEADER(config.h)
80 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
81 AM_MAINTAINER_MODE
82 AC_CANONICAL_HOST
83 AM_SILENT_RULES
84 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
85
86 # Enable GNU extensions on systems that have them.
87 AC_GNU_SOURCE
88
89 AH_VERBATIM([_REENTRANT],
90 [/* To allow the use of GPGME in multithreaded programs we have to use
91   special features from the library.
92   IMPORTANT: gpgme is not yet fully reentrant and you should use it
93   only from one thread.  */
94 #ifndef _REENTRANT
95 # define _REENTRANT 1
96 #endif])
97
98 AC_PROG_CC
99 AC_PROG_CXX
100
101 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
102 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
103
104 AC_SUBST(LIBGPGME_LT_CURRENT)
105 AC_SUBST(LIBGPGME_LT_AGE)
106 AC_SUBST(LIBGPGME_LT_REVISION)
107
108 AC_SUBST(PACKAGE)
109 AC_SUBST(VERSION)
110 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
111 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
112 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
113                           mym4_version_minor mym4_version_micro)
114 AC_SUBST(VERSION_NUMBER)
115
116 # Don't default to build static libs.
117 LT_PREREQ([2.2.6])
118 LT_INIT([win32-dll disable-static])
119 LT_LANG([Windows Resource])
120
121 # For now we hardcode the use of version scripts.  It would be better
122 # to write a test for this or even implement this within libtool.
123 have_ld_version_script=no
124 case "${host}" in
125     *-*-linux*)
126         have_ld_version_script=yes
127         ;;
128     *-*-gnu*)
129         have_ld_version_script=yes
130         ;;
131     *-apple-darwin*)
132         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
133         ;;
134 esac
135
136 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
137
138 GPG_DEFAULT=no
139 GPGSM_DEFAULT=no
140 GPGCONF_DEFAULT=no
141 G13_DEFAULT=no
142 component_system=None
143 have_dosish_system=no
144 have_android_system=no
145 have_w32_system=no
146 have_w64_system=no
147 build_w32_glib=no
148 build_w32_qt=no
149 available_languages="cpp cl"
150 default_languages="cpp cl"
151 case "${host}" in
152     x86_64-*mingw32*)
153         have_w64_system=yes
154         ;;
155     *-mingw32ce*)
156         have_w32ce_system=yes
157         ;;
158     *-linux-androideabi)
159         have_android_system=yes
160         ;;
161 esac
162 case "${host}" in
163     *-mingw32ce*|*-mingw32*)
164         have_dosish_system=yes
165         have_w32_system=yes
166         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
167         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
168         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
169         G13_DEFAULT='c:\\gnupg\\g13.exe'
170         #component_system='COM+'
171
172         AM_PATH_GLIB_2_0
173         AC_ARG_ENABLE(w32-glib,
174             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
175                            build_w32_glib=$enableval)
176
177         # Check disabled, because the qt-dev packages in gpg4win do
178         # not provide any support for cross compilation.
179         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
180
181         # Use it like this:
182         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
183         AC_SUBST(QT4_CORE_CFLAGS)
184         AC_SUBST(QT4_CORE_LIBS)
185         AC_ARG_ENABLE(w32-qt,
186             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
187                            build_w32_qt=$enableval)
188         ;;
189     *)
190         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
191         if test "$have_pthread" = yes; then
192           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
193         fi
194
195         # XXX: Probably use exec-prefix here?
196 #       GPG_DEFAULT='/usr/bin/gpg'
197 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
198 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
199 #       G13_DEFAULT='/usr/bin/g13'
200         ;;
201 esac
202
203 if test "$have_dosish_system" = yes; then
204    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
205              [Defined if we run on some of the PCDOS like systems
206               (DOS, Windoze. OS/2) with special properties like
207               no file modes])
208 fi
209 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
210
211 if test "$have_w32_system" = yes; then
212    AC_DEFINE(HAVE_W32_SYSTEM,1,
213              [Defined if we run on any kind of W32 API based system])
214 fi
215 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
216
217 if test "$have_w64_system" = yes; then
218    AC_DEFINE(HAVE_W64_SYSTEM,1,
219              [Defined if we run on a 64 bit W32 API based system])
220 fi
221 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
222
223 if test "$have_w32ce_system" = yes; then
224    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
225              [Defined if we run on a W32 CE API based system])
226 fi
227 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
228
229 if test "$have_android_system" = yes; then
230    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
231 fi
232 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
233
234 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
235 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
236
237 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
238
239
240 AC_ARG_ENABLE([fixed-path],
241               AC_HELP_STRING([--enable-fixed-path=PATH],
242                              [locate binaries only via this PATH]),
243               [fixed_search_path="$enableval"],
244               [fixed_search_path=""])
245 if test x$fixed_search_path != x ; then
246   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
247                     [Locate binaries only via this PATH])
248 fi
249
250 AC_ARG_ENABLE([languages],
251               AC_HELP_STRING([--enable-languages=languages],
252                              [enable only specific language bindings]),
253                              [enabled_languages=`echo $enableval | \
254                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
255                              sed 's/c++/cpp/'`],
256                              [enabled_languages="$default_languages"])
257 if test "x$enabled_languages" = "x" \
258    -o "$enabled_languages" = "no"; then
259    enabled_languages=
260 fi
261 for language in $enabled_languages; do
262     LIST_MEMBER($language, $available_languages)
263     if test "$found" = "0"; then
264        AC_MSG_ERROR([unsupported language binding specified])
265     fi
266 done
267 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
268
269 #
270 # Provide information about the build.
271 #
272 BUILD_REVISION="mym4_revision"
273 AC_SUBST(BUILD_REVISION)
274 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
275                    [GIT commit id revision used to build this package])
276
277 changequote(,)dnl
278 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
279 changequote([,])dnl
280 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
281 AC_SUBST(BUILD_FILEVERSION)
282
283 AC_ARG_ENABLE([build-timestamp],
284   AC_HELP_STRING([--enable-build-timestamp],
285                  [set an explicit build timestamp for reproducibility.
286                   (default is the current time in ISO-8601 format)]),
287      [if test "$enableval" = "yes"; then
288         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
289       else
290         BUILD_TIMESTAMP="$enableval"
291       fi],
292      [BUILD_TIMESTAMP="<none>"])
293 AC_SUBST(BUILD_TIMESTAMP)
294 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
295                    [The time this package was configured for a build])
296
297
298 #
299 # Options to disable some regression tests
300 #
301 run_gpgconf_test="yes"
302 AC_ARG_ENABLE(gpgconf-test,
303   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
304          run_gpgconf_test=$enableval)
305 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
306
307 run_gpg_test="yes"
308 AC_ARG_ENABLE(gpg-test,
309   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
310          run_gpg_test=$enableval)
311 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
312
313 run_gpgsm_test="yes"
314 AC_ARG_ENABLE(gpgsm-test,
315   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
316          run_gpgsm_test=$enableval)
317 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
318
319 run_g13_test="yes"
320 AC_ARG_ENABLE(g13-test,
321   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
322          run_g13_test=$enableval)
323 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
324
325
326 # Checks for header files.
327 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
328                        unistd.h sys/time.h sys/types.h sys/stat.h])
329
330
331 # Type checks.
332 AC_C_INLINE
333 AC_CHECK_SIZEOF(unsigned int)
334 AC_SYS_LARGEFILE
335 AC_TYPE_OFF_T
336 AC_TYPE_UINTPTR_T
337
338 # A simple compile time check in gpgme.h for GNU/Linux systems that
339 # prevents a file offset bits mismatch between gpgme and the application.
340 NEED__FILE_OFFSET_BITS=0
341 if test "$have_w32_system" != yes; then
342   case "$ac_cv_sys_file_offset_bits" in
343     "" | no | unknown) ;;
344     *)
345     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
346     ;;
347   esac
348 fi
349 AC_SUBST(NEED__FILE_OFFSET_BITS)
350
351 # Figure out platform dependent typedefs for gpgme.h
352 if test "$have_w32_system" = yes; then
353     INSERT__TYPEDEFS_FOR_GPGME_H="
354 #ifdef _WIN64
355 # include <stdint.h>
356   typedef int64_t gpgme_off_t;
357   typedef int64_t gpgme_ssize_t;
358 #else /* _WIN32 */
359   typedef long gpgme_off_t;
360   typedef long gpgme_ssize_t;
361 #endif /* _WIN32 */"
362     API__OFF_T="gpgme_off_t"
363     API__SSIZE_T="gpgme_ssize_t"
364 else
365     INSERT__TYPEDEFS_FOR_GPGME_H="
366 #include <sys/types.h>
367 typedef off_t   gpgme_off_t;
368 typedef ssize_t gpgme_ssize_t;"
369     API__OFF_T="off_t"
370     API__SSIZE_T="ssize_t"
371 fi
372 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
373 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
374 AC_SUBST(API__OFF_T)
375 AM_SUBST_NOTMAKE(API__OFF_T)
376 AC_SUBST(API__SSIZE_T)
377 AM_SUBST_NOTMAKE(API__SSIZE_T)
378
379 # Checks for compiler features.
380 if test "$GCC" = yes; then
381     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
382     if test "$have_w32_system" = yes; then
383        CFLAGS="$CFLAGS -mms-bitfields"
384     fi
385 fi
386
387 # Only used for debugging, so no serious test needed (for actual
388 # functionality you have to test libc as well, this only tests the
389 # compiler).
390 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
391    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
392                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
393 if test "$gpgme_cv_tls_works" = yes; then
394   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
395 fi
396
397
398 # Checks for library functions.
399 AC_MSG_NOTICE([checking for libraries])
400
401 AC_FUNC_FSEEKO
402
403 AC_REPLACE_FUNCS(vasprintf)
404 if test "$ac_cv_func_vasprintf" != yes; then
405   GNUPG_CHECK_VA_COPY
406 fi
407
408 # Try to find a thread-safe version of ttyname().
409 gnupg_REPLACE_TTYNAME_R
410 if test "$ac_cv_func_ttyname_r" != yes; then
411   AC_MSG_WARN([
412 ***
413 *** ttyname() is not thread-safe and ttyname_r() does not exist
414 ***])
415 fi
416
417 # Try to find a thread-safe version of getenv().
418 have_thread_safe_getenv=no
419 jm_GLIBC21
420 if test $GLIBC21 = yes; then
421   have_thread_safe_getenv=yes
422 fi
423 if test $have_thread_safe_getenv = yes; then
424   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
425 fi
426 have_getenv_r=no
427 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
428 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
429   AC_MSG_WARN([
430 ***
431 *** getenv() is not thread-safe and getenv_r() does not exist
432 ***])
433 fi
434
435 # For converting time strings to seconds since Epoch, we need the timegm
436 # function.
437 AC_CHECK_FUNCS(timegm)
438 if test "$ac_cv_func_timegm" != yes; then
439   AC_MSG_WARN([
440 ***
441 *** timegm() not available - a non-thread-safe kludge will be used
442 *** and the TZ variable might be changed at runtime.
443 ***])
444 fi
445
446 AC_CHECK_FUNCS(setlocale)
447
448 # Checking for libgpg-error.
449 have_gpg_error=no
450 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
451                   have_gpg_error=yes, have_gpg_error=no)
452 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
453           [The default error source for GPGME.])
454
455 # And for libassuan.
456 have_libassuan=no
457 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
458                   have_libassuan=yes, have_libassuan=no)
459 if test "$have_libassuan" = "yes"; then
460   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
461                      [version of the libassuan library])
462 fi
463
464
465 #
466 # Other checks
467 #
468
469 # Check for funopen
470 AC_CHECK_FUNCS(funopen)
471 if test $ac_cv_func_funopen != yes; then
472     # No funopen but we can implement that in terms of fopencookie.
473     AC_CHECK_FUNCS(fopencookie)
474     if test $ac_cv_func_fopencookie = yes; then
475         AC_REPLACE_FUNCS(funopen)
476     else
477         AC_MSG_WARN([
478 ***
479 *** No implementation of fopencookie or funopen available
480 ***])
481     fi
482 fi
483
484 # Check for getgid etc
485 AC_CHECK_FUNCS(getgid getegid)
486
487
488 # Replacement functions.
489 AC_REPLACE_FUNCS(stpcpy)
490 AC_REPLACE_FUNCS(setenv)
491
492 # Assuan check for descriptor passing.
493 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
494                 [supports_descriptor_passing=yes],
495                 [supports_descriptor_passing=no
496                  AC_MSG_WARN([
497 ***
498 *** Data structure for sending ancillary data missing.
499 *** Descriptor passing won't work.
500 ***])],[
501 #include <stdlib.h>
502 #include <stddef.h>
503 #include <stdio.h>
504 #include <sys/types.h>
505 #include <sys/socket.h>
506 #include <sys/un.h>
507 #if HAVE_SYS_UIO_H
508 #include <sys/uio.h>
509 #endif
510 #include <unistd.h>
511        ])
512
513
514 dnl There seems to be a problem with Apple and decriptor passing.
515 dnl Until we found a solution we change the default to no.
516 dnl See bug 1483.
517 case "${host}" in
518     *-apple-darwin*)
519       use_descriptor_passing=no
520       ;;
521     *)
522       use_descriptor_passing=yes
523       ;;
524 esac
525 AC_ARG_ENABLE(fd-passing,
526   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
527   use_descriptor_passing=$enableval)
528
529 if test "$supports_descriptor_passing" != "yes"; then
530   use_descriptor_passing=no
531 fi
532
533 if test "$use_descriptor_passing" = "yes"; then
534 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
535           [Defined if descriptor passing is enabled and supported])
536 fi
537
538 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
539
540
541 uiserver=no
542 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
543   uiserver=yes
544 fi
545 if test "$uiserver" != "no"; then
546   AC_DEFINE(ENABLE_UISERVER, 1,
547             [Defined if we are building with uiserver support.])
548 fi
549 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
550
551
552 # Add a few constants to help porting to W32
553 AH_VERBATIM([SEPCONSTANTS],
554 [
555 /* Separators as used in $PATH and file name.  */
556 #ifdef HAVE_DOSISH_SYSTEM
557 #define PATHSEP_C ';'
558 #define DIRSEP_C '\\'
559 #define DIRSEP_S "\\"
560 #else
561 #define PATHSEP_C ':'
562 #define DIRSEP_C '/'
563 #define DIRSEP_S "/"
564 #endif
565 ])
566
567 AH_BOTTOM([
568 /* Definition of GCC specific attributes.  */
569 #if __GNUC__ > 2
570 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
571 #else
572 # define GPGME_GCC_A_PURE
573 #endif
574
575 /* Under WindowsCE we need gpg-error's strerror macro.  */
576 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
577
578 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
579                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
580 ])
581
582
583 # Substitution used for gpgme-config
584 GPGME_CONFIG_LIBS="-lgpgme"
585 GPGME_CONFIG_CFLAGS=""
586 GPGME_CONFIG_HOST="$host"
587 AC_SUBST(GPGME_CONFIG_API_VERSION)
588 AC_SUBST(GPGME_CONFIG_LIBS)
589 AC_SUBST(GPGME_CONFIG_CFLAGS)
590 AC_SUBST(GPGME_CONFIG_HOST)
591
592 # Frob'da Variables
593 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
594            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
595 AC_SUBST(LTLIBOBJS)
596
597 # Some checks for gpgme-tool
598 # Done at top: AC_CHECK_HEADER([argp.h])
599 AC_CHECK_TYPES([error_t], [],
600    [AC_DEFINE([error_t], [int],
601    [Define to a type to use for `error_t' if it is not otherwise available.])],
602    [#include <errno.h>])
603
604
605 # A substitution to set generated files in a Emacs buffer to read-only.
606 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
607 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
608 AC_SUBST(emacs_local_vars_end, ['End:'])
609
610
611 # Last check.
612 die=no
613 if test "$have_gpg_error" = "no"; then
614    die=yes
615    AC_MSG_NOTICE([[
616 ***
617 *** You need libgpg-error to build this program.
618 **  This library is for example available at
619 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
620 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
621 ***]])
622 fi
623 if test "$have_libassuan" = "no"; then
624    die=yes
625    AC_MSG_NOTICE([[
626 ***
627 *** You need libassuan to build this program.
628 *** This library is for example available at
629 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
630 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
631 ***]])
632 fi
633
634 if test "$die" = "yes"; then
635     AC_MSG_ERROR([[
636 ***
637 *** Required libraries not found. Please consult the above messages
638 *** and install them before running configure again.
639 ***]])
640 fi
641
642
643 #
644 # Create config files
645
646 AC_CONFIG_FILES(Makefile src/Makefile
647                 tests/Makefile
648                 tests/gpg/Makefile
649                 tests/gpgsm/Makefile
650                 tests/opassuan/Makefile
651                 doc/Makefile
652                 src/versioninfo.rc
653                 src/gpgme.h)
654 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
655 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
656 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
657 AC_OUTPUT
658
659 echo "
660         GPGME v${VERSION} has been configured as follows:
661
662         Revision:          mym4_revision  (mym4_revision_dec)
663         Platform:          $host
664
665         UI Server:         $uiserver
666         FD Passing:        $use_descriptor_passing
667         GPGME Pthread:     $have_pthread
668
669         Language bindings: $enabled_languages
670 "
671 if test "x${gpg_config_script_warn}" != x; then
672 cat <<G10EOF
673         Mismatches between the target platform and the to
674         be used libraries have been been detected for:
675          ${gpg_config_script_warn}
676         Please check above for warning messages.
677
678 G10EOF
679 fi