doc: Get rid of version.texi
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [7])
32 m4_define(mym4_version_micro, [0])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=6
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=1
67
68 LIBQGPGME_LT_CURRENT=6
69 LIBQGPGME_LT_AGE=0
70 LIBQGPGME_LT_REVISION=1
71
72 # If the API is changed in an incompatible way: increment the next counter.
73 GPGME_CONFIG_API_VERSION=1
74 ##############################################
75
76 NEED_GPG_ERROR_VERSION=1.11
77 NEED_LIBASSUAN_API=2
78 NEED_LIBASSUAN_VERSION=2.0.2
79
80
81 PACKAGE=$PACKAGE_NAME
82 VERSION=$PACKAGE_VERSION
83
84 AC_CONFIG_AUX_DIR([build-aux])
85 AC_CONFIG_MACRO_DIR([m4])
86 AC_CONFIG_SRCDIR(src/gpgme.h.in)
87 AC_CONFIG_HEADER(config.h)
88 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
89 AM_MAINTAINER_MODE
90 AC_CANONICAL_HOST
91 AM_SILENT_RULES
92 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
93
94 # Enable GNU extensions on systems that have them.
95 AC_GNU_SOURCE
96
97 AH_VERBATIM([_REENTRANT],
98 [/* To allow the use of GPGME in multithreaded programs we have to use
99   special features from the library.
100   IMPORTANT: gpgme is not yet fully reentrant and you should use it
101   only from one thread.  */
102 #ifndef _REENTRANT
103 # define _REENTRANT 1
104 #endif])
105
106 AC_PROG_CC
107 AC_PROG_CXX
108
109 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
110 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
111
112 AC_SUBST(LIBGPGME_LT_CURRENT)
113 AC_SUBST(LIBGPGME_LT_AGE)
114 AC_SUBST(LIBGPGME_LT_REVISION)
115 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
116 AC_SUBST(LIBGPGMEPP_LT_AGE)
117 AC_SUBST(LIBGPGMEPP_LT_REVISION)
118 AC_SUBST(LIBQGPGME_LT_CURRENT)
119 AC_SUBST(LIBQGPGME_LT_AGE)
120 AC_SUBST(LIBQGPGME_LT_REVISION)
121
122 AC_SUBST(PACKAGE)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
126 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
127                           mym4_version_minor mym4_version_micro)
128 AC_SUBST(VERSION_NUMBER)
129
130 # We need to compile and run a program on the build machine.  A
131 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
132 # the AC archive is broken for autoconf 2.57.  Given that there is no
133 # newer version of that macro, we assume that it is also broken for
134 # autoconf 2.61 and thus we use a simple but usually sufficient
135 # approach.
136 AC_MSG_CHECKING(for cc for build)
137 if test "$cross_compiling" = "yes"; then
138   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
139 else
140   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
141 fi
142 AC_MSG_RESULT($CC_FOR_BUILD)
143 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
144
145
146 # Don't default to build static libs.
147 LT_PREREQ([2.2.6])
148 LT_INIT([win32-dll disable-static])
149 LT_LANG([Windows Resource])
150
151 # For now we hardcode the use of version scripts.  It would be better
152 # to write a test for this or even implement this within libtool.
153 have_ld_version_script=no
154 case "${host}" in
155     *-*-linux*)
156         have_ld_version_script=yes
157         ;;
158     *-*-gnu*)
159         have_ld_version_script=yes
160         ;;
161     *-apple-darwin*)
162         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
163         ;;
164 esac
165
166 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
167
168 GPG_DEFAULT=no
169 GPGSM_DEFAULT=no
170 GPGCONF_DEFAULT=no
171 G13_DEFAULT=no
172 component_system=None
173 have_dosish_system=no
174 have_android_system=no
175 have_w32_system=no
176 have_w64_system=no
177 build_w32_glib=no
178 build_w32_qt=no
179 available_languages="cl cpp python qt"
180 default_languages="cl cpp python qt"
181 case "${host}" in
182     x86_64-*mingw32*)
183         have_w64_system=yes
184         ;;
185     *-mingw32ce*)
186         have_w32ce_system=yes
187         ;;
188     *-linux-androideabi)
189         have_android_system=yes
190         ;;
191 esac
192 case "${host}" in
193     *-mingw32ce*|*-mingw32*)
194         have_dosish_system=yes
195         have_w32_system=yes
196         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
197         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
198         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
199         G13_DEFAULT='c:\\gnupg\\g13.exe'
200         #component_system='COM+'
201
202         AM_PATH_GLIB_2_0
203         AC_ARG_ENABLE(w32-glib,
204             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
205                            build_w32_glib=$enableval)
206        ;;
207     *)
208
209         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
210         if test "$have_pthread" = yes; then
211           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
212         fi
213
214         # XXX: Probably use exec-prefix here?
215 #       GPG_DEFAULT='/usr/bin/gpg'
216 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
217 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
218 #       G13_DEFAULT='/usr/bin/g13'
219         ;;
220 esac
221
222 if test "$have_dosish_system" = yes; then
223    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
224              [Defined if we run on some of the PCDOS like systems
225               (DOS, Windoze. OS/2) with special properties like
226               no file modes])
227 fi
228 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
229
230 if test "$have_w32_system" = yes; then
231    AC_DEFINE(HAVE_W32_SYSTEM,1,
232              [Defined if we run on any kind of W32 API based system])
233 fi
234 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
235
236 if test "$have_w64_system" = yes; then
237    AC_DEFINE(HAVE_W64_SYSTEM,1,
238              [Defined if we run on a 64 bit W32 API based system])
239 fi
240 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
241
242 if test "$have_w32ce_system" = yes; then
243    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
244              [Defined if we run on a W32 CE API based system])
245 fi
246 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
247
248 if test "$have_android_system" = yes; then
249    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
250 fi
251 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
252
253 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
254
255 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
256
257
258 AC_ARG_ENABLE([fixed-path],
259               AC_HELP_STRING([--enable-fixed-path=PATH],
260                              [locate binaries only via this PATH]),
261               [fixed_search_path="$enableval"],
262               [fixed_search_path=""])
263 if test x$fixed_search_path != x ; then
264   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
265                     [Locate binaries only via this PATH])
266 fi
267
268
269 # Note: You need to declare all possible langauges also in
270 #       lang/Makefile.am's DIST_SUBDIRS.
271 AC_ARG_ENABLE([languages],
272               AC_HELP_STRING([--enable-languages=languages],
273                              [enable only specific language bindings]),
274                              [enabled_languages=`echo $enableval | \
275                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
276                              sed 's/c++/cpp/'`],
277                              [enabled_languages="maybe"])
278 if test "x$enabled_languages" = "x" \
279    -o "$enabled_languages" = "no"; then
280    enabled_languages=
281 fi
282
283 # If languages are explicitly set missing requirements
284 # for the languages are treated as errors otherwise
285 # there will be a warning.
286 explicit_languages=1
287 if test "x$enabled_languages" = "xmaybe"; then
288     explicit_languages=0
289     enabled_languages="$default_languages"
290 fi
291
292 for language in $enabled_languages; do
293     LIST_MEMBER($language, $available_languages)
294     if test "$found" = "0"; then
295        AC_MSG_ERROR([unsupported language binding specified])
296     fi
297 done
298
299
300
301 # Enable C++ 11 if cpp language is requested
302 LIST_MEMBER("cpp", $enabled_languages)
303 if test "$found" = "1"; then
304     AX_CXX_COMPILE_STDCXX(11, noext, optional)
305     if test "$HAVE_CXX11" != "1"; then
306         if test "$explicit_languages" = "1"; then
307             AC_MSG_ERROR([[
308 ***
309 *** A compiler with c++11 support is required for the c++ binding.
310 ***]])
311         else
312             enabled_languages=$(echo $enabled_languages | sed 's/cpp//')
313             enabled_languages=$(echo $enabled_languages | sed 's/qt//')
314             AC_MSG_WARN([[
315 ***
316 *** No c++11 support detected. C++ and Qt bindings will be disabled.
317 ***]])
318         fi
319     fi
320 fi
321
322 # Check that if qt is enabled cpp also is enabled
323 LIST_MEMBER("qt", $enabled_languages)
324 if test "$found" = "1"; then
325     # We need to ensure that in the langauge order qt comes after cpp
326     # so we remove qt first and explicitly add it as last list member.
327     enabled_languages=$(echo $enabled_languages | sed 's/qt//')
328     LIST_MEMBER("cpp", $enabled_languages)
329     if test "$found" = "0"; then
330         AC_MSG_ERROR([[
331 ***
332 *** Qt language binding depends on cpp binding.
333 ***]])
334     fi
335     FIND_QT
336     if test "$have_qt5_libs" != "yes"; then
337         if test "$explicit_languages" = "1"; then
338         AC_MSG_ERROR([[
339 ***
340 *** Qt5 (Qt5Core) is required for Qt binding.
341 ***]])
342         else
343            AC_MSG_WARN([[
344 ***
345 *** Qt5 (Qt5Core) not found Qt Binding will be disabled.
346 ***]])
347         fi
348     else
349         enabled_languages=`echo $enabled_languages qt`
350
351         AC_CHECK_PROGS([DOXYGEN], [doxygen])
352         if test -z "$DOXYGEN";
353             # This is not highlighted becase it's not really important.
354             then AC_MSG_WARN([Doxygen not found - Qt binding doc will not be built.])
355         fi
356         AC_CHECK_PROGS([GRAPHVIZ], [dot])
357         if test -z "$GRAPHVIZ";
358             then AC_MSG_WARN([Graphviz not found - Qt binding doc will not have diagrams.])
359         fi
360     fi
361 fi
362 AM_CONDITIONAL([HAVE_DOXYGEN],
363                [test -n "$DOXYGEN"])
364 if test -n "$GRAPHVIZ"; then
365     HAVE_DOT="YES"
366 else
367     HAVE_DOT="NO"
368 fi
369 AC_SUBST(HAVE_DOT)
370
371 # Python bindings.
372 LIST_MEMBER("python", $enabled_languages)
373 if test "$found" = "1"; then
374     AX_PKG_SWIG
375     if test -z "$SWIG"; then
376         if test "$explicit_languages" = "1"; then
377             AC_MSG_ERROR([[
378 ***
379 *** You need SWIG to build the Python bindings.
380 ***]])
381         else
382             enabled_languages=$(echo $enabled_languages | sed 's/python//')
383         fi
384     else
385         AM_PATH_PYTHON([3.4])
386         AX_SWIG_PYTHON
387         if test -z "$PYTHON_VERSION"; then
388            if test "$explicit_languages" = "1"; then
389               AC_MSG_ERROR([[
390 ***
391 *** Please install the python development packages.
392 ***]])
393             else
394                 enabled_languages=$(echo $enabled_languages | sed 's/python//')
395             fi
396         fi
397     fi
398 fi
399
400 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
401
402 #
403 # Provide information about the build.
404 #
405 BUILD_REVISION="mym4_revision"
406 AC_SUBST(BUILD_REVISION)
407 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
408                    [GIT commit id revision used to build this package])
409
410 changequote(,)dnl
411 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
412 changequote([,])dnl
413 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
414 AC_SUBST(BUILD_FILEVERSION)
415
416 AC_ARG_ENABLE([build-timestamp],
417   AC_HELP_STRING([--enable-build-timestamp],
418                  [set an explicit build timestamp for reproducibility.
419                   (default is the current time in ISO-8601 format)]),
420      [if test "$enableval" = "yes"; then
421         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
422       else
423         BUILD_TIMESTAMP="$enableval"
424       fi],
425      [BUILD_TIMESTAMP="<none>"])
426 AC_SUBST(BUILD_TIMESTAMP)
427 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
428                    [The time this package was configured for a build])
429
430
431 #
432 # Options to disable some regression tests
433 #
434 run_gpgconf_test="yes"
435 AC_ARG_ENABLE(gpgconf-test,
436   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
437          run_gpgconf_test=$enableval)
438 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
439
440 run_gpg_test="yes"
441 AC_ARG_ENABLE(gpg-test,
442   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
443          run_gpg_test=$enableval)
444 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
445
446 run_gpgsm_test="yes"
447 AC_ARG_ENABLE(gpgsm-test,
448   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
449          run_gpgsm_test=$enableval)
450 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
451
452 run_g13_test="yes"
453 AC_ARG_ENABLE(g13-test,
454   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
455          run_g13_test=$enableval)
456 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
457
458
459 # Checks for header files.
460 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
461                        unistd.h sys/time.h sys/types.h sys/stat.h])
462
463
464 # Type checks.
465 AC_C_INLINE
466 AC_CHECK_SIZEOF(unsigned int)
467 AC_SYS_LARGEFILE
468 AC_TYPE_OFF_T
469 AC_TYPE_UINTPTR_T
470
471 # A simple compile time check in gpgme.h for GNU/Linux systems that
472 # prevents a file offset bits mismatch between gpgme and the application.
473 NEED__FILE_OFFSET_BITS=0
474 if test "$have_w32_system" != yes; then
475   case "$ac_cv_sys_file_offset_bits" in
476     "" | no | unknown) ;;
477     *)
478     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
479     ;;
480   esac
481 fi
482 AC_SUBST(NEED__FILE_OFFSET_BITS)
483
484 # Figure out platform dependent typedefs for gpgme.h
485 if test "$have_w32_system" = yes; then
486     INSERT__TYPEDEFS_FOR_GPGME_H="
487 #ifdef _WIN64
488 # include <stdint.h>
489   typedef int64_t gpgme_off_t;
490   typedef int64_t gpgme_ssize_t;
491 #else /* _WIN32 */
492   typedef long gpgme_off_t;
493   typedef long gpgme_ssize_t;
494 #endif /* _WIN32 */"
495     API__OFF_T="gpgme_off_t"
496     API__SSIZE_T="gpgme_ssize_t"
497 else
498     INSERT__TYPEDEFS_FOR_GPGME_H="
499 #include <sys/types.h>
500 typedef off_t   gpgme_off_t;
501 typedef ssize_t gpgme_ssize_t;"
502     API__OFF_T="off_t"
503     API__SSIZE_T="ssize_t"
504 fi
505 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
506 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
507 AC_SUBST(API__OFF_T)
508 AM_SUBST_NOTMAKE(API__OFF_T)
509 AC_SUBST(API__SSIZE_T)
510 AM_SUBST_NOTMAKE(API__SSIZE_T)
511
512 # Checks for compiler features.
513 if test "$GCC" = yes; then
514     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
515     if test "$have_w32_system" = yes; then
516        CFLAGS="$CFLAGS -mms-bitfields"
517     fi
518 fi
519
520 # Only used for debugging, so no serious test needed (for actual
521 # functionality you have to test libc as well, this only tests the
522 # compiler).
523 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
524    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
525                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
526 if test "$gpgme_cv_tls_works" = yes; then
527   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
528 fi
529
530
531 # Checks for library functions.
532 AC_MSG_NOTICE([checking for libraries])
533
534 AC_FUNC_FSEEKO
535
536 AC_REPLACE_FUNCS(vasprintf)
537 if test "$ac_cv_func_vasprintf" != yes; then
538   GNUPG_CHECK_VA_COPY
539 fi
540
541 # Try to find a thread-safe version of ttyname().
542 gnupg_REPLACE_TTYNAME_R
543 if test "$ac_cv_func_ttyname_r" != yes; then
544   AC_MSG_WARN([
545 ***
546 *** ttyname() is not thread-safe and ttyname_r() does not exist
547 ***])
548 fi
549
550 # Try to find a thread-safe version of getenv().
551 have_thread_safe_getenv=no
552 jm_GLIBC21
553 if test $GLIBC21 = yes; then
554   have_thread_safe_getenv=yes
555 fi
556 if test $have_thread_safe_getenv = yes; then
557   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
558 fi
559 have_getenv_r=no
560 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
561 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
562   AC_MSG_WARN([
563 ***
564 *** getenv() is not thread-safe and getenv_r() does not exist
565 ***])
566 fi
567
568 # For converting time strings to seconds since Epoch, we need the timegm
569 # function.
570 AC_CHECK_FUNCS(timegm)
571 if test "$ac_cv_func_timegm" != yes; then
572   AC_MSG_WARN([
573 ***
574 *** timegm() not available - a non-thread-safe kludge will be used
575 *** and the TZ variable might be changed at runtime.
576 ***])
577 fi
578
579 AC_CHECK_FUNCS(setlocale)
580
581 # Checking for libgpg-error.
582 have_gpg_error=no
583 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
584                   have_gpg_error=yes, have_gpg_error=no)
585 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
586           [The default error source for GPGME.])
587
588 # And for libassuan.
589 have_libassuan=no
590 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
591                   have_libassuan=yes, have_libassuan=no)
592 if test "$have_libassuan" = "yes"; then
593   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
594                      [version of the libassuan library])
595 fi
596
597
598 #
599 # Other checks
600 #
601
602 # Check for funopen
603 AC_CHECK_FUNCS(funopen)
604 if test $ac_cv_func_funopen != yes; then
605     # No funopen but we can implement that in terms of fopencookie.
606     AC_CHECK_FUNCS(fopencookie)
607     if test $ac_cv_func_fopencookie = yes; then
608         AC_REPLACE_FUNCS(funopen)
609     else
610         AC_MSG_WARN([
611 ***
612 *** No implementation of fopencookie or funopen available
613 ***])
614     fi
615 fi
616
617 # Check for getgid etc
618 AC_CHECK_FUNCS(getgid getegid)
619
620
621 # Replacement functions.
622 AC_REPLACE_FUNCS(stpcpy)
623 AC_REPLACE_FUNCS(setenv)
624
625 # Assuan check for descriptor passing.
626 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
627                 [supports_descriptor_passing=yes],
628                 [supports_descriptor_passing=no
629                  AC_MSG_WARN([
630 ***
631 *** Data structure for sending ancillary data missing.
632 *** Descriptor passing won't work.
633 ***])],[
634 #include <stdlib.h>
635 #include <stddef.h>
636 #include <stdio.h>
637 #include <sys/types.h>
638 #include <sys/socket.h>
639 #include <sys/un.h>
640 #if HAVE_SYS_UIO_H
641 #include <sys/uio.h>
642 #endif
643 #include <unistd.h>
644        ])
645
646
647 dnl There seems to be a problem with Apple and decriptor passing.
648 dnl Until we found a solution we change the default to no.
649 dnl See bug 1483.
650 case "${host}" in
651     *-apple-darwin*)
652       use_descriptor_passing=no
653       ;;
654     *)
655       use_descriptor_passing=yes
656       ;;
657 esac
658 AC_ARG_ENABLE(fd-passing,
659   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
660   use_descriptor_passing=$enableval)
661
662 if test "$supports_descriptor_passing" != "yes"; then
663   use_descriptor_passing=no
664 fi
665
666 if test "$use_descriptor_passing" = "yes"; then
667 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
668           [Defined if descriptor passing is enabled and supported])
669 fi
670
671 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
672
673
674 uiserver=no
675 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
676   uiserver=yes
677 fi
678 if test "$uiserver" != "no"; then
679   AC_DEFINE(ENABLE_UISERVER, 1,
680             [Defined if we are building with uiserver support.])
681 fi
682 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
683
684
685 # Add a few constants to help porting to W32
686 AH_VERBATIM([SEPCONSTANTS],
687 [
688 /* Separators as used in $PATH and file name.  */
689 #ifdef HAVE_DOSISH_SYSTEM
690 #define PATHSEP_C ';'
691 #define DIRSEP_C '\\'
692 #define DIRSEP_S "\\"
693 #else
694 #define PATHSEP_C ':'
695 #define DIRSEP_C '/'
696 #define DIRSEP_S "/"
697 #endif
698 ])
699
700 AH_BOTTOM([
701 /* Definition of GCC specific attributes.  */
702 #if __GNUC__ > 2
703 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
704 #else
705 # define GPGME_GCC_A_PURE
706 #endif
707
708 /* Under WindowsCE we need gpg-error's strerror macro.  */
709 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
710
711 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
712                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
713 ])
714
715
716 # Substitution used for gpgme-config
717 GPGME_CONFIG_LIBS="-lgpgme"
718 GPGME_CONFIG_CFLAGS=""
719 GPGME_CONFIG_HOST="$host"
720 AC_SUBST(GPGME_CONFIG_API_VERSION)
721 AC_SUBST(GPGME_CONFIG_LIBS)
722 AC_SUBST(GPGME_CONFIG_CFLAGS)
723 AC_SUBST(GPGME_CONFIG_HOST)
724
725 # Frob'da Variables
726 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
727            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
728 AC_SUBST(LTLIBOBJS)
729
730 # Some checks for gpgme-tool
731 # Done at top: AC_CHECK_HEADER([argp.h])
732 AC_CHECK_TYPES([error_t], [],
733    [AC_DEFINE([error_t], [int],
734    [Define to a type to use for `error_t' if it is not otherwise available.])],
735    [#include <errno.h>])
736
737
738 # A substitution to set generated files in a Emacs buffer to read-only.
739 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
740 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
741 AC_SUBST(emacs_local_vars_end, ['End:'])
742
743 # Last check.
744 die=no
745 if test "$have_gpg_error" = "no"; then
746    die=yes
747    AC_MSG_NOTICE([[
748 ***
749 *** You need libgpg-error to build this program.
750 **  This library is for example available at
751 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
752 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
753 ***]])
754 fi
755 if test "$have_libassuan" = "no"; then
756    die=yes
757    AC_MSG_NOTICE([[
758 ***
759 *** You need libassuan to build this program.
760 *** This library is for example available at
761 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
762 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
763 ***]])
764 fi
765
766 if test "$die" = "yes"; then
767     AC_MSG_ERROR([[
768 ***
769 *** Required libraries not found. Please consult the above messages
770 *** and install them before running configure again.
771 ***]])
772 fi
773
774
775 #
776 # Create config files
777
778 AC_CONFIG_FILES(Makefile src/Makefile
779                 tests/Makefile
780                 tests/gpg/Makefile
781                 tests/gpgsm/Makefile
782                 tests/opassuan/Makefile
783                 doc/Makefile
784                 src/versioninfo.rc
785                 src/gpgme.h)
786 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
787 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
788 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
789 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
790 AC_CONFIG_FILES(lang/cpp/src/gpgmepp_version.h)
791 AC_CONFIG_FILES(lang/qt/Makefile lang/qt/src/Makefile)
792 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfig.cmake.in)
793 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfigVersion.cmake)
794 AC_CONFIG_FILES(lang/qt/tests/Makefile)
795 AC_CONFIG_FILES(lang/qt/src/qgpgme_version.h)
796 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
797 AM_COND_IF([HAVE_DOXYGEN], [AC_CONFIG_FILES([lang/qt/doc/Doxyfile])])
798 AC_CONFIG_FILES(lang/qt/doc/Makefile)
799 AC_CONFIG_FILES([lang/python/Makefile
800                  lang/python/setup.py
801                  lang/python/pyme/version.py
802                  lang/python/tests/Makefile])
803 AC_OUTPUT
804
805 echo "
806         GPGME v${VERSION} has been configured as follows:
807
808         Revision:          mym4_revision  (mym4_revision_dec)
809         Platform:          $host
810
811         UI Server:         $uiserver
812         FD Passing:        $use_descriptor_passing
813         GPGME Pthread:     $have_pthread
814
815         Language bindings: $enabled_languages
816 "
817 if test "x${gpg_config_script_warn}" != x; then
818 cat <<G10EOF
819         Mismatches between the target platform and the to
820         be used libraries have been been detected for:
821          ${gpg_config_script_warn}
822         Please check above for warning messages.
823
824 G10EOF
825 fi