pubkey: Re-map all depreccated RSA algo numbers.
[libgcrypt.git] / cipher / camellia-aesni-avx-amd64.S
1 /* camellia-avx-aesni-amd64.S  -  AES-NI/AVX implementation of Camellia cipher
2  *
3  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
4  *
5  * This file is part of Libgcrypt.
6  *
7  * Libgcrypt is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU Lesser General Public License as
9  * published by the Free Software Foundation; either version 2.1 of
10  * the License, or (at your option) any later version.
11  *
12  * Libgcrypt is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
19  */
20
21 #ifdef __x86_64
22 #include <config.h>
23 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
24     defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)
25
26 #ifdef __PIC__
27 #  define RIP (%rip)
28 #else
29 #  define RIP
30 #endif
31
32 #define CAMELLIA_TABLE_BYTE_LEN 272
33
34 /* struct CAMELLIA_context: */
35 #define key_table 0
36 #define key_bitlength CAMELLIA_TABLE_BYTE_LEN
37
38 /* register macros */
39 #define CTX %rdi
40 #define RIO %r8
41
42 /**********************************************************************
43   helper macros
44  **********************************************************************/
45 #define filter_8bit(x, lo_t, hi_t, mask4bit, tmp0) \
46         vpand x, mask4bit, tmp0; \
47         vpandn x, mask4bit, x; \
48         vpsrld $4, x, x; \
49         \
50         vpshufb tmp0, lo_t, tmp0; \
51         vpshufb x, hi_t, x; \
52         vpxor tmp0, x, x;
53
54 /**********************************************************************
55   16-way camellia
56  **********************************************************************/
57
58 /*
59  * IN:
60  *   x0..x7: byte-sliced AB state
61  *   mem_cd: register pointer storing CD state
62  *   key: index for key material
63  * OUT:
64  *   x0..x7: new byte-sliced CD state
65  */
66 #define roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, t0, t1, t2, t3, t4, t5, t6, \
67                   t7, mem_cd, key) \
68         /* \
69          * S-function with AES subbytes \
70          */ \
71         vmovdqa .Linv_shift_row RIP, t4; \
72         vbroadcastss .L0f0f0f0f RIP, t7; \
73         vmovdqa .Lpre_tf_lo_s1 RIP, t0; \
74         vmovdqa .Lpre_tf_hi_s1 RIP, t1; \
75         \
76         /* AES inverse shift rows */ \
77         vpshufb t4, x0, x0; \
78         vpshufb t4, x7, x7; \
79         vpshufb t4, x1, x1; \
80         vpshufb t4, x4, x4; \
81         vpshufb t4, x2, x2; \
82         vpshufb t4, x5, x5; \
83         vpshufb t4, x3, x3; \
84         vpshufb t4, x6, x6; \
85         \
86         /* prefilter sboxes 1, 2 and 3 */ \
87         vmovdqa .Lpre_tf_lo_s4 RIP, t2; \
88         vmovdqa .Lpre_tf_hi_s4 RIP, t3; \
89         filter_8bit(x0, t0, t1, t7, t6); \
90         filter_8bit(x7, t0, t1, t7, t6); \
91         filter_8bit(x1, t0, t1, t7, t6); \
92         filter_8bit(x4, t0, t1, t7, t6); \
93         filter_8bit(x2, t0, t1, t7, t6); \
94         filter_8bit(x5, t0, t1, t7, t6); \
95         \
96         /* prefilter sbox 4 */ \
97         vpxor t4, t4, t4; \
98         filter_8bit(x3, t2, t3, t7, t6); \
99         filter_8bit(x6, t2, t3, t7, t6); \
100         \
101         /* AES subbytes + AES shift rows */ \
102         vmovdqa .Lpost_tf_lo_s1 RIP, t0; \
103         vmovdqa .Lpost_tf_hi_s1 RIP, t1; \
104         vaesenclast t4, x0, x0; \
105         vaesenclast t4, x7, x7; \
106         vaesenclast t4, x1, x1; \
107         vaesenclast t4, x4, x4; \
108         vaesenclast t4, x2, x2; \
109         vaesenclast t4, x5, x5; \
110         vaesenclast t4, x3, x3; \
111         vaesenclast t4, x6, x6; \
112         \
113         /* postfilter sboxes 1 and 4 */ \
114         vmovdqa .Lpost_tf_lo_s3 RIP, t2; \
115         vmovdqa .Lpost_tf_hi_s3 RIP, t3; \
116         filter_8bit(x0, t0, t1, t7, t6); \
117         filter_8bit(x7, t0, t1, t7, t6); \
118         filter_8bit(x3, t0, t1, t7, t6); \
119         filter_8bit(x6, t0, t1, t7, t6); \
120         \
121         /* postfilter sbox 3 */ \
122         vmovdqa .Lpost_tf_lo_s2 RIP, t4; \
123         vmovdqa .Lpost_tf_hi_s2 RIP, t5; \
124         filter_8bit(x2, t2, t3, t7, t6); \
125         filter_8bit(x5, t2, t3, t7, t6); \
126         \
127         vpxor t6, t6, t6; \
128         vmovq key, t0; \
129         \
130         /* postfilter sbox 2 */ \
131         filter_8bit(x1, t4, t5, t7, t2); \
132         filter_8bit(x4, t4, t5, t7, t2); \
133         \
134         vpsrldq $5, t0, t5; \
135         vpsrldq $1, t0, t1; \
136         vpsrldq $2, t0, t2; \
137         vpsrldq $3, t0, t3; \
138         vpsrldq $4, t0, t4; \
139         vpshufb t6, t0, t0; \
140         vpshufb t6, t1, t1; \
141         vpshufb t6, t2, t2; \
142         vpshufb t6, t3, t3; \
143         vpshufb t6, t4, t4; \
144         vpsrldq $2, t5, t7; \
145         vpshufb t6, t7, t7; \
146         \
147         /* P-function */ \
148         vpxor x5, x0, x0; \
149         vpxor x6, x1, x1; \
150         vpxor x7, x2, x2; \
151         vpxor x4, x3, x3; \
152         \
153         vpxor x2, x4, x4; \
154         vpxor x3, x5, x5; \
155         vpxor x0, x6, x6; \
156         vpxor x1, x7, x7; \
157         \
158         vpxor x7, x0, x0; \
159         vpxor x4, x1, x1; \
160         vpxor x5, x2, x2; \
161         vpxor x6, x3, x3; \
162         \
163         vpxor x3, x4, x4; \
164         vpxor x0, x5, x5; \
165         vpxor x1, x6, x6; \
166         vpxor x2, x7, x7; /* note: high and low parts swapped */ \
167         \
168         /* Add key material and result to CD (x becomes new CD) */ \
169         \
170         vpxor t3, x4, x4; \
171         vpxor 0 * 16(mem_cd), x4, x4; \
172         \
173         vpxor t2, x5, x5; \
174         vpxor 1 * 16(mem_cd), x5, x5; \
175         \
176         vpsrldq $1, t5, t3; \
177         vpshufb t6, t5, t5; \
178         vpshufb t6, t3, t6; \
179         \
180         vpxor t1, x6, x6; \
181         vpxor 2 * 16(mem_cd), x6, x6; \
182         \
183         vpxor t0, x7, x7; \
184         vpxor 3 * 16(mem_cd), x7, x7; \
185         \
186         vpxor t7, x0, x0; \
187         vpxor 4 * 16(mem_cd), x0, x0; \
188         \
189         vpxor t6, x1, x1; \
190         vpxor 5 * 16(mem_cd), x1, x1; \
191         \
192         vpxor t5, x2, x2; \
193         vpxor 6 * 16(mem_cd), x2, x2; \
194         \
195         vpxor t4, x3, x3; \
196         vpxor 7 * 16(mem_cd), x3, x3;
197
198 /*
199  * IN/OUT:
200  *  x0..x7: byte-sliced AB state preloaded
201  *  mem_ab: byte-sliced AB state in memory
202  *  mem_cb: byte-sliced CD state in memory
203  */
204 #define two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
205                       y6, y7, mem_ab, mem_cd, i, dir, store_ab) \
206         roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
207                   y6, y7, mem_cd, (key_table + (i) * 8)(CTX)); \
208         \
209         vmovdqu x4, 0 * 16(mem_cd); \
210         vmovdqu x5, 1 * 16(mem_cd); \
211         vmovdqu x6, 2 * 16(mem_cd); \
212         vmovdqu x7, 3 * 16(mem_cd); \
213         vmovdqu x0, 4 * 16(mem_cd); \
214         vmovdqu x1, 5 * 16(mem_cd); \
215         vmovdqu x2, 6 * 16(mem_cd); \
216         vmovdqu x3, 7 * 16(mem_cd); \
217         \
218         roundsm16(x4, x5, x6, x7, x0, x1, x2, x3, y0, y1, y2, y3, y4, y5, \
219                   y6, y7, mem_ab, (key_table + ((i) + (dir)) * 8)(CTX)); \
220         \
221         store_ab(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab);
222
223 #define dummy_store(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) /* do nothing */
224
225 #define store_ab_state(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) \
226         /* Store new AB state */ \
227         vmovdqu x0, 0 * 16(mem_ab); \
228         vmovdqu x1, 1 * 16(mem_ab); \
229         vmovdqu x2, 2 * 16(mem_ab); \
230         vmovdqu x3, 3 * 16(mem_ab); \
231         vmovdqu x4, 4 * 16(mem_ab); \
232         vmovdqu x5, 5 * 16(mem_ab); \
233         vmovdqu x6, 6 * 16(mem_ab); \
234         vmovdqu x7, 7 * 16(mem_ab);
235
236 #define enc_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
237                       y6, y7, mem_ab, mem_cd, i) \
238         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
239                       y6, y7, mem_ab, mem_cd, (i) + 2, 1, store_ab_state); \
240         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
241                       y6, y7, mem_ab, mem_cd, (i) + 4, 1, store_ab_state); \
242         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
243                       y6, y7, mem_ab, mem_cd, (i) + 6, 1, dummy_store);
244
245 #define dec_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
246                       y6, y7, mem_ab, mem_cd, i) \
247         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
248                       y6, y7, mem_ab, mem_cd, (i) + 7, -1, store_ab_state); \
249         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
250                       y6, y7, mem_ab, mem_cd, (i) + 5, -1, store_ab_state); \
251         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
252                       y6, y7, mem_ab, mem_cd, (i) + 3, -1, dummy_store);
253
254 /*
255  * IN:
256  *  v0..3: byte-sliced 32-bit integers
257  * OUT:
258  *  v0..3: (IN <<< 1)
259  */
260 #define rol32_1_16(v0, v1, v2, v3, t0, t1, t2, zero) \
261         vpcmpgtb v0, zero, t0; \
262         vpaddb v0, v0, v0; \
263         vpabsb t0, t0; \
264         \
265         vpcmpgtb v1, zero, t1; \
266         vpaddb v1, v1, v1; \
267         vpabsb t1, t1; \
268         \
269         vpcmpgtb v2, zero, t2; \
270         vpaddb v2, v2, v2; \
271         vpabsb t2, t2; \
272         \
273         vpor t0, v1, v1; \
274         \
275         vpcmpgtb v3, zero, t0; \
276         vpaddb v3, v3, v3; \
277         vpabsb t0, t0; \
278         \
279         vpor t1, v2, v2; \
280         vpor t2, v3, v3; \
281         vpor t0, v0, v0;
282
283 /*
284  * IN:
285  *   r: byte-sliced AB state in memory
286  *   l: byte-sliced CD state in memory
287  * OUT:
288  *   x0..x7: new byte-sliced CD state
289  */
290 #define fls16(l, l0, l1, l2, l3, l4, l5, l6, l7, r, t0, t1, t2, t3, tt0, \
291               tt1, tt2, tt3, kll, klr, krl, krr) \
292         /* \
293          * t0 = kll; \
294          * t0 &= ll; \
295          * lr ^= rol32(t0, 1); \
296          */ \
297         vpxor tt0, tt0, tt0; \
298         vmovd kll, t0; \
299         vpshufb tt0, t0, t3; \
300         vpsrldq $1, t0, t0; \
301         vpshufb tt0, t0, t2; \
302         vpsrldq $1, t0, t0; \
303         vpshufb tt0, t0, t1; \
304         vpsrldq $1, t0, t0; \
305         vpshufb tt0, t0, t0; \
306         \
307         vpand l0, t0, t0; \
308         vpand l1, t1, t1; \
309         vpand l2, t2, t2; \
310         vpand l3, t3, t3; \
311         \
312         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
313         \
314         vpxor l4, t0, l4; \
315         vmovdqu l4, 4 * 16(l); \
316         vpxor l5, t1, l5; \
317         vmovdqu l5, 5 * 16(l); \
318         vpxor l6, t2, l6; \
319         vmovdqu l6, 6 * 16(l); \
320         vpxor l7, t3, l7; \
321         vmovdqu l7, 7 * 16(l); \
322         \
323         /* \
324          * t2 = krr; \
325          * t2 |= rr; \
326          * rl ^= t2; \
327          */ \
328         \
329         vmovd krr, t0; \
330         vpshufb tt0, t0, t3; \
331         vpsrldq $1, t0, t0; \
332         vpshufb tt0, t0, t2; \
333         vpsrldq $1, t0, t0; \
334         vpshufb tt0, t0, t1; \
335         vpsrldq $1, t0, t0; \
336         vpshufb tt0, t0, t0; \
337         \
338         vpor 4 * 16(r), t0, t0; \
339         vpor 5 * 16(r), t1, t1; \
340         vpor 6 * 16(r), t2, t2; \
341         vpor 7 * 16(r), t3, t3; \
342         \
343         vpxor 0 * 16(r), t0, t0; \
344         vpxor 1 * 16(r), t1, t1; \
345         vpxor 2 * 16(r), t2, t2; \
346         vpxor 3 * 16(r), t3, t3; \
347         vmovdqu t0, 0 * 16(r); \
348         vmovdqu t1, 1 * 16(r); \
349         vmovdqu t2, 2 * 16(r); \
350         vmovdqu t3, 3 * 16(r); \
351         \
352         /* \
353          * t2 = krl; \
354          * t2 &= rl; \
355          * rr ^= rol32(t2, 1); \
356          */ \
357         vmovd krl, t0; \
358         vpshufb tt0, t0, t3; \
359         vpsrldq $1, t0, t0; \
360         vpshufb tt0, t0, t2; \
361         vpsrldq $1, t0, t0; \
362         vpshufb tt0, t0, t1; \
363         vpsrldq $1, t0, t0; \
364         vpshufb tt0, t0, t0; \
365         \
366         vpand 0 * 16(r), t0, t0; \
367         vpand 1 * 16(r), t1, t1; \
368         vpand 2 * 16(r), t2, t2; \
369         vpand 3 * 16(r), t3, t3; \
370         \
371         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
372         \
373         vpxor 4 * 16(r), t0, t0; \
374         vpxor 5 * 16(r), t1, t1; \
375         vpxor 6 * 16(r), t2, t2; \
376         vpxor 7 * 16(r), t3, t3; \
377         vmovdqu t0, 4 * 16(r); \
378         vmovdqu t1, 5 * 16(r); \
379         vmovdqu t2, 6 * 16(r); \
380         vmovdqu t3, 7 * 16(r); \
381         \
382         /* \
383          * t0 = klr; \
384          * t0 |= lr; \
385          * ll ^= t0; \
386          */ \
387         \
388         vmovd klr, t0; \
389         vpshufb tt0, t0, t3; \
390         vpsrldq $1, t0, t0; \
391         vpshufb tt0, t0, t2; \
392         vpsrldq $1, t0, t0; \
393         vpshufb tt0, t0, t1; \
394         vpsrldq $1, t0, t0; \
395         vpshufb tt0, t0, t0; \
396         \
397         vpor l4, t0, t0; \
398         vpor l5, t1, t1; \
399         vpor l6, t2, t2; \
400         vpor l7, t3, t3; \
401         \
402         vpxor l0, t0, l0; \
403         vmovdqu l0, 0 * 16(l); \
404         vpxor l1, t1, l1; \
405         vmovdqu l1, 1 * 16(l); \
406         vpxor l2, t2, l2; \
407         vmovdqu l2, 2 * 16(l); \
408         vpxor l3, t3, l3; \
409         vmovdqu l3, 3 * 16(l);
410
411 #define transpose_4x4(x0, x1, x2, x3, t1, t2) \
412         vpunpckhdq x1, x0, t2; \
413         vpunpckldq x1, x0, x0; \
414         \
415         vpunpckldq x3, x2, t1; \
416         vpunpckhdq x3, x2, x2; \
417         \
418         vpunpckhqdq t1, x0, x1; \
419         vpunpcklqdq t1, x0, x0; \
420         \
421         vpunpckhqdq x2, t2, x3; \
422         vpunpcklqdq x2, t2, x2;
423
424 #define byteslice_16x16b_fast(a0, b0, c0, d0, a1, b1, c1, d1, a2, b2, c2, d2, \
425                               a3, b3, c3, d3, st0, st1) \
426         vmovdqu d2, st0; \
427         vmovdqu d3, st1; \
428         transpose_4x4(a0, a1, a2, a3, d2, d3); \
429         transpose_4x4(b0, b1, b2, b3, d2, d3); \
430         vmovdqu st0, d2; \
431         vmovdqu st1, d3; \
432         \
433         vmovdqu a0, st0; \
434         vmovdqu a1, st1; \
435         transpose_4x4(c0, c1, c2, c3, a0, a1); \
436         transpose_4x4(d0, d1, d2, d3, a0, a1); \
437         \
438         vmovdqu .Lshufb_16x16b RIP, a0; \
439         vmovdqu st1, a1; \
440         vpshufb a0, a2, a2; \
441         vpshufb a0, a3, a3; \
442         vpshufb a0, b0, b0; \
443         vpshufb a0, b1, b1; \
444         vpshufb a0, b2, b2; \
445         vpshufb a0, b3, b3; \
446         vpshufb a0, a1, a1; \
447         vpshufb a0, c0, c0; \
448         vpshufb a0, c1, c1; \
449         vpshufb a0, c2, c2; \
450         vpshufb a0, c3, c3; \
451         vpshufb a0, d0, d0; \
452         vpshufb a0, d1, d1; \
453         vpshufb a0, d2, d2; \
454         vpshufb a0, d3, d3; \
455         vmovdqu d3, st1; \
456         vmovdqu st0, d3; \
457         vpshufb a0, d3, a0; \
458         vmovdqu d2, st0; \
459         \
460         transpose_4x4(a0, b0, c0, d0, d2, d3); \
461         transpose_4x4(a1, b1, c1, d1, d2, d3); \
462         vmovdqu st0, d2; \
463         vmovdqu st1, d3; \
464         \
465         vmovdqu b0, st0; \
466         vmovdqu b1, st1; \
467         transpose_4x4(a2, b2, c2, d2, b0, b1); \
468         transpose_4x4(a3, b3, c3, d3, b0, b1); \
469         vmovdqu st0, b0; \
470         vmovdqu st1, b1; \
471         /* does not adjust output bytes inside vectors */
472
473 #define transpose_8x8b(a, b, c, d, e, f, g, h, t0, t1, t2, t3, t4) \
474         vpunpcklbw a, b, t0; \
475         vpunpckhbw a, b, b; \
476         \
477         vpunpcklbw c, d, t1; \
478         vpunpckhbw c, d, d; \
479         \
480         vpunpcklbw e, f, t2; \
481         vpunpckhbw e, f, f; \
482         \
483         vpunpcklbw g, h, t3; \
484         vpunpckhbw g, h, h; \
485         \
486         vpunpcklwd t0, t1, g; \
487         vpunpckhwd t0, t1, t0; \
488         \
489         vpunpcklwd b, d, t1; \
490         vpunpckhwd b, d, e; \
491         \
492         vpunpcklwd t2, t3, c; \
493         vpunpckhwd t2, t3, t2; \
494         \
495         vpunpcklwd f, h, t3; \
496         vpunpckhwd f, h, b; \
497         \
498         vpunpcklwd e, b, t4; \
499         vpunpckhwd e, b, b; \
500         \
501         vpunpcklwd t1, t3, e; \
502         vpunpckhwd t1, t3, f; \
503         \
504         vmovdqa .Ltranspose_8x8_shuf RIP, t3; \
505         \
506         vpunpcklwd g, c, d; \
507         vpunpckhwd g, c, c; \
508         \
509         vpunpcklwd t0, t2, t1; \
510         vpunpckhwd t0, t2, h; \
511         \
512         vpunpckhqdq b, h, a; \
513         vpshufb t3, a, a; \
514         vpunpcklqdq b, h, b; \
515         vpshufb t3, b, b; \
516         \
517         vpunpckhqdq e, d, g; \
518         vpshufb t3, g, g; \
519         vpunpcklqdq e, d, h; \
520         vpshufb t3, h, h; \
521         \
522         vpunpckhqdq f, c, e; \
523         vpshufb t3, e, e; \
524         vpunpcklqdq f, c, f; \
525         vpshufb t3, f, f; \
526         \
527         vpunpckhqdq t4, t1, c; \
528         vpshufb t3, c, c; \
529         vpunpcklqdq t4, t1, d; \
530         vpshufb t3, d, d;
531
532 /* load blocks to registers and apply pre-whitening */
533 #define inpack16_pre(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
534                      y6, y7, rio, key) \
535         vmovq key, x0; \
536         vpshufb .Lpack_bswap RIP, x0, x0; \
537         \
538         vpxor 0 * 16(rio), x0, y7; \
539         vpxor 1 * 16(rio), x0, y6; \
540         vpxor 2 * 16(rio), x0, y5; \
541         vpxor 3 * 16(rio), x0, y4; \
542         vpxor 4 * 16(rio), x0, y3; \
543         vpxor 5 * 16(rio), x0, y2; \
544         vpxor 6 * 16(rio), x0, y1; \
545         vpxor 7 * 16(rio), x0, y0; \
546         vpxor 8 * 16(rio), x0, x7; \
547         vpxor 9 * 16(rio), x0, x6; \
548         vpxor 10 * 16(rio), x0, x5; \
549         vpxor 11 * 16(rio), x0, x4; \
550         vpxor 12 * 16(rio), x0, x3; \
551         vpxor 13 * 16(rio), x0, x2; \
552         vpxor 14 * 16(rio), x0, x1; \
553         vpxor 15 * 16(rio), x0, x0;
554
555 /* byteslice pre-whitened blocks and store to temporary memory */
556 #define inpack16_post(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
557                       y6, y7, mem_ab, mem_cd) \
558         byteslice_16x16b_fast(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, \
559                               y4, y5, y6, y7, (mem_ab), (mem_cd)); \
560         \
561         vmovdqu x0, 0 * 16(mem_ab); \
562         vmovdqu x1, 1 * 16(mem_ab); \
563         vmovdqu x2, 2 * 16(mem_ab); \
564         vmovdqu x3, 3 * 16(mem_ab); \
565         vmovdqu x4, 4 * 16(mem_ab); \
566         vmovdqu x5, 5 * 16(mem_ab); \
567         vmovdqu x6, 6 * 16(mem_ab); \
568         vmovdqu x7, 7 * 16(mem_ab); \
569         vmovdqu y0, 0 * 16(mem_cd); \
570         vmovdqu y1, 1 * 16(mem_cd); \
571         vmovdqu y2, 2 * 16(mem_cd); \
572         vmovdqu y3, 3 * 16(mem_cd); \
573         vmovdqu y4, 4 * 16(mem_cd); \
574         vmovdqu y5, 5 * 16(mem_cd); \
575         vmovdqu y6, 6 * 16(mem_cd); \
576         vmovdqu y7, 7 * 16(mem_cd);
577
578 /* de-byteslice, apply post-whitening and store blocks */
579 #define outunpack16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, \
580                     y5, y6, y7, key, stack_tmp0, stack_tmp1) \
581         byteslice_16x16b_fast(y0, y4, x0, x4, y1, y5, x1, x5, y2, y6, x2, x6, \
582                               y3, y7, x3, x7, stack_tmp0, stack_tmp1); \
583         \
584         vmovdqu x0, stack_tmp0; \
585         \
586         vmovq key, x0; \
587         vpshufb .Lpack_bswap RIP, x0, x0; \
588         \
589         vpxor x0, y7, y7; \
590         vpxor x0, y6, y6; \
591         vpxor x0, y5, y5; \
592         vpxor x0, y4, y4; \
593         vpxor x0, y3, y3; \
594         vpxor x0, y2, y2; \
595         vpxor x0, y1, y1; \
596         vpxor x0, y0, y0; \
597         vpxor x0, x7, x7; \
598         vpxor x0, x6, x6; \
599         vpxor x0, x5, x5; \
600         vpxor x0, x4, x4; \
601         vpxor x0, x3, x3; \
602         vpxor x0, x2, x2; \
603         vpxor x0, x1, x1; \
604         vpxor stack_tmp0, x0, x0;
605
606 #define write_output(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
607                      y6, y7, rio) \
608         vmovdqu x0, 0 * 16(rio); \
609         vmovdqu x1, 1 * 16(rio); \
610         vmovdqu x2, 2 * 16(rio); \
611         vmovdqu x3, 3 * 16(rio); \
612         vmovdqu x4, 4 * 16(rio); \
613         vmovdqu x5, 5 * 16(rio); \
614         vmovdqu x6, 6 * 16(rio); \
615         vmovdqu x7, 7 * 16(rio); \
616         vmovdqu y0, 8 * 16(rio); \
617         vmovdqu y1, 9 * 16(rio); \
618         vmovdqu y2, 10 * 16(rio); \
619         vmovdqu y3, 11 * 16(rio); \
620         vmovdqu y4, 12 * 16(rio); \
621         vmovdqu y5, 13 * 16(rio); \
622         vmovdqu y6, 14 * 16(rio); \
623         vmovdqu y7, 15 * 16(rio);
624
625 .data
626 .align 16
627
628 #define SHUFB_BYTES(idx) \
629         0 + (idx), 4 + (idx), 8 + (idx), 12 + (idx)
630
631 .Lshufb_16x16b:
632         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3);
633
634 .Lpack_bswap:
635         .long 0x00010203
636         .long 0x04050607
637         .long 0x80808080
638         .long 0x80808080
639
640 /* For CTR-mode IV byteswap */
641 .Lbswap128_mask:
642         .byte 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0
643
644 /*
645  * pre-SubByte transform
646  *
647  * pre-lookup for sbox1, sbox2, sbox3:
648  *   swap_bitendianness(
649  *       isom_map_camellia_to_aes(
650  *           camellia_f(
651  *               swap_bitendianess(in)
652  *           )
653  *       )
654  *   )
655  *
656  * (note: '⊕ 0xc5' inside camellia_f())
657  */
658 .Lpre_tf_lo_s1:
659         .byte 0x45, 0xe8, 0x40, 0xed, 0x2e, 0x83, 0x2b, 0x86
660         .byte 0x4b, 0xe6, 0x4e, 0xe3, 0x20, 0x8d, 0x25, 0x88
661 .Lpre_tf_hi_s1:
662         .byte 0x00, 0x51, 0xf1, 0xa0, 0x8a, 0xdb, 0x7b, 0x2a
663         .byte 0x09, 0x58, 0xf8, 0xa9, 0x83, 0xd2, 0x72, 0x23
664
665 /*
666  * pre-SubByte transform
667  *
668  * pre-lookup for sbox4:
669  *   swap_bitendianness(
670  *       isom_map_camellia_to_aes(
671  *           camellia_f(
672  *               swap_bitendianess(in <<< 1)
673  *           )
674  *       )
675  *   )
676  *
677  * (note: '⊕ 0xc5' inside camellia_f())
678  */
679 .Lpre_tf_lo_s4:
680         .byte 0x45, 0x40, 0x2e, 0x2b, 0x4b, 0x4e, 0x20, 0x25
681         .byte 0x14, 0x11, 0x7f, 0x7a, 0x1a, 0x1f, 0x71, 0x74
682 .Lpre_tf_hi_s4:
683         .byte 0x00, 0xf1, 0x8a, 0x7b, 0x09, 0xf8, 0x83, 0x72
684         .byte 0xad, 0x5c, 0x27, 0xd6, 0xa4, 0x55, 0x2e, 0xdf
685
686 /*
687  * post-SubByte transform
688  *
689  * post-lookup for sbox1, sbox4:
690  *  swap_bitendianness(
691  *      camellia_h(
692  *          isom_map_aes_to_camellia(
693  *              swap_bitendianness(
694  *                  aes_inverse_affine_transform(in)
695  *              )
696  *          )
697  *      )
698  *  )
699  *
700  * (note: '⊕ 0x6e' inside camellia_h())
701  */
702 .Lpost_tf_lo_s1:
703         .byte 0x3c, 0xcc, 0xcf, 0x3f, 0x32, 0xc2, 0xc1, 0x31
704         .byte 0xdc, 0x2c, 0x2f, 0xdf, 0xd2, 0x22, 0x21, 0xd1
705 .Lpost_tf_hi_s1:
706         .byte 0x00, 0xf9, 0x86, 0x7f, 0xd7, 0x2e, 0x51, 0xa8
707         .byte 0xa4, 0x5d, 0x22, 0xdb, 0x73, 0x8a, 0xf5, 0x0c
708
709 /*
710  * post-SubByte transform
711  *
712  * post-lookup for sbox2:
713  *  swap_bitendianness(
714  *      camellia_h(
715  *          isom_map_aes_to_camellia(
716  *              swap_bitendianness(
717  *                  aes_inverse_affine_transform(in)
718  *              )
719  *          )
720  *      )
721  *  ) <<< 1
722  *
723  * (note: '⊕ 0x6e' inside camellia_h())
724  */
725 .Lpost_tf_lo_s2:
726         .byte 0x78, 0x99, 0x9f, 0x7e, 0x64, 0x85, 0x83, 0x62
727         .byte 0xb9, 0x58, 0x5e, 0xbf, 0xa5, 0x44, 0x42, 0xa3
728 .Lpost_tf_hi_s2:
729         .byte 0x00, 0xf3, 0x0d, 0xfe, 0xaf, 0x5c, 0xa2, 0x51
730         .byte 0x49, 0xba, 0x44, 0xb7, 0xe6, 0x15, 0xeb, 0x18
731
732 /*
733  * post-SubByte transform
734  *
735  * post-lookup for sbox3:
736  *  swap_bitendianness(
737  *      camellia_h(
738  *          isom_map_aes_to_camellia(
739  *              swap_bitendianness(
740  *                  aes_inverse_affine_transform(in)
741  *              )
742  *          )
743  *      )
744  *  ) >>> 1
745  *
746  * (note: '⊕ 0x6e' inside camellia_h())
747  */
748 .Lpost_tf_lo_s3:
749         .byte 0x1e, 0x66, 0xe7, 0x9f, 0x19, 0x61, 0xe0, 0x98
750         .byte 0x6e, 0x16, 0x97, 0xef, 0x69, 0x11, 0x90, 0xe8
751 .Lpost_tf_hi_s3:
752         .byte 0x00, 0xfc, 0x43, 0xbf, 0xeb, 0x17, 0xa8, 0x54
753         .byte 0x52, 0xae, 0x11, 0xed, 0xb9, 0x45, 0xfa, 0x06
754
755 /* For isolating SubBytes from AESENCLAST, inverse shift row */
756 .Linv_shift_row:
757         .byte 0x00, 0x0d, 0x0a, 0x07, 0x04, 0x01, 0x0e, 0x0b
758         .byte 0x08, 0x05, 0x02, 0x0f, 0x0c, 0x09, 0x06, 0x03
759
760 /* shuffle mask for 8x8 byte transpose */
761 .Ltranspose_8x8_shuf:
762         .byte 0, 1, 4, 5, 2, 3, 6, 7, 8+0, 8+1, 8+4, 8+5, 8+2, 8+3, 8+6, 8+7
763
764 .align 4
765 /* 4-bit mask */
766 .L0f0f0f0f:
767         .long 0x0f0f0f0f
768
769 .text
770
771 .align 8
772 .type   __camellia_enc_blk16,@function;
773
774 __camellia_enc_blk16:
775         /* input:
776          *      %rdi: ctx, CTX
777          *      %rax: temporary storage, 256 bytes
778          *      %xmm0..%xmm15: 16 plaintext blocks
779          * output:
780          *      %xmm0..%xmm15: 16 encrypted blocks, order swapped:
781          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
782          */
783
784         leaq 8 * 16(%rax), %rcx;
785
786         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
787                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
788                       %xmm15, %rax, %rcx);
789
790         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
791                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
792                      %xmm15, %rax, %rcx, 0);
793
794         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
795               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
796               %xmm15,
797               ((key_table + (8) * 8) + 0)(CTX),
798               ((key_table + (8) * 8) + 4)(CTX),
799               ((key_table + (8) * 8) + 8)(CTX),
800               ((key_table + (8) * 8) + 12)(CTX));
801
802         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
803                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
804                      %xmm15, %rax, %rcx, 8);
805
806         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
807               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
808               %xmm15,
809               ((key_table + (16) * 8) + 0)(CTX),
810               ((key_table + (16) * 8) + 4)(CTX),
811               ((key_table + (16) * 8) + 8)(CTX),
812               ((key_table + (16) * 8) + 12)(CTX));
813
814         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
815                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
816                      %xmm15, %rax, %rcx, 16);
817
818         movl $24, %r8d;
819         cmpl $128, key_bitlength(CTX);
820         jne .Lenc_max32;
821
822 .Lenc_done:
823         /* load CD for output */
824         vmovdqu 0 * 16(%rcx), %xmm8;
825         vmovdqu 1 * 16(%rcx), %xmm9;
826         vmovdqu 2 * 16(%rcx), %xmm10;
827         vmovdqu 3 * 16(%rcx), %xmm11;
828         vmovdqu 4 * 16(%rcx), %xmm12;
829         vmovdqu 5 * 16(%rcx), %xmm13;
830         vmovdqu 6 * 16(%rcx), %xmm14;
831         vmovdqu 7 * 16(%rcx), %xmm15;
832
833         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
834                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
835                     %xmm15, (key_table)(CTX, %r8, 8), (%rax), 1 * 16(%rax));
836
837         ret;
838
839 .align 8
840 .Lenc_max32:
841         movl $32, %r8d;
842
843         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
844               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
845               %xmm15,
846               ((key_table + (24) * 8) + 0)(CTX),
847               ((key_table + (24) * 8) + 4)(CTX),
848               ((key_table + (24) * 8) + 8)(CTX),
849               ((key_table + (24) * 8) + 12)(CTX));
850
851         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
852                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
853                      %xmm15, %rax, %rcx, 24);
854
855         jmp .Lenc_done;
856 .size __camellia_enc_blk16,.-__camellia_enc_blk16;
857
858 .align 8
859 .type   __camellia_dec_blk16,@function;
860
861 __camellia_dec_blk16:
862         /* input:
863          *      %rdi: ctx, CTX
864          *      %rax: temporary storage, 256 bytes
865          *      %r8d: 24 for 16 byte key, 32 for larger
866          *      %xmm0..%xmm15: 16 encrypted blocks
867          * output:
868          *      %xmm0..%xmm15: 16 plaintext blocks, order swapped:
869          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
870          */
871
872         leaq 8 * 16(%rax), %rcx;
873
874         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
875                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
876                       %xmm15, %rax, %rcx);
877
878         cmpl $32, %r8d;
879         je .Ldec_max32;
880
881 .Ldec_max24:
882         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
883                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
884                      %xmm15, %rax, %rcx, 16);
885
886         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
887               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
888               %xmm15,
889               ((key_table + (16) * 8) + 8)(CTX),
890               ((key_table + (16) * 8) + 12)(CTX),
891               ((key_table + (16) * 8) + 0)(CTX),
892               ((key_table + (16) * 8) + 4)(CTX));
893
894         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
895                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
896                      %xmm15, %rax, %rcx, 8);
897
898         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
899               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
900               %xmm15,
901               ((key_table + (8) * 8) + 8)(CTX),
902               ((key_table + (8) * 8) + 12)(CTX),
903               ((key_table + (8) * 8) + 0)(CTX),
904               ((key_table + (8) * 8) + 4)(CTX));
905
906         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
907                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
908                      %xmm15, %rax, %rcx, 0);
909
910         /* load CD for output */
911         vmovdqu 0 * 16(%rcx), %xmm8;
912         vmovdqu 1 * 16(%rcx), %xmm9;
913         vmovdqu 2 * 16(%rcx), %xmm10;
914         vmovdqu 3 * 16(%rcx), %xmm11;
915         vmovdqu 4 * 16(%rcx), %xmm12;
916         vmovdqu 5 * 16(%rcx), %xmm13;
917         vmovdqu 6 * 16(%rcx), %xmm14;
918         vmovdqu 7 * 16(%rcx), %xmm15;
919
920         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
921                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
922                     %xmm15, (key_table)(CTX), (%rax), 1 * 16(%rax));
923
924         ret;
925
926 .align 8
927 .Ldec_max32:
928         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
929                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
930                      %xmm15, %rax, %rcx, 24);
931
932         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
933               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
934               %xmm15,
935               ((key_table + (24) * 8) + 8)(CTX),
936               ((key_table + (24) * 8) + 12)(CTX),
937               ((key_table + (24) * 8) + 0)(CTX),
938               ((key_table + (24) * 8) + 4)(CTX));
939
940         jmp .Ldec_max24;
941 .size __camellia_dec_blk16,.-__camellia_dec_blk16;
942
943 #define inc_le128(x, minus_one, tmp) \
944         vpcmpeqq minus_one, x, tmp; \
945         vpsubq minus_one, x, x; \
946         vpslldq $8, tmp, tmp; \
947         vpsubq tmp, x, x;
948
949 .align 8
950 .globl _gcry_camellia_aesni_avx_ctr_enc
951 .type   _gcry_camellia_aesni_avx_ctr_enc,@function;
952
953 _gcry_camellia_aesni_avx_ctr_enc:
954         /* input:
955          *      %rdi: ctx, CTX
956          *      %rsi: dst (16 blocks)
957          *      %rdx: src (16 blocks)
958          *      %rcx: iv (big endian, 128bit)
959          */
960
961         pushq %rbp;
962         movq %rsp, %rbp;
963
964         vzeroupper;
965
966         subq $(16 * 16), %rsp;
967         andq $~31, %rsp;
968         movq %rsp, %rax;
969
970         vmovdqa .Lbswap128_mask RIP, %xmm14;
971
972         /* load IV and byteswap */
973         vmovdqu (%rcx), %xmm15;
974         vmovdqu %xmm15, 15 * 16(%rax);
975         vpshufb %xmm14, %xmm15, %xmm0; /* be => le */
976
977         vpcmpeqd %xmm15, %xmm15, %xmm15;
978         vpsrldq $8, %xmm15, %xmm15; /* low: -1, high: 0 */
979
980         /* construct IVs */
981         inc_le128(%xmm0, %xmm15, %xmm13);
982         vpshufb %xmm14, %xmm0, %xmm13;
983         vmovdqu %xmm13, 14 * 16(%rax);
984         inc_le128(%xmm0, %xmm15, %xmm13);
985         vpshufb %xmm14, %xmm0, %xmm13;
986         vmovdqu %xmm13, 13 * 16(%rax);
987         inc_le128(%xmm0, %xmm15, %xmm13);
988         vpshufb %xmm14, %xmm0, %xmm12;
989         inc_le128(%xmm0, %xmm15, %xmm13);
990         vpshufb %xmm14, %xmm0, %xmm11;
991         inc_le128(%xmm0, %xmm15, %xmm13);
992         vpshufb %xmm14, %xmm0, %xmm10;
993         inc_le128(%xmm0, %xmm15, %xmm13);
994         vpshufb %xmm14, %xmm0, %xmm9;
995         inc_le128(%xmm0, %xmm15, %xmm13);
996         vpshufb %xmm14, %xmm0, %xmm8;
997         inc_le128(%xmm0, %xmm15, %xmm13);
998         vpshufb %xmm14, %xmm0, %xmm7;
999         inc_le128(%xmm0, %xmm15, %xmm13);
1000         vpshufb %xmm14, %xmm0, %xmm6;
1001         inc_le128(%xmm0, %xmm15, %xmm13);
1002         vpshufb %xmm14, %xmm0, %xmm5;
1003         inc_le128(%xmm0, %xmm15, %xmm13);
1004         vpshufb %xmm14, %xmm0, %xmm4;
1005         inc_le128(%xmm0, %xmm15, %xmm13);
1006         vpshufb %xmm14, %xmm0, %xmm3;
1007         inc_le128(%xmm0, %xmm15, %xmm13);
1008         vpshufb %xmm14, %xmm0, %xmm2;
1009         inc_le128(%xmm0, %xmm15, %xmm13);
1010         vpshufb %xmm14, %xmm0, %xmm1;
1011         inc_le128(%xmm0, %xmm15, %xmm13);
1012         vmovdqa %xmm0, %xmm13;
1013         vpshufb %xmm14, %xmm0, %xmm0;
1014         inc_le128(%xmm13, %xmm15, %xmm14);
1015         vpshufb .Lbswap128_mask RIP, %xmm13, %xmm13; /* le => be */
1016         vmovdqu %xmm13, (%rcx);
1017
1018         /* inpack16_pre: */
1019         vmovq (key_table)(CTX), %xmm15;
1020         vpshufb .Lpack_bswap RIP, %xmm15, %xmm15;
1021         vpxor %xmm0, %xmm15, %xmm0;
1022         vpxor %xmm1, %xmm15, %xmm1;
1023         vpxor %xmm2, %xmm15, %xmm2;
1024         vpxor %xmm3, %xmm15, %xmm3;
1025         vpxor %xmm4, %xmm15, %xmm4;
1026         vpxor %xmm5, %xmm15, %xmm5;
1027         vpxor %xmm6, %xmm15, %xmm6;
1028         vpxor %xmm7, %xmm15, %xmm7;
1029         vpxor %xmm8, %xmm15, %xmm8;
1030         vpxor %xmm9, %xmm15, %xmm9;
1031         vpxor %xmm10, %xmm15, %xmm10;
1032         vpxor %xmm11, %xmm15, %xmm11;
1033         vpxor %xmm12, %xmm15, %xmm12;
1034         vpxor 13 * 16(%rax), %xmm15, %xmm13;
1035         vpxor 14 * 16(%rax), %xmm15, %xmm14;
1036         vpxor 15 * 16(%rax), %xmm15, %xmm15;
1037
1038         call __camellia_enc_blk16;
1039
1040         vpxor 0 * 16(%rdx), %xmm7, %xmm7;
1041         vpxor 1 * 16(%rdx), %xmm6, %xmm6;
1042         vpxor 2 * 16(%rdx), %xmm5, %xmm5;
1043         vpxor 3 * 16(%rdx), %xmm4, %xmm4;
1044         vpxor 4 * 16(%rdx), %xmm3, %xmm3;
1045         vpxor 5 * 16(%rdx), %xmm2, %xmm2;
1046         vpxor 6 * 16(%rdx), %xmm1, %xmm1;
1047         vpxor 7 * 16(%rdx), %xmm0, %xmm0;
1048         vpxor 8 * 16(%rdx), %xmm15, %xmm15;
1049         vpxor 9 * 16(%rdx), %xmm14, %xmm14;
1050         vpxor 10 * 16(%rdx), %xmm13, %xmm13;
1051         vpxor 11 * 16(%rdx), %xmm12, %xmm12;
1052         vpxor 12 * 16(%rdx), %xmm11, %xmm11;
1053         vpxor 13 * 16(%rdx), %xmm10, %xmm10;
1054         vpxor 14 * 16(%rdx), %xmm9, %xmm9;
1055         vpxor 15 * 16(%rdx), %xmm8, %xmm8;
1056
1057         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1058                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1059                      %xmm8, %rsi);
1060
1061         vzeroall;
1062
1063         leave;
1064         ret;
1065 .size _gcry_camellia_aesni_avx_ctr_enc,.-_gcry_camellia_aesni_avx_ctr_enc;
1066
1067 .align 8
1068 .globl _gcry_camellia_aesni_avx_cbc_dec
1069 .type   _gcry_camellia_aesni_avx_cbc_dec,@function;
1070
1071 _gcry_camellia_aesni_avx_cbc_dec:
1072         /* input:
1073          *      %rdi: ctx, CTX
1074          *      %rsi: dst (16 blocks)
1075          *      %rdx: src (16 blocks)
1076          *      %rcx: iv
1077          */
1078
1079         pushq %rbp;
1080         movq %rsp, %rbp;
1081
1082         vzeroupper;
1083
1084         movq %rcx, %r9;
1085
1086         cmpl $128, key_bitlength(CTX);
1087         movl $32, %r8d;
1088         movl $24, %eax;
1089         cmovel %eax, %r8d; /* max */
1090
1091         inpack16_pre(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
1092                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
1093                      %xmm15, %rdx, (key_table)(CTX, %r8, 8));
1094
1095         subq $(16 * 16), %rsp;
1096         andq $~31, %rsp;
1097         movq %rsp, %rax;
1098
1099         call __camellia_dec_blk16;
1100
1101         /* XOR output with IV */
1102         vpxor (%r9), %xmm7, %xmm7;
1103         vpxor (0 * 16)(%rdx), %xmm6, %xmm6;
1104         vpxor (1 * 16)(%rdx), %xmm5, %xmm5;
1105         vpxor (2 * 16)(%rdx), %xmm4, %xmm4;
1106         vpxor (3 * 16)(%rdx), %xmm3, %xmm3;
1107         vpxor (4 * 16)(%rdx), %xmm2, %xmm2;
1108         vpxor (5 * 16)(%rdx), %xmm1, %xmm1;
1109         vpxor (6 * 16)(%rdx), %xmm0, %xmm0;
1110         vpxor (7 * 16)(%rdx), %xmm15, %xmm15;
1111         vpxor (8 * 16)(%rdx), %xmm14, %xmm14;
1112         vpxor (9 * 16)(%rdx), %xmm13, %xmm13;
1113         vpxor (10 * 16)(%rdx), %xmm12, %xmm12;
1114         vpxor (11 * 16)(%rdx), %xmm11, %xmm11;
1115         vpxor (12 * 16)(%rdx), %xmm10, %xmm10;
1116         vpxor (13 * 16)(%rdx), %xmm9, %xmm9;
1117         vpxor (14 * 16)(%rdx), %xmm8, %xmm8;
1118         movq (15 * 16 + 0)(%rdx), %r10;
1119         movq (15 * 16 + 8)(%rdx), %r11;
1120
1121         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1122                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1123                      %xmm8, %rsi);
1124
1125         /* store new IV */
1126         movq %r10, (0)(%r9);
1127         movq %r11, (8)(%r9);
1128
1129         vzeroall;
1130
1131         leave;
1132         ret;
1133 .size _gcry_camellia_aesni_avx_cbc_dec,.-_gcry_camellia_aesni_avx_cbc_dec;
1134
1135 .align 8
1136 .globl _gcry_camellia_aesni_avx_cfb_dec
1137 .type   _gcry_camellia_aesni_avx_cfb_dec,@function;
1138
1139 _gcry_camellia_aesni_avx_cfb_dec:
1140         /* input:
1141          *      %rdi: ctx, CTX
1142          *      %rsi: dst (16 blocks)
1143          *      %rdx: src (16 blocks)
1144          *      %rcx: iv
1145          */
1146
1147         pushq %rbp;
1148         movq %rsp, %rbp;
1149
1150         vzeroupper;
1151
1152         subq $(16 * 16), %rsp;
1153         andq $~31, %rsp;
1154         movq %rsp, %rax;
1155
1156         /* inpack16_pre: */
1157         vmovq (key_table)(CTX), %xmm0;
1158         vpshufb .Lpack_bswap RIP, %xmm0, %xmm0;
1159         vpxor (%rcx), %xmm0, %xmm15;
1160         vmovdqu 15 * 16(%rdx), %xmm1;
1161         vmovdqu %xmm1, (%rcx); /* store new IV */
1162         vpxor 0 * 16(%rdx), %xmm0, %xmm14;
1163         vpxor 1 * 16(%rdx), %xmm0, %xmm13;
1164         vpxor 2 * 16(%rdx), %xmm0, %xmm12;
1165         vpxor 3 * 16(%rdx), %xmm0, %xmm11;
1166         vpxor 4 * 16(%rdx), %xmm0, %xmm10;
1167         vpxor 5 * 16(%rdx), %xmm0, %xmm9;
1168         vpxor 6 * 16(%rdx), %xmm0, %xmm8;
1169         vpxor 7 * 16(%rdx), %xmm0, %xmm7;
1170         vpxor 8 * 16(%rdx), %xmm0, %xmm6;
1171         vpxor 9 * 16(%rdx), %xmm0, %xmm5;
1172         vpxor 10 * 16(%rdx), %xmm0, %xmm4;
1173         vpxor 11 * 16(%rdx), %xmm0, %xmm3;
1174         vpxor 12 * 16(%rdx), %xmm0, %xmm2;
1175         vpxor 13 * 16(%rdx), %xmm0, %xmm1;
1176         vpxor 14 * 16(%rdx), %xmm0, %xmm0;
1177
1178         call __camellia_enc_blk16;
1179
1180         vpxor 0 * 16(%rdx), %xmm7, %xmm7;
1181         vpxor 1 * 16(%rdx), %xmm6, %xmm6;
1182         vpxor 2 * 16(%rdx), %xmm5, %xmm5;
1183         vpxor 3 * 16(%rdx), %xmm4, %xmm4;
1184         vpxor 4 * 16(%rdx), %xmm3, %xmm3;
1185         vpxor 5 * 16(%rdx), %xmm2, %xmm2;
1186         vpxor 6 * 16(%rdx), %xmm1, %xmm1;
1187         vpxor 7 * 16(%rdx), %xmm0, %xmm0;
1188         vpxor 8 * 16(%rdx), %xmm15, %xmm15;
1189         vpxor 9 * 16(%rdx), %xmm14, %xmm14;
1190         vpxor 10 * 16(%rdx), %xmm13, %xmm13;
1191         vpxor 11 * 16(%rdx), %xmm12, %xmm12;
1192         vpxor 12 * 16(%rdx), %xmm11, %xmm11;
1193         vpxor 13 * 16(%rdx), %xmm10, %xmm10;
1194         vpxor 14 * 16(%rdx), %xmm9, %xmm9;
1195         vpxor 15 * 16(%rdx), %xmm8, %xmm8;
1196
1197         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1198                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1199                      %xmm8, %rsi);
1200
1201         vzeroall;
1202
1203         leave;
1204         ret;
1205 .size _gcry_camellia_aesni_avx_cfb_dec,.-_gcry_camellia_aesni_avx_cfb_dec;
1206
1207 /*
1208  * IN:
1209  *  ab: 64-bit AB state
1210  *  cd: 64-bit CD state
1211  */
1212 #define camellia_f(ab, x, t0, t1, t2, t3, t4, inv_shift_row, sbox4mask, \
1213                    _0f0f0f0fmask, pre_s1lo_mask, pre_s1hi_mask, key) \
1214         vmovq key, t0; \
1215         vpxor x, x, t3; \
1216         \
1217         vpxor ab, t0, x; \
1218         \
1219         /* \
1220          * S-function with AES subbytes \
1221          */ \
1222         \
1223         /* input rotation for sbox4 (<<< 1) */ \
1224         vpand x, sbox4mask, t0; \
1225         vpandn x, sbox4mask, x; \
1226         vpaddw t0, t0, t1; \
1227         vpsrlw $7, t0, t0; \
1228         vpor t0, t1, t0; \
1229         vpand sbox4mask, t0, t0; \
1230         vpor t0, x, x; \
1231         \
1232         vmovdqa .Lpost_tf_lo_s1 RIP, t0; \
1233         vmovdqa .Lpost_tf_hi_s1 RIP, t1; \
1234         \
1235         /* prefilter sboxes */ \
1236         filter_8bit(x, pre_s1lo_mask, pre_s1hi_mask, _0f0f0f0fmask, t2); \
1237         \
1238         /* AES subbytes + AES shift rows + AES inv shift rows */ \
1239         vaesenclast t3, x, x; \
1240         \
1241         /* postfilter sboxes */ \
1242         filter_8bit(x, t0, t1, _0f0f0f0fmask, t2); \
1243         \
1244         /* output rotation for sbox2 (<<< 1) */ \
1245         /* output rotation for sbox3 (>>> 1) */ \
1246         vpshufb inv_shift_row, x, t1; \
1247         vpshufb .Lsp0044440444044404mask RIP, x, t4; \
1248         vpshufb .Lsp1110111010011110mask RIP, x, x; \
1249         vpaddb t1, t1, t2; \
1250         vpsrlw $7, t1, t0; \
1251         vpsllw $7, t1, t3; \
1252         vpor t0, t2, t0; \
1253         vpsrlw $1, t1, t1; \
1254         vpshufb .Lsp0222022222000222mask RIP, t0, t0; \
1255         vpor t1, t3, t1; \
1256         \
1257         vpxor x, t4, t4; \
1258         vpshufb .Lsp3033303303303033mask RIP, t1, t1; \
1259         vpxor t4, t0, t0; \
1260         vpxor t1, t0, t0; \
1261         vpsrldq $8, t0, x; \
1262         vpxor t0, x, x;
1263
1264 #define vec_rol128(in, out, nrol, t0) \
1265         vpshufd $0x4e, in, out; \
1266         vpsllq $(nrol), in, t0; \
1267         vpsrlq $(64-(nrol)), out, out; \
1268         vpaddd t0, out, out;
1269
1270 #define vec_ror128(in, out, nror, t0) \
1271         vpshufd $0x4e, in, out; \
1272         vpsrlq $(nror), in, t0; \
1273         vpsllq $(64-(nror)), out, out; \
1274         vpaddd t0, out, out;
1275
1276 .data
1277
1278 .align 16
1279 .Linv_shift_row_and_unpcklbw:
1280         .byte 0x00, 0xff, 0x0d, 0xff, 0x0a, 0xff, 0x07, 0xff
1281         .byte 0x04, 0xff, 0x01, 0xff, 0x0e, 0xff, 0x0b, 0xff
1282 .Lsp0044440444044404mask:
1283         .long 0xffff0404, 0x0404ff04;
1284         .long 0x0d0dff0d, 0x0d0dff0d;
1285 .Lsp1110111010011110mask:
1286         .long 0x000000ff, 0x000000ff;
1287         .long 0x0bffff0b, 0x0b0b0bff;
1288 .Lsp0222022222000222mask:
1289         .long 0xff060606, 0xff060606;
1290         .long 0x0c0cffff, 0xff0c0c0c;
1291 .Lsp3033303303303033mask:
1292         .long 0x04ff0404, 0x04ff0404;
1293         .long 0xff0a0aff, 0x0aff0a0a;
1294 .Lsbox4_input_mask:
1295         .byte 0x00, 0xff, 0x00, 0x00, 0xff, 0x00, 0x00, 0x00;
1296 .Lsigma1:
1297         .long 0x3BCC908B, 0xA09E667F;
1298 .Lsigma2:
1299         .long 0x4CAA73B2, 0xB67AE858;
1300 .Lsigma3:
1301         .long 0xE94F82BE, 0xC6EF372F;
1302 .Lsigma4:
1303         .long 0xF1D36F1C, 0x54FF53A5;
1304 .Lsigma5:
1305         .long 0xDE682D1D, 0x10E527FA;
1306 .Lsigma6:
1307         .long 0xB3E6C1FD, 0xB05688C2;
1308
1309 .text
1310
1311 .align 8
1312 .type  __camellia_avx_setup128,@function;
1313 __camellia_avx_setup128:
1314         /* input:
1315          *      %rdi: ctx, CTX; subkey storage at key_table(CTX)
1316          *      %xmm0: key
1317          */
1318 #define cmll_sub(n, ctx) (key_table+((n)*8))(ctx)
1319 #define KL128 %xmm0
1320 #define KA128 %xmm2
1321
1322         vpshufb .Lbswap128_mask RIP, KL128, KL128;
1323
1324         vmovdqa .Linv_shift_row_and_unpcklbw RIP, %xmm11;
1325         vmovq .Lsbox4_input_mask RIP, %xmm12;
1326         vbroadcastss .L0f0f0f0f RIP, %xmm13;
1327         vmovdqa .Lpre_tf_lo_s1 RIP, %xmm14;
1328         vmovdqa .Lpre_tf_hi_s1 RIP, %xmm15;
1329
1330         /*
1331          * Generate KA
1332          */
1333         vpsrldq $8, KL128, %xmm2;
1334         vmovdqa KL128, %xmm3;
1335         vpslldq $8, %xmm3, %xmm3;
1336         vpsrldq $8, %xmm3, %xmm3;
1337
1338         camellia_f(%xmm2, %xmm4, %xmm1,
1339                    %xmm5, %xmm6, %xmm7, %xmm8,
1340                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma1 RIP);
1341         vpxor %xmm4, %xmm3, %xmm3;
1342         camellia_f(%xmm3, %xmm2, %xmm1,
1343                    %xmm5, %xmm6, %xmm7, %xmm8,
1344                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma2 RIP);
1345         camellia_f(%xmm2, %xmm3, %xmm1,
1346                    %xmm5, %xmm6, %xmm7, %xmm8,
1347                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma3 RIP);
1348         vpxor %xmm4, %xmm3, %xmm3;
1349         camellia_f(%xmm3, %xmm4, %xmm1,
1350                    %xmm5, %xmm6, %xmm7, %xmm8,
1351                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma4 RIP);
1352
1353         vpslldq $8, %xmm3, %xmm3;
1354         vpxor %xmm4, %xmm2, %xmm2;
1355         vpsrldq $8, %xmm3, %xmm3;
1356         vpslldq $8, %xmm2, KA128;
1357         vpor %xmm3, KA128, KA128;
1358
1359         /*
1360          * Generate subkeys
1361          */
1362         vmovdqu KA128, cmll_sub(24, CTX);
1363         vec_rol128(KL128, %xmm3, 15, %xmm15);
1364         vec_rol128(KA128, %xmm4, 15, %xmm15);
1365         vec_rol128(KA128, %xmm5, 30, %xmm15);
1366         vec_rol128(KL128, %xmm6, 45, %xmm15);
1367         vec_rol128(KA128, %xmm7, 45, %xmm15);
1368         vec_rol128(KL128, %xmm8, 60, %xmm15);
1369         vec_rol128(KA128, %xmm9, 60, %xmm15);
1370         vec_ror128(KL128, %xmm10, 128-77, %xmm15);
1371
1372         /* absorb kw2 to other subkeys */
1373         vpslldq $8, KL128, %xmm15;
1374         vpsrldq $8, %xmm15, %xmm15;
1375         vpxor %xmm15, KA128, KA128;
1376         vpxor %xmm15, %xmm3, %xmm3;
1377         vpxor %xmm15, %xmm4, %xmm4;
1378
1379         /* subl(1) ^= subr(1) & ~subr(9); */
1380         vpandn %xmm15, %xmm5, %xmm13;
1381         vpslldq $12, %xmm13, %xmm13;
1382         vpsrldq $8, %xmm13, %xmm13;
1383         vpxor %xmm13, %xmm15, %xmm15;
1384         /* dw = subl(1) & subl(9), subr(1) ^= CAMELLIA_RL1(dw); */
1385         vpand %xmm15, %xmm5, %xmm14;
1386         vpslld $1, %xmm14, %xmm11;
1387         vpsrld $31, %xmm14, %xmm14;
1388         vpaddd %xmm11, %xmm14, %xmm14;
1389         vpslldq $8, %xmm14, %xmm14;
1390         vpsrldq $12, %xmm14, %xmm14;
1391         vpxor %xmm14, %xmm15, %xmm15;
1392
1393         vpxor %xmm15, %xmm6, %xmm6;
1394         vpxor %xmm15, %xmm8, %xmm8;
1395         vpxor %xmm15, %xmm9, %xmm9;
1396
1397         /* subl(1) ^= subr(1) & ~subr(17); */
1398         vpandn %xmm15, %xmm10, %xmm13;
1399         vpslldq $12, %xmm13, %xmm13;
1400         vpsrldq $8, %xmm13, %xmm13;
1401         vpxor %xmm13, %xmm15, %xmm15;
1402         /* dw = subl(1) & subl(17), subr(1) ^= CAMELLIA_RL1(dw); */
1403         vpand %xmm15, %xmm10, %xmm14;
1404         vpslld $1, %xmm14, %xmm11;
1405         vpsrld $31, %xmm14, %xmm14;
1406         vpaddd %xmm11, %xmm14, %xmm14;
1407         vpslldq $8, %xmm14, %xmm14;
1408         vpsrldq $12, %xmm14, %xmm14;
1409         vpxor %xmm14, %xmm15, %xmm15;
1410
1411         vpshufd $0x1b, KL128, KL128;
1412         vpshufd $0x1b, KA128, KA128;
1413         vpshufd $0x1b, %xmm3, %xmm3;
1414         vpshufd $0x1b, %xmm4, %xmm4;
1415         vpshufd $0x1b, %xmm5, %xmm5;
1416         vpshufd $0x1b, %xmm6, %xmm6;
1417         vpshufd $0x1b, %xmm7, %xmm7;
1418         vpshufd $0x1b, %xmm8, %xmm8;
1419         vpshufd $0x1b, %xmm9, %xmm9;
1420         vpshufd $0x1b, %xmm10, %xmm10;
1421
1422         vmovdqu KL128, cmll_sub(0, CTX);
1423         vpshufd $0x1b, KL128, KL128;
1424         vmovdqu KA128, cmll_sub(2, CTX);
1425         vmovdqu %xmm3, cmll_sub(4, CTX);
1426         vmovdqu %xmm4, cmll_sub(6, CTX);
1427         vmovdqu %xmm5, cmll_sub(8, CTX);
1428         vmovdqu %xmm6, cmll_sub(10, CTX);
1429         vpsrldq $8, %xmm8, %xmm8;
1430         vmovq %xmm7, cmll_sub(12, CTX);
1431         vmovq %xmm8, cmll_sub(13, CTX);
1432         vmovdqu %xmm9, cmll_sub(14, CTX);
1433         vmovdqu %xmm10, cmll_sub(16, CTX);
1434
1435         vmovdqu cmll_sub(24, CTX), KA128;
1436
1437         vec_ror128(KL128, %xmm3, 128 - 94, %xmm7);
1438         vec_ror128(KA128, %xmm4, 128 - 94, %xmm7);
1439         vec_ror128(KL128, %xmm5, 128 - 111, %xmm7);
1440         vec_ror128(KA128, %xmm6, 128 - 111, %xmm7);
1441
1442         vpxor %xmm15, %xmm3, %xmm3;
1443         vpxor %xmm15, %xmm4, %xmm4;
1444         vpxor %xmm15, %xmm5, %xmm5;
1445         vpslldq $8, %xmm15, %xmm15;
1446         vpxor %xmm15, %xmm6, %xmm6;
1447
1448         /* absorb kw4 to other subkeys */
1449         vpslldq $8, %xmm6, %xmm15;
1450         vpxor %xmm15, %xmm5, %xmm5;
1451         vpxor %xmm15, %xmm4, %xmm4;
1452         vpxor %xmm15, %xmm3, %xmm3;
1453
1454         /* subl(25) ^= subr(25) & ~subr(16); */
1455         vpshufd $0x1b, cmll_sub(16, CTX), %xmm10;
1456         vpandn %xmm15, %xmm10, %xmm13;
1457         vpslldq $4, %xmm13, %xmm13;
1458         vpxor %xmm13, %xmm15, %xmm15;
1459         /* dw = subl(25) & subl(16), subr(25) ^= CAMELLIA_RL1(dw); */
1460         vpand %xmm15, %xmm10, %xmm14;
1461         vpslld $1, %xmm14, %xmm11;
1462         vpsrld $31, %xmm14, %xmm14;
1463         vpaddd %xmm11, %xmm14, %xmm14;
1464         vpsrldq $12, %xmm14, %xmm14;
1465         vpslldq $8, %xmm14, %xmm14;
1466         vpxor %xmm14, %xmm15, %xmm15;
1467
1468         vpshufd $0x1b, %xmm3, %xmm3;
1469         vpshufd $0x1b, %xmm4, %xmm4;
1470         vpshufd $0x1b, %xmm5, %xmm5;
1471         vpshufd $0x1b, %xmm6, %xmm6;
1472
1473         vmovdqu %xmm3, cmll_sub(18, CTX);
1474         vmovdqu %xmm4, cmll_sub(20, CTX);
1475         vmovdqu %xmm5, cmll_sub(22, CTX);
1476         vmovdqu %xmm6, cmll_sub(24, CTX);
1477
1478         vpshufd $0x1b, cmll_sub(14, CTX), %xmm3;
1479         vpshufd $0x1b, cmll_sub(12, CTX), %xmm4;
1480         vpshufd $0x1b, cmll_sub(10, CTX), %xmm5;
1481         vpshufd $0x1b, cmll_sub(8, CTX), %xmm6;
1482
1483         vpxor %xmm15, %xmm3, %xmm3;
1484         vpxor %xmm15, %xmm4, %xmm4;
1485         vpxor %xmm15, %xmm5, %xmm5;
1486
1487         /* subl(25) ^= subr(25) & ~subr(8); */
1488         vpandn %xmm15, %xmm6, %xmm13;
1489         vpslldq $4, %xmm13, %xmm13;
1490         vpxor %xmm13, %xmm15, %xmm15;
1491         /* dw = subl(25) & subl(8), subr(25) ^= CAMELLIA_RL1(dw); */
1492         vpand %xmm15, %xmm6, %xmm14;
1493         vpslld $1, %xmm14, %xmm11;
1494         vpsrld $31, %xmm14, %xmm14;
1495         vpaddd %xmm11, %xmm14, %xmm14;
1496         vpsrldq $12, %xmm14, %xmm14;
1497         vpslldq $8, %xmm14, %xmm14;
1498         vpxor %xmm14, %xmm15, %xmm15;
1499
1500         vpshufd $0x1b, %xmm3, %xmm3;
1501         vpshufd $0x1b, %xmm4, %xmm4;
1502         vpshufd $0x1b, %xmm5, %xmm5;
1503
1504         vmovdqu %xmm3, cmll_sub(14, CTX);
1505         vmovdqu %xmm4, cmll_sub(12, CTX);
1506         vmovdqu %xmm5, cmll_sub(10, CTX);
1507
1508         vpshufd $0x1b, cmll_sub(6, CTX), %xmm6;
1509         vpshufd $0x1b, cmll_sub(4, CTX), %xmm4;
1510         vpshufd $0x1b, cmll_sub(2, CTX), %xmm2;
1511         vpshufd $0x1b, cmll_sub(0, CTX), %xmm0;
1512
1513         vpxor %xmm15, %xmm6, %xmm6;
1514         vpxor %xmm15, %xmm4, %xmm4;
1515         vpxor %xmm15, %xmm2, %xmm2;
1516         vpxor %xmm15, %xmm0, %xmm0;
1517
1518         vpshufd $0x1b, %xmm6, %xmm6;
1519         vpshufd $0x1b, %xmm4, %xmm4;
1520         vpshufd $0x1b, %xmm2, %xmm2;
1521         vpshufd $0x1b, %xmm0, %xmm0;
1522
1523         vpsrldq $8, %xmm2, %xmm3;
1524         vpsrldq $8, %xmm4, %xmm5;
1525         vpsrldq $8, %xmm6, %xmm7;
1526
1527         /*
1528          * key XOR is end of F-function.
1529          */
1530         vpxor %xmm2, %xmm0, %xmm0;
1531         vpxor %xmm4, %xmm2, %xmm2;
1532
1533         vmovq %xmm0, cmll_sub(0, CTX);
1534         vmovq %xmm3, cmll_sub(2, CTX);
1535         vpxor %xmm5, %xmm3, %xmm3;
1536         vpxor %xmm6, %xmm4, %xmm4;
1537         vpxor %xmm7, %xmm5, %xmm5;
1538         vmovq %xmm2, cmll_sub(3, CTX);
1539         vmovq %xmm3, cmll_sub(4, CTX);
1540         vmovq %xmm4, cmll_sub(5, CTX);
1541         vmovq %xmm5, cmll_sub(6, CTX);
1542
1543         vmovq cmll_sub(7, CTX), %xmm7;
1544         vmovq cmll_sub(8, CTX), %xmm8;
1545         vmovq cmll_sub(9, CTX), %xmm9;
1546         vmovq cmll_sub(10, CTX), %xmm10;
1547         /* tl = subl(10) ^ (subr(10) & ~subr(8)); */
1548         vpandn %xmm10, %xmm8, %xmm15;
1549         vpsrldq $4, %xmm15, %xmm15;
1550         vpxor %xmm15, %xmm10, %xmm0;
1551         /* dw = tl & subl(8), tr = subr(10) ^ CAMELLIA_RL1(dw); */
1552         vpand %xmm8, %xmm0, %xmm15;
1553         vpslld $1, %xmm15, %xmm14;
1554         vpsrld $31, %xmm15, %xmm15;
1555         vpaddd %xmm14, %xmm15, %xmm15;
1556         vpslldq $12, %xmm15, %xmm15;
1557         vpsrldq $8, %xmm15, %xmm15;
1558         vpxor %xmm15, %xmm0, %xmm0;
1559
1560         vpxor %xmm0, %xmm6, %xmm6;
1561         vmovq %xmm6, cmll_sub(7, CTX);
1562
1563         vmovq cmll_sub(11, CTX), %xmm11;
1564         vmovq cmll_sub(12, CTX), %xmm12;
1565         vmovq cmll_sub(13, CTX), %xmm13;
1566         vmovq cmll_sub(14, CTX), %xmm14;
1567         vmovq cmll_sub(15, CTX), %xmm15;
1568         /* tl = subl(7) ^ (subr(7) & ~subr(9)); */
1569         vpandn %xmm7, %xmm9, %xmm1;
1570         vpsrldq $4, %xmm1, %xmm1;
1571         vpxor %xmm1, %xmm7, %xmm0;
1572         /* dw = tl & subl(9), tr = subr(7) ^ CAMELLIA_RL1(dw); */
1573         vpand %xmm9, %xmm0, %xmm1;
1574         vpslld $1, %xmm1, %xmm2;
1575         vpsrld $31, %xmm1, %xmm1;
1576         vpaddd %xmm2, %xmm1, %xmm1;
1577         vpslldq $12, %xmm1, %xmm1;
1578         vpsrldq $8, %xmm1, %xmm1;
1579         vpxor %xmm1, %xmm0, %xmm0;
1580
1581         vpxor %xmm11, %xmm0, %xmm0;
1582         vpxor %xmm12, %xmm10, %xmm10;
1583         vpxor %xmm13, %xmm11, %xmm11;
1584         vpxor %xmm14, %xmm12, %xmm12;
1585         vpxor %xmm15, %xmm13, %xmm13;
1586         vmovq %xmm0, cmll_sub(10, CTX);
1587         vmovq %xmm10, cmll_sub(11, CTX);
1588         vmovq %xmm11, cmll_sub(12, CTX);
1589         vmovq %xmm12, cmll_sub(13, CTX);
1590         vmovq %xmm13, cmll_sub(14, CTX);
1591
1592         vmovq cmll_sub(16, CTX), %xmm6;
1593         vmovq cmll_sub(17, CTX), %xmm7;
1594         vmovq cmll_sub(18, CTX), %xmm8;
1595         vmovq cmll_sub(19, CTX), %xmm9;
1596         vmovq cmll_sub(20, CTX), %xmm10;
1597         /* tl = subl(18) ^ (subr(18) & ~subr(16)); */
1598         vpandn %xmm8, %xmm6, %xmm1;
1599         vpsrldq $4, %xmm1, %xmm1;
1600         vpxor %xmm1, %xmm8, %xmm0;
1601         /* dw = tl & subl(16), tr = subr(18) ^ CAMELLIA_RL1(dw); */
1602         vpand %xmm6, %xmm0, %xmm1;
1603         vpslld $1, %xmm1, %xmm2;
1604         vpsrld $31, %xmm1, %xmm1;
1605         vpaddd %xmm2, %xmm1, %xmm1;
1606         vpslldq $12, %xmm1, %xmm1;
1607         vpsrldq $8, %xmm1, %xmm1;
1608         vpxor %xmm1, %xmm0, %xmm0;
1609
1610         vpxor %xmm14, %xmm0, %xmm0;
1611         vmovq %xmm0, cmll_sub(15, CTX);
1612
1613         /* tl = subl(15) ^ (subr(15) & ~subr(17)); */
1614         vpandn %xmm15, %xmm7, %xmm1;
1615         vpsrldq $4, %xmm1, %xmm1;
1616         vpxor %xmm1, %xmm15, %xmm0;
1617         /* dw = tl & subl(17), tr = subr(15) ^ CAMELLIA_RL1(dw); */
1618         vpand %xmm7, %xmm0, %xmm1;
1619         vpslld $1, %xmm1, %xmm2;
1620         vpsrld $31, %xmm1, %xmm1;
1621         vpaddd %xmm2, %xmm1, %xmm1;
1622         vpslldq $12, %xmm1, %xmm1;
1623         vpsrldq $8, %xmm1, %xmm1;
1624         vpxor %xmm1, %xmm0, %xmm0;
1625
1626         vmovq cmll_sub(21, CTX), %xmm1;
1627         vmovq cmll_sub(22, CTX), %xmm2;
1628         vmovq cmll_sub(23, CTX), %xmm3;
1629         vmovq cmll_sub(24, CTX), %xmm4;
1630
1631         vpxor %xmm9, %xmm0, %xmm0;
1632         vpxor %xmm10, %xmm8, %xmm8;
1633         vpxor %xmm1, %xmm9, %xmm9;
1634         vpxor %xmm2, %xmm10, %xmm10;
1635         vpxor %xmm3, %xmm1, %xmm1;
1636         vpxor %xmm4, %xmm3, %xmm3;
1637
1638         vmovq %xmm0, cmll_sub(18, CTX);
1639         vmovq %xmm8, cmll_sub(19, CTX);
1640         vmovq %xmm9, cmll_sub(20, CTX);
1641         vmovq %xmm10, cmll_sub(21, CTX);
1642         vmovq %xmm1, cmll_sub(22, CTX);
1643         vmovq %xmm2, cmll_sub(23, CTX);
1644         vmovq %xmm3, cmll_sub(24, CTX);
1645
1646         /* kw2 and kw4 are unused now. */
1647         movq $0, cmll_sub(1, CTX);
1648         movq $0, cmll_sub(25, CTX);
1649
1650         vzeroall;
1651
1652         ret;
1653 .size __camellia_avx_setup128,.-__camellia_avx_setup128;
1654
1655 .align 8
1656 .type  __camellia_avx_setup256,@function;
1657
1658 __camellia_avx_setup256:
1659         /* input:
1660          *      %rdi: ctx, CTX; subkey storage at key_table(CTX)
1661          *      %xmm0 & %xmm1: key
1662          */
1663 #define KL128 %xmm0
1664 #define KR128 %xmm1
1665 #define KA128 %xmm2
1666 #define KB128 %xmm3
1667
1668         vpshufb .Lbswap128_mask RIP, KL128, KL128;
1669         vpshufb .Lbswap128_mask RIP, KR128, KR128;
1670
1671         vmovdqa .Linv_shift_row_and_unpcklbw RIP, %xmm11;
1672         vmovq .Lsbox4_input_mask RIP, %xmm12;
1673         vbroadcastss .L0f0f0f0f RIP, %xmm13;
1674         vmovdqa .Lpre_tf_lo_s1 RIP, %xmm14;
1675         vmovdqa .Lpre_tf_hi_s1 RIP, %xmm15;
1676
1677         /*
1678          * Generate KA
1679          */
1680         vpxor KL128, KR128, %xmm3;
1681         vpsrldq $8, KR128, %xmm6;
1682         vpsrldq $8, %xmm3, %xmm2;
1683         vpslldq $8, %xmm3, %xmm3;
1684         vpsrldq $8, %xmm3, %xmm3;
1685
1686         camellia_f(%xmm2, %xmm4, %xmm5,
1687                    %xmm7, %xmm8, %xmm9, %xmm10,
1688                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma1 RIP);
1689         vpxor %xmm4, %xmm3, %xmm3;
1690         camellia_f(%xmm3, %xmm2, %xmm5,
1691                    %xmm7, %xmm8, %xmm9, %xmm10,
1692                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma2 RIP);
1693         vpxor %xmm6, %xmm2, %xmm2;
1694         camellia_f(%xmm2, %xmm3, %xmm5,
1695                    %xmm7, %xmm8, %xmm9, %xmm10,
1696                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma3 RIP);
1697         vpxor %xmm4, %xmm3, %xmm3;
1698         vpxor KR128, %xmm3, %xmm3;
1699         camellia_f(%xmm3, %xmm4, %xmm5,
1700                    %xmm7, %xmm8, %xmm9, %xmm10,
1701                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma4 RIP);
1702
1703         vpslldq $8, %xmm3, %xmm3;
1704         vpxor %xmm4, %xmm2, %xmm2;
1705         vpsrldq $8, %xmm3, %xmm3;
1706         vpslldq $8, %xmm2, KA128;
1707         vpor %xmm3, KA128, KA128;
1708
1709         /*
1710          * Generate KB
1711          */
1712         vpxor KA128, KR128, %xmm3;
1713         vpsrldq $8, %xmm3, %xmm4;
1714         vpslldq $8, %xmm3, %xmm3;
1715         vpsrldq $8, %xmm3, %xmm3;
1716
1717         camellia_f(%xmm4, %xmm5, %xmm6,
1718                    %xmm7, %xmm8, %xmm9, %xmm10,
1719                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma5 RIP);
1720         vpxor %xmm5, %xmm3, %xmm3;
1721
1722         camellia_f(%xmm3, %xmm5, %xmm6,
1723                    %xmm7, %xmm8, %xmm9, %xmm10,
1724                    %xmm11, %xmm12, %xmm13, %xmm14, %xmm15, .Lsigma6 RIP);
1725         vpslldq $8, %xmm3, %xmm3;
1726         vpxor %xmm5, %xmm4, %xmm4;
1727         vpsrldq $8, %xmm3, %xmm3;
1728         vpslldq $8, %xmm4, %xmm4;
1729         vpor %xmm3, %xmm4, KB128;
1730
1731         /*
1732          * Generate subkeys
1733          */
1734         vmovdqu KB128, cmll_sub(32, CTX);
1735         vec_rol128(KR128, %xmm4, 15, %xmm15);
1736         vec_rol128(KA128, %xmm5, 15, %xmm15);
1737         vec_rol128(KR128, %xmm6, 30, %xmm15);
1738         vec_rol128(KB128, %xmm7, 30, %xmm15);
1739         vec_rol128(KL128, %xmm8, 45, %xmm15);
1740         vec_rol128(KA128, %xmm9, 45, %xmm15);
1741         vec_rol128(KL128, %xmm10, 60, %xmm15);
1742         vec_rol128(KR128, %xmm11, 60, %xmm15);
1743         vec_rol128(KB128, %xmm12, 60, %xmm15);
1744
1745         /* absorb kw2 to other subkeys */
1746         vpslldq $8, KL128, %xmm15;
1747         vpsrldq $8, %xmm15, %xmm15;
1748         vpxor %xmm15, KB128, KB128;
1749         vpxor %xmm15, %xmm4, %xmm4;
1750         vpxor %xmm15, %xmm5, %xmm5;
1751
1752         /* subl(1) ^= subr(1) & ~subr(9); */
1753         vpandn %xmm15, %xmm6, %xmm13;
1754         vpslldq $12, %xmm13, %xmm13;
1755         vpsrldq $8, %xmm13, %xmm13;
1756         vpxor %xmm13, %xmm15, %xmm15;
1757         /* dw = subl(1) & subl(9), subr(1) ^= CAMELLIA_RL1(dw); */
1758         vpand %xmm15, %xmm6, %xmm14;
1759         vpslld $1, %xmm14, %xmm13;
1760         vpsrld $31, %xmm14, %xmm14;
1761         vpaddd %xmm13, %xmm14, %xmm14;
1762         vpslldq $8, %xmm14, %xmm14;
1763         vpsrldq $12, %xmm14, %xmm14;
1764         vpxor %xmm14, %xmm15, %xmm15;
1765
1766         vpxor %xmm15, %xmm7, %xmm7;
1767         vpxor %xmm15, %xmm8, %xmm8;
1768         vpxor %xmm15, %xmm9, %xmm9;
1769
1770         vpshufd $0x1b, KL128, KL128;
1771         vpshufd $0x1b, KB128, KB128;
1772         vpshufd $0x1b, %xmm4, %xmm4;
1773         vpshufd $0x1b, %xmm5, %xmm5;
1774         vpshufd $0x1b, %xmm6, %xmm6;
1775         vpshufd $0x1b, %xmm7, %xmm7;
1776         vpshufd $0x1b, %xmm8, %xmm8;
1777         vpshufd $0x1b, %xmm9, %xmm9;
1778
1779         vmovdqu KL128, cmll_sub(0, CTX);
1780         vpshufd $0x1b, KL128, KL128;
1781         vmovdqu KB128, cmll_sub(2, CTX);
1782         vmovdqu %xmm4, cmll_sub(4, CTX);
1783         vmovdqu %xmm5, cmll_sub(6, CTX);
1784         vmovdqu %xmm6, cmll_sub(8, CTX);
1785         vmovdqu %xmm7, cmll_sub(10, CTX);
1786         vmovdqu %xmm8, cmll_sub(12, CTX);
1787         vmovdqu %xmm9, cmll_sub(14, CTX);
1788
1789         vmovdqu cmll_sub(32, CTX), KB128;
1790
1791         /* subl(1) ^= subr(1) & ~subr(17); */
1792         vpandn %xmm15, %xmm10, %xmm13;
1793         vpslldq $12, %xmm13, %xmm13;
1794         vpsrldq $8, %xmm13, %xmm13;
1795         vpxor %xmm13, %xmm15, %xmm15;
1796         /* dw = subl(1) & subl(17), subr(1) ^= CAMELLIA_RL1(dw); */
1797         vpand %xmm15, %xmm10, %xmm14;
1798         vpslld $1, %xmm14, %xmm13;
1799         vpsrld $31, %xmm14, %xmm14;
1800         vpaddd %xmm13, %xmm14, %xmm14;
1801         vpslldq $8, %xmm14, %xmm14;
1802         vpsrldq $12, %xmm14, %xmm14;
1803         vpxor %xmm14, %xmm15, %xmm15;
1804
1805         vpxor %xmm15, %xmm11, %xmm11;
1806         vpxor %xmm15, %xmm12, %xmm12;
1807
1808         vec_ror128(KL128, %xmm4, 128-77, %xmm14);
1809         vec_ror128(KA128, %xmm5, 128-77, %xmm14);
1810         vec_ror128(KR128, %xmm6, 128-94, %xmm14);
1811         vec_ror128(KA128, %xmm7, 128-94, %xmm14);
1812         vec_ror128(KL128, %xmm8, 128-111, %xmm14);
1813         vec_ror128(KB128, %xmm9, 128-111, %xmm14);
1814
1815         vpxor %xmm15, %xmm4, %xmm4;
1816
1817         vpshufd $0x1b, %xmm10, %xmm10;
1818         vpshufd $0x1b, %xmm11, %xmm11;
1819         vpshufd $0x1b, %xmm12, %xmm12;
1820         vpshufd $0x1b, %xmm4, %xmm4;
1821
1822         vmovdqu %xmm10, cmll_sub(16, CTX);
1823         vmovdqu %xmm11, cmll_sub(18, CTX);
1824         vmovdqu %xmm12, cmll_sub(20, CTX);
1825         vmovdqu %xmm4, cmll_sub(22, CTX);
1826
1827         /* subl(1) ^= subr(1) & ~subr(25); */
1828         vpandn %xmm15, %xmm5, %xmm13;
1829         vpslldq $12, %xmm13, %xmm13;
1830         vpsrldq $8, %xmm13, %xmm13;
1831         vpxor %xmm13, %xmm15, %xmm15;
1832         /* dw = subl(1) & subl(25), subr(1) ^= CAMELLIA_RL1(dw); */
1833         vpand %xmm15, %xmm5, %xmm14;
1834         vpslld $1, %xmm14, %xmm13;
1835         vpsrld $31, %xmm14, %xmm14;
1836         vpaddd %xmm13, %xmm14, %xmm14;
1837         vpslldq $8, %xmm14, %xmm14;
1838         vpsrldq $12, %xmm14, %xmm14;
1839         vpxor %xmm14, %xmm15, %xmm15;
1840
1841         vpxor %xmm15, %xmm6, %xmm6;
1842         vpxor %xmm15, %xmm7, %xmm7;
1843         vpxor %xmm15, %xmm8, %xmm8;
1844         vpslldq $8, %xmm15, %xmm15;
1845         vpxor %xmm15, %xmm9, %xmm9;
1846
1847         /* absorb kw4 to other subkeys */
1848         vpslldq $8, %xmm9, %xmm15;
1849         vpxor %xmm15, %xmm8, %xmm8;
1850         vpxor %xmm15, %xmm7, %xmm7;
1851         vpxor %xmm15, %xmm6, %xmm6;
1852
1853         /* subl(33) ^= subr(33) & ~subr(24); */
1854         vpandn %xmm15, %xmm5, %xmm14;
1855         vpslldq $4, %xmm14, %xmm14;
1856         vpxor %xmm14, %xmm15, %xmm15;
1857         /* dw = subl(33) & subl(24), subr(33) ^= CAMELLIA_RL1(dw); */
1858         vpand %xmm15, %xmm5, %xmm14;
1859         vpslld $1, %xmm14, %xmm13;
1860         vpsrld $31, %xmm14, %xmm14;
1861         vpaddd %xmm13, %xmm14, %xmm14;
1862         vpsrldq $12, %xmm14, %xmm14;
1863         vpslldq $8, %xmm14, %xmm14;
1864         vpxor %xmm14, %xmm15, %xmm15;
1865
1866         vpshufd $0x1b, %xmm5, %xmm5;
1867         vpshufd $0x1b, %xmm6, %xmm6;
1868         vpshufd $0x1b, %xmm7, %xmm7;
1869         vpshufd $0x1b, %xmm8, %xmm8;
1870         vpshufd $0x1b, %xmm9, %xmm9;
1871
1872         vmovdqu %xmm5, cmll_sub(24, CTX);
1873         vmovdqu %xmm6, cmll_sub(26, CTX);
1874         vmovdqu %xmm7, cmll_sub(28, CTX);
1875         vmovdqu %xmm8, cmll_sub(30, CTX);
1876         vmovdqu %xmm9, cmll_sub(32, CTX);
1877
1878         vpshufd $0x1b, cmll_sub(22, CTX), %xmm0;
1879         vpshufd $0x1b, cmll_sub(20, CTX), %xmm1;
1880         vpshufd $0x1b, cmll_sub(18, CTX), %xmm2;
1881         vpshufd $0x1b, cmll_sub(16, CTX), %xmm3;
1882         vpshufd $0x1b, cmll_sub(14, CTX), %xmm4;
1883         vpshufd $0x1b, cmll_sub(12, CTX), %xmm5;
1884         vpshufd $0x1b, cmll_sub(10, CTX), %xmm6;
1885         vpshufd $0x1b, cmll_sub(8, CTX), %xmm7;
1886
1887         vpxor %xmm15, %xmm0, %xmm0;
1888         vpxor %xmm15, %xmm1, %xmm1;
1889         vpxor %xmm15, %xmm2, %xmm2;
1890
1891         /* subl(33) ^= subr(33) & ~subr(24); */
1892         vpandn %xmm15, %xmm3, %xmm14;
1893         vpslldq $4, %xmm14, %xmm14;
1894         vpxor %xmm14, %xmm15, %xmm15;
1895         /* dw = subl(33) & subl(24), subr(33) ^= CAMELLIA_RL1(dw); */
1896         vpand %xmm15, %xmm3, %xmm14;
1897         vpslld $1, %xmm14, %xmm13;
1898         vpsrld $31, %xmm14, %xmm14;
1899         vpaddd %xmm13, %xmm14, %xmm14;
1900         vpsrldq $12, %xmm14, %xmm14;
1901         vpslldq $8, %xmm14, %xmm14;
1902         vpxor %xmm14, %xmm15, %xmm15;
1903
1904         vpxor %xmm15, %xmm4, %xmm4;
1905         vpxor %xmm15, %xmm5, %xmm5;
1906         vpxor %xmm15, %xmm6, %xmm6;
1907
1908         vpshufd $0x1b, %xmm0, %xmm0;
1909         vpshufd $0x1b, %xmm1, %xmm1;
1910         vpshufd $0x1b, %xmm2, %xmm2;
1911         vpshufd $0x1b, %xmm4, %xmm4;
1912         vpshufd $0x1b, %xmm5, %xmm5;
1913         vpshufd $0x1b, %xmm6, %xmm6;
1914
1915         vmovdqu %xmm0, cmll_sub(22, CTX);
1916         vmovdqu %xmm1, cmll_sub(20, CTX);
1917         vmovdqu %xmm2, cmll_sub(18, CTX);
1918         vmovdqu %xmm4, cmll_sub(14, CTX);
1919         vmovdqu %xmm5, cmll_sub(12, CTX);
1920         vmovdqu %xmm6, cmll_sub(10, CTX);
1921
1922         vpshufd $0x1b, cmll_sub(6, CTX), %xmm6;
1923         vpshufd $0x1b, cmll_sub(4, CTX), %xmm4;
1924         vpshufd $0x1b, cmll_sub(2, CTX), %xmm2;
1925         vpshufd $0x1b, cmll_sub(0, CTX), %xmm0;
1926
1927         /* subl(33) ^= subr(33) & ~subr(24); */
1928         vpandn %xmm15, %xmm7, %xmm14;
1929         vpslldq $4, %xmm14, %xmm14;
1930         vpxor %xmm14, %xmm15, %xmm15;
1931         /* dw = subl(33) & subl(24), subr(33) ^= CAMELLIA_RL1(dw); */
1932         vpand %xmm15, %xmm7, %xmm14;
1933         vpslld $1, %xmm14, %xmm13;
1934         vpsrld $31, %xmm14, %xmm14;
1935         vpaddd %xmm13, %xmm14, %xmm14;
1936         vpsrldq $12, %xmm14, %xmm14;
1937         vpslldq $8, %xmm14, %xmm14;
1938         vpxor %xmm14, %xmm15, %xmm15;
1939
1940         vpxor %xmm15, %xmm6, %xmm6;
1941         vpxor %xmm15, %xmm4, %xmm4;
1942         vpxor %xmm15, %xmm2, %xmm2;
1943         vpxor %xmm15, %xmm0, %xmm0;
1944
1945         vpshufd $0x1b, %xmm6, %xmm6;
1946         vpshufd $0x1b, %xmm4, %xmm4;
1947         vpshufd $0x1b, %xmm2, %xmm2;
1948         vpshufd $0x1b, %xmm0, %xmm0;
1949
1950         vpsrldq $8, %xmm2, %xmm3;
1951         vpsrldq $8, %xmm4, %xmm5;
1952         vpsrldq $8, %xmm6, %xmm7;
1953
1954         /*
1955          * key XOR is end of F-function.
1956          */
1957         vpxor %xmm2, %xmm0, %xmm0;
1958         vpxor %xmm4, %xmm2, %xmm2;
1959
1960         vmovq %xmm0, cmll_sub(0, CTX);
1961         vmovq %xmm3, cmll_sub(2, CTX);
1962         vpxor %xmm5, %xmm3, %xmm3;
1963         vpxor %xmm6, %xmm4, %xmm4;
1964         vpxor %xmm7, %xmm5, %xmm5;
1965         vmovq %xmm2, cmll_sub(3, CTX);
1966         vmovq %xmm3, cmll_sub(4, CTX);
1967         vmovq %xmm4, cmll_sub(5, CTX);
1968         vmovq %xmm5, cmll_sub(6, CTX);
1969
1970         vmovq cmll_sub(7, CTX), %xmm7;
1971         vmovq cmll_sub(8, CTX), %xmm8;
1972         vmovq cmll_sub(9, CTX), %xmm9;
1973         vmovq cmll_sub(10, CTX), %xmm10;
1974         /* tl = subl(10) ^ (subr(10) & ~subr(8)); */
1975         vpandn %xmm10, %xmm8, %xmm15;
1976         vpsrldq $4, %xmm15, %xmm15;
1977         vpxor %xmm15, %xmm10, %xmm0;
1978         /* dw = tl & subl(8), tr = subr(10) ^ CAMELLIA_RL1(dw); */
1979         vpand %xmm8, %xmm0, %xmm15;
1980         vpslld $1, %xmm15, %xmm14;
1981         vpsrld $31, %xmm15, %xmm15;
1982         vpaddd %xmm14, %xmm15, %xmm15;
1983         vpslldq $12, %xmm15, %xmm15;
1984         vpsrldq $8, %xmm15, %xmm15;
1985         vpxor %xmm15, %xmm0, %xmm0;
1986
1987         vpxor %xmm0, %xmm6, %xmm6;
1988         vmovq %xmm6, cmll_sub(7, CTX);
1989
1990         vmovq cmll_sub(11, CTX), %xmm11;
1991         vmovq cmll_sub(12, CTX), %xmm12;
1992         vmovq cmll_sub(13, CTX), %xmm13;
1993         vmovq cmll_sub(14, CTX), %xmm14;
1994         vmovq cmll_sub(15, CTX), %xmm15;
1995         /* tl = subl(7) ^ (subr(7) & ~subr(9)); */
1996         vpandn %xmm7, %xmm9, %xmm1;
1997         vpsrldq $4, %xmm1, %xmm1;
1998         vpxor %xmm1, %xmm7, %xmm0;
1999         /* dw = tl & subl(9), tr = subr(7) ^ CAMELLIA_RL1(dw); */
2000         vpand %xmm9, %xmm0, %xmm1;
2001         vpslld $1, %xmm1, %xmm2;
2002         vpsrld $31, %xmm1, %xmm1;
2003         vpaddd %xmm2, %xmm1, %xmm1;
2004         vpslldq $12, %xmm1, %xmm1;
2005         vpsrldq $8, %xmm1, %xmm1;
2006         vpxor %xmm1, %xmm0, %xmm0;
2007
2008         vpxor %xmm11, %xmm0, %xmm0;
2009         vpxor %xmm12, %xmm10, %xmm10;
2010         vpxor %xmm13, %xmm11, %xmm11;
2011         vpxor %xmm14, %xmm12, %xmm12;
2012         vpxor %xmm15, %xmm13, %xmm13;
2013         vmovq %xmm0, cmll_sub(10, CTX);
2014         vmovq %xmm10, cmll_sub(11, CTX);
2015         vmovq %xmm11, cmll_sub(12, CTX);
2016         vmovq %xmm12, cmll_sub(13, CTX);
2017         vmovq %xmm13, cmll_sub(14, CTX);
2018
2019         vmovq cmll_sub(16, CTX), %xmm6;
2020         vmovq cmll_sub(17, CTX), %xmm7;
2021         vmovq cmll_sub(18, CTX), %xmm8;
2022         vmovq cmll_sub(19, CTX), %xmm9;
2023         vmovq cmll_sub(20, CTX), %xmm10;
2024         /* tl = subl(18) ^ (subr(18) & ~subr(16)); */
2025         vpandn %xmm8, %xmm6, %xmm1;
2026         vpsrldq $4, %xmm1, %xmm1;
2027         vpxor %xmm1, %xmm8, %xmm0;
2028         /* dw = tl & subl(16), tr = subr(18) ^ CAMELLIA_RL1(dw); */
2029         vpand %xmm6, %xmm0, %xmm1;
2030         vpslld $1, %xmm1, %xmm2;
2031         vpsrld $31, %xmm1, %xmm1;
2032         vpaddd %xmm2, %xmm1, %xmm1;
2033         vpslldq $12, %xmm1, %xmm1;
2034         vpsrldq $8, %xmm1, %xmm1;
2035         vpxor %xmm1, %xmm0, %xmm0;
2036
2037         vpxor %xmm14, %xmm0, %xmm0;
2038         vmovq %xmm0, cmll_sub(15, CTX);
2039
2040         /* tl = subl(15) ^ (subr(15) & ~subr(17)); */
2041         vpandn %xmm15, %xmm7, %xmm1;
2042         vpsrldq $4, %xmm1, %xmm1;
2043         vpxor %xmm1, %xmm15, %xmm0;
2044         /* dw = tl & subl(17), tr = subr(15) ^ CAMELLIA_RL1(dw); */
2045         vpand %xmm7, %xmm0, %xmm1;
2046         vpslld $1, %xmm1, %xmm2;
2047         vpsrld $31, %xmm1, %xmm1;
2048         vpaddd %xmm2, %xmm1, %xmm1;
2049         vpslldq $12, %xmm1, %xmm1;
2050         vpsrldq $8, %xmm1, %xmm1;
2051         vpxor %xmm1, %xmm0, %xmm0;
2052
2053         vmovq cmll_sub(21, CTX), %xmm1;
2054         vmovq cmll_sub(22, CTX), %xmm2;
2055         vmovq cmll_sub(23, CTX), %xmm3;
2056         vmovq cmll_sub(24, CTX), %xmm4;
2057
2058         vpxor %xmm9, %xmm0, %xmm0;
2059         vpxor %xmm10, %xmm8, %xmm8;
2060         vpxor %xmm1, %xmm9, %xmm9;
2061         vpxor %xmm2, %xmm10, %xmm10;
2062         vpxor %xmm3, %xmm1, %xmm1;
2063
2064         vmovq %xmm0, cmll_sub(18, CTX);
2065         vmovq %xmm8, cmll_sub(19, CTX);
2066         vmovq %xmm9, cmll_sub(20, CTX);
2067         vmovq %xmm10, cmll_sub(21, CTX);
2068         vmovq %xmm1, cmll_sub(22, CTX);
2069
2070         vmovq cmll_sub(25, CTX), %xmm5;
2071         vmovq cmll_sub(26, CTX), %xmm6;
2072         vmovq cmll_sub(27, CTX), %xmm7;
2073         vmovq cmll_sub(28, CTX), %xmm8;
2074         vmovq cmll_sub(29, CTX), %xmm9;
2075         vmovq cmll_sub(30, CTX), %xmm10;
2076         vmovq cmll_sub(31, CTX), %xmm11;
2077         vmovq cmll_sub(32, CTX), %xmm12;
2078
2079         /* tl = subl(26) ^ (subr(26) & ~subr(24)); */
2080         vpandn %xmm6, %xmm4, %xmm15;
2081         vpsrldq $4, %xmm15, %xmm15;
2082         vpxor %xmm15, %xmm6, %xmm0;
2083         /* dw = tl & subl(26), tr = subr(24) ^ CAMELLIA_RL1(dw); */
2084         vpand %xmm4, %xmm0, %xmm15;
2085         vpslld $1, %xmm15, %xmm14;
2086         vpsrld $31, %xmm15, %xmm15;
2087         vpaddd %xmm14, %xmm15, %xmm15;
2088         vpslldq $12, %xmm15, %xmm15;
2089         vpsrldq $8, %xmm15, %xmm15;
2090         vpxor %xmm15, %xmm0, %xmm0;
2091
2092         vpxor %xmm0, %xmm2, %xmm2;
2093         vmovq %xmm2, cmll_sub(23, CTX);
2094
2095         /* tl = subl(23) ^ (subr(23) &  ~subr(25)); */
2096         vpandn %xmm3, %xmm5, %xmm15;
2097         vpsrldq $4, %xmm15, %xmm15;
2098         vpxor %xmm15, %xmm3, %xmm0;
2099         /* dw = tl & subl(26), tr = subr(24) ^ CAMELLIA_RL1(dw); */
2100         vpand %xmm5, %xmm0, %xmm15;
2101         vpslld $1, %xmm15, %xmm14;
2102         vpsrld $31, %xmm15, %xmm15;
2103         vpaddd %xmm14, %xmm15, %xmm15;
2104         vpslldq $12, %xmm15, %xmm15;
2105         vpsrldq $8, %xmm15, %xmm15;
2106         vpxor %xmm15, %xmm0, %xmm0;
2107
2108         vpxor %xmm7, %xmm0, %xmm0;
2109         vpxor %xmm8, %xmm6, %xmm6;
2110         vpxor %xmm9, %xmm7, %xmm7;
2111         vpxor %xmm10, %xmm8, %xmm8;
2112         vpxor %xmm11, %xmm9, %xmm9;
2113         vpxor %xmm12, %xmm11, %xmm11;
2114
2115         vmovq %xmm0, cmll_sub(26, CTX);
2116         vmovq %xmm6, cmll_sub(27, CTX);
2117         vmovq %xmm7, cmll_sub(28, CTX);
2118         vmovq %xmm8, cmll_sub(29, CTX);
2119         vmovq %xmm9, cmll_sub(30, CTX);
2120         vmovq %xmm10, cmll_sub(31, CTX);
2121         vmovq %xmm11, cmll_sub(32, CTX);
2122
2123         /* kw2 and kw4 are unused now. */
2124         movq $0, cmll_sub(1, CTX);
2125         movq $0, cmll_sub(33, CTX);
2126
2127         vzeroall;
2128
2129         ret;
2130 .size __camellia_avx_setup256,.-__camellia_avx_setup256;
2131
2132 .align 8
2133 .globl _gcry_camellia_aesni_avx_keygen
2134 .type  _gcry_camellia_aesni_avx_keygen,@function;
2135
2136 _gcry_camellia_aesni_avx_keygen:
2137         /* input:
2138          *      %rdi: ctx, CTX
2139          *      %rsi: key
2140          *      %rdx: keylen
2141          */
2142
2143         vzeroupper;
2144
2145         vmovdqu (%rsi), %xmm0;
2146         cmpl $24, %edx;
2147         jb __camellia_avx_setup128;
2148         je .Lprepare_key192;
2149
2150         vmovdqu 16(%rsi), %xmm1;
2151         jmp __camellia_avx_setup256;
2152
2153 .Lprepare_key192:
2154         vpcmpeqd %xmm2, %xmm2, %xmm2;
2155         vmovq 16(%rsi), %xmm1;
2156
2157         vpxor %xmm1, %xmm2, %xmm2;
2158         vpslldq $8, %xmm2, %xmm2;
2159         vpor %xmm2, %xmm1, %xmm1;
2160
2161         jmp __camellia_avx_setup256;
2162 .size _gcry_camellia_aesni_avx_keygen,.-_gcry_camellia_aesni_avx_keygen;
2163
2164 #endif /*defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)*/
2165 #endif /*__x86_64*/