2005-11-17 Marcus Brinkmann <marcus@g10code.de>
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU Lesser General Public License as
9 # published by the Free Software Foundation; either version 2.1 of the
10 # License, or (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
15 # Public License for more details.
16
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 AC_PREREQ(2.59)
24 min_automake_version="1.9.3"
25
26 # Version number: Remember to change it immediately *after* a release.
27 #                 Make sure to run  "svn up" before a "make dist".
28 AC_INIT(gpgme, 1.2.0-cvs, [bug-gpgme@gnupg.org])
29 # LT Version numbers, remember to change them just *before* a release.
30 #   (Code changed:                      REVISION++)
31 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
32 #   (Interfaces added:                  AGE++)
33 #   (Interfaces removed/changed:        AGE=0)
34 #
35 LIBGPGME_LT_CURRENT=16
36 # Subtract 2 from this value if you want to make the LFS transition an
37 # ABI break.  [Note to self: Remove this comment with the next regular break.]
38 LIBGPGME_LT_AGE=5
39 LIBGPGME_LT_REVISION=0
40
41 # If the API is changed in an incompatible way: increment the next counter.
42 GPGME_CONFIG_API_VERSION=1
43
44 NEED_GPG_VERSION=1.2.2
45 NEED_GPGSM_VERSION=1.9.6
46 ##############################################
47
48
49 PACKAGE=$PACKAGE_NAME
50 VERSION=$PACKAGE_VERSION
51
52 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
53 dnl FIXME: Enable this with autoconf 2.59.
54 dnl AC_CONFIG_MACRO_DIR(m4)
55 AM_CONFIG_HEADER(config.h)
56 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
57 AM_MAINTAINER_MODE
58 AC_CANONICAL_HOST
59
60 # Enable GNU extensions on systems that have them.
61 AC_GNU_SOURCE
62
63 AH_VERBATIM([_REENTRANT],
64 [/* To allow the use of GPGME in multithreaded programs we have to use
65   special features from the library.
66   IMPORTANT: gpgme is not yet fully reentrant and you should use it
67   only from one thread.  */
68 #ifndef _REENTRANT
69 # define _REENTRANT 1
70 #endif])
71
72 AC_PROG_CC
73
74 AC_SUBST(LIBGPGME_LT_CURRENT)
75 AC_SUBST(LIBGPGME_LT_AGE)
76 AC_SUBST(LIBGPGME_LT_REVISION)
77 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
78                                      [Min. needed GnuPG version.])
79 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
80                                        [Min. needed GPGSM version.])
81
82 AC_SUBST(PACKAGE)
83 AC_SUBST(VERSION)
84 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
85 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
86
87 # Don't default to build static libs.
88 AC_DISABLE_STATIC
89 AC_LIBTOOL_WIN32_DLL
90 AC_LIBTOOL_RC
91 AC_PROG_LIBTOOL
92
93 # For now we hardcode the use of version scripts.  It would be better
94 # to write a test for this or even implement this within libtool.
95 have_ld_version_script=no
96 case "${host}" in
97     *-*-linux*)
98         have_ld_version_script=yes
99         ;;
100     *-*-gnu*)
101         have_ld_version_script=yes
102         ;;
103 esac
104 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
105
106 GPG_DEFAULT=no
107 GPGSM_DEFAULT=no
108 component_system=None
109 have_dosish_system=no
110 have_w32_system=no
111 case "${host}" in
112     *-mingw32*)
113         # special stuff for Windoze NT
114         have_dosish_system=yes
115         have_w32_system=yes
116         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
117         # XXX Assuan is not supported in this configuration.
118         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
119         #component_system='COM+'
120         ;;
121     *)
122         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
123         if test "$have_pth" = yes; then
124           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
125         fi
126         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
127         if test "$have_pthread" = yes; then
128           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
129         fi
130
131         # XXX: Probably use exec-prefix here?
132 #       GPG_DEFAULT='/usr/bin/gpg'
133 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
134         ;;
135 esac
136
137 if test "$have_dosish_system" = yes; then
138    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
139              [Defined if we run on some of the PCDOS like systems 
140               (DOS, Windoze. OS/2) with special properties like
141               no file modes])
142 fi
143 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
144
145 if test "$have_w32_system" = yes; then
146    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
147 fi
148 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
149
150 build_w32_glib=no
151 AM_PATH_GLIB_2_0
152 AC_ARG_ENABLE(w32-glib,
153             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
154             build_w32_glib=$withval)
155 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
156
157 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
158 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
159
160
161 # Checks for header files.
162 AC_CHECK_HEADERS(sys/select.h)
163
164
165 # Type checks.
166 AC_CHECK_SIZEOF(unsigned int)
167 AC_SYS_LARGEFILE
168 AC_TYPE_OFF_T
169
170 # Checks for compiler features.
171 if test "$GCC" = yes; then
172     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
173 fi
174
175
176 # Checks for library functions.
177 AC_FUNC_FSEEKO
178
179 AC_CHECK_FUNCS(stpcpy)
180
181 AC_REPLACE_FUNCS(vasprintf)
182 if test "$ac_cv_func_vasprintf" != yes; then
183   GNUPG_CHECK_VA_COPY
184 fi
185
186 # Try to find a thread-safe version of ttyname().
187 AC_REPLACE_FUNCS(ttyname_r)
188 if test "$ac_cv_func_ttyname_r" != yes; then
189   AC_MSG_WARN([
190 ***
191 *** ttyname() is not thread-safe and ttyname_r() does not exist
192 ***])
193 fi
194
195 # Try to find a thread-safe version of getenv().
196 have_thread_safe_getenv=no
197 jm_GLIBC21
198 if test $GLIBC21 = yes; then
199   have_thread_safe_getenv=yes
200 fi
201 if test $have_thread_safe_getenv = yes; then
202   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
203 fi
204 have_getenv_r=no
205 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
206 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
207   AC_MSG_WARN([
208 ***
209 *** getenv() is not thread-safe and getenv_r() does not exist
210 ***])
211 fi
212
213 # For converting time strings to seconds since Epoch, we need the timegm
214 # function.
215 AC_CHECK_FUNCS(timegm)
216 if test "$ac_cv_func_timegm" != yes; then
217   AC_MSG_WARN([
218 ***
219 *** timegm() not available - a non-thread-safe kludge will be used
220 *** and the TZ variable might be changed at runtime.
221 ***])
222 fi
223
224 # Checking for libgpg-error.
225 AM_PATH_GPG_ERROR(0.5,, AC_MSG_ERROR([libgpg-error was not found]))
226 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
227           [The default error source for GPGME.])
228
229
230
231 # Checks for system services
232 NO_OVERRIDE=no
233 AC_ARG_WITH(gpg,
234             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
235             GPG=$withval, NO_OVERRIDE=yes)
236 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
237   GPG=
238   NO_OVERRIDE=yes
239   if test "$cross_compiling" != "yes"; then
240     AC_PATH_PROG(GPG, gpg)
241   fi
242   if test -z "$GPG"; then
243     GPG="$GPG_DEFAULT"
244   fi
245 fi
246 if test "$GPG" = no; then
247   if test "$NO_OVERRIDE" = "yes"; then
248     if test "$cross_compiling" != "yes"; then
249       AC_MSG_WARN([
250 ***
251 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
252 ***])
253     else
254       AC_MSG_ERROR([
255 ***
256 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
257 ***])
258     fi
259   fi
260 else
261   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
262   AC_SUBST(GPG)
263 fi
264 dnl Check for GnuPG version requirement.
265 GPG_VERSION=unknown
266 ok=maybe
267 if test -z "$GPG" -o "x$GPG" = "xno"; then
268   ok=no
269 else
270   if test "$cross_compiling" = "yes"; then
271     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
272     ok=no
273   else
274     if test ! -x "$GPG"; then
275       AC_MSG_WARN([GnuPG not executable, version check disabled])
276       ok=no
277     fi
278   fi
279 fi
280 if test "$ok" = "maybe"; then
281   AC_MSG_CHECKING(for GnuPG >= $NEED_GPG_VERSION)
282   req_major=`echo $NEED_GPG_VERSION | \
283              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
284   req_minor=`echo $NEED_GPG_VERSION | \
285              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
286   req_micro=`echo $NEED_GPG_VERSION | \
287              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
288   gpg_version=`$GPG --version | grep ^gpg`
289   major=`echo $gpg_version | \
290          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
291   minor=`echo $gpg_version | \
292          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
293   micro=`echo $gpg_version | \
294          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
295   GPG_VERSION=`echo $gpg_version | sed 's/^gpg (GnuPG) //'`
296
297   if test "$major" -gt "$req_major"; then
298     ok=yes
299   else
300     if test "$major" -eq "$req_major"; then
301       if test "$minor" -gt "$req_minor"; then
302         ok=yes
303       else
304         if test "$minor" -eq "$req_minor"; then
305           if test "$micro" -ge "$req_micro"; then
306             ok=yes
307           fi
308         fi
309       fi
310     fi
311   fi
312   if test "$ok" = "yes"; then
313     AC_MSG_RESULT(yes)
314   else
315     AC_MSG_RESULT(no)
316     AC_MSG_WARN([GnuPG must be at least version $NEED_GPG_VERSION])
317   fi
318 fi
319 AM_CONDITIONAL(RUN_GPG_TESTS, test "$ok" = "yes")
320 AC_SUBST(GPG_PATH)
321
322 NO_OVERRIDE=no
323 AC_ARG_WITH(gpgsm,
324             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
325             GPGSM=$withval, NO_OVERRIDE=yes)
326 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
327   GPGSM=
328   NO_OVERRIDE=yes
329   if test "$cross_compiling" != "yes"; then
330     AC_PATH_PROG(GPGSM, gpgsm)
331   fi
332   if test -z "$GPGSM"; then
333     GPGSM="$GPGSM_DEFAULT"
334   fi
335 fi
336 if test "$GPGSM" = no; then
337   if test "$NO_OVERRIDE" = "yes"; then
338     if test "$cross_compiling" != "yes"; then
339       AC_MSG_WARN([
340 ***
341 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
342 ***])
343     else
344       AC_MSG_ERROR([
345 ***
346 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
347 ***])
348     fi
349   fi
350 else
351   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
352   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
353 fi
354 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
355
356
357 dnl Check for GPGSM version requirement.
358 GPGSM_VERSION=unknown
359 ok=maybe
360 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
361   ok=no
362 else
363   if test "$cross_compiling" = "yes"; then
364     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
365     ok=no
366   else
367     if test ! -x "$GPGSM"; then
368       AC_MSG_WARN([GPGSM not executable, version check disabled])
369       ok=no
370     fi
371   fi
372 fi
373 if test "$ok" = "maybe"; then
374   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
375   req_major=`echo $NEED_GPGSM_VERSION | \
376              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
377   req_minor=`echo $NEED_GPGSM_VERSION | \
378              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
379   req_micro=`echo $NEED_GPGSM_VERSION | \
380              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
381   gpgsm_version=`$GPGSM --version | grep ^gpgsm`
382   major=`echo $gpgsm_version | \
383          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
384   minor=`echo $gpgsm_version | \
385          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
386   micro=`echo $gpgsm_version | \
387          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
388   GPGSM_VERSION=`echo $gpgsm_version | sed 's/^gpgsm (GnuPG) //'`
389
390   if test "$major" -gt "$req_major"; then
391     ok=yes
392   else
393     if test "$major" -eq "$req_major"; then
394       if test "$minor" -gt "$req_minor"; then
395         ok=yes
396       else
397         if test "$minor" -eq "$req_minor"; then
398           if test "$micro" -ge "$req_micro"; then
399             ok=yes
400           fi
401         fi
402       fi
403     fi
404   fi
405   if test "$ok" = "yes"; then
406     AC_MSG_RESULT(yes)
407   else
408     AC_MSG_RESULT(no)
409     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
410   fi
411 fi
412 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$ok" = "yes")
413
414 # FIXME: Only build if supported.
415 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
416
417
418 # The assuan code uses funopen but it will also build without it.  So
419 # test for it.  Frankly, this is not required in gpgme, but thats the
420 # way we handle it in libassuan.
421 AC_CHECK_FUNCS(funopen)
422 if test $ac_cv_func_funopen != yes; then
423     # No funopen but we can implement that in terms of fopencookie.
424     AC_CHECK_FUNCS(fopencookie)
425     if test $ac_cv_func_fopencookie = yes; then
426         AC_LIBOBJ([funopen])
427     else
428         AC_MSG_WARN([
429 ***
430 *** No implementation of fopencookie or funopen available
431 ***])
432     fi
433 fi
434
435 # More assuan replacement functions.
436 AC_REPLACE_FUNCS(isascii)
437 AC_REPLACE_FUNCS(putc_unlocked)
438 AC_REPLACE_FUNCS(memrchr)
439
440 # More assuan checks.
441 AC_CHECK_HEADERS([sys/uio.h])
442
443 # End of assuan checks.
444
445 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
446
447 # Make the version number in gpgme/gpgme.h the same as the one here.
448 # (this is easier than to have a *.in file just for one substitution)
449 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
450
451 # Generate values for the DLL version info
452 if test "$have_w32_system" = yes; then
453     BUILD_TIMESTAMP=`date --iso-8601=minutes`
454     changequote(,)dnl 
455     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
456     tmp="`echo '$Revision$' | sed 's/[^0-9]//g'`"
457     changequote([,])dnl
458     test -z "$tmp" && tmp="0"
459     BUILD_FILEVERSION="${BUILD_FILEVERSION}$tmp"
460 fi
461 AC_SUBST(BUILD_TIMESTAMP)
462 AC_SUBST(BUILD_FILEVERSION)
463
464 # Add a few constants to help porting to W32
465 AH_VERBATIM([SEPCONSTANTS],
466 [
467 /* Separators as used in file names and $PATH. Please note that the
468    string version must not contain more than one character because
469    the using code assumes strlen()==1 */
470 #ifdef HAVE_DOSISH_SYSTEM
471 #define DIRSEP_C '\\\\'
472 #define EXTSEP_C '.'
473 #define DIRSEP_S "\\\\"
474 #define EXTSEP_S "."
475 #define PATHSEP_C ';'
476 #define PATHSEP_S ";"
477 #else
478 #define DIRSEP_C '/'
479 #define EXTSEP_C '.'
480 #define DIRSEP_S "/"
481 #define EXTSEP_S "."
482 #define PATHSEP_C ':'
483 #define PATHSEP_S ":"
484 #endif
485 ])
486
487
488 # Substitution used for gpgme-config 
489 GPGME_CONFIG_LIBS="-lgpgme"
490 GPGME_CONFIG_CFLAGS=""
491 AC_SUBST(GPGME_CONFIG_API_VERSION)
492 AC_SUBST(GPGME_CONFIG_LIBS)
493 AC_SUBST(GPGME_CONFIG_CFLAGS)
494
495 # Frob'da Variables
496 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
497            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
498 AC_SUBST(LTLIBOBJS)
499
500 #
501 # Create config files 
502
503 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
504                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
505                 doc/Makefile complus/Makefile
506                 gpgme/versioninfo.rc)
507 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
508 AC_OUTPUT
509
510 echo "
511         GPGME v${VERSION} has been configured as follows:
512
513         GnuPG path:    $GPG
514         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
515
516         GpgSM path:    $GPGSM
517         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
518
519         GPGME Pthread: $have_pthread
520         GPGME Pth:     $have_pth
521 "