doc: Fix typo.
[libgcrypt.git] / cipher / camellia-aesni-avx2-amd64.S
1 /* camellia-avx2-aesni-amd64.S  -  AES-NI/AVX2 implementation of Camellia cipher
2  *
3  * Copyright (C) 2013-2015 Jussi Kivilinna <jussi.kivilinna@iki.fi>
4  *
5  * This file is part of Libgcrypt.
6  *
7  * Libgcrypt is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU Lesser General Public License as
9  * published by the Free Software Foundation; either version 2.1 of
10  * the License, or (at your option) any later version.
11  *
12  * Libgcrypt is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
19  */
20
21 #ifdef __x86_64
22 #include <config.h>
23 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
24      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
25     defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX2_SUPPORT)
26
27 #ifdef __PIC__
28 #  define RIP (%rip)
29 #else
30 #  define RIP
31 #endif
32
33 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
34 # define ELF(...) __VA_ARGS__
35 #else
36 # define ELF(...) /*_*/
37 #endif
38
39 #define CAMELLIA_TABLE_BYTE_LEN 272
40
41 /* struct CAMELLIA_context: */
42 #define key_table 0
43 #define key_bitlength CAMELLIA_TABLE_BYTE_LEN
44
45 /* register macros */
46 #define CTX %rdi
47 #define RIO %r8
48
49 /**********************************************************************
50   helper macros
51  **********************************************************************/
52 #define filter_8bit(x, lo_t, hi_t, mask4bit, tmp0) \
53         vpand x, mask4bit, tmp0; \
54         vpandn x, mask4bit, x; \
55         vpsrld $4, x, x; \
56         \
57         vpshufb tmp0, lo_t, tmp0; \
58         vpshufb x, hi_t, x; \
59         vpxor tmp0, x, x;
60
61 #define ymm0_x xmm0
62 #define ymm1_x xmm1
63 #define ymm2_x xmm2
64 #define ymm3_x xmm3
65 #define ymm4_x xmm4
66 #define ymm5_x xmm5
67 #define ymm6_x xmm6
68 #define ymm7_x xmm7
69 #define ymm8_x xmm8
70 #define ymm9_x xmm9
71 #define ymm10_x xmm10
72 #define ymm11_x xmm11
73 #define ymm12_x xmm12
74 #define ymm13_x xmm13
75 #define ymm14_x xmm14
76 #define ymm15_x xmm15
77
78 /**********************************************************************
79   32-way camellia
80  **********************************************************************/
81
82 /*
83  * IN:
84  *   x0..x7: byte-sliced AB state
85  *   mem_cd: register pointer storing CD state
86  *   key: index for key material
87  * OUT:
88  *   x0..x7: new byte-sliced CD state
89  */
90 #define roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, t0, t1, t2, t3, t4, t5, t6, \
91                   t7, mem_cd, key) \
92         /* \
93          * S-function with AES subbytes \
94          */ \
95         vbroadcasti128 .Linv_shift_row RIP, t4; \
96         vpbroadcastd .L0f0f0f0f RIP, t7; \
97         vbroadcasti128 .Lpre_tf_lo_s1 RIP, t5; \
98         vbroadcasti128 .Lpre_tf_hi_s1 RIP, t6; \
99         vbroadcasti128 .Lpre_tf_lo_s4 RIP, t2; \
100         vbroadcasti128 .Lpre_tf_hi_s4 RIP, t3; \
101         \
102         /* AES inverse shift rows */ \
103         vpshufb t4, x0, x0; \
104         vpshufb t4, x7, x7; \
105         vpshufb t4, x3, x3; \
106         vpshufb t4, x6, x6; \
107         vpshufb t4, x2, x2; \
108         vpshufb t4, x5, x5; \
109         vpshufb t4, x1, x1; \
110         vpshufb t4, x4, x4; \
111         \
112         /* prefilter sboxes 1, 2 and 3 */ \
113         /* prefilter sbox 4 */ \
114         filter_8bit(x0, t5, t6, t7, t4); \
115         filter_8bit(x7, t5, t6, t7, t4); \
116         vextracti128 $1, x0, t0##_x; \
117         vextracti128 $1, x7, t1##_x; \
118         filter_8bit(x3, t2, t3, t7, t4); \
119         filter_8bit(x6, t2, t3, t7, t4); \
120         vextracti128 $1, x3, t3##_x; \
121         vextracti128 $1, x6, t2##_x; \
122         filter_8bit(x2, t5, t6, t7, t4); \
123         filter_8bit(x5, t5, t6, t7, t4); \
124         filter_8bit(x1, t5, t6, t7, t4); \
125         filter_8bit(x4, t5, t6, t7, t4); \
126         \
127         vpxor t4##_x, t4##_x, t4##_x; \
128         \
129         /* AES subbytes + AES shift rows */ \
130         vextracti128 $1, x2, t6##_x; \
131         vextracti128 $1, x5, t5##_x; \
132         vaesenclast t4##_x, x0##_x, x0##_x; \
133         vaesenclast t4##_x, t0##_x, t0##_x; \
134         vaesenclast t4##_x, x7##_x, x7##_x; \
135         vaesenclast t4##_x, t1##_x, t1##_x; \
136         vaesenclast t4##_x, x3##_x, x3##_x; \
137         vaesenclast t4##_x, t3##_x, t3##_x; \
138         vaesenclast t4##_x, x6##_x, x6##_x; \
139         vaesenclast t4##_x, t2##_x, t2##_x; \
140         vinserti128 $1, t0##_x, x0, x0; \
141         vinserti128 $1, t1##_x, x7, x7; \
142         vinserti128 $1, t3##_x, x3, x3; \
143         vinserti128 $1, t2##_x, x6, x6; \
144         vextracti128 $1, x1, t3##_x; \
145         vextracti128 $1, x4, t2##_x; \
146         vbroadcasti128 .Lpost_tf_lo_s1 RIP, t0; \
147         vbroadcasti128 .Lpost_tf_hi_s1 RIP, t1; \
148         vaesenclast t4##_x, x2##_x, x2##_x; \
149         vaesenclast t4##_x, t6##_x, t6##_x; \
150         vaesenclast t4##_x, x5##_x, x5##_x; \
151         vaesenclast t4##_x, t5##_x, t5##_x; \
152         vaesenclast t4##_x, x1##_x, x1##_x; \
153         vaesenclast t4##_x, t3##_x, t3##_x; \
154         vaesenclast t4##_x, x4##_x, x4##_x; \
155         vaesenclast t4##_x, t2##_x, t2##_x; \
156         vinserti128 $1, t6##_x, x2, x2; \
157         vinserti128 $1, t5##_x, x5, x5; \
158         vinserti128 $1, t3##_x, x1, x1; \
159         vinserti128 $1, t2##_x, x4, x4; \
160         \
161         /* postfilter sboxes 1 and 4 */ \
162         vbroadcasti128 .Lpost_tf_lo_s3 RIP, t2; \
163         vbroadcasti128 .Lpost_tf_hi_s3 RIP, t3; \
164         filter_8bit(x0, t0, t1, t7, t4); \
165         filter_8bit(x7, t0, t1, t7, t4); \
166         filter_8bit(x3, t0, t1, t7, t6); \
167         filter_8bit(x6, t0, t1, t7, t6); \
168         \
169         /* postfilter sbox 3 */ \
170         vbroadcasti128 .Lpost_tf_lo_s2 RIP, t4; \
171         vbroadcasti128 .Lpost_tf_hi_s2 RIP, t5; \
172         filter_8bit(x2, t2, t3, t7, t6); \
173         filter_8bit(x5, t2, t3, t7, t6); \
174         \
175         vpbroadcastq key, t0; /* higher 64-bit duplicate ignored */ \
176         \
177         /* postfilter sbox 2 */ \
178         filter_8bit(x1, t4, t5, t7, t2); \
179         filter_8bit(x4, t4, t5, t7, t2); \
180         vpxor t7, t7, t7; \
181         \
182         vpsrldq $1, t0, t1; \
183         vpsrldq $2, t0, t2; \
184         vpshufb t7, t1, t1; \
185         vpsrldq $3, t0, t3; \
186         \
187         /* P-function */ \
188         vpxor x5, x0, x0; \
189         vpxor x6, x1, x1; \
190         vpxor x7, x2, x2; \
191         vpxor x4, x3, x3; \
192         \
193         vpshufb t7, t2, t2; \
194         vpsrldq $4, t0, t4; \
195         vpshufb t7, t3, t3; \
196         vpsrldq $5, t0, t5; \
197         vpshufb t7, t4, t4; \
198         \
199         vpxor x2, x4, x4; \
200         vpxor x3, x5, x5; \
201         vpxor x0, x6, x6; \
202         vpxor x1, x7, x7; \
203         \
204         vpsrldq $6, t0, t6; \
205         vpshufb t7, t5, t5; \
206         vpshufb t7, t6, t6; \
207         \
208         vpxor x7, x0, x0; \
209         vpxor x4, x1, x1; \
210         vpxor x5, x2, x2; \
211         vpxor x6, x3, x3; \
212         \
213         vpxor x3, x4, x4; \
214         vpxor x0, x5, x5; \
215         vpxor x1, x6, x6; \
216         vpxor x2, x7, x7; /* note: high and low parts swapped */ \
217         \
218         /* Add key material and result to CD (x becomes new CD) */ \
219         \
220         vpxor t6, x1, x1; \
221         vpxor 5 * 32(mem_cd), x1, x1; \
222         \
223         vpsrldq $7, t0, t6; \
224         vpshufb t7, t0, t0; \
225         vpshufb t7, t6, t7; \
226         \
227         vpxor t7, x0, x0; \
228         vpxor 4 * 32(mem_cd), x0, x0; \
229         \
230         vpxor t5, x2, x2; \
231         vpxor 6 * 32(mem_cd), x2, x2; \
232         \
233         vpxor t4, x3, x3; \
234         vpxor 7 * 32(mem_cd), x3, x3; \
235         \
236         vpxor t3, x4, x4; \
237         vpxor 0 * 32(mem_cd), x4, x4; \
238         \
239         vpxor t2, x5, x5; \
240         vpxor 1 * 32(mem_cd), x5, x5; \
241         \
242         vpxor t1, x6, x6; \
243         vpxor 2 * 32(mem_cd), x6, x6; \
244         \
245         vpxor t0, x7, x7; \
246         vpxor 3 * 32(mem_cd), x7, x7;
247
248 /*
249  * IN/OUT:
250  *  x0..x7: byte-sliced AB state preloaded
251  *  mem_ab: byte-sliced AB state in memory
252  *  mem_cb: byte-sliced CD state in memory
253  */
254 #define two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
255                       y6, y7, mem_ab, mem_cd, i, dir, store_ab) \
256         roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
257                   y6, y7, mem_cd, (key_table + (i) * 8)(CTX)); \
258         \
259         vmovdqu x0, 4 * 32(mem_cd); \
260         vmovdqu x1, 5 * 32(mem_cd); \
261         vmovdqu x2, 6 * 32(mem_cd); \
262         vmovdqu x3, 7 * 32(mem_cd); \
263         vmovdqu x4, 0 * 32(mem_cd); \
264         vmovdqu x5, 1 * 32(mem_cd); \
265         vmovdqu x6, 2 * 32(mem_cd); \
266         vmovdqu x7, 3 * 32(mem_cd); \
267         \
268         roundsm32(x4, x5, x6, x7, x0, x1, x2, x3, y0, y1, y2, y3, y4, y5, \
269                   y6, y7, mem_ab, (key_table + ((i) + (dir)) * 8)(CTX)); \
270         \
271         store_ab(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab);
272
273 #define dummy_store(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) /* do nothing */
274
275 #define store_ab_state(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) \
276         /* Store new AB state */ \
277         vmovdqu x4, 4 * 32(mem_ab); \
278         vmovdqu x5, 5 * 32(mem_ab); \
279         vmovdqu x6, 6 * 32(mem_ab); \
280         vmovdqu x7, 7 * 32(mem_ab); \
281         vmovdqu x0, 0 * 32(mem_ab); \
282         vmovdqu x1, 1 * 32(mem_ab); \
283         vmovdqu x2, 2 * 32(mem_ab); \
284         vmovdqu x3, 3 * 32(mem_ab);
285
286 #define enc_rounds32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
287                       y6, y7, mem_ab, mem_cd, i) \
288         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
289                       y6, y7, mem_ab, mem_cd, (i) + 2, 1, store_ab_state); \
290         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
291                       y6, y7, mem_ab, mem_cd, (i) + 4, 1, store_ab_state); \
292         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
293                       y6, y7, mem_ab, mem_cd, (i) + 6, 1, dummy_store);
294
295 #define dec_rounds32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
296                       y6, y7, mem_ab, mem_cd, i) \
297         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
298                       y6, y7, mem_ab, mem_cd, (i) + 7, -1, store_ab_state); \
299         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
300                       y6, y7, mem_ab, mem_cd, (i) + 5, -1, store_ab_state); \
301         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
302                       y6, y7, mem_ab, mem_cd, (i) + 3, -1, dummy_store);
303
304 /*
305  * IN:
306  *  v0..3: byte-sliced 32-bit integers
307  * OUT:
308  *  v0..3: (IN <<< 1)
309  */
310 #define rol32_1_32(v0, v1, v2, v3, t0, t1, t2, zero) \
311         vpcmpgtb v0, zero, t0; \
312         vpaddb v0, v0, v0; \
313         vpabsb t0, t0; \
314         \
315         vpcmpgtb v1, zero, t1; \
316         vpaddb v1, v1, v1; \
317         vpabsb t1, t1; \
318         \
319         vpcmpgtb v2, zero, t2; \
320         vpaddb v2, v2, v2; \
321         vpabsb t2, t2; \
322         \
323         vpor t0, v1, v1; \
324         \
325         vpcmpgtb v3, zero, t0; \
326         vpaddb v3, v3, v3; \
327         vpabsb t0, t0; \
328         \
329         vpor t1, v2, v2; \
330         vpor t2, v3, v3; \
331         vpor t0, v0, v0;
332
333 /*
334  * IN:
335  *   r: byte-sliced AB state in memory
336  *   l: byte-sliced CD state in memory
337  * OUT:
338  *   x0..x7: new byte-sliced CD state
339  */
340 #define fls32(l, l0, l1, l2, l3, l4, l5, l6, l7, r, t0, t1, t2, t3, tt0, \
341               tt1, tt2, tt3, kll, klr, krl, krr) \
342         /* \
343          * t0 = kll; \
344          * t0 &= ll; \
345          * lr ^= rol32(t0, 1); \
346          */ \
347         vpbroadcastd kll, t0; /* only lowest 32-bit used */ \
348         vpxor tt0, tt0, tt0; \
349         vpshufb tt0, t0, t3; \
350         vpsrldq $1, t0, t0; \
351         vpshufb tt0, t0, t2; \
352         vpsrldq $1, t0, t0; \
353         vpshufb tt0, t0, t1; \
354         vpsrldq $1, t0, t0; \
355         vpshufb tt0, t0, t0; \
356         \
357         vpand l0, t0, t0; \
358         vpand l1, t1, t1; \
359         vpand l2, t2, t2; \
360         vpand l3, t3, t3; \
361         \
362         rol32_1_32(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
363         \
364         vpxor l4, t0, l4; \
365         vpbroadcastd krr, t0; /* only lowest 32-bit used */ \
366         vmovdqu l4, 4 * 32(l); \
367         vpxor l5, t1, l5; \
368         vmovdqu l5, 5 * 32(l); \
369         vpxor l6, t2, l6; \
370         vmovdqu l6, 6 * 32(l); \
371         vpxor l7, t3, l7; \
372         vmovdqu l7, 7 * 32(l); \
373         \
374         /* \
375          * t2 = krr; \
376          * t2 |= rr; \
377          * rl ^= t2; \
378          */ \
379         \
380         vpshufb tt0, t0, t3; \
381         vpsrldq $1, t0, t0; \
382         vpshufb tt0, t0, t2; \
383         vpsrldq $1, t0, t0; \
384         vpshufb tt0, t0, t1; \
385         vpsrldq $1, t0, t0; \
386         vpshufb tt0, t0, t0; \
387         \
388         vpor 4 * 32(r), t0, t0; \
389         vpor 5 * 32(r), t1, t1; \
390         vpor 6 * 32(r), t2, t2; \
391         vpor 7 * 32(r), t3, t3; \
392         \
393         vpxor 0 * 32(r), t0, t0; \
394         vpxor 1 * 32(r), t1, t1; \
395         vpxor 2 * 32(r), t2, t2; \
396         vpxor 3 * 32(r), t3, t3; \
397         vmovdqu t0, 0 * 32(r); \
398         vpbroadcastd krl, t0; /* only lowest 32-bit used */ \
399         vmovdqu t1, 1 * 32(r); \
400         vmovdqu t2, 2 * 32(r); \
401         vmovdqu t3, 3 * 32(r); \
402         \
403         /* \
404          * t2 = krl; \
405          * t2 &= rl; \
406          * rr ^= rol32(t2, 1); \
407          */ \
408         vpshufb tt0, t0, t3; \
409         vpsrldq $1, t0, t0; \
410         vpshufb tt0, t0, t2; \
411         vpsrldq $1, t0, t0; \
412         vpshufb tt0, t0, t1; \
413         vpsrldq $1, t0, t0; \
414         vpshufb tt0, t0, t0; \
415         \
416         vpand 0 * 32(r), t0, t0; \
417         vpand 1 * 32(r), t1, t1; \
418         vpand 2 * 32(r), t2, t2; \
419         vpand 3 * 32(r), t3, t3; \
420         \
421         rol32_1_32(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
422         \
423         vpxor 4 * 32(r), t0, t0; \
424         vpxor 5 * 32(r), t1, t1; \
425         vpxor 6 * 32(r), t2, t2; \
426         vpxor 7 * 32(r), t3, t3; \
427         vmovdqu t0, 4 * 32(r); \
428         vpbroadcastd klr, t0; /* only lowest 32-bit used */ \
429         vmovdqu t1, 5 * 32(r); \
430         vmovdqu t2, 6 * 32(r); \
431         vmovdqu t3, 7 * 32(r); \
432         \
433         /* \
434          * t0 = klr; \
435          * t0 |= lr; \
436          * ll ^= t0; \
437          */ \
438         \
439         vpshufb tt0, t0, t3; \
440         vpsrldq $1, t0, t0; \
441         vpshufb tt0, t0, t2; \
442         vpsrldq $1, t0, t0; \
443         vpshufb tt0, t0, t1; \
444         vpsrldq $1, t0, t0; \
445         vpshufb tt0, t0, t0; \
446         \
447         vpor l4, t0, t0; \
448         vpor l5, t1, t1; \
449         vpor l6, t2, t2; \
450         vpor l7, t3, t3; \
451         \
452         vpxor l0, t0, l0; \
453         vmovdqu l0, 0 * 32(l); \
454         vpxor l1, t1, l1; \
455         vmovdqu l1, 1 * 32(l); \
456         vpxor l2, t2, l2; \
457         vmovdqu l2, 2 * 32(l); \
458         vpxor l3, t3, l3; \
459         vmovdqu l3, 3 * 32(l);
460
461 #define transpose_4x4(x0, x1, x2, x3, t1, t2) \
462         vpunpckhdq x1, x0, t2; \
463         vpunpckldq x1, x0, x0; \
464         \
465         vpunpckldq x3, x2, t1; \
466         vpunpckhdq x3, x2, x2; \
467         \
468         vpunpckhqdq t1, x0, x1; \
469         vpunpcklqdq t1, x0, x0; \
470         \
471         vpunpckhqdq x2, t2, x3; \
472         vpunpcklqdq x2, t2, x2;
473
474 #define byteslice_16x16b_fast(a0, b0, c0, d0, a1, b1, c1, d1, a2, b2, c2, d2, \
475                               a3, b3, c3, d3, st0, st1) \
476         vmovdqu d2, st0; \
477         vmovdqu d3, st1; \
478         transpose_4x4(a0, a1, a2, a3, d2, d3); \
479         transpose_4x4(b0, b1, b2, b3, d2, d3); \
480         vmovdqu st0, d2; \
481         vmovdqu st1, d3; \
482         \
483         vmovdqu a0, st0; \
484         vmovdqu a1, st1; \
485         transpose_4x4(c0, c1, c2, c3, a0, a1); \
486         transpose_4x4(d0, d1, d2, d3, a0, a1); \
487         \
488         vbroadcasti128 .Lshufb_16x16b RIP, a0; \
489         vmovdqu st1, a1; \
490         vpshufb a0, a2, a2; \
491         vpshufb a0, a3, a3; \
492         vpshufb a0, b0, b0; \
493         vpshufb a0, b1, b1; \
494         vpshufb a0, b2, b2; \
495         vpshufb a0, b3, b3; \
496         vpshufb a0, a1, a1; \
497         vpshufb a0, c0, c0; \
498         vpshufb a0, c1, c1; \
499         vpshufb a0, c2, c2; \
500         vpshufb a0, c3, c3; \
501         vpshufb a0, d0, d0; \
502         vpshufb a0, d1, d1; \
503         vpshufb a0, d2, d2; \
504         vpshufb a0, d3, d3; \
505         vmovdqu d3, st1; \
506         vmovdqu st0, d3; \
507         vpshufb a0, d3, a0; \
508         vmovdqu d2, st0; \
509         \
510         transpose_4x4(a0, b0, c0, d0, d2, d3); \
511         transpose_4x4(a1, b1, c1, d1, d2, d3); \
512         vmovdqu st0, d2; \
513         vmovdqu st1, d3; \
514         \
515         vmovdqu b0, st0; \
516         vmovdqu b1, st1; \
517         transpose_4x4(a2, b2, c2, d2, b0, b1); \
518         transpose_4x4(a3, b3, c3, d3, b0, b1); \
519         vmovdqu st0, b0; \
520         vmovdqu st1, b1; \
521         /* does not adjust output bytes inside vectors */
522
523 /* load blocks to registers and apply pre-whitening */
524 #define inpack32_pre(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
525                      y6, y7, rio, key) \
526         vpbroadcastq key, x0; \
527         vpshufb .Lpack_bswap RIP, x0, x0; \
528         \
529         vpxor 0 * 32(rio), x0, y7; \
530         vpxor 1 * 32(rio), x0, y6; \
531         vpxor 2 * 32(rio), x0, y5; \
532         vpxor 3 * 32(rio), x0, y4; \
533         vpxor 4 * 32(rio), x0, y3; \
534         vpxor 5 * 32(rio), x0, y2; \
535         vpxor 6 * 32(rio), x0, y1; \
536         vpxor 7 * 32(rio), x0, y0; \
537         vpxor 8 * 32(rio), x0, x7; \
538         vpxor 9 * 32(rio), x0, x6; \
539         vpxor 10 * 32(rio), x0, x5; \
540         vpxor 11 * 32(rio), x0, x4; \
541         vpxor 12 * 32(rio), x0, x3; \
542         vpxor 13 * 32(rio), x0, x2; \
543         vpxor 14 * 32(rio), x0, x1; \
544         vpxor 15 * 32(rio), x0, x0;
545
546 /* byteslice pre-whitened blocks and store to temporary memory */
547 #define inpack32_post(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
548                       y6, y7, mem_ab, mem_cd) \
549         byteslice_16x16b_fast(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, \
550                               y4, y5, y6, y7, (mem_ab), (mem_cd)); \
551         \
552         vmovdqu x0, 0 * 32(mem_ab); \
553         vmovdqu x1, 1 * 32(mem_ab); \
554         vmovdqu x2, 2 * 32(mem_ab); \
555         vmovdqu x3, 3 * 32(mem_ab); \
556         vmovdqu x4, 4 * 32(mem_ab); \
557         vmovdqu x5, 5 * 32(mem_ab); \
558         vmovdqu x6, 6 * 32(mem_ab); \
559         vmovdqu x7, 7 * 32(mem_ab); \
560         vmovdqu y0, 0 * 32(mem_cd); \
561         vmovdqu y1, 1 * 32(mem_cd); \
562         vmovdqu y2, 2 * 32(mem_cd); \
563         vmovdqu y3, 3 * 32(mem_cd); \
564         vmovdqu y4, 4 * 32(mem_cd); \
565         vmovdqu y5, 5 * 32(mem_cd); \
566         vmovdqu y6, 6 * 32(mem_cd); \
567         vmovdqu y7, 7 * 32(mem_cd);
568
569 /* de-byteslice, apply post-whitening and store blocks */
570 #define outunpack32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, \
571                     y5, y6, y7, key, stack_tmp0, stack_tmp1) \
572         byteslice_16x16b_fast(y0, y4, x0, x4, y1, y5, x1, x5, y2, y6, x2, x6, \
573                               y3, y7, x3, x7, stack_tmp0, stack_tmp1); \
574         \
575         vmovdqu x0, stack_tmp0; \
576         \
577         vpbroadcastq key, x0; \
578         vpshufb .Lpack_bswap RIP, x0, x0; \
579         \
580         vpxor x0, y7, y7; \
581         vpxor x0, y6, y6; \
582         vpxor x0, y5, y5; \
583         vpxor x0, y4, y4; \
584         vpxor x0, y3, y3; \
585         vpxor x0, y2, y2; \
586         vpxor x0, y1, y1; \
587         vpxor x0, y0, y0; \
588         vpxor x0, x7, x7; \
589         vpxor x0, x6, x6; \
590         vpxor x0, x5, x5; \
591         vpxor x0, x4, x4; \
592         vpxor x0, x3, x3; \
593         vpxor x0, x2, x2; \
594         vpxor x0, x1, x1; \
595         vpxor stack_tmp0, x0, x0;
596
597 #define write_output(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
598                      y6, y7, rio) \
599         vmovdqu x0, 0 * 32(rio); \
600         vmovdqu x1, 1 * 32(rio); \
601         vmovdqu x2, 2 * 32(rio); \
602         vmovdqu x3, 3 * 32(rio); \
603         vmovdqu x4, 4 * 32(rio); \
604         vmovdqu x5, 5 * 32(rio); \
605         vmovdqu x6, 6 * 32(rio); \
606         vmovdqu x7, 7 * 32(rio); \
607         vmovdqu y0, 8 * 32(rio); \
608         vmovdqu y1, 9 * 32(rio); \
609         vmovdqu y2, 10 * 32(rio); \
610         vmovdqu y3, 11 * 32(rio); \
611         vmovdqu y4, 12 * 32(rio); \
612         vmovdqu y5, 13 * 32(rio); \
613         vmovdqu y6, 14 * 32(rio); \
614         vmovdqu y7, 15 * 32(rio);
615
616 .data
617 .align 32
618
619 #define SHUFB_BYTES(idx) \
620         0 + (idx), 4 + (idx), 8 + (idx), 12 + (idx)
621
622 .Lshufb_16x16b:
623         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3)
624         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3)
625
626 .Lpack_bswap:
627         .long 0x00010203, 0x04050607, 0x80808080, 0x80808080
628         .long 0x00010203, 0x04050607, 0x80808080, 0x80808080
629
630 /* For CTR-mode IV byteswap */
631 .Lbswap128_mask:
632         .byte 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0
633
634 /*
635  * pre-SubByte transform
636  *
637  * pre-lookup for sbox1, sbox2, sbox3:
638  *   swap_bitendianness(
639  *       isom_map_camellia_to_aes(
640  *           camellia_f(
641  *               swap_bitendianess(in)
642  *           )
643  *       )
644  *   )
645  *
646  * (note: '⊕ 0xc5' inside camellia_f())
647  */
648 .Lpre_tf_lo_s1:
649         .byte 0x45, 0xe8, 0x40, 0xed, 0x2e, 0x83, 0x2b, 0x86
650         .byte 0x4b, 0xe6, 0x4e, 0xe3, 0x20, 0x8d, 0x25, 0x88
651 .Lpre_tf_hi_s1:
652         .byte 0x00, 0x51, 0xf1, 0xa0, 0x8a, 0xdb, 0x7b, 0x2a
653         .byte 0x09, 0x58, 0xf8, 0xa9, 0x83, 0xd2, 0x72, 0x23
654
655 /*
656  * pre-SubByte transform
657  *
658  * pre-lookup for sbox4:
659  *   swap_bitendianness(
660  *       isom_map_camellia_to_aes(
661  *           camellia_f(
662  *               swap_bitendianess(in <<< 1)
663  *           )
664  *       )
665  *   )
666  *
667  * (note: '⊕ 0xc5' inside camellia_f())
668  */
669 .Lpre_tf_lo_s4:
670         .byte 0x45, 0x40, 0x2e, 0x2b, 0x4b, 0x4e, 0x20, 0x25
671         .byte 0x14, 0x11, 0x7f, 0x7a, 0x1a, 0x1f, 0x71, 0x74
672 .Lpre_tf_hi_s4:
673         .byte 0x00, 0xf1, 0x8a, 0x7b, 0x09, 0xf8, 0x83, 0x72
674         .byte 0xad, 0x5c, 0x27, 0xd6, 0xa4, 0x55, 0x2e, 0xdf
675
676 /*
677  * post-SubByte transform
678  *
679  * post-lookup for sbox1, sbox4:
680  *  swap_bitendianness(
681  *      camellia_h(
682  *          isom_map_aes_to_camellia(
683  *              swap_bitendianness(
684  *                  aes_inverse_affine_transform(in)
685  *              )
686  *          )
687  *      )
688  *  )
689  *
690  * (note: '⊕ 0x6e' inside camellia_h())
691  */
692 .Lpost_tf_lo_s1:
693         .byte 0x3c, 0xcc, 0xcf, 0x3f, 0x32, 0xc2, 0xc1, 0x31
694         .byte 0xdc, 0x2c, 0x2f, 0xdf, 0xd2, 0x22, 0x21, 0xd1
695 .Lpost_tf_hi_s1:
696         .byte 0x00, 0xf9, 0x86, 0x7f, 0xd7, 0x2e, 0x51, 0xa8
697         .byte 0xa4, 0x5d, 0x22, 0xdb, 0x73, 0x8a, 0xf5, 0x0c
698
699 /*
700  * post-SubByte transform
701  *
702  * post-lookup for sbox2:
703  *  swap_bitendianness(
704  *      camellia_h(
705  *          isom_map_aes_to_camellia(
706  *              swap_bitendianness(
707  *                  aes_inverse_affine_transform(in)
708  *              )
709  *          )
710  *      )
711  *  ) <<< 1
712  *
713  * (note: '⊕ 0x6e' inside camellia_h())
714  */
715 .Lpost_tf_lo_s2:
716         .byte 0x78, 0x99, 0x9f, 0x7e, 0x64, 0x85, 0x83, 0x62
717         .byte 0xb9, 0x58, 0x5e, 0xbf, 0xa5, 0x44, 0x42, 0xa3
718 .Lpost_tf_hi_s2:
719         .byte 0x00, 0xf3, 0x0d, 0xfe, 0xaf, 0x5c, 0xa2, 0x51
720         .byte 0x49, 0xba, 0x44, 0xb7, 0xe6, 0x15, 0xeb, 0x18
721
722 /*
723  * post-SubByte transform
724  *
725  * post-lookup for sbox3:
726  *  swap_bitendianness(
727  *      camellia_h(
728  *          isom_map_aes_to_camellia(
729  *              swap_bitendianness(
730  *                  aes_inverse_affine_transform(in)
731  *              )
732  *          )
733  *      )
734  *  ) >>> 1
735  *
736  * (note: '⊕ 0x6e' inside camellia_h())
737  */
738 .Lpost_tf_lo_s3:
739         .byte 0x1e, 0x66, 0xe7, 0x9f, 0x19, 0x61, 0xe0, 0x98
740         .byte 0x6e, 0x16, 0x97, 0xef, 0x69, 0x11, 0x90, 0xe8
741 .Lpost_tf_hi_s3:
742         .byte 0x00, 0xfc, 0x43, 0xbf, 0xeb, 0x17, 0xa8, 0x54
743         .byte 0x52, 0xae, 0x11, 0xed, 0xb9, 0x45, 0xfa, 0x06
744
745 /* For isolating SubBytes from AESENCLAST, inverse shift row */
746 .Linv_shift_row:
747         .byte 0x00, 0x0d, 0x0a, 0x07, 0x04, 0x01, 0x0e, 0x0b
748         .byte 0x08, 0x05, 0x02, 0x0f, 0x0c, 0x09, 0x06, 0x03
749
750 .align 4
751 /* 4-bit mask */
752 .L0f0f0f0f:
753         .long 0x0f0f0f0f
754
755 .text
756
757 .align 8
758 ELF(.type   __camellia_enc_blk32,@function;)
759
760 __camellia_enc_blk32:
761         /* input:
762          *      %rdi: ctx, CTX
763          *      %rax: temporary storage, 512 bytes
764          *      %ymm0..%ymm15: 32 plaintext blocks
765          * output:
766          *      %ymm0..%ymm15: 32 encrypted blocks, order swapped:
767          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
768          */
769
770         leaq 8 * 32(%rax), %rcx;
771
772         inpack32_post(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
773                       %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
774                       %ymm15, %rax, %rcx);
775
776         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
777                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
778                      %ymm15, %rax, %rcx, 0);
779
780         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
781               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
782               %ymm15,
783               ((key_table + (8) * 8) + 0)(CTX),
784               ((key_table + (8) * 8) + 4)(CTX),
785               ((key_table + (8) * 8) + 8)(CTX),
786               ((key_table + (8) * 8) + 12)(CTX));
787
788         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
789                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
790                      %ymm15, %rax, %rcx, 8);
791
792         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
793               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
794               %ymm15,
795               ((key_table + (16) * 8) + 0)(CTX),
796               ((key_table + (16) * 8) + 4)(CTX),
797               ((key_table + (16) * 8) + 8)(CTX),
798               ((key_table + (16) * 8) + 12)(CTX));
799
800         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
801                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
802                      %ymm15, %rax, %rcx, 16);
803
804         movl $24, %r8d;
805         cmpl $128, key_bitlength(CTX);
806         jne .Lenc_max32;
807
808 .Lenc_done:
809         /* load CD for output */
810         vmovdqu 0 * 32(%rcx), %ymm8;
811         vmovdqu 1 * 32(%rcx), %ymm9;
812         vmovdqu 2 * 32(%rcx), %ymm10;
813         vmovdqu 3 * 32(%rcx), %ymm11;
814         vmovdqu 4 * 32(%rcx), %ymm12;
815         vmovdqu 5 * 32(%rcx), %ymm13;
816         vmovdqu 6 * 32(%rcx), %ymm14;
817         vmovdqu 7 * 32(%rcx), %ymm15;
818
819         outunpack32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
820                     %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
821                     %ymm15, (key_table)(CTX, %r8, 8), (%rax), 1 * 32(%rax));
822
823         ret;
824
825 .align 8
826 .Lenc_max32:
827         movl $32, %r8d;
828
829         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
830               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
831               %ymm15,
832               ((key_table + (24) * 8) + 0)(CTX),
833               ((key_table + (24) * 8) + 4)(CTX),
834               ((key_table + (24) * 8) + 8)(CTX),
835               ((key_table + (24) * 8) + 12)(CTX));
836
837         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
838                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
839                      %ymm15, %rax, %rcx, 24);
840
841         jmp .Lenc_done;
842 ELF(.size __camellia_enc_blk32,.-__camellia_enc_blk32;)
843
844 .align 8
845 ELF(.type   __camellia_dec_blk32,@function;)
846
847 __camellia_dec_blk32:
848         /* input:
849          *      %rdi: ctx, CTX
850          *      %rax: temporary storage, 512 bytes
851          *      %r8d: 24 for 16 byte key, 32 for larger
852          *      %ymm0..%ymm15: 16 encrypted blocks
853          * output:
854          *      %ymm0..%ymm15: 16 plaintext blocks, order swapped:
855          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
856          */
857
858         leaq 8 * 32(%rax), %rcx;
859
860         inpack32_post(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
861                       %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
862                       %ymm15, %rax, %rcx);
863
864         cmpl $32, %r8d;
865         je .Ldec_max32;
866
867 .Ldec_max24:
868         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
869                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
870                      %ymm15, %rax, %rcx, 16);
871
872         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
873               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
874               %ymm15,
875               ((key_table + (16) * 8) + 8)(CTX),
876               ((key_table + (16) * 8) + 12)(CTX),
877               ((key_table + (16) * 8) + 0)(CTX),
878               ((key_table + (16) * 8) + 4)(CTX));
879
880         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
881                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
882                      %ymm15, %rax, %rcx, 8);
883
884         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
885               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
886               %ymm15,
887               ((key_table + (8) * 8) + 8)(CTX),
888               ((key_table + (8) * 8) + 12)(CTX),
889               ((key_table + (8) * 8) + 0)(CTX),
890               ((key_table + (8) * 8) + 4)(CTX));
891
892         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
893                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
894                      %ymm15, %rax, %rcx, 0);
895
896         /* load CD for output */
897         vmovdqu 0 * 32(%rcx), %ymm8;
898         vmovdqu 1 * 32(%rcx), %ymm9;
899         vmovdqu 2 * 32(%rcx), %ymm10;
900         vmovdqu 3 * 32(%rcx), %ymm11;
901         vmovdqu 4 * 32(%rcx), %ymm12;
902         vmovdqu 5 * 32(%rcx), %ymm13;
903         vmovdqu 6 * 32(%rcx), %ymm14;
904         vmovdqu 7 * 32(%rcx), %ymm15;
905
906         outunpack32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
907                     %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
908                     %ymm15, (key_table)(CTX), (%rax), 1 * 32(%rax));
909
910         ret;
911
912 .align 8
913 .Ldec_max32:
914         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
915                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
916                      %ymm15, %rax, %rcx, 24);
917
918         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
919               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
920               %ymm15,
921               ((key_table + (24) * 8) + 8)(CTX),
922               ((key_table + (24) * 8) + 12)(CTX),
923               ((key_table + (24) * 8) + 0)(CTX),
924               ((key_table + (24) * 8) + 4)(CTX));
925
926         jmp .Ldec_max24;
927 ELF(.size __camellia_dec_blk32,.-__camellia_dec_blk32;)
928
929 #define inc_le128(x, minus_one, tmp) \
930         vpcmpeqq minus_one, x, tmp; \
931         vpsubq minus_one, x, x; \
932         vpslldq $8, tmp, tmp; \
933         vpsubq tmp, x, x;
934
935 .align 8
936 .globl _gcry_camellia_aesni_avx2_ctr_enc
937 ELF(.type   _gcry_camellia_aesni_avx2_ctr_enc,@function;)
938
939 _gcry_camellia_aesni_avx2_ctr_enc:
940         /* input:
941          *      %rdi: ctx, CTX
942          *      %rsi: dst (32 blocks)
943          *      %rdx: src (32 blocks)
944          *      %rcx: iv (big endian, 128bit)
945          */
946
947         pushq %rbp;
948         movq %rsp, %rbp;
949
950         movq 8(%rcx), %r11;
951         bswapq %r11;
952
953         vzeroupper;
954
955         subq $(16 * 32), %rsp;
956         andq $~63, %rsp;
957         movq %rsp, %rax;
958
959         vpcmpeqd %ymm15, %ymm15, %ymm15;
960         vpsrldq $8, %ymm15, %ymm15; /* ab: -1:0 ; cd: -1:0 */
961
962         /* load IV and byteswap */
963         vmovdqu (%rcx), %xmm0;
964         vpshufb .Lbswap128_mask RIP, %xmm0, %xmm0;
965         vmovdqa %xmm0, %xmm1;
966         inc_le128(%xmm0, %xmm15, %xmm14);
967         vbroadcasti128 .Lbswap128_mask RIP, %ymm14;
968         vinserti128 $1, %xmm0, %ymm1, %ymm0;
969         vpshufb %ymm14, %ymm0, %ymm13;
970         vmovdqu %ymm13, 15 * 32(%rax);
971
972         /* check need for handling 64-bit overflow and carry */
973         cmpq $(0xffffffffffffffff - 32), %r11;
974         ja .Lload_ctr_carry;
975
976         /* construct IVs */
977         vpaddq %ymm15, %ymm15, %ymm15; /* ab: -2:0 ; cd: -2:0 */
978         vpsubq %ymm15, %ymm0, %ymm0;
979         vpshufb %ymm14, %ymm0, %ymm13;
980         vmovdqu %ymm13, 14 * 32(%rax);
981         vpsubq %ymm15, %ymm0, %ymm0;
982         vpshufb %ymm14, %ymm0, %ymm13;
983         vmovdqu %ymm13, 13 * 32(%rax);
984         vpsubq %ymm15, %ymm0, %ymm0;
985         vpshufb %ymm14, %ymm0, %ymm12;
986         vpsubq %ymm15, %ymm0, %ymm0;
987         vpshufb %ymm14, %ymm0, %ymm11;
988         vpsubq %ymm15, %ymm0, %ymm0;
989         vpshufb %ymm14, %ymm0, %ymm10;
990         vpsubq %ymm15, %ymm0, %ymm0;
991         vpshufb %ymm14, %ymm0, %ymm9;
992         vpsubq %ymm15, %ymm0, %ymm0;
993         vpshufb %ymm14, %ymm0, %ymm8;
994         vpsubq %ymm15, %ymm0, %ymm0;
995         vpshufb %ymm14, %ymm0, %ymm7;
996         vpsubq %ymm15, %ymm0, %ymm0;
997         vpshufb %ymm14, %ymm0, %ymm6;
998         vpsubq %ymm15, %ymm0, %ymm0;
999         vpshufb %ymm14, %ymm0, %ymm5;
1000         vpsubq %ymm15, %ymm0, %ymm0;
1001         vpshufb %ymm14, %ymm0, %ymm4;
1002         vpsubq %ymm15, %ymm0, %ymm0;
1003         vpshufb %ymm14, %ymm0, %ymm3;
1004         vpsubq %ymm15, %ymm0, %ymm0;
1005         vpshufb %ymm14, %ymm0, %ymm2;
1006         vpsubq %ymm15, %ymm0, %ymm0;
1007         vpshufb %ymm14, %ymm0, %ymm1;
1008         vpsubq %ymm15, %ymm0, %ymm0;  /* +30 ; +31 */
1009         vpsubq %xmm15, %xmm0, %xmm13; /* +32 */
1010         vpshufb %ymm14, %ymm0, %ymm0;
1011         vpshufb %xmm14, %xmm13, %xmm13;
1012         vmovdqu %xmm13, (%rcx);
1013
1014         jmp .Lload_ctr_done;
1015
1016 .align 4
1017 .Lload_ctr_carry:
1018         /* construct IVs */
1019         inc_le128(%ymm0, %ymm15, %ymm13); /* ab: le1 ; cd: le2 */
1020         inc_le128(%ymm0, %ymm15, %ymm13); /* ab: le2 ; cd: le3 */
1021         vpshufb %ymm14, %ymm0, %ymm13;
1022         vmovdqu %ymm13, 14 * 32(%rax);
1023         inc_le128(%ymm0, %ymm15, %ymm13);
1024         inc_le128(%ymm0, %ymm15, %ymm13);
1025         vpshufb %ymm14, %ymm0, %ymm13;
1026         vmovdqu %ymm13, 13 * 32(%rax);
1027         inc_le128(%ymm0, %ymm15, %ymm13);
1028         inc_le128(%ymm0, %ymm15, %ymm13);
1029         vpshufb %ymm14, %ymm0, %ymm12;
1030         inc_le128(%ymm0, %ymm15, %ymm13);
1031         inc_le128(%ymm0, %ymm15, %ymm13);
1032         vpshufb %ymm14, %ymm0, %ymm11;
1033         inc_le128(%ymm0, %ymm15, %ymm13);
1034         inc_le128(%ymm0, %ymm15, %ymm13);
1035         vpshufb %ymm14, %ymm0, %ymm10;
1036         inc_le128(%ymm0, %ymm15, %ymm13);
1037         inc_le128(%ymm0, %ymm15, %ymm13);
1038         vpshufb %ymm14, %ymm0, %ymm9;
1039         inc_le128(%ymm0, %ymm15, %ymm13);
1040         inc_le128(%ymm0, %ymm15, %ymm13);
1041         vpshufb %ymm14, %ymm0, %ymm8;
1042         inc_le128(%ymm0, %ymm15, %ymm13);
1043         inc_le128(%ymm0, %ymm15, %ymm13);
1044         vpshufb %ymm14, %ymm0, %ymm7;
1045         inc_le128(%ymm0, %ymm15, %ymm13);
1046         inc_le128(%ymm0, %ymm15, %ymm13);
1047         vpshufb %ymm14, %ymm0, %ymm6;
1048         inc_le128(%ymm0, %ymm15, %ymm13);
1049         inc_le128(%ymm0, %ymm15, %ymm13);
1050         vpshufb %ymm14, %ymm0, %ymm5;
1051         inc_le128(%ymm0, %ymm15, %ymm13);
1052         inc_le128(%ymm0, %ymm15, %ymm13);
1053         vpshufb %ymm14, %ymm0, %ymm4;
1054         inc_le128(%ymm0, %ymm15, %ymm13);
1055         inc_le128(%ymm0, %ymm15, %ymm13);
1056         vpshufb %ymm14, %ymm0, %ymm3;
1057         inc_le128(%ymm0, %ymm15, %ymm13);
1058         inc_le128(%ymm0, %ymm15, %ymm13);
1059         vpshufb %ymm14, %ymm0, %ymm2;
1060         inc_le128(%ymm0, %ymm15, %ymm13);
1061         inc_le128(%ymm0, %ymm15, %ymm13);
1062         vpshufb %ymm14, %ymm0, %ymm1;
1063         inc_le128(%ymm0, %ymm15, %ymm13);
1064         inc_le128(%ymm0, %ymm15, %ymm13);
1065         vextracti128 $1, %ymm0, %xmm13;
1066         vpshufb %ymm14, %ymm0, %ymm0;
1067         inc_le128(%xmm13, %xmm15, %xmm14);
1068         vpshufb .Lbswap128_mask RIP, %xmm13, %xmm13;
1069         vmovdqu %xmm13, (%rcx);
1070
1071 .align 4
1072 .Lload_ctr_done:
1073         /* inpack16_pre: */
1074         vpbroadcastq (key_table)(CTX), %ymm15;
1075         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1076         vpxor %ymm0, %ymm15, %ymm0;
1077         vpxor %ymm1, %ymm15, %ymm1;
1078         vpxor %ymm2, %ymm15, %ymm2;
1079         vpxor %ymm3, %ymm15, %ymm3;
1080         vpxor %ymm4, %ymm15, %ymm4;
1081         vpxor %ymm5, %ymm15, %ymm5;
1082         vpxor %ymm6, %ymm15, %ymm6;
1083         vpxor %ymm7, %ymm15, %ymm7;
1084         vpxor %ymm8, %ymm15, %ymm8;
1085         vpxor %ymm9, %ymm15, %ymm9;
1086         vpxor %ymm10, %ymm15, %ymm10;
1087         vpxor %ymm11, %ymm15, %ymm11;
1088         vpxor %ymm12, %ymm15, %ymm12;
1089         vpxor 13 * 32(%rax), %ymm15, %ymm13;
1090         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1091         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1092
1093         call __camellia_enc_blk32;
1094
1095         vpxor 0 * 32(%rdx), %ymm7, %ymm7;
1096         vpxor 1 * 32(%rdx), %ymm6, %ymm6;
1097         vpxor 2 * 32(%rdx), %ymm5, %ymm5;
1098         vpxor 3 * 32(%rdx), %ymm4, %ymm4;
1099         vpxor 4 * 32(%rdx), %ymm3, %ymm3;
1100         vpxor 5 * 32(%rdx), %ymm2, %ymm2;
1101         vpxor 6 * 32(%rdx), %ymm1, %ymm1;
1102         vpxor 7 * 32(%rdx), %ymm0, %ymm0;
1103         vpxor 8 * 32(%rdx), %ymm15, %ymm15;
1104         vpxor 9 * 32(%rdx), %ymm14, %ymm14;
1105         vpxor 10 * 32(%rdx), %ymm13, %ymm13;
1106         vpxor 11 * 32(%rdx), %ymm12, %ymm12;
1107         vpxor 12 * 32(%rdx), %ymm11, %ymm11;
1108         vpxor 13 * 32(%rdx), %ymm10, %ymm10;
1109         vpxor 14 * 32(%rdx), %ymm9, %ymm9;
1110         vpxor 15 * 32(%rdx), %ymm8, %ymm8;
1111         leaq 32 * 16(%rdx), %rdx;
1112
1113         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1114                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1115                      %ymm8, %rsi);
1116
1117         vzeroall;
1118
1119         leave;
1120         ret;
1121 ELF(.size _gcry_camellia_aesni_avx2_ctr_enc,.-_gcry_camellia_aesni_avx2_ctr_enc;)
1122
1123 .align 8
1124 .globl _gcry_camellia_aesni_avx2_cbc_dec
1125 ELF(.type   _gcry_camellia_aesni_avx2_cbc_dec,@function;)
1126
1127 _gcry_camellia_aesni_avx2_cbc_dec:
1128         /* input:
1129          *      %rdi: ctx, CTX
1130          *      %rsi: dst (32 blocks)
1131          *      %rdx: src (32 blocks)
1132          *      %rcx: iv
1133          */
1134
1135         pushq %rbp;
1136         movq %rsp, %rbp;
1137
1138         vzeroupper;
1139
1140         movq %rcx, %r9;
1141
1142         cmpl $128, key_bitlength(CTX);
1143         movl $32, %r8d;
1144         movl $24, %eax;
1145         cmovel %eax, %r8d; /* max */
1146
1147         subq $(16 * 32), %rsp;
1148         andq $~63, %rsp;
1149         movq %rsp, %rax;
1150
1151         inpack32_pre(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
1152                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
1153                      %ymm15, %rdx, (key_table)(CTX, %r8, 8));
1154
1155         call __camellia_dec_blk32;
1156
1157         /* XOR output with IV */
1158         vmovdqu %ymm8, (%rax);
1159         vmovdqu (%r9), %xmm8;
1160         vinserti128 $1, (%rdx), %ymm8, %ymm8;
1161         vpxor %ymm8, %ymm7, %ymm7;
1162         vmovdqu (%rax), %ymm8;
1163         vpxor (0 * 32 + 16)(%rdx), %ymm6, %ymm6;
1164         vpxor (1 * 32 + 16)(%rdx), %ymm5, %ymm5;
1165         vpxor (2 * 32 + 16)(%rdx), %ymm4, %ymm4;
1166         vpxor (3 * 32 + 16)(%rdx), %ymm3, %ymm3;
1167         vpxor (4 * 32 + 16)(%rdx), %ymm2, %ymm2;
1168         vpxor (5 * 32 + 16)(%rdx), %ymm1, %ymm1;
1169         vpxor (6 * 32 + 16)(%rdx), %ymm0, %ymm0;
1170         vpxor (7 * 32 + 16)(%rdx), %ymm15, %ymm15;
1171         vpxor (8 * 32 + 16)(%rdx), %ymm14, %ymm14;
1172         vpxor (9 * 32 + 16)(%rdx), %ymm13, %ymm13;
1173         vpxor (10 * 32 + 16)(%rdx), %ymm12, %ymm12;
1174         vpxor (11 * 32 + 16)(%rdx), %ymm11, %ymm11;
1175         vpxor (12 * 32 + 16)(%rdx), %ymm10, %ymm10;
1176         vpxor (13 * 32 + 16)(%rdx), %ymm9, %ymm9;
1177         vpxor (14 * 32 + 16)(%rdx), %ymm8, %ymm8;
1178         movq (15 * 32 + 16 + 0)(%rdx), %rax;
1179         movq (15 * 32 + 16 + 8)(%rdx), %rcx;
1180
1181         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1182                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1183                      %ymm8, %rsi);
1184
1185         /* store new IV */
1186         movq %rax, (0)(%r9);
1187         movq %rcx, (8)(%r9);
1188
1189         vzeroall;
1190
1191         leave;
1192         ret;
1193 ELF(.size _gcry_camellia_aesni_avx2_cbc_dec,.-_gcry_camellia_aesni_avx2_cbc_dec;)
1194
1195 .align 8
1196 .globl _gcry_camellia_aesni_avx2_cfb_dec
1197 ELF(.type   _gcry_camellia_aesni_avx2_cfb_dec,@function;)
1198
1199 _gcry_camellia_aesni_avx2_cfb_dec:
1200         /* input:
1201          *      %rdi: ctx, CTX
1202          *      %rsi: dst (32 blocks)
1203          *      %rdx: src (32 blocks)
1204          *      %rcx: iv
1205          */
1206
1207         pushq %rbp;
1208         movq %rsp, %rbp;
1209
1210         vzeroupper;
1211
1212         subq $(16 * 32), %rsp;
1213         andq $~63, %rsp;
1214         movq %rsp, %rax;
1215
1216         /* inpack16_pre: */
1217         vpbroadcastq (key_table)(CTX), %ymm0;
1218         vpshufb .Lpack_bswap RIP, %ymm0, %ymm0;
1219         vmovdqu (%rcx), %xmm15;
1220         vinserti128 $1, (%rdx), %ymm15, %ymm15;
1221         vpxor %ymm15, %ymm0, %ymm15;
1222         vmovdqu (15 * 32 + 16)(%rdx), %xmm1;
1223         vmovdqu %xmm1, (%rcx); /* store new IV */
1224         vpxor (0 * 32 + 16)(%rdx), %ymm0, %ymm14;
1225         vpxor (1 * 32 + 16)(%rdx), %ymm0, %ymm13;
1226         vpxor (2 * 32 + 16)(%rdx), %ymm0, %ymm12;
1227         vpxor (3 * 32 + 16)(%rdx), %ymm0, %ymm11;
1228         vpxor (4 * 32 + 16)(%rdx), %ymm0, %ymm10;
1229         vpxor (5 * 32 + 16)(%rdx), %ymm0, %ymm9;
1230         vpxor (6 * 32 + 16)(%rdx), %ymm0, %ymm8;
1231         vpxor (7 * 32 + 16)(%rdx), %ymm0, %ymm7;
1232         vpxor (8 * 32 + 16)(%rdx), %ymm0, %ymm6;
1233         vpxor (9 * 32 + 16)(%rdx), %ymm0, %ymm5;
1234         vpxor (10 * 32 + 16)(%rdx), %ymm0, %ymm4;
1235         vpxor (11 * 32 + 16)(%rdx), %ymm0, %ymm3;
1236         vpxor (12 * 32 + 16)(%rdx), %ymm0, %ymm2;
1237         vpxor (13 * 32 + 16)(%rdx), %ymm0, %ymm1;
1238         vpxor (14 * 32 + 16)(%rdx), %ymm0, %ymm0;
1239
1240         call __camellia_enc_blk32;
1241
1242         vpxor 0 * 32(%rdx), %ymm7, %ymm7;
1243         vpxor 1 * 32(%rdx), %ymm6, %ymm6;
1244         vpxor 2 * 32(%rdx), %ymm5, %ymm5;
1245         vpxor 3 * 32(%rdx), %ymm4, %ymm4;
1246         vpxor 4 * 32(%rdx), %ymm3, %ymm3;
1247         vpxor 5 * 32(%rdx), %ymm2, %ymm2;
1248         vpxor 6 * 32(%rdx), %ymm1, %ymm1;
1249         vpxor 7 * 32(%rdx), %ymm0, %ymm0;
1250         vpxor 8 * 32(%rdx), %ymm15, %ymm15;
1251         vpxor 9 * 32(%rdx), %ymm14, %ymm14;
1252         vpxor 10 * 32(%rdx), %ymm13, %ymm13;
1253         vpxor 11 * 32(%rdx), %ymm12, %ymm12;
1254         vpxor 12 * 32(%rdx), %ymm11, %ymm11;
1255         vpxor 13 * 32(%rdx), %ymm10, %ymm10;
1256         vpxor 14 * 32(%rdx), %ymm9, %ymm9;
1257         vpxor 15 * 32(%rdx), %ymm8, %ymm8;
1258
1259         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1260                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1261                      %ymm8, %rsi);
1262
1263         vzeroall;
1264
1265         leave;
1266         ret;
1267 ELF(.size _gcry_camellia_aesni_avx2_cfb_dec,.-_gcry_camellia_aesni_avx2_cfb_dec;)
1268
1269 .align 8
1270 .globl _gcry_camellia_aesni_avx2_ocb_enc
1271 ELF(.type   _gcry_camellia_aesni_avx2_ocb_enc,@function;)
1272
1273 _gcry_camellia_aesni_avx2_ocb_enc:
1274         /* input:
1275          *      %rdi: ctx, CTX
1276          *      %rsi: dst (32 blocks)
1277          *      %rdx: src (32 blocks)
1278          *      %rcx: offset
1279          *      %r8 : checksum
1280          *      %r9 : L pointers (void *L[32])
1281          */
1282
1283         pushq %rbp;
1284         movq %rsp, %rbp;
1285
1286         vzeroupper;
1287
1288         subq $(16 * 32 + 4 * 8), %rsp;
1289         andq $~63, %rsp;
1290         movq %rsp, %rax;
1291
1292         movq %r10, (16 * 32 + 0 * 8)(%rax);
1293         movq %r11, (16 * 32 + 1 * 8)(%rax);
1294         movq %r12, (16 * 32 + 2 * 8)(%rax);
1295         movq %r13, (16 * 32 + 3 * 8)(%rax);
1296
1297         vmovdqu (%rcx), %xmm14;
1298         vmovdqu (%r8), %xmm13;
1299
1300         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1301         /* Checksum_i = Checksum_{i-1} xor P_i  */
1302         /* C_i = Offset_i xor ENCIPHER(K, P_i xor Offset_i)  */
1303
1304 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1305           vmovdqu (n * 32)(%rdx), yreg; \
1306           vpxor (l0reg), %xmm14, %xmm15; \
1307           vpxor (l1reg), %xmm15, %xmm14; \
1308           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1309           vpxor yreg, %ymm13, %ymm13; \
1310           vpxor yreg, %ymm15, yreg; \
1311           vmovdqu %ymm15, (n * 32)(%rsi);
1312
1313         movq (0 * 8)(%r9), %r10;
1314         movq (1 * 8)(%r9), %r11;
1315         movq (2 * 8)(%r9), %r12;
1316         movq (3 * 8)(%r9), %r13;
1317         OCB_INPUT(0, %r10, %r11, %ymm0);
1318         vmovdqu %ymm0, (15 * 32)(%rax);
1319         OCB_INPUT(1, %r12, %r13, %ymm0);
1320         vmovdqu %ymm0, (14 * 32)(%rax);
1321         movq (4 * 8)(%r9), %r10;
1322         movq (5 * 8)(%r9), %r11;
1323         movq (6 * 8)(%r9), %r12;
1324         movq (7 * 8)(%r9), %r13;
1325         OCB_INPUT(2, %r10, %r11, %ymm0);
1326         vmovdqu %ymm0, (13 * 32)(%rax);
1327         OCB_INPUT(3, %r12, %r13, %ymm12);
1328         movq (8 * 8)(%r9), %r10;
1329         movq (9 * 8)(%r9), %r11;
1330         movq (10 * 8)(%r9), %r12;
1331         movq (11 * 8)(%r9), %r13;
1332         OCB_INPUT(4, %r10, %r11, %ymm11);
1333         OCB_INPUT(5, %r12, %r13, %ymm10);
1334         movq (12 * 8)(%r9), %r10;
1335         movq (13 * 8)(%r9), %r11;
1336         movq (14 * 8)(%r9), %r12;
1337         movq (15 * 8)(%r9), %r13;
1338         OCB_INPUT(6, %r10, %r11, %ymm9);
1339         OCB_INPUT(7, %r12, %r13, %ymm8);
1340         movq (16 * 8)(%r9), %r10;
1341         movq (17 * 8)(%r9), %r11;
1342         movq (18 * 8)(%r9), %r12;
1343         movq (19 * 8)(%r9), %r13;
1344         OCB_INPUT(8, %r10, %r11, %ymm7);
1345         OCB_INPUT(9, %r12, %r13, %ymm6);
1346         movq (20 * 8)(%r9), %r10;
1347         movq (21 * 8)(%r9), %r11;
1348         movq (22 * 8)(%r9), %r12;
1349         movq (23 * 8)(%r9), %r13;
1350         OCB_INPUT(10, %r10, %r11, %ymm5);
1351         OCB_INPUT(11, %r12, %r13, %ymm4);
1352         movq (24 * 8)(%r9), %r10;
1353         movq (25 * 8)(%r9), %r11;
1354         movq (26 * 8)(%r9), %r12;
1355         movq (27 * 8)(%r9), %r13;
1356         OCB_INPUT(12, %r10, %r11, %ymm3);
1357         OCB_INPUT(13, %r12, %r13, %ymm2);
1358         movq (28 * 8)(%r9), %r10;
1359         movq (29 * 8)(%r9), %r11;
1360         movq (30 * 8)(%r9), %r12;
1361         movq (31 * 8)(%r9), %r13;
1362         OCB_INPUT(14, %r10, %r11, %ymm1);
1363         OCB_INPUT(15, %r12, %r13, %ymm0);
1364 #undef OCB_INPUT
1365
1366         vextracti128 $1, %ymm13, %xmm15;
1367         vmovdqu %xmm14, (%rcx);
1368         vpxor %xmm13, %xmm15, %xmm15;
1369         vmovdqu %xmm15, (%r8);
1370
1371         /* inpack16_pre: */
1372         vpbroadcastq (key_table)(CTX), %ymm15;
1373         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1374         vpxor %ymm0, %ymm15, %ymm0;
1375         vpxor %ymm1, %ymm15, %ymm1;
1376         vpxor %ymm2, %ymm15, %ymm2;
1377         vpxor %ymm3, %ymm15, %ymm3;
1378         vpxor %ymm4, %ymm15, %ymm4;
1379         vpxor %ymm5, %ymm15, %ymm5;
1380         vpxor %ymm6, %ymm15, %ymm6;
1381         vpxor %ymm7, %ymm15, %ymm7;
1382         vpxor %ymm8, %ymm15, %ymm8;
1383         vpxor %ymm9, %ymm15, %ymm9;
1384         vpxor %ymm10, %ymm15, %ymm10;
1385         vpxor %ymm11, %ymm15, %ymm11;
1386         vpxor %ymm12, %ymm15, %ymm12;
1387         vpxor 13 * 32(%rax), %ymm15, %ymm13;
1388         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1389         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1390
1391         call __camellia_enc_blk32;
1392
1393         vpxor 0 * 32(%rsi), %ymm7, %ymm7;
1394         vpxor 1 * 32(%rsi), %ymm6, %ymm6;
1395         vpxor 2 * 32(%rsi), %ymm5, %ymm5;
1396         vpxor 3 * 32(%rsi), %ymm4, %ymm4;
1397         vpxor 4 * 32(%rsi), %ymm3, %ymm3;
1398         vpxor 5 * 32(%rsi), %ymm2, %ymm2;
1399         vpxor 6 * 32(%rsi), %ymm1, %ymm1;
1400         vpxor 7 * 32(%rsi), %ymm0, %ymm0;
1401         vpxor 8 * 32(%rsi), %ymm15, %ymm15;
1402         vpxor 9 * 32(%rsi), %ymm14, %ymm14;
1403         vpxor 10 * 32(%rsi), %ymm13, %ymm13;
1404         vpxor 11 * 32(%rsi), %ymm12, %ymm12;
1405         vpxor 12 * 32(%rsi), %ymm11, %ymm11;
1406         vpxor 13 * 32(%rsi), %ymm10, %ymm10;
1407         vpxor 14 * 32(%rsi), %ymm9, %ymm9;
1408         vpxor 15 * 32(%rsi), %ymm8, %ymm8;
1409
1410         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1411                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1412                      %ymm8, %rsi);
1413
1414         vzeroall;
1415
1416         movq (16 * 32 + 0 * 8)(%rax), %r10;
1417         movq (16 * 32 + 1 * 8)(%rax), %r11;
1418         movq (16 * 32 + 2 * 8)(%rax), %r12;
1419         movq (16 * 32 + 3 * 8)(%rax), %r13;
1420
1421         leave;
1422         ret;
1423 ELF(.size _gcry_camellia_aesni_avx2_ocb_enc,.-_gcry_camellia_aesni_avx2_ocb_enc;)
1424
1425 .align 8
1426 .globl _gcry_camellia_aesni_avx2_ocb_dec
1427 ELF(.type   _gcry_camellia_aesni_avx2_ocb_dec,@function;)
1428
1429 _gcry_camellia_aesni_avx2_ocb_dec:
1430         /* input:
1431          *      %rdi: ctx, CTX
1432          *      %rsi: dst (32 blocks)
1433          *      %rdx: src (32 blocks)
1434          *      %rcx: offset
1435          *      %r8 : checksum
1436          *      %r9 : L pointers (void *L[32])
1437          */
1438
1439         pushq %rbp;
1440         movq %rsp, %rbp;
1441
1442         vzeroupper;
1443
1444         subq $(16 * 32 + 4 * 8), %rsp;
1445         andq $~63, %rsp;
1446         movq %rsp, %rax;
1447
1448         movq %r10, (16 * 32 + 0 * 8)(%rax);
1449         movq %r11, (16 * 32 + 1 * 8)(%rax);
1450         movq %r12, (16 * 32 + 2 * 8)(%rax);
1451         movq %r13, (16 * 32 + 3 * 8)(%rax);
1452
1453         vmovdqu (%rcx), %xmm14;
1454
1455         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1456         /* P_i = Offset_i xor DECIPHER(K, C_i xor Offset_i)  */
1457
1458 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1459           vmovdqu (n * 32)(%rdx), yreg; \
1460           vpxor (l0reg), %xmm14, %xmm15; \
1461           vpxor (l1reg), %xmm15, %xmm14; \
1462           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1463           vpxor yreg, %ymm15, yreg; \
1464           vmovdqu %ymm15, (n * 32)(%rsi);
1465
1466         movq (0 * 8)(%r9), %r10;
1467         movq (1 * 8)(%r9), %r11;
1468         movq (2 * 8)(%r9), %r12;
1469         movq (3 * 8)(%r9), %r13;
1470         OCB_INPUT(0, %r10, %r11, %ymm0);
1471         vmovdqu %ymm0, (15 * 32)(%rax);
1472         OCB_INPUT(1, %r12, %r13, %ymm0);
1473         vmovdqu %ymm0, (14 * 32)(%rax);
1474         movq (4 * 8)(%r9), %r10;
1475         movq (5 * 8)(%r9), %r11;
1476         movq (6 * 8)(%r9), %r12;
1477         movq (7 * 8)(%r9), %r13;
1478         OCB_INPUT(2, %r10, %r11, %ymm13);
1479         OCB_INPUT(3, %r12, %r13, %ymm12);
1480         movq (8 * 8)(%r9), %r10;
1481         movq (9 * 8)(%r9), %r11;
1482         movq (10 * 8)(%r9), %r12;
1483         movq (11 * 8)(%r9), %r13;
1484         OCB_INPUT(4, %r10, %r11, %ymm11);
1485         OCB_INPUT(5, %r12, %r13, %ymm10);
1486         movq (12 * 8)(%r9), %r10;
1487         movq (13 * 8)(%r9), %r11;
1488         movq (14 * 8)(%r9), %r12;
1489         movq (15 * 8)(%r9), %r13;
1490         OCB_INPUT(6, %r10, %r11, %ymm9);
1491         OCB_INPUT(7, %r12, %r13, %ymm8);
1492         movq (16 * 8)(%r9), %r10;
1493         movq (17 * 8)(%r9), %r11;
1494         movq (18 * 8)(%r9), %r12;
1495         movq (19 * 8)(%r9), %r13;
1496         OCB_INPUT(8, %r10, %r11, %ymm7);
1497         OCB_INPUT(9, %r12, %r13, %ymm6);
1498         movq (20 * 8)(%r9), %r10;
1499         movq (21 * 8)(%r9), %r11;
1500         movq (22 * 8)(%r9), %r12;
1501         movq (23 * 8)(%r9), %r13;
1502         OCB_INPUT(10, %r10, %r11, %ymm5);
1503         OCB_INPUT(11, %r12, %r13, %ymm4);
1504         movq (24 * 8)(%r9), %r10;
1505         movq (25 * 8)(%r9), %r11;
1506         movq (26 * 8)(%r9), %r12;
1507         movq (27 * 8)(%r9), %r13;
1508         OCB_INPUT(12, %r10, %r11, %ymm3);
1509         OCB_INPUT(13, %r12, %r13, %ymm2);
1510         movq (28 * 8)(%r9), %r10;
1511         movq (29 * 8)(%r9), %r11;
1512         movq (30 * 8)(%r9), %r12;
1513         movq (31 * 8)(%r9), %r13;
1514         OCB_INPUT(14, %r10, %r11, %ymm1);
1515         OCB_INPUT(15, %r12, %r13, %ymm0);
1516 #undef OCB_INPUT
1517
1518         vmovdqu %xmm14, (%rcx);
1519
1520         movq %r8, %r10;
1521
1522         cmpl $128, key_bitlength(CTX);
1523         movl $32, %r8d;
1524         movl $24, %r9d;
1525         cmovel %r9d, %r8d; /* max */
1526
1527         /* inpack16_pre: */
1528         vpbroadcastq (key_table)(CTX, %r8, 8), %ymm15;
1529         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1530         vpxor %ymm0, %ymm15, %ymm0;
1531         vpxor %ymm1, %ymm15, %ymm1;
1532         vpxor %ymm2, %ymm15, %ymm2;
1533         vpxor %ymm3, %ymm15, %ymm3;
1534         vpxor %ymm4, %ymm15, %ymm4;
1535         vpxor %ymm5, %ymm15, %ymm5;
1536         vpxor %ymm6, %ymm15, %ymm6;
1537         vpxor %ymm7, %ymm15, %ymm7;
1538         vpxor %ymm8, %ymm15, %ymm8;
1539         vpxor %ymm9, %ymm15, %ymm9;
1540         vpxor %ymm10, %ymm15, %ymm10;
1541         vpxor %ymm11, %ymm15, %ymm11;
1542         vpxor %ymm12, %ymm15, %ymm12;
1543         vpxor %ymm13, %ymm15, %ymm13;
1544         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1545         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1546
1547         call __camellia_dec_blk32;
1548
1549         vpxor 0 * 32(%rsi), %ymm7, %ymm7;
1550         vpxor 1 * 32(%rsi), %ymm6, %ymm6;
1551         vpxor 2 * 32(%rsi), %ymm5, %ymm5;
1552         vpxor 3 * 32(%rsi), %ymm4, %ymm4;
1553         vpxor 4 * 32(%rsi), %ymm3, %ymm3;
1554         vpxor 5 * 32(%rsi), %ymm2, %ymm2;
1555         vpxor 6 * 32(%rsi), %ymm1, %ymm1;
1556         vpxor 7 * 32(%rsi), %ymm0, %ymm0;
1557         vmovdqu %ymm7, (7 * 32)(%rax);
1558         vmovdqu %ymm6, (6 * 32)(%rax);
1559         vpxor 8 * 32(%rsi), %ymm15, %ymm15;
1560         vpxor 9 * 32(%rsi), %ymm14, %ymm14;
1561         vpxor 10 * 32(%rsi), %ymm13, %ymm13;
1562         vpxor 11 * 32(%rsi), %ymm12, %ymm12;
1563         vpxor 12 * 32(%rsi), %ymm11, %ymm11;
1564         vpxor 13 * 32(%rsi), %ymm10, %ymm10;
1565         vpxor 14 * 32(%rsi), %ymm9, %ymm9;
1566         vpxor 15 * 32(%rsi), %ymm8, %ymm8;
1567
1568         /* Checksum_i = Checksum_{i-1} xor P_i  */
1569
1570         vpxor %ymm5, %ymm7, %ymm7;
1571         vpxor %ymm4, %ymm6, %ymm6;
1572         vpxor %ymm3, %ymm7, %ymm7;
1573         vpxor %ymm2, %ymm6, %ymm6;
1574         vpxor %ymm1, %ymm7, %ymm7;
1575         vpxor %ymm0, %ymm6, %ymm6;
1576         vpxor %ymm15, %ymm7, %ymm7;
1577         vpxor %ymm14, %ymm6, %ymm6;
1578         vpxor %ymm13, %ymm7, %ymm7;
1579         vpxor %ymm12, %ymm6, %ymm6;
1580         vpxor %ymm11, %ymm7, %ymm7;
1581         vpxor %ymm10, %ymm6, %ymm6;
1582         vpxor %ymm9, %ymm7, %ymm7;
1583         vpxor %ymm8, %ymm6, %ymm6;
1584         vpxor %ymm7, %ymm6, %ymm7;
1585
1586         vextracti128 $1, %ymm7, %xmm6;
1587         vpxor %xmm6, %xmm7, %xmm7;
1588         vpxor (%r10), %xmm7, %xmm7;
1589         vmovdqu %xmm7, (%r10);
1590
1591         vmovdqu 7 * 32(%rax), %ymm7;
1592         vmovdqu 6 * 32(%rax), %ymm6;
1593
1594         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1595                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1596                      %ymm8, %rsi);
1597
1598         vzeroall;
1599
1600         movq (16 * 32 + 0 * 8)(%rax), %r10;
1601         movq (16 * 32 + 1 * 8)(%rax), %r11;
1602         movq (16 * 32 + 2 * 8)(%rax), %r12;
1603         movq (16 * 32 + 3 * 8)(%rax), %r13;
1604
1605         leave;
1606         ret;
1607 ELF(.size _gcry_camellia_aesni_avx2_ocb_dec,.-_gcry_camellia_aesni_avx2_ocb_dec;)
1608
1609 .align 8
1610 .globl _gcry_camellia_aesni_avx2_ocb_auth
1611 ELF(.type   _gcry_camellia_aesni_avx2_ocb_auth,@function;)
1612
1613 _gcry_camellia_aesni_avx2_ocb_auth:
1614         /* input:
1615          *      %rdi: ctx, CTX
1616          *      %rsi: abuf (16 blocks)
1617          *      %rdx: offset
1618          *      %rcx: checksum
1619          *      %r8 : L pointers (void *L[16])
1620          */
1621
1622         pushq %rbp;
1623         movq %rsp, %rbp;
1624
1625         vzeroupper;
1626
1627         subq $(16 * 32 + 4 * 8), %rsp;
1628         andq $~63, %rsp;
1629         movq %rsp, %rax;
1630
1631         movq %r10, (16 * 32 + 0 * 8)(%rax);
1632         movq %r11, (16 * 32 + 1 * 8)(%rax);
1633         movq %r12, (16 * 32 + 2 * 8)(%rax);
1634         movq %r13, (16 * 32 + 3 * 8)(%rax);
1635
1636         vmovdqu (%rdx), %xmm14;
1637
1638         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1639         /* Checksum_i = Checksum_{i-1} xor P_i  */
1640         /* C_i = Offset_i xor ENCIPHER(K, P_i xor Offset_i)  */
1641
1642 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1643           vmovdqu (n * 32)(%rsi), yreg; \
1644           vpxor (l0reg), %xmm14, %xmm15; \
1645           vpxor (l1reg), %xmm15, %xmm14; \
1646           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1647           vpxor yreg, %ymm15, yreg;
1648
1649         movq (0 * 8)(%r8), %r10;
1650         movq (1 * 8)(%r8), %r11;
1651         movq (2 * 8)(%r8), %r12;
1652         movq (3 * 8)(%r8), %r13;
1653         OCB_INPUT(0, %r10, %r11, %ymm0);
1654         vmovdqu %ymm0, (15 * 32)(%rax);
1655         OCB_INPUT(1, %r12, %r13, %ymm0);
1656         vmovdqu %ymm0, (14 * 32)(%rax);
1657         movq (4 * 8)(%r8), %r10;
1658         movq (5 * 8)(%r8), %r11;
1659         movq (6 * 8)(%r8), %r12;
1660         movq (7 * 8)(%r8), %r13;
1661         OCB_INPUT(2, %r10, %r11, %ymm13);
1662         OCB_INPUT(3, %r12, %r13, %ymm12);
1663         movq (8 * 8)(%r8), %r10;
1664         movq (9 * 8)(%r8), %r11;
1665         movq (10 * 8)(%r8), %r12;
1666         movq (11 * 8)(%r8), %r13;
1667         OCB_INPUT(4, %r10, %r11, %ymm11);
1668         OCB_INPUT(5, %r12, %r13, %ymm10);
1669         movq (12 * 8)(%r8), %r10;
1670         movq (13 * 8)(%r8), %r11;
1671         movq (14 * 8)(%r8), %r12;
1672         movq (15 * 8)(%r8), %r13;
1673         OCB_INPUT(6, %r10, %r11, %ymm9);
1674         OCB_INPUT(7, %r12, %r13, %ymm8);
1675         movq (16 * 8)(%r8), %r10;
1676         movq (17 * 8)(%r8), %r11;
1677         movq (18 * 8)(%r8), %r12;
1678         movq (19 * 8)(%r8), %r13;
1679         OCB_INPUT(8, %r10, %r11, %ymm7);
1680         OCB_INPUT(9, %r12, %r13, %ymm6);
1681         movq (20 * 8)(%r8), %r10;
1682         movq (21 * 8)(%r8), %r11;
1683         movq (22 * 8)(%r8), %r12;
1684         movq (23 * 8)(%r8), %r13;
1685         OCB_INPUT(10, %r10, %r11, %ymm5);
1686         OCB_INPUT(11, %r12, %r13, %ymm4);
1687         movq (24 * 8)(%r8), %r10;
1688         movq (25 * 8)(%r8), %r11;
1689         movq (26 * 8)(%r8), %r12;
1690         movq (27 * 8)(%r8), %r13;
1691         OCB_INPUT(12, %r10, %r11, %ymm3);
1692         OCB_INPUT(13, %r12, %r13, %ymm2);
1693         movq (28 * 8)(%r8), %r10;
1694         movq (29 * 8)(%r8), %r11;
1695         movq (30 * 8)(%r8), %r12;
1696         movq (31 * 8)(%r8), %r13;
1697         OCB_INPUT(14, %r10, %r11, %ymm1);
1698         OCB_INPUT(15, %r12, %r13, %ymm0);
1699 #undef OCB_INPUT
1700
1701         vmovdqu %xmm14, (%rdx);
1702
1703         movq %rcx, %r10;
1704
1705         /* inpack16_pre: */
1706         vpbroadcastq (key_table)(CTX), %ymm15;
1707         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1708         vpxor %ymm0, %ymm15, %ymm0;
1709         vpxor %ymm1, %ymm15, %ymm1;
1710         vpxor %ymm2, %ymm15, %ymm2;
1711         vpxor %ymm3, %ymm15, %ymm3;
1712         vpxor %ymm4, %ymm15, %ymm4;
1713         vpxor %ymm5, %ymm15, %ymm5;
1714         vpxor %ymm6, %ymm15, %ymm6;
1715         vpxor %ymm7, %ymm15, %ymm7;
1716         vpxor %ymm8, %ymm15, %ymm8;
1717         vpxor %ymm9, %ymm15, %ymm9;
1718         vpxor %ymm10, %ymm15, %ymm10;
1719         vpxor %ymm11, %ymm15, %ymm11;
1720         vpxor %ymm12, %ymm15, %ymm12;
1721         vpxor %ymm13, %ymm15, %ymm13;
1722         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1723         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1724
1725         call __camellia_enc_blk32;
1726
1727         vpxor %ymm7, %ymm6, %ymm6;
1728         vpxor %ymm5, %ymm4, %ymm4;
1729         vpxor %ymm3, %ymm2, %ymm2;
1730         vpxor %ymm1, %ymm0, %ymm0;
1731         vpxor %ymm15, %ymm14, %ymm14;
1732         vpxor %ymm13, %ymm12, %ymm12;
1733         vpxor %ymm11, %ymm10, %ymm10;
1734         vpxor %ymm9, %ymm8, %ymm8;
1735
1736         vpxor %ymm6, %ymm4, %ymm4;
1737         vpxor %ymm2, %ymm0, %ymm0;
1738         vpxor %ymm14, %ymm12, %ymm12;
1739         vpxor %ymm10, %ymm8, %ymm8;
1740
1741         vpxor %ymm4, %ymm0, %ymm0;
1742         vpxor %ymm12, %ymm8, %ymm8;
1743
1744         vpxor %ymm0, %ymm8, %ymm0;
1745
1746         vextracti128 $1, %ymm0, %xmm1;
1747         vpxor (%r10), %xmm0, %xmm0;
1748         vpxor %xmm0, %xmm1, %xmm0;
1749         vmovdqu %xmm0, (%r10);
1750
1751         vzeroall;
1752
1753         movq (16 * 32 + 0 * 8)(%rax), %r10;
1754         movq (16 * 32 + 1 * 8)(%rax), %r11;
1755         movq (16 * 32 + 2 * 8)(%rax), %r12;
1756         movq (16 * 32 + 3 * 8)(%rax), %r13;
1757
1758         leave;
1759         ret;
1760 ELF(.size _gcry_camellia_aesni_avx2_ocb_auth,.-_gcry_camellia_aesni_avx2_ocb_auth;)
1761
1762 #endif /*defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX2_SUPPORT)*/
1763 #endif /*__x86_64*/