Map public key algos returned by gpg to gpgme values.
[gpgme.git] / m4 / gpg-error.m4
1 # gpg-error.m4 - autoconf macro to detect libgpg-error.
2 # Copyright (C) 2002, 2003, 2004, 2011 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 dnl AM_PATH_GPG_ERROR([MINIMUM-VERSION,
13 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
14 dnl Test for libgpg-error and define GPG_ERROR_CFLAGS and GPG_ERROR_LIBS
15 dnl
16 AC_DEFUN([AM_PATH_GPG_ERROR],
17 [ AC_REQUIRE([AC_CANONICAL_HOST])
18   gpg_error_config_prefix=""
19   dnl --with-libgpg-error-prefix=PFX is the preferred name for this option,
20   dnl since that is consistent with how our three siblings use the directory/
21   dnl package name in --with-$dir_name-prefix=PFX.
22   AC_ARG_WITH(libgpg-error-prefix,
23               AC_HELP_STRING([--with-libgpg-error-prefix=PFX],
24                              [prefix where GPG Error is installed (optional)]),
25               [gpg_error_config_prefix="$withval"])
26
27   dnl Accept --with-gpg-error-prefix and make it work the same as
28   dnl --with-libgpg-error-prefix above, for backwards compatibility,
29   dnl but do not document this old, inconsistently-named option.
30   AC_ARG_WITH(gpg-error-prefix,,
31               [gpg_error_config_prefix="$withval"])
32
33   if test x$gpg_error_config_prefix != x ; then
34      if test x${GPG_ERROR_CONFIG+set} != xset ; then
35         GPG_ERROR_CONFIG=$gpg_error_config_prefix/bin/gpg-error-config
36      fi
37   fi
38
39   AC_PATH_TOOL(GPG_ERROR_CONFIG, gpg-error-config, no)
40   min_gpg_error_version=ifelse([$1], ,0.0,$1)
41   AC_MSG_CHECKING(for GPG Error - version >= $min_gpg_error_version)
42   ok=no
43   if test "$GPG_ERROR_CONFIG" != "no" \
44      && test -f "$GPG_ERROR_CONFIG" ; then
45     req_major=`echo $min_gpg_error_version | \
46                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
47     req_minor=`echo $min_gpg_error_version | \
48                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
49     gpg_error_config_version=`$GPG_ERROR_CONFIG $gpg_error_config_args --version`
50     major=`echo $gpg_error_config_version | \
51                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
52     minor=`echo $gpg_error_config_version | \
53                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
54     if test "$major" -gt "$req_major"; then
55         ok=yes
56     else
57         if test "$major" -eq "$req_major"; then
58             if test "$minor" -ge "$req_minor"; then
59                ok=yes
60             fi
61         fi
62     fi
63   fi
64   if test $ok = yes; then
65     GPG_ERROR_CFLAGS=`$GPG_ERROR_CONFIG $gpg_error_config_args --cflags`
66     GPG_ERROR_LIBS=`$GPG_ERROR_CONFIG $gpg_error_config_args --libs`
67     AC_MSG_RESULT([yes ($gpg_error_config_version)])
68     ifelse([$2], , :, [$2])
69     gpg_error_config_host=`$GPG_ERROR_CONFIG $gpg_error_config_args --host 2>/dev/null || echo none`
70     if test x"$gpg_error_config_host" != xnone ; then
71       if test x"$gpg_error_config_host" != x"$host" ; then
72   AC_MSG_WARN([[
73 ***
74 *** The config script $GPG_ERROR_CONFIG was
75 *** built for $gpg_error_config_host and thus may not match the
76 *** used host $host.
77 *** You may want to use the configure option --with-gpg-error-prefix
78 *** to specify a matching config script.
79 ***]])
80       fi
81     fi
82   else
83     GPG_ERROR_CFLAGS=""
84     GPG_ERROR_LIBS=""
85     AC_MSG_RESULT(no)
86     ifelse([$3], , :, [$3])
87   fi
88   AC_SUBST(GPG_ERROR_CFLAGS)
89   AC_SUBST(GPG_ERROR_LIBS)
90 ])