cpp: Add wrapper for gpgme_set_global_flag
[gpgme.git] / m4 / libassuan.m4
1 dnl Autoconf macros for libassuan
2 dnl Copyright (C) 2002, 2003, 2011 Free Software Foundation, Inc.
3 dnl
4 dnl This file is free software; as a special exception the author gives
5 dnl unlimited permission to copy and/or distribute it, with or without
6 dnl modifications, as long as this notice is preserved.
7 dnl
8 dnl This file is distributed in the hope that it will be useful, but
9 dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11 dnl SPDX-License-Identifier: FSFULLR
12
13 dnl
14 dnl Common code used for libassuan detection [internal]
15 dnl Returns ok set to yes or no.
16 dnl
17 AC_DEFUN([_AM_PATH_LIBASSUAN_COMMON],
18 [ AC_REQUIRE([AC_CANONICAL_HOST])
19   AC_ARG_WITH(libassuan-prefix,
20               AC_HELP_STRING([--with-libassuan-prefix=PFX],
21                              [prefix where LIBASSUAN is installed (optional)]),
22      libassuan_config_prefix="$withval", libassuan_config_prefix="")
23   if test x$libassuan_config_prefix != x ; then
24     if test x${LIBASSUAN_CONFIG+set} != xset ; then
25       LIBASSUAN_CONFIG=$libassuan_config_prefix/bin/libassuan-config
26     fi
27   fi
28
29   use_gpgrt_config=""
30   if test x"${LIBASSUAN_CONFIG}" = x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
31     if $GPGRT_CONFIG libassuan --exists; then
32       LIBASSUAN_CONFIG="$GPGRT_CONFIG libassuan"
33       AC_MSG_NOTICE([Use gpgrt-config as libassuan-config])
34       use_gpgrt_config=yes
35     fi
36   fi
37   if test -z "$use_gpgrt_config"; then
38     AC_PATH_PROG(LIBASSUAN_CONFIG, libassuan-config, no)
39   fi
40
41   tmp=ifelse([$1], ,1:0.9.2,$1)
42   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
43     req_libassuan_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
44     min_libassuan_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
45   else
46     req_libassuan_api=0
47     min_libassuan_version="$tmp"
48   fi
49
50   AC_MSG_CHECKING(for LIBASSUAN - version >= $min_libassuan_version)
51   ok=no
52   if test "$LIBASSUAN_CONFIG" != "no"; then
53     req_major=`echo $min_libassuan_version | \
54                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
55     req_minor=`echo $min_libassuan_version | \
56                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
57     req_micro=`echo $min_libassuan_version | \
58                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
59
60     if test -z "$use_gpgrt_config"; then
61       libassuan_config_version=`$LIBASSUAN_CONFIG --version`
62     else
63       libassuan_config_version=`$LIBASSUAN_CONFIG --modversion`
64     fi
65     major=`echo $libassuan_config_version | \
66                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
67     minor=`echo $libassuan_config_version | \
68                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
69     micro=`echo $libassuan_config_version | \
70                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
71
72     if test "$major" -gt "$req_major"; then
73         ok=yes
74     else
75         if test "$major" -eq "$req_major"; then
76             if test "$minor" -gt "$req_minor"; then
77                ok=yes
78             else
79                if test "$minor" -eq "$req_minor"; then
80                    if test "$micro" -ge "$req_micro"; then
81                      ok=yes
82                    fi
83                fi
84             fi
85         fi
86     fi
87   fi
88
89   if test $ok = yes; then
90     AC_MSG_RESULT([yes ($libassuan_config_version)])
91   else
92     AC_MSG_RESULT(no)
93   fi
94
95   if test $ok = yes; then
96     if test "$req_libassuan_api" -gt 0 ; then
97       if test -z "$use_gpgrt_config"; then
98         tmp=`$LIBASSUAN_CONFIG --api-version 2>/dev/null || echo 0`
99       else
100         tmp=`$LIBASSUAN_CONFIG --variable=api_version 2>/dev/null || echo 0`
101       fi
102       if test "$tmp" -gt 0 ; then
103         AC_MSG_CHECKING([LIBASSUAN API version])
104         if test "$req_libassuan_api" -eq "$tmp" ; then
105           AC_MSG_RESULT(okay)
106         else
107           ok=no
108           AC_MSG_RESULT([does not match.  want=$req_libassuan_api got=$tmp.])
109         fi
110       fi
111     fi
112   fi
113
114   if test $ok = yes; then
115     if test x"$host" != x ; then
116       if test -z "$use_gpgrt_config"; then
117         libassuan_config_host=`$LIBASSUAN_CONFIG --host 2>/dev/null || echo none`
118       else
119         libassuan_config_host=`$LIBASSUAN_CONFIG --variable=host 2>/dev/null || echo none`
120       fi
121       if test x"$libassuan_config_host" != xnone ; then
122         if test x"$libassuan_config_host" != x"$host" ; then
123   AC_MSG_WARN([[
124 ***
125 *** The config script "$LIBASSUAN_CONFIG" was
126 *** built for $libassuan_config_host and thus may not match the
127 *** used host $host.
128 *** You may want to use the configure option --with-libassuan-prefix
129 *** to specify a matching config script.
130 ***]])
131         fi
132       fi
133     fi
134   fi
135 ])
136
137 dnl AM_CHECK_LIBASSUAN([MINIMUM-VERSION,
138 dnl                    [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
139 dnl Test whether libassuan has at least MINIMUM-VERSION. This is
140 dnl used to test for features only available in newer versions.
141 dnl
142 AC_DEFUN([AM_CHECK_LIBASSUAN],
143 [ _AM_PATH_LIBASSUAN_COMMON($1)
144   if test $ok = yes; then
145     ifelse([$2], , :, [$2])
146   else
147     ifelse([$3], , :, [$3])
148   fi
149 ])
150
151
152
153
154 dnl AM_PATH_LIBASSUAN([MINIMUM-VERSION,
155 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
156 dnl Test for libassuan and define LIBASSUAN_CFLAGS and LIBASSUAN_LIBS
157 dnl
158 AC_DEFUN([AM_PATH_LIBASSUAN],
159 [ _AM_PATH_LIBASSUAN_COMMON($1)
160   if test $ok = yes; then
161     LIBASSUAN_CFLAGS=`$LIBASSUAN_CONFIG --cflags`
162     LIBASSUAN_LIBS=`$LIBASSUAN_CONFIG --libs`
163     ifelse([$2], , :, [$2])
164   else
165     LIBASSUAN_CFLAGS=""
166     LIBASSUAN_LIBS=""
167     ifelse([$3], , :, [$3])
168   fi
169   AC_SUBST(LIBASSUAN_CFLAGS)
170   AC_SUBST(LIBASSUAN_LIBS)
171 ])