Release 1.5.4.
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [5])
32 m4_define(mym4_version_micro, [4])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=24
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=13
62 LIBGPGME_LT_REVISION=3
63
64 # If the API is changed in an incompatible way: increment the next counter.
65 GPGME_CONFIG_API_VERSION=1
66 ##############################################
67
68 NEED_GPG_ERROR_VERSION=1.11
69 NEED_LIBASSUAN_API=2
70 NEED_LIBASSUAN_VERSION=2.0.2
71
72
73 PACKAGE=$PACKAGE_NAME
74 VERSION=$PACKAGE_VERSION
75
76 AC_CONFIG_AUX_DIR([build-aux])
77 AC_CONFIG_MACRO_DIR([m4])
78 AC_CONFIG_SRCDIR(src/gpgme.h.in)
79 AC_CONFIG_HEADER(config.h)
80 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
81 AM_MAINTAINER_MODE
82 AC_CANONICAL_HOST
83 AM_SILENT_RULES
84 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
85
86 # Enable GNU extensions on systems that have them.
87 AC_GNU_SOURCE
88
89 AH_VERBATIM([_REENTRANT],
90 [/* To allow the use of GPGME in multithreaded programs we have to use
91   special features from the library.
92   IMPORTANT: gpgme is not yet fully reentrant and you should use it
93   only from one thread.  */
94 #ifndef _REENTRANT
95 # define _REENTRANT 1
96 #endif])
97
98 AC_PROG_CC
99 AC_PROG_CXX
100
101 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
102 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
103
104 AC_SUBST(LIBGPGME_LT_CURRENT)
105 AC_SUBST(LIBGPGME_LT_AGE)
106 AC_SUBST(LIBGPGME_LT_REVISION)
107
108 AC_SUBST(PACKAGE)
109 AC_SUBST(VERSION)
110 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
111 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
112 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
113                           mym4_version_minor mym4_version_micro)
114 AC_SUBST(VERSION_NUMBER)
115
116 # Don't default to build static libs.
117 LT_PREREQ([2.2.6])
118 LT_INIT([win32-dll disable-static])
119 LT_LANG([Windows Resource])
120
121 # For now we hardcode the use of version scripts.  It would be better
122 # to write a test for this or even implement this within libtool.
123 have_ld_version_script=no
124 case "${host}" in
125     *-*-linux*)
126         have_ld_version_script=yes
127         ;;
128     *-*-gnu*)
129         have_ld_version_script=yes
130         ;;
131     *-apple-darwin*)
132         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
133         ;;
134 esac
135
136 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
137
138 GPG_DEFAULT=no
139 GPGSM_DEFAULT=no
140 GPGCONF_DEFAULT=no
141 G13_DEFAULT=no
142 component_system=None
143 have_dosish_system=no
144 have_android_system=no
145 have_w32_system=no
146 have_w64_system=no
147 build_w32_glib=no
148 build_w32_qt=no
149 case "${host}" in
150     x86_64-*mingw32*)
151         have_w64_system=yes
152         ;;
153     *-mingw32ce*)
154         have_w32ce_system=yes
155         ;;
156     *-linux-androideabi)
157         have_android_system=yes
158         ;;
159 esac
160 case "${host}" in
161     *-mingw32ce*|*-mingw32*)
162         have_dosish_system=yes
163         have_w32_system=yes
164         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
165         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
166         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
167         G13_DEFAULT='c:\\gnupg\\g13.exe'
168         #component_system='COM+'
169
170         AM_PATH_GLIB_2_0
171         AC_ARG_ENABLE(w32-glib,
172             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
173                            build_w32_glib=$enableval)
174
175         # Check disabled, because the qt-dev packages in gpg4win do
176         # not provide any support for cross compilation.
177         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
178
179         # Use it like this:
180         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
181         AC_SUBST(QT4_CORE_CFLAGS)
182         AC_SUBST(QT4_CORE_LIBS)
183         AC_ARG_ENABLE(w32-qt,
184             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
185                            build_w32_qt=$enableval)
186         ;;
187     *)
188         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
189         if test "$have_pthread" = yes; then
190           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
191         fi
192
193         # XXX: Probably use exec-prefix here?
194 #       GPG_DEFAULT='/usr/bin/gpg'
195 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
196 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
197 #       G13_DEFAULT='/usr/bin/g13'
198         ;;
199 esac
200
201 if test "$have_dosish_system" = yes; then
202    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
203              [Defined if we run on some of the PCDOS like systems
204               (DOS, Windoze. OS/2) with special properties like
205               no file modes])
206 fi
207 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
208
209 if test "$have_w32_system" = yes; then
210    AC_DEFINE(HAVE_W32_SYSTEM,1,
211              [Defined if we run on any kind of W32 API based system])
212 fi
213 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
214
215 if test "$have_w64_system" = yes; then
216    AC_DEFINE(HAVE_W64_SYSTEM,1,
217              [Defined if we run on a 64 bit W32 API based system])
218 fi
219 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
220
221 if test "$have_w32ce_system" = yes; then
222    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
223              [Defined if we run on a W32 CE API based system])
224 fi
225 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
226
227 if test "$have_android_system" = yes; then
228    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
229 fi
230 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
231
232 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
233 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
234
235 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
236
237
238 AC_ARG_ENABLE([fixed-path],
239               AC_HELP_STRING([--enable-fixed-path=PATH],
240                              [locate binaries only via this PATH]),
241               [fixed_search_path="$enableval"],
242               [fixed_search_path=""])
243 if test x$fixed_search_path != x ; then
244   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
245                     [Locate binaries only via this PATH])
246 fi
247
248
249 #
250 # Provide information about the build.
251 #
252 BUILD_REVISION="mym4_revision"
253 AC_SUBST(BUILD_REVISION)
254 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
255                    [GIT commit id revision used to build this package])
256
257 changequote(,)dnl
258 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
259 changequote([,])dnl
260 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
261 AC_SUBST(BUILD_FILEVERSION)
262
263 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
264 AC_SUBST(BUILD_TIMESTAMP)
265 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
266                    [The time this package was configured for a build])
267
268 #
269 # Options to disable some regression tests
270 #
271 run_gpgconf_test="yes"
272 AC_ARG_ENABLE(gpgconf-test,
273   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
274          run_gpgconf_test=$enableval)
275 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
276
277 run_gpg_test="yes"
278 AC_ARG_ENABLE(gpg-test,
279   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
280          run_gpg_test=$enableval)
281 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
282
283 run_gpgsm_test="yes"
284 AC_ARG_ENABLE(gpgsm-test,
285   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
286          run_gpgsm_test=$enableval)
287 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
288
289 run_g13_test="yes"
290 AC_ARG_ENABLE(g13-test,
291   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
292          run_g13_test=$enableval)
293 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
294
295
296 # Checks for header files.
297 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
298                        unistd.h sys/time.h sys/types.h sys/stat.h])
299
300
301 # Type checks.
302 AC_C_INLINE
303 AC_CHECK_SIZEOF(unsigned int)
304 AC_SYS_LARGEFILE
305 AC_TYPE_OFF_T
306 AC_TYPE_UINTPTR_T
307
308 # A simple compile time check in gpgme.h for GNU/Linux systems that
309 # prevents a file offset bits mismatch between gpgme and the application.
310 NEED__FILE_OFFSET_BITS=0
311 if test "$have_w32_system" != yes; then
312   case "$ac_cv_sys_file_offset_bits" in
313     "" | no | unknown) ;;
314     *)
315     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
316     ;;
317   esac
318 fi
319 AC_SUBST(NEED__FILE_OFFSET_BITS)
320
321 # Figure out platform dependent typedefs for gpgme.h
322 if test "$have_w32_system" = yes; then
323     INSERT__TYPEDEFS_FOR_GPGME_H="
324 #ifdef _WIN64
325 # include <stdint.h>
326   typedef int64_t gpgme_off_t;
327   typedef int64_t gpgme_ssize_t;
328 #else /* _WIN32 */
329   typedef long gpgme_off_t;
330   typedef long gpgme_ssize_t;
331 #endif /* _WIN32 */"
332     API__OFF_T="gpgme_off_t"
333     API__SSIZE_T="gpgme_ssize_t"
334 else
335     INSERT__TYPEDEFS_FOR_GPGME_H="
336 #include <sys/types.h>
337 typedef off_t   gpgme_off_t;
338 typedef ssize_t gpgme_ssize_t;"
339     API__OFF_T="off_t"
340     API__SSIZE_T="ssize_t"
341 fi
342 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
343 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
344 AC_SUBST(API__OFF_T)
345 AM_SUBST_NOTMAKE(API__OFF_T)
346 AC_SUBST(API__SSIZE_T)
347 AM_SUBST_NOTMAKE(API__SSIZE_T)
348
349 # Checks for compiler features.
350 if test "$GCC" = yes; then
351     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
352     if test "$have_w32_system" = yes; then
353        CFLAGS="$CFLAGS -mms-bitfields"
354     fi
355 fi
356
357 # Only used for debugging, so no serious test needed (for actual
358 # functionality you have to test libc as well, this only tests the
359 # compiler).
360 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
361    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
362                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
363 if test "$gpgme_cv_tls_works" = yes; then
364   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
365 fi
366
367
368 # Checks for library functions.
369 AC_MSG_NOTICE([checking for libraries])
370
371 AC_FUNC_FSEEKO
372
373 AC_REPLACE_FUNCS(vasprintf)
374 if test "$ac_cv_func_vasprintf" != yes; then
375   GNUPG_CHECK_VA_COPY
376 fi
377
378 # Try to find a thread-safe version of ttyname().
379 gnupg_REPLACE_TTYNAME_R
380 if test "$ac_cv_func_ttyname_r" != yes; then
381   AC_MSG_WARN([
382 ***
383 *** ttyname() is not thread-safe and ttyname_r() does not exist
384 ***])
385 fi
386
387 # Try to find a thread-safe version of getenv().
388 have_thread_safe_getenv=no
389 jm_GLIBC21
390 if test $GLIBC21 = yes; then
391   have_thread_safe_getenv=yes
392 fi
393 if test $have_thread_safe_getenv = yes; then
394   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
395 fi
396 have_getenv_r=no
397 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
398 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
399   AC_MSG_WARN([
400 ***
401 *** getenv() is not thread-safe and getenv_r() does not exist
402 ***])
403 fi
404
405 # For converting time strings to seconds since Epoch, we need the timegm
406 # function.
407 AC_CHECK_FUNCS(timegm)
408 if test "$ac_cv_func_timegm" != yes; then
409   AC_MSG_WARN([
410 ***
411 *** timegm() not available - a non-thread-safe kludge will be used
412 *** and the TZ variable might be changed at runtime.
413 ***])
414 fi
415
416 AC_CHECK_FUNCS(setlocale)
417
418 # Checking for libgpg-error.
419 have_gpg_error=no
420 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
421                   have_gpg_error=yes, have_gpg_error=no)
422 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
423           [The default error source for GPGME.])
424
425 # And for libassuan.
426 have_libassuan=no
427 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
428                   have_libassuan=yes, have_libassuan=no)
429 if test "$have_libassuan" = "yes"; then
430   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
431                      [version of the libassuan library])
432 fi
433
434
435 #
436 # Other checks
437 #
438
439 # Check for funopen
440 AC_CHECK_FUNCS(funopen)
441 if test $ac_cv_func_funopen != yes; then
442     # No funopen but we can implement that in terms of fopencookie.
443     AC_CHECK_FUNCS(fopencookie)
444     if test $ac_cv_func_fopencookie = yes; then
445         AC_REPLACE_FUNCS(funopen)
446     else
447         AC_MSG_WARN([
448 ***
449 *** No implementation of fopencookie or funopen available
450 ***])
451     fi
452 fi
453
454 # Check for getgid etc
455 AC_CHECK_FUNCS(getgid getegid)
456
457
458 # Replacement functions.
459 AC_REPLACE_FUNCS(stpcpy)
460 AC_REPLACE_FUNCS(setenv)
461
462 # Assuan check for descriptor passing.
463 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
464                 [supports_descriptor_passing=yes],
465                 [supports_descriptor_passing=no
466                  AC_MSG_WARN([
467 ***
468 *** Data structure for sending ancillary data missing.
469 *** Descriptor passing won't work.
470 ***])],[
471 #include <stdlib.h>
472 #include <stddef.h>
473 #include <stdio.h>
474 #include <sys/types.h>
475 #include <sys/socket.h>
476 #include <sys/un.h>
477 #if HAVE_SYS_UIO_H
478 #include <sys/uio.h>
479 #endif
480 #include <unistd.h>
481        ])
482
483
484 dnl There seems to be a problem with Apple and decriptor passing.
485 dnl Until we found a solution we change the default to no.
486 dnl See bug 1483.
487 case "${host}" in
488     *-apple-darwin*)
489       use_descriptor_passing=no
490       ;;
491     *)
492       use_descriptor_passing=yes
493       ;;
494 esac
495 AC_ARG_ENABLE(fd-passing,
496   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
497   use_descriptor_passing=$enableval)
498
499 if test "$supports_descriptor_passing" != "yes"; then
500   use_descriptor_passing=no
501 fi
502
503 if test "$use_descriptor_passing" = "yes"; then
504 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
505           [Defined if descriptor passing is enabled and supported])
506 fi
507
508 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
509
510
511 uiserver=no
512 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
513   uiserver=yes
514 fi
515 if test "$uiserver" != "no"; then
516   AC_DEFINE(ENABLE_UISERVER, 1,
517             [Defined if we are building with uiserver support.])
518 fi
519 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
520
521
522 # Add a few constants to help porting to W32
523 AH_VERBATIM([SEPCONSTANTS],
524 [
525 /* Separators as used in $PATH and file name.  */
526 #ifdef HAVE_DOSISH_SYSTEM
527 #define PATHSEP_C ';'
528 #define DIRSEP_C '\\'
529 #define DIRSEP_S "\\"
530 #else
531 #define PATHSEP_C ':'
532 #define DIRSEP_C '/'
533 #define DIRSEP_S "/"
534 #endif
535 ])
536
537 AH_BOTTOM([
538 /* Definition of GCC specific attributes.  */
539 #if __GNUC__ > 2
540 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
541 #else
542 # define GPGME_GCC_A_PURE
543 #endif
544
545 /* Under WindowsCE we need gpg-error's strerror macro.  */
546 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
547
548 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
549                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
550 ])
551
552
553 # Substitution used for gpgme-config
554 GPGME_CONFIG_LIBS="-lgpgme"
555 GPGME_CONFIG_CFLAGS=""
556 GPGME_CONFIG_HOST="$host"
557 AC_SUBST(GPGME_CONFIG_API_VERSION)
558 AC_SUBST(GPGME_CONFIG_LIBS)
559 AC_SUBST(GPGME_CONFIG_CFLAGS)
560 AC_SUBST(GPGME_CONFIG_HOST)
561
562 # Frob'da Variables
563 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
564            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
565 AC_SUBST(LTLIBOBJS)
566
567 # Some checks for gpgme-tool
568 # Done at top: AC_CHECK_HEADER([argp.h])
569 AC_CHECK_TYPES([error_t], [],
570    [AC_DEFINE([error_t], [int],
571    [Define to a type to use for `error_t' if it is not otherwise available.])],
572    [#include <errno.h>])
573
574
575 # A substitution to set generated files in a Emacs buffer to read-only.
576 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
577 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
578 AC_SUBST(emacs_local_vars_end, ['End:'])
579
580
581 # Last check.
582 die=no
583 if test "$have_gpg_error" = "no"; then
584    die=yes
585    AC_MSG_NOTICE([[
586 ***
587 *** You need libgpg-error to build this program.
588 **  This library is for example available at
589 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
590 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
591 ***]])
592 fi
593 if test "$have_libassuan" = "no"; then
594    die=yes
595    AC_MSG_NOTICE([[
596 ***
597 *** You need libassuan to build this program.
598 *** This library is for example available at
599 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
600 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
601 ***]])
602 fi
603
604 if test "$die" = "yes"; then
605     AC_MSG_ERROR([[
606 ***
607 *** Required libraries not found. Please consult the above messages
608 *** and install them before running configure again.
609 ***]])
610 fi
611
612
613 #
614 # Create config files
615
616 AC_CONFIG_FILES(Makefile src/Makefile
617                 tests/Makefile
618                 tests/gpg/Makefile
619                 tests/gpgsm/Makefile
620                 tests/opassuan/Makefile
621                 doc/Makefile
622                 src/versioninfo.rc
623                 src/gpgme.h)
624 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
625 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
626 AC_OUTPUT
627
628 echo "
629         GPGME v${VERSION} has been configured as follows:
630
631         Revision:        mym4_revision  (mym4_revision_dec)
632         Platform:        $host
633
634         UI Server:       $uiserver
635         FD Passing:      $use_descriptor_passing
636         GPGME Pthread:   $have_pthread
637 "
638 if test "x${gpg_config_script_warn}" != x; then
639 cat <<G10EOF
640         Mismatches between the target platform and the to
641         be used libraries have been been detected for:
642          ${gpg_config_script_warn}
643         Please check above for warning messages.
644
645 G10EOF
646 fi