Fixes for building without gpgsm and for W32
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU Lesser General Public License as
9 # published by the Free Software Foundation; either version 2.1 of the
10 # License, or (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
15 # Public License for more details.
16
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Make sure to run  "svn up" before a "make dist".
27 #                 See below for the LT versions.
28 #
29 # The CVS version is usually the next intended release version with
30 # the string "-cvs" appended.  The reason for this is that tests for a
31 # specific feature can already be done under the assumption that the
32 # CVS version is the most recent one in a branch.  To disable the CVS
33 # version for the real release, just comment out the my_iscvs macro.
34 # Note, that we are now using Subversion instead of CVS and append the
35 # SVN revision number to the "cvs" suffix.  To make this most useful
36 # for snapshot releases please do an "svn up" right before recreating
37 # the configure script, so that a proper revision number for all files
38 # is available when running a "make distcheck".
39 m4_define(my_version, [1.1.3])
40 m4_define(my_iscvs, yes)
41 AC_INIT([gpgme], my_version[]m4_ifdef([my_iscvs], [-cvs[]m4_translit(
42                [$Revision$],[Ra-z $:])]),
43                [bug-gpgme@gnupg.org])
44
45 # LT Version numbers, remember to change them just *before* a release.
46 #   (Code changed:                      REVISION++)
47 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
48 #   (Interfaces added:                  AGE++)
49 #   (Interfaces removed/changed:        AGE=0)
50 #
51 LIBGPGME_LT_CURRENT=17
52 # Subtract 2 from this value if you want to make the LFS transition an
53 # ABI break.  [Note to self: Remove this comment with the next regular break.]
54 LIBGPGME_LT_AGE=6
55 LIBGPGME_LT_REVISION=1
56
57 # If the API is changed in an incompatible way: increment the next counter.
58 GPGME_CONFIG_API_VERSION=1
59 ##############################################
60
61
62 PACKAGE=$PACKAGE_NAME
63 VERSION=$PACKAGE_VERSION
64
65 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
66 dnl FIXME: Enable this with autoconf 2.59.
67 dnl AC_CONFIG_MACRO_DIR(m4)
68 AM_CONFIG_HEADER(config.h)
69 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
70 AM_MAINTAINER_MODE
71 AC_CANONICAL_HOST
72
73 # Enable GNU extensions on systems that have them.
74 AC_GNU_SOURCE
75
76 AH_VERBATIM([_REENTRANT],
77 [/* To allow the use of GPGME in multithreaded programs we have to use
78   special features from the library.
79   IMPORTANT: gpgme is not yet fully reentrant and you should use it
80   only from one thread.  */
81 #ifndef _REENTRANT
82 # define _REENTRANT 1
83 #endif])
84
85 AC_PROG_CC
86
87 AC_SUBST(LIBGPGME_LT_CURRENT)
88 AC_SUBST(LIBGPGME_LT_AGE)
89 AC_SUBST(LIBGPGME_LT_REVISION)
90 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
91                                      [Min. needed GnuPG version.])
92 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
93                                        [Min. needed GPGSM version.])
94
95 AC_SUBST(PACKAGE)
96 AC_SUBST(VERSION)
97 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
98 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
99
100 # Don't default to build static libs.
101 AC_DISABLE_STATIC
102 AC_LIBTOOL_WIN32_DLL
103 AC_LIBTOOL_RC
104 AC_PROG_LIBTOOL
105
106 # For now we hardcode the use of version scripts.  It would be better
107 # to write a test for this or even implement this within libtool.
108 have_ld_version_script=no
109 case "${host}" in
110     *-*-linux*)
111         have_ld_version_script=yes
112         ;;
113     *-*-gnu*)
114         have_ld_version_script=yes
115         ;;
116 esac
117 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
118
119 GPG_DEFAULT=no
120 GPGSM_DEFAULT=no
121 component_system=None
122 have_dosish_system=no
123 have_w32_system=no
124 case "${host}" in
125     *-mingw32*)
126         # special stuff for Windoze NT
127         have_dosish_system=yes
128         have_w32_system=yes
129         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
130         # XXX Assuan is not supported in this configuration.
131         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
132         #component_system='COM+'
133         ;;
134     *)
135         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
136         if test "$have_pth" = yes; then
137           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
138         fi
139         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
140         if test "$have_pthread" = yes; then
141           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
142         fi
143
144         # XXX: Probably use exec-prefix here?
145 #       GPG_DEFAULT='/usr/bin/gpg'
146 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
147         ;;
148 esac
149
150 if test "$have_dosish_system" = yes; then
151    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
152              [Defined if we run on some of the PCDOS like systems 
153               (DOS, Windoze. OS/2) with special properties like
154               no file modes])
155 fi
156 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
157
158 if test "$have_w32_system" = yes; then
159    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
160 fi
161 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
162
163 build_w32_glib=no
164 AM_PATH_GLIB_2_0
165 AC_ARG_ENABLE(w32-glib,
166             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
167             build_w32_glib=$withval)
168 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
169
170 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
171 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
172
173
174 # Checks for header files.
175 AC_CHECK_HEADERS(sys/select.h)
176
177
178 # Type checks.
179 AC_C_INLINE
180 AC_CHECK_SIZEOF(unsigned int)
181 AC_SYS_LARGEFILE
182 AC_TYPE_OFF_T
183
184 # Checks for compiler features.
185 if test "$GCC" = yes; then
186     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
187     if test "$have_w32_system" = yes; then
188        CFLAGS="$CFLAGS -mms-bitfields"
189     fi
190 fi
191
192 # Network library fun.
193 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
194         [NETLIBS="-lnsl $NETLIBS"]))
195 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
196         [NETLIBS="-lsocket $NETLIBS"]))
197 AC_SUBST(NETLIBS)
198
199 # Checks for library functions.
200 AC_FUNC_FSEEKO
201
202 AC_REPLACE_FUNCS(vasprintf)
203 if test "$ac_cv_func_vasprintf" != yes; then
204   GNUPG_CHECK_VA_COPY
205 fi
206
207 # Try to find a thread-safe version of ttyname().
208 AC_REPLACE_FUNCS(ttyname_r)
209 if test "$ac_cv_func_ttyname_r" != yes; then
210   AC_MSG_WARN([
211 ***
212 *** ttyname() is not thread-safe and ttyname_r() does not exist
213 ***])
214 fi
215
216 # Try to find a thread-safe version of getenv().
217 have_thread_safe_getenv=no
218 jm_GLIBC21
219 if test $GLIBC21 = yes; then
220   have_thread_safe_getenv=yes
221 fi
222 if test $have_thread_safe_getenv = yes; then
223   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
224 fi
225 have_getenv_r=no
226 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
227 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
228   AC_MSG_WARN([
229 ***
230 *** getenv() is not thread-safe and getenv_r() does not exist
231 ***])
232 fi
233
234 # For converting time strings to seconds since Epoch, we need the timegm
235 # function.
236 AC_CHECK_FUNCS(timegm)
237 if test "$ac_cv_func_timegm" != yes; then
238   AC_MSG_WARN([
239 ***
240 *** timegm() not available - a non-thread-safe kludge will be used
241 *** and the TZ variable might be changed at runtime.
242 ***])
243 fi
244
245 # Checking for libgpg-error.
246 AM_PATH_GPG_ERROR(1.4,, AC_MSG_ERROR([libgpg-error was not found]))
247 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
248           [The default error source for GPGME.])
249
250
251
252 # Checks for system services
253 NEED_GPG_VERSION_DEFAULT=1.3.0
254 NEED_GPGSM_VERSION_DEFAULT=1.9.6
255 NEED_GPG_VERSION="$NEED_GPG_VERSION_DEFAULT"
256 NEED_GPGSM_VERSION="$NEED_GPGSM_VERSION_DEFAULT"
257 AC_ARG_WITH(gpg-version,
258             AC_HELP_STRING([--with-gpg-version=VER], [require GnuPG version VER]),
259             NEED_GPG_VERSION=$withval)
260 if test "$NEED_GPG_VERSION" = "yes"; then
261   NEED_GPG_VERSION="$NEED_GPG_VERSION_DEFAULT"
262 fi
263 if test "$NEED_GPG_VERSION" = "no"; then
264   NEED_GPG_VERSION=0.0.0
265 fi
266 AC_ARG_WITH(gpgsm-version,
267             AC_HELP_STRING([--with-gpgsm-version=VER], [require GPGSM version VER]),
268             NEED_GPGSM_VERSION=$withval)
269 if test "$NEED_GPGSM_VERSION" = "yes"; then
270   NEED_GPGSM_VERSION="$NEED_GPGSM_VERSION_DEFAULT"
271 fi
272 if test "$NEED_GPGSM_VERSION" = "no"; then
273   NEED_GPGSM_VERSION=0.0.0
274 fi
275
276
277 NO_OVERRIDE=no
278 AC_ARG_WITH(gpg,
279             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
280             GPG=$withval, NO_OVERRIDE=yes)
281 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
282   GPG=
283   NO_OVERRIDE=yes
284   if test "$cross_compiling" != "yes"; then
285     AC_PATH_PROG(GPG, gpg)
286   fi
287   if test -z "$GPG"; then
288     GPG="$GPG_DEFAULT"
289   fi
290 fi
291 if test "$GPG" = no; then
292   if test "$NO_OVERRIDE" = "yes"; then
293     if test "$cross_compiling" != "yes"; then
294       AC_MSG_WARN([
295 ***
296 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
297 ***])
298     else
299       AC_MSG_ERROR([
300 ***
301 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
302 ***])
303     fi
304   fi
305 else
306   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
307   AC_SUBST(GPG)
308 fi
309 dnl Check for GnuPG version requirement.
310 GPG_VERSION=unknown
311 ok=maybe
312 if test -z "$GPG" -o "x$GPG" = "xno"; then
313   ok=no
314 else
315   if test "$cross_compiling" = "yes"; then
316     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
317     ok=no
318   else
319     if test ! -x "$GPG"; then
320       AC_MSG_WARN([GnuPG not executable, version check disabled])
321       ok=no
322     fi
323   fi
324 fi
325 if test "$ok" = "maybe"; then
326   AC_MSG_CHECKING(for GnuPG >= $NEED_GPG_VERSION)
327   req_major=`echo $NEED_GPG_VERSION | \
328              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
329   req_minor=`echo $NEED_GPG_VERSION | \
330              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
331   req_micro=`echo $NEED_GPG_VERSION | \
332              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
333   gpg_version=`$GPG --version | grep ^gpg`
334   major=`echo $gpg_version | \
335          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
336   minor=`echo $gpg_version | \
337          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
338   micro=`echo $gpg_version | \
339          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
340   GPG_VERSION=`echo $gpg_version | sed 's/^gpg (GnuPG) //'`
341
342   if test "$major" -gt "$req_major"; then
343     ok=yes
344   else
345     if test "$major" -eq "$req_major"; then
346       if test "$minor" -gt "$req_minor"; then
347         ok=yes
348       else
349         if test "$minor" -eq "$req_minor"; then
350           if test "$micro" -ge "$req_micro"; then
351             ok=yes
352           fi
353         fi
354       fi
355     fi
356   fi
357   if test "$ok" = "yes"; then
358     AC_MSG_RESULT(yes)
359   else
360     AC_MSG_RESULT(no)
361     AC_MSG_WARN([GnuPG must be at least version $NEED_GPG_VERSION])
362   fi
363 fi
364 AM_CONDITIONAL(RUN_GPG_TESTS, test "$ok" = "yes")
365 AC_SUBST(GPG_PATH)
366
367 NO_OVERRIDE=no
368 AC_ARG_WITH(gpgsm,
369             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
370             GPGSM=$withval, NO_OVERRIDE=yes)
371 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
372   GPGSM=
373   NO_OVERRIDE=yes
374   if test "$cross_compiling" != "yes"; then
375     AC_PATH_PROG(GPGSM, gpgsm)
376   fi
377   if test -z "$GPGSM"; then
378     GPGSM="$GPGSM_DEFAULT"
379   fi
380 fi
381 if test "$GPGSM" = no; then
382   if test "$NO_OVERRIDE" = "yes"; then
383     if test "$cross_compiling" != "yes"; then
384       AC_MSG_WARN([
385 ***
386 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
387 ***])
388     else
389       AC_MSG_ERROR([
390 ***
391 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
392 ***])
393     fi
394   fi
395 else
396   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
397   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
398 fi
399 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
400
401
402 dnl Check for GPGSM version requirement.
403 GPGSM_VERSION=unknown
404 ok=maybe
405 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
406   ok=no
407 else
408   if test "$cross_compiling" = "yes"; then
409     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
410     ok=no
411   else
412     if test ! -x "$GPGSM"; then
413       AC_MSG_WARN([GPGSM not executable, version check disabled])
414       ok=no
415     fi
416   fi
417 fi
418 if test "$ok" = "maybe"; then
419   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
420   req_major=`echo $NEED_GPGSM_VERSION | \
421              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
422   req_minor=`echo $NEED_GPGSM_VERSION | \
423              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
424   req_micro=`echo $NEED_GPGSM_VERSION | \
425              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
426   gpgsm_version=`$GPGSM --version | grep ^gpgsm`
427   major=`echo $gpgsm_version | \
428          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
429   minor=`echo $gpgsm_version | \
430          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
431   micro=`echo $gpgsm_version | \
432          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
433   GPGSM_VERSION=`echo $gpgsm_version | sed 's/^gpgsm (GnuPG) //'`
434
435   if test "$major" -gt "$req_major"; then
436     ok=yes
437   else
438     if test "$major" -eq "$req_major"; then
439       if test "$minor" -gt "$req_minor"; then
440         ok=yes
441       else
442         if test "$minor" -eq "$req_minor"; then
443           if test "$micro" -ge "$req_micro"; then
444             ok=yes
445           fi
446         fi
447       fi
448     fi
449   fi
450   if test "$ok" = "yes"; then
451     AC_MSG_RESULT(yes)
452   else
453     AC_MSG_RESULT(no)
454     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
455   fi
456 fi
457 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$ok" = "yes")
458
459 # FIXME: Only build if supported.
460 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
461 if test "$GPGSM" != "no"; then
462   AC_DEFINE(HAVE_ASSUAN_H, ,[Defined if we are building with assuan support.])
463 fi
464
465 # The assuan code uses funopen but it will also build without it.  So
466 # test for it.  Frankly, this is not required in gpgme, but thats the
467 # way we handle it in libassuan.
468 AC_CHECK_FUNCS(funopen)
469 if test $ac_cv_func_funopen != yes; then
470     # No funopen but we can implement that in terms of fopencookie.
471     AC_CHECK_FUNCS(fopencookie)
472     if test $ac_cv_func_fopencookie = yes; then
473         AC_LIBOBJ([funopen])
474     else
475         AC_MSG_WARN([
476 ***
477 *** No implementation of fopencookie or funopen available
478 ***])
479     fi
480 fi
481
482 # More assuan replacement functions.
483 AC_REPLACE_FUNCS(isascii)
484 AC_REPLACE_FUNCS(putc_unlocked)
485 AC_REPLACE_FUNCS(memrchr)
486 AC_REPLACE_FUNCS(stpcpy)
487 # Check for unistd.h for setenv replacement function.
488 AC_CHECK_HEADERS(unistd.h)
489 AC_REPLACE_FUNCS(setenv)
490
491 # More assuan checks.
492 AC_CHECK_HEADERS([sys/uio.h])
493
494 # Assuan check for descriptor passing.
495 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
496                 [supports_descriptor_passing=yes],
497                 [supports_descriptor_passing=no
498                  AC_MSG_WARN([
499 ***
500 *** Data structure for sending ancillary data missing.
501 *** Descriptor passing won't work.
502 ***])],[
503 #include <stdlib.h>
504 #include <stddef.h>
505 #include <stdio.h>
506 #include <sys/types.h>
507 #include <sys/socket.h>
508 #include <sys/un.h>
509 #if HAVE_SYS_UIO_H
510 #include <sys/uio.h>
511 #endif
512 #include <unistd.h>
513        ])
514
515 AC_ARG_ENABLE(fd-passing,
516   AC_HELP_STRING([--enable-fd-passing], [use FD passing if supported]),
517   use_descriptor_passing=$enableval)
518
519 if test "$supports_descriptor_passing" != "yes"; then
520   use_descriptor_passing=no
521 fi
522
523 if test "$use_descriptor_passing" = "yes"; then
524   fd_passing=1
525 else
526   fd_passing=0
527 fi
528
529 AC_DEFINE_UNQUOTED(USE_DESCRIPTOR_PASSING, $fd_passing,
530           [Defined if descriptor passing is enabled and supported])
531 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
532
533 # End of assuan checks.
534
535 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
536
537 # Make the version number in gpgme/gpgme.h the same as the one here.
538 # (this is easier than to have a *.in file just for one substitution)
539 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
540
541 # Generate values for the DLL version info
542 changequote(,)dnl 
543 BUILD_REVISION="`echo '$Revision$' | sed 's/[^0-9]//g'`"
544 changequote([,])dnl
545 test -z "$BUILD_REVISION" && BUILD_REVISION="0"
546 if test "$have_w32_system" = yes; then
547     BUILD_TIMESTAMP=`date --iso-8601=minutes`
548     changequote(,)dnl 
549     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
550     changequote([,])dnl
551     BUILD_FILEVERSION="${BUILD_FILEVERSION}${BUILD_REVISION}"
552 fi
553 AC_SUBST(BUILD_REVISION)
554 AC_SUBST(BUILD_TIMESTAMP)
555 AC_SUBST(BUILD_FILEVERSION)
556
557 # Add a few constants to help porting to W32
558 AH_VERBATIM([SEPCONSTANTS],
559 [
560 /* Separators as used in file names and $PATH. Please note that the
561    string version must not contain more than one character because
562    the using code assumes strlen()==1 */
563 #ifdef HAVE_DOSISH_SYSTEM
564 #define DIRSEP_C '\\\\'
565 #define EXTSEP_C '.'
566 #define DIRSEP_S "\\\\"
567 #define EXTSEP_S "."
568 #define PATHSEP_C ';'
569 #define PATHSEP_S ";"
570 #else
571 #define DIRSEP_C '/'
572 #define EXTSEP_C '.'
573 #define DIRSEP_S "/"
574 #define EXTSEP_S "."
575 #define PATHSEP_C ':'
576 #define PATHSEP_S ":"
577 #endif
578 ])
579
580 AH_BOTTOM([
581 /* Definition of GCC specific attributes.  */
582 #if __GNUC__ > 2 
583 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
584 #else
585 # define GPGME_GCC_A_PURE
586 #endif
587 ])
588
589
590 # Substitution used for gpgme-config 
591 GPGME_CONFIG_LIBS="-lgpgme"
592 GPGME_CONFIG_CFLAGS=""
593 AC_SUBST(GPGME_CONFIG_API_VERSION)
594 AC_SUBST(GPGME_CONFIG_LIBS)
595 AC_SUBST(GPGME_CONFIG_CFLAGS)
596
597 # Frob'da Variables
598 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
599            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
600 AC_SUBST(LTLIBOBJS)
601
602 #
603 # Create config files 
604
605 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
606                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
607                 doc/Makefile complus/Makefile
608                 gpgme/versioninfo.rc)
609 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
610 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
611 AC_OUTPUT
612
613 echo "
614         GPGME v${VERSION} has been configured as follows:
615
616         GnuPG path:    $GPG
617         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
618
619         GpgSM path:    $GPGSM
620         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
621
622         GPGME Pthread: $have_pthread
623         GPGME Pth:     $have_pth
624 "