Started documentation.
[gpgol.git] / configure.ac
1 # configure.ac - for GpgOL
2 # Copyright (C) 2005, 2006, 2007 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This program is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 # Process this file with autoconf to produce a configure script.
13 AC_PREREQ(2.59)
14 min_automake_version="1.9.4"
15
16 # Remember to change the version number immediately *after* a release.
17 # Set my_issvn to "yes" for non-released code.  Remember to run an
18 # "svn up" and "autogen.sh" right before creating a distribution.
19 m4_define([my_version], [0.10.0])
20 m4_define([my_issvn], [yes])
21
22 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
23             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q;}')]))
24 AC_INIT([gpgol], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
25         [bug-gpgol@g10code.com])
26
27 NEED_GPG_ERROR_VERSION=1.4
28 NEED_GPGME_API=1
29 NEED_GPGME_VERSION=1.1.0
30 NEED_LIBASSUAN_API=1
31 NEED_LIBASSUAN_VERSION=1.0.4
32
33
34 SVN_REVISION=svn_revision
35 PACKAGE=$PACKAGE_NAME
36 PACKAGE_GT=${PACKAGE_NAME}
37 VERSION=$PACKAGE_VERSION
38
39 AC_CONFIG_SRCDIR(src/gpgol.def)
40 AM_CONFIG_HEADER(config.h)
41 AC_CANONICAL_TARGET()
42 AM_INIT_AUTOMAKE
43
44 AC_GNU_SOURCE
45
46 have_gpg_error=no
47 have_libassuan=no
48
49 AC_SUBST(PACKAGE)
50 AC_SUBST(PACKAGE_GT)
51 AC_SUBST(VERSION)
52 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
53 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
54                                 [Name of this package for gettext])
55 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
56 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
57                                         [Bug report address])
58 AC_DEFINE_UNQUOTED(NEED_GPGME_VERSION, "$NEED_GPGME_VERSION",
59                                        [Required version of GPGME])
60
61
62 BUILD_TIMESTAMP=`date --iso-8601=minutes`
63 AC_SUBST(BUILD_TIMESTAMP)
64 changequote(,)dnl
65 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
66 changequote([,])dnl
67 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
68 AC_SUBST(BUILD_FILEVERSION)
69
70
71 AH_BOTTOM([
72 /* Some global constants. */
73
74 /* Force using of NLS for W32 even if no libintl has been found.  This is 
75    okay because we have our own gettext implementation for W32.  */
76 #if defined(HAVE_W32_SYSTEM) && !defined(ENABLE_NLS)
77 #define ENABLE_NLS 1
78 #endif
79 ])
80
81 AM_MAINTAINER_MODE
82
83 # Checks for programs.
84 AC_PROG_MAKE_SET
85 AM_SANITY_CHECK
86 missing_dir=`cd $ac_aux_dir && pwd`
87 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
88 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
89 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
90 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
91 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
92 AC_PROG_AWK
93 AC_PROG_CC
94 AC_PROG_CPP
95 AC_PROG_CXX
96 AC_PROG_INSTALL
97 AC_PROG_LN_S
98 AC_PROG_MAKE_SET
99 AC_PROG_RANLIB
100 AC_CHECK_TOOL(AR, ar, :)
101 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
102 AC_CHECK_TOOL(WINDRES, windres, :)
103
104
105 have_dosish_system=no
106 have_w32_system=no
107 case "${host}" in
108     *-mingw32*)
109         # special stuff for Windoze NT
110         ac_cv_have_dev_random=no
111         AC_DEFINE(USE_ONLY_8DOT3,1,
112                   [set this to limit filenames to the 8.3 format])
113         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
114                   [defined if we must run on a stupid file system])
115         have_dosish_system=yes
116         have_w32_system=yes
117         ;;
118     *)
119     AC_MSG_ERROR([[
120 ***
121 *** This software my only be build for W32 systems.  Use
122 ***     ./autogen.sh --build-w32
123 *** to prepare it for such a build.
124 ***]])
125        ;;
126 esac
127
128 if test "$have_dosish_system" = yes; then
129    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
130              [Defined if we run on some of the PCDOS like systems
131               (DOS, Windoze. OS/2) with special properties like
132               no file modes])
133 fi
134 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
135
136 if test "$have_w32_system" = yes; then
137    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
138 fi
139 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
140
141
142
143 #
144 # Checks for libraries.
145 #
146
147
148 AM_PATH_GPGME("$NEED_GPGME_API:$NEED_GPGME_VERSION",
149                have_gpgme=yes,have_gpgme=no)
150 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
151                   have_gpg_error=yes,have_gpg_error=no)
152 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_USER_2,
153           [The default error source for GpgOL.])
154 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
155                   have_libassuan=yes,have_libassuan=no)
156
157 AH_BOTTOM([
158 /* We don't want the old assuan codes anymore. */
159 #define _ASSUAN_ONLY_GPG_ERRORS 1
160 ])
161
162
163
164 # Note, that autogen.sh greps for the next line.
165 AM_GNU_GETTEXT_VERSION(0.12.1)
166 AM_GNU_GETTEXT([external])
167 # We always want NLs, despite what the above macro figures out.
168 USE_NLS=yes
169
170 # Checks for header files.
171 AC_HEADER_STDC
172 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
173
174 AC_CHECK_FUNCS(stpcpy)
175
176 # Checks for typedefs, structures, and compiler characteristics.
177 AC_C_CONST
178 AC_C_INLINE
179 AC_TYPE_SIZE_T
180 AC_TYPE_SIGNAL
181
182 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
183
184 # Add some extra libs here so that previous tests don't fail for
185 # mysterious reasons - the final link step should bail out.
186 if test "$have_w32_system" = yes; then
187    W32LIBS="-lwsock32"
188 fi
189
190 if test "$GCC" = yes; then
191     CFLAGS="$CFLAGS -Wall -mms-bitfields"
192     CXXFLAGS="$CXXFLAGS -Wall -mms-bitfields"
193     if test "$USE_MAINTAINER_MODE" = "yes"; then
194         CFLAGS="$CFLAGS -Wcast-align -Wshadow -Wstrict-prototypes"
195         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security"
196         CXXFLAGS="$CXXFLAGS -Wcast-align -Wshadow"
197         CXXFLAGS="$CXXFLAGS -Wno-format-y2k -Wformat-security"
198     fi
199 fi
200
201 AC_SUBST(W32LIBS)
202
203
204
205 #
206 # Print errors here so that they are visible all
207 # together and the user can acquire them all together.
208 #
209 die=no
210 if test "$have_gpg_error" = "no"; then
211    die=yes
212    AC_MSG_NOTICE([[
213 ***  
214 *** You need libgpg-error to build this program.
215 **  This library is for example available at
216 ***   ftp://ftp.gnupg.org/pub/gcrypt/libgpg-error
217 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
218 ***]])
219 fi
220 if test "$have_gpgme" = "no"; then
221    die=yes
222    AC_MSG_NOTICE([[
223 ***  
224 *** You need gpgme to build this program.
225 **  This library is for example available at
226 ***   ftp://ftp.gnupg.org/gcrypt/gpgme/
227 *** (at least version $NEED_GPGME_VERSION is required.)
228 ***]])
229 fi
230 if test "$have_libassuan" = "no"; then
231    die=yes
232    AC_MSG_NOTICE([[
233 ***
234 *** You need libassuan to build this program.
235 *** This library is for example available at
236 ***   ftp://ftp.gnupg.org/pub/gcrypt/libassuan/
237 *** (at least version $NEED_LIBASSUAN_VERSION is required).
238 ***]])
239 fi
240 if test "$die" = "yes"; then
241     AC_MSG_ERROR([[
242 ***
243 *** Required libraries not found. Please consult the above messages
244 *** and install them before running configure again.
245 ***]])
246 fi
247
248
249 AC_CONFIG_FILES([ Makefile
250 src/Makefile
251 src/versioninfo.rc        
252 doc/Makefile
253 po/Makefile.in
254 m4/Makefile
255 ])
256 AC_OUTPUT