json: Print signatures for decrypt/verify
[gpgme.git] / m4 / python.m4
1 ## ------------------------                                 -*- Autoconf -*-
2 ## Python file handling
3 ## From Andrew Dalke
4 ## Updated by James Henstridge
5 ## ------------------------
6 # Copyright (C) 1999-2017 Free Software Foundation, Inc.
7 #
8 # This file is free software; the Free Software Foundation
9 # gives unlimited permission to copy and/or distribute it,
10 # with or without modifications, as long as this notice is preserved.
11
12
13 # AM_PATH_PYTHON([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
14 # ---------------------------------------------------------------------------
15 # Adds support for distributing Python modules and packages.  To
16 # install modules, copy them to $(pythondir), using the python_PYTHON
17 # automake variable.  To install a package with the same name as the
18 # automake package, install to $(pkgpythondir), or use the
19 # pkgpython_PYTHON automake variable.
20 #
21 # The variables $(pyexecdir) and $(pkgpyexecdir) are provided as
22 # locations to install python extension modules (shared libraries).
23 # Another macro is required to find the appropriate flags to compile
24 # extension modules.
25 #
26 # If your package is configured with a different prefix to python,
27 # users will have to add the install directory to the PYTHONPATH
28 # environment variable, or create a .pth file (see the python
29 # documentation for details).
30 #
31 # If the MINIMUM-VERSION argument is passed, AM_PATH_PYTHON will
32 # cause an error if the version of python installed on the system
33 # doesn't meet the requirement.  MINIMUM-VERSION should consist of
34 # numbers and dots only.
35 AC_DEFUN([AM_PATH_PYTHON],
36  [
37   dnl Find a Python interpreter.  Python versions prior to 2.0 are not
38   dnl supported. (2.0 was released on October 16, 2000).
39   m4_define_default([_AM_PYTHON_INTERPRETER_LIST],
40 [python2 python2.7 dnl
41  python dnl
42  python3 python3.0 python3.1 python3.2 python3.3  dnl
43  python3.4 python3.5 python3.6 python3.7 python3.8])
44
45   AC_ARG_VAR([PYTHON], [the Python interpreter])
46
47   m4_if([$1],[],[
48     dnl No version check is needed.
49     # Find any Python interpreter.
50     if test -z "$PYTHON"; then
51       AC_PATH_PROGS([PYTHON], _AM_PYTHON_INTERPRETER_LIST, :)
52     fi
53     am_display_PYTHON=python
54   ], [
55     dnl A version check is needed.
56     if test -n "$PYTHON"; then
57       # If the user set $PYTHON, use it and don't search something else.
58       AC_MSG_CHECKING([whether $PYTHON version is >= $1])
59       AM_PYTHON_CHECK_VERSION([$PYTHON], [$1],
60                               [AC_MSG_RESULT([yes])],
61                               [AC_MSG_RESULT([no])
62                                AC_MSG_ERROR([Python interpreter is too old])])
63       am_display_PYTHON=$PYTHON
64     else
65       # Otherwise, try each interpreter until we find one that satisfies
66       # VERSION.
67       AC_CACHE_CHECK([for a Python interpreter with version >= $1],
68         [am_cv_pathless_PYTHON],[
69         for am_cv_pathless_PYTHON in _AM_PYTHON_INTERPRETER_LIST none; do
70           test "$am_cv_pathless_PYTHON" = none && break
71           AM_PYTHON_CHECK_VERSION([$am_cv_pathless_PYTHON], [$1], [break])
72         done])
73       # Set $PYTHON to the absolute path of $am_cv_pathless_PYTHON.
74       if test "$am_cv_pathless_PYTHON" = none; then
75         PYTHON=:
76       else
77         AC_PATH_PROG([PYTHON], [$am_cv_pathless_PYTHON])
78       fi
79       am_display_PYTHON=$am_cv_pathless_PYTHON
80     fi
81   ])
82
83   if test "$PYTHON" = :; then
84   dnl Run any user-specified action, or abort.
85     m4_default([$3], [AC_MSG_ERROR([no suitable Python interpreter found])])
86   else
87
88   dnl Query Python for its version number.  Getting [:3] seems to be
89   dnl the best way to do this; it's what "site.py" does in the standard
90   dnl library.
91
92   AC_CACHE_CHECK([for $am_display_PYTHON version], [am_cv_python_version],
93     [am_cv_python_version=`$PYTHON -c "import sys; sys.stdout.write(sys.version[[:3]])"`])
94   AC_SUBST([PYTHON_VERSION], [$am_cv_python_version])
95
96   dnl Use the values of $prefix and $exec_prefix for the corresponding
97   dnl values of PYTHON_PREFIX and PYTHON_EXEC_PREFIX.  These are made
98   dnl distinct variables so they can be overridden if need be.  However,
99   dnl general consensus is that you shouldn't need this ability.
100
101   AC_SUBST([PYTHON_PREFIX], ['${prefix}'])
102   AC_SUBST([PYTHON_EXEC_PREFIX], ['${exec_prefix}'])
103
104   dnl At times (like when building shared libraries) you may want
105   dnl to know which OS platform Python thinks this is.
106
107   AC_CACHE_CHECK([for $am_display_PYTHON platform], [am_cv_python_platform],
108     [am_cv_python_platform=`$PYTHON -c "import sys; sys.stdout.write(sys.platform)"`])
109   AC_SUBST([PYTHON_PLATFORM], [$am_cv_python_platform])
110
111   # Just factor out some code duplication.
112   am_python_setup_sysconfig="\
113 import sys
114 # Prefer sysconfig over distutils.sysconfig, for better compatibility
115 # with python 3.x.  See automake bug#10227.
116 try:
117     import sysconfig
118 except ImportError:
119     can_use_sysconfig = 0
120 else:
121     can_use_sysconfig = 1
122 # Can't use sysconfig in CPython 2.7, since it's broken in virtualenvs:
123 # <https://github.com/pypa/virtualenv/issues/118>
124 try:
125     from platform import python_implementation
126     if python_implementation() == 'CPython' and sys.version[[:3]] == '2.7':
127         can_use_sysconfig = 0
128 except ImportError:
129     pass"
130
131   dnl Set up 4 directories:
132
133   dnl pythondir -- where to install python scripts.  This is the
134   dnl   site-packages directory, not the python standard library
135   dnl   directory like in previous automake betas.  This behavior
136   dnl   is more consistent with lispdir.m4 for example.
137   dnl Query distutils for this directory.
138   AC_CACHE_CHECK([for $am_display_PYTHON script directory],
139     [am_cv_python_pythondir],
140     [if test "x$prefix" = xNONE
141      then
142        am_py_prefix=$ac_default_prefix
143      else
144        am_py_prefix=$prefix
145      fi
146      am_cv_python_pythondir=`$PYTHON -c "
147 $am_python_setup_sysconfig
148 if can_use_sysconfig:
149     sitedir = sysconfig.get_path('purelib', vars={'base':'$am_py_prefix'})
150 else:
151     from distutils import sysconfig
152     sitedir = sysconfig.get_python_lib(0, 0, prefix='$am_py_prefix')
153 sys.stdout.write(sitedir)"`
154      case $am_cv_python_pythondir in
155      $am_py_prefix*)
156        am__strip_prefix=`echo "$am_py_prefix" | sed 's|.|.|g'`
157        am_cv_python_pythondir=`echo "$am_cv_python_pythondir" | sed "s,^$am__strip_prefix,$PYTHON_PREFIX,"`
158        ;;
159      *)
160        case $am_py_prefix in
161          /usr|/System*) ;;
162          *)
163           am_cv_python_pythondir=$PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages
164           ;;
165        esac
166        ;;
167      esac
168     ])
169   AC_SUBST([pythondir], [$am_cv_python_pythondir])
170
171   dnl pkgpythondir -- $PACKAGE directory under pythondir.  Was
172   dnl   PYTHON_SITE_PACKAGE in previous betas, but this naming is
173   dnl   more consistent with the rest of automake.
174
175   AC_SUBST([pkgpythondir], [\${pythondir}/$PACKAGE])
176
177   dnl pyexecdir -- directory for installing python extension modules
178   dnl   (shared libraries)
179   dnl Query distutils for this directory.
180   AC_CACHE_CHECK([for $am_display_PYTHON extension module directory],
181     [am_cv_python_pyexecdir],
182     [if test "x$exec_prefix" = xNONE
183      then
184        am_py_exec_prefix=$am_py_prefix
185      else
186        am_py_exec_prefix=$exec_prefix
187      fi
188      am_cv_python_pyexecdir=`$PYTHON -c "
189 $am_python_setup_sysconfig
190 if can_use_sysconfig:
191     sitedir = sysconfig.get_path('platlib', vars={'platbase':'$am_py_prefix'})
192 else:
193     from distutils import sysconfig
194     sitedir = sysconfig.get_python_lib(1, 0, prefix='$am_py_prefix')
195 sys.stdout.write(sitedir)"`
196      case $am_cv_python_pyexecdir in
197      $am_py_exec_prefix*)
198        am__strip_prefix=`echo "$am_py_exec_prefix" | sed 's|.|.|g'`
199        am_cv_python_pyexecdir=`echo "$am_cv_python_pyexecdir" | sed "s,^$am__strip_prefix,$PYTHON_EXEC_PREFIX,"`
200        ;;
201      *)
202        case $am_py_exec_prefix in
203          /usr|/System*) ;;
204          *)
205            am_cv_python_pyexecdir=$PYTHON_EXEC_PREFIX/lib/python$PYTHON_VERSION/site-packages
206            ;;
207        esac
208        ;;
209      esac
210     ])
211   AC_SUBST([pyexecdir], [$am_cv_python_pyexecdir])
212
213   dnl pkgpyexecdir -- $(pyexecdir)/$(PACKAGE)
214
215   AC_SUBST([pkgpyexecdir], [\${pyexecdir}/$PACKAGE])
216
217   dnl Run any user-specified action.
218   $2
219   fi
220
221 ])
222
223
224 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
225 # ---------------------------------------------------------------------------
226 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
227 # Run ACTION-IF-FALSE otherwise.
228 # This test uses sys.hexversion instead of the string equivalent (first
229 # word of sys.version), in order to cope with versions such as 2.2c1.
230 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
231 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
232  [prog="import sys
233 # split strings by '.' and convert to numeric.  Append some zeros
234 # because we need at least 4 digits for the hex conversion.
235 # map returns an iterator in Python 3.0 and a list in 2.x
236 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
237 minverhex = 0
238 # xrange is not present in Python 3.0 and range returns an iterator
239 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
240 sys.exit(sys.hexversion < minverhex)"
241   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])