Add crypto hash SM3.
[libgcrypt.git] / cipher / camellia-aesni-avx2-amd64.S
1 /* camellia-avx2-aesni-amd64.S  -  AES-NI/AVX2 implementation of Camellia cipher
2  *
3  * Copyright (C) 2013-2015 Jussi Kivilinna <jussi.kivilinna@iki.fi>
4  *
5  * This file is part of Libgcrypt.
6  *
7  * Libgcrypt is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU Lesser General Public License as
9  * published by the Free Software Foundation; either version 2.1 of
10  * the License, or (at your option) any later version.
11  *
12  * Libgcrypt is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
19  */
20
21 #ifdef __x86_64
22 #include <config.h>
23 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
24      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
25     defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX2_SUPPORT)
26
27 #ifdef __PIC__
28 #  define RIP (%rip)
29 #else
30 #  define RIP
31 #endif
32
33 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
34 # define ELF(...) __VA_ARGS__
35 #else
36 # define ELF(...) /*_*/
37 #endif
38
39 #define CAMELLIA_TABLE_BYTE_LEN 272
40
41 /* struct CAMELLIA_context: */
42 #define key_table 0
43 #define key_bitlength CAMELLIA_TABLE_BYTE_LEN
44
45 /* register macros */
46 #define CTX %rdi
47 #define RIO %r8
48
49 /**********************************************************************
50   helper macros
51  **********************************************************************/
52 #define filter_8bit(x, lo_t, hi_t, mask4bit, tmp0) \
53         vpand x, mask4bit, tmp0; \
54         vpandn x, mask4bit, x; \
55         vpsrld $4, x, x; \
56         \
57         vpshufb tmp0, lo_t, tmp0; \
58         vpshufb x, hi_t, x; \
59         vpxor tmp0, x, x;
60
61 #define ymm0_x xmm0
62 #define ymm1_x xmm1
63 #define ymm2_x xmm2
64 #define ymm3_x xmm3
65 #define ymm4_x xmm4
66 #define ymm5_x xmm5
67 #define ymm6_x xmm6
68 #define ymm7_x xmm7
69 #define ymm8_x xmm8
70 #define ymm9_x xmm9
71 #define ymm10_x xmm10
72 #define ymm11_x xmm11
73 #define ymm12_x xmm12
74 #define ymm13_x xmm13
75 #define ymm14_x xmm14
76 #define ymm15_x xmm15
77
78 /**********************************************************************
79   32-way camellia
80  **********************************************************************/
81
82 /*
83  * IN:
84  *   x0..x7: byte-sliced AB state
85  *   mem_cd: register pointer storing CD state
86  *   key: index for key material
87  * OUT:
88  *   x0..x7: new byte-sliced CD state
89  */
90 #define roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, t0, t1, t2, t3, t4, t5, t6, \
91                   t7, mem_cd, key) \
92         /* \
93          * S-function with AES subbytes \
94          */ \
95         vbroadcasti128 .Linv_shift_row RIP, t4; \
96         vpbroadcastd .L0f0f0f0f RIP, t7; \
97         vbroadcasti128 .Lpre_tf_lo_s1 RIP, t5; \
98         vbroadcasti128 .Lpre_tf_hi_s1 RIP, t6; \
99         vbroadcasti128 .Lpre_tf_lo_s4 RIP, t2; \
100         vbroadcasti128 .Lpre_tf_hi_s4 RIP, t3; \
101         \
102         /* AES inverse shift rows */ \
103         vpshufb t4, x0, x0; \
104         vpshufb t4, x7, x7; \
105         vpshufb t4, x3, x3; \
106         vpshufb t4, x6, x6; \
107         vpshufb t4, x2, x2; \
108         vpshufb t4, x5, x5; \
109         vpshufb t4, x1, x1; \
110         vpshufb t4, x4, x4; \
111         \
112         /* prefilter sboxes 1, 2 and 3 */ \
113         /* prefilter sbox 4 */ \
114         filter_8bit(x0, t5, t6, t7, t4); \
115         filter_8bit(x7, t5, t6, t7, t4); \
116         vextracti128 $1, x0, t0##_x; \
117         vextracti128 $1, x7, t1##_x; \
118         filter_8bit(x3, t2, t3, t7, t4); \
119         filter_8bit(x6, t2, t3, t7, t4); \
120         vextracti128 $1, x3, t3##_x; \
121         vextracti128 $1, x6, t2##_x; \
122         filter_8bit(x2, t5, t6, t7, t4); \
123         filter_8bit(x5, t5, t6, t7, t4); \
124         filter_8bit(x1, t5, t6, t7, t4); \
125         filter_8bit(x4, t5, t6, t7, t4); \
126         \
127         vpxor t4##_x, t4##_x, t4##_x; \
128         \
129         /* AES subbytes + AES shift rows */ \
130         vextracti128 $1, x2, t6##_x; \
131         vextracti128 $1, x5, t5##_x; \
132         vaesenclast t4##_x, x0##_x, x0##_x; \
133         vaesenclast t4##_x, t0##_x, t0##_x; \
134         vaesenclast t4##_x, x7##_x, x7##_x; \
135         vaesenclast t4##_x, t1##_x, t1##_x; \
136         vaesenclast t4##_x, x3##_x, x3##_x; \
137         vaesenclast t4##_x, t3##_x, t3##_x; \
138         vaesenclast t4##_x, x6##_x, x6##_x; \
139         vaesenclast t4##_x, t2##_x, t2##_x; \
140         vinserti128 $1, t0##_x, x0, x0; \
141         vinserti128 $1, t1##_x, x7, x7; \
142         vinserti128 $1, t3##_x, x3, x3; \
143         vinserti128 $1, t2##_x, x6, x6; \
144         vextracti128 $1, x1, t3##_x; \
145         vextracti128 $1, x4, t2##_x; \
146         vbroadcasti128 .Lpost_tf_lo_s1 RIP, t0; \
147         vbroadcasti128 .Lpost_tf_hi_s1 RIP, t1; \
148         vaesenclast t4##_x, x2##_x, x2##_x; \
149         vaesenclast t4##_x, t6##_x, t6##_x; \
150         vaesenclast t4##_x, x5##_x, x5##_x; \
151         vaesenclast t4##_x, t5##_x, t5##_x; \
152         vaesenclast t4##_x, x1##_x, x1##_x; \
153         vaesenclast t4##_x, t3##_x, t3##_x; \
154         vaesenclast t4##_x, x4##_x, x4##_x; \
155         vaesenclast t4##_x, t2##_x, t2##_x; \
156         vinserti128 $1, t6##_x, x2, x2; \
157         vinserti128 $1, t5##_x, x5, x5; \
158         vinserti128 $1, t3##_x, x1, x1; \
159         vinserti128 $1, t2##_x, x4, x4; \
160         \
161         /* postfilter sboxes 1 and 4 */ \
162         vbroadcasti128 .Lpost_tf_lo_s3 RIP, t2; \
163         vbroadcasti128 .Lpost_tf_hi_s3 RIP, t3; \
164         filter_8bit(x0, t0, t1, t7, t4); \
165         filter_8bit(x7, t0, t1, t7, t4); \
166         filter_8bit(x3, t0, t1, t7, t6); \
167         filter_8bit(x6, t0, t1, t7, t6); \
168         \
169         /* postfilter sbox 3 */ \
170         vbroadcasti128 .Lpost_tf_lo_s2 RIP, t4; \
171         vbroadcasti128 .Lpost_tf_hi_s2 RIP, t5; \
172         filter_8bit(x2, t2, t3, t7, t6); \
173         filter_8bit(x5, t2, t3, t7, t6); \
174         \
175         vpbroadcastq key, t0; /* higher 64-bit duplicate ignored */ \
176         \
177         /* postfilter sbox 2 */ \
178         filter_8bit(x1, t4, t5, t7, t2); \
179         filter_8bit(x4, t4, t5, t7, t2); \
180         vpxor t7, t7, t7; \
181         \
182         vpsrldq $1, t0, t1; \
183         vpsrldq $2, t0, t2; \
184         vpshufb t7, t1, t1; \
185         vpsrldq $3, t0, t3; \
186         \
187         /* P-function */ \
188         vpxor x5, x0, x0; \
189         vpxor x6, x1, x1; \
190         vpxor x7, x2, x2; \
191         vpxor x4, x3, x3; \
192         \
193         vpshufb t7, t2, t2; \
194         vpsrldq $4, t0, t4; \
195         vpshufb t7, t3, t3; \
196         vpsrldq $5, t0, t5; \
197         vpshufb t7, t4, t4; \
198         \
199         vpxor x2, x4, x4; \
200         vpxor x3, x5, x5; \
201         vpxor x0, x6, x6; \
202         vpxor x1, x7, x7; \
203         \
204         vpsrldq $6, t0, t6; \
205         vpshufb t7, t5, t5; \
206         vpshufb t7, t6, t6; \
207         \
208         vpxor x7, x0, x0; \
209         vpxor x4, x1, x1; \
210         vpxor x5, x2, x2; \
211         vpxor x6, x3, x3; \
212         \
213         vpxor x3, x4, x4; \
214         vpxor x0, x5, x5; \
215         vpxor x1, x6, x6; \
216         vpxor x2, x7, x7; /* note: high and low parts swapped */ \
217         \
218         /* Add key material and result to CD (x becomes new CD) */ \
219         \
220         vpxor t6, x1, x1; \
221         vpxor 5 * 32(mem_cd), x1, x1; \
222         \
223         vpsrldq $7, t0, t6; \
224         vpshufb t7, t0, t0; \
225         vpshufb t7, t6, t7; \
226         \
227         vpxor t7, x0, x0; \
228         vpxor 4 * 32(mem_cd), x0, x0; \
229         \
230         vpxor t5, x2, x2; \
231         vpxor 6 * 32(mem_cd), x2, x2; \
232         \
233         vpxor t4, x3, x3; \
234         vpxor 7 * 32(mem_cd), x3, x3; \
235         \
236         vpxor t3, x4, x4; \
237         vpxor 0 * 32(mem_cd), x4, x4; \
238         \
239         vpxor t2, x5, x5; \
240         vpxor 1 * 32(mem_cd), x5, x5; \
241         \
242         vpxor t1, x6, x6; \
243         vpxor 2 * 32(mem_cd), x6, x6; \
244         \
245         vpxor t0, x7, x7; \
246         vpxor 3 * 32(mem_cd), x7, x7;
247
248 /*
249  * IN/OUT:
250  *  x0..x7: byte-sliced AB state preloaded
251  *  mem_ab: byte-sliced AB state in memory
252  *  mem_cb: byte-sliced CD state in memory
253  */
254 #define two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
255                       y6, y7, mem_ab, mem_cd, i, dir, store_ab) \
256         roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
257                   y6, y7, mem_cd, (key_table + (i) * 8)(CTX)); \
258         \
259         vmovdqu x0, 4 * 32(mem_cd); \
260         vmovdqu x1, 5 * 32(mem_cd); \
261         vmovdqu x2, 6 * 32(mem_cd); \
262         vmovdqu x3, 7 * 32(mem_cd); \
263         vmovdqu x4, 0 * 32(mem_cd); \
264         vmovdqu x5, 1 * 32(mem_cd); \
265         vmovdqu x6, 2 * 32(mem_cd); \
266         vmovdqu x7, 3 * 32(mem_cd); \
267         \
268         roundsm32(x4, x5, x6, x7, x0, x1, x2, x3, y0, y1, y2, y3, y4, y5, \
269                   y6, y7, mem_ab, (key_table + ((i) + (dir)) * 8)(CTX)); \
270         \
271         store_ab(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab);
272
273 #define dummy_store(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) /* do nothing */
274
275 #define store_ab_state(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) \
276         /* Store new AB state */ \
277         vmovdqu x4, 4 * 32(mem_ab); \
278         vmovdqu x5, 5 * 32(mem_ab); \
279         vmovdqu x6, 6 * 32(mem_ab); \
280         vmovdqu x7, 7 * 32(mem_ab); \
281         vmovdqu x0, 0 * 32(mem_ab); \
282         vmovdqu x1, 1 * 32(mem_ab); \
283         vmovdqu x2, 2 * 32(mem_ab); \
284         vmovdqu x3, 3 * 32(mem_ab);
285
286 #define enc_rounds32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
287                       y6, y7, mem_ab, mem_cd, i) \
288         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
289                       y6, y7, mem_ab, mem_cd, (i) + 2, 1, store_ab_state); \
290         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
291                       y6, y7, mem_ab, mem_cd, (i) + 4, 1, store_ab_state); \
292         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
293                       y6, y7, mem_ab, mem_cd, (i) + 6, 1, dummy_store);
294
295 #define dec_rounds32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
296                       y6, y7, mem_ab, mem_cd, i) \
297         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
298                       y6, y7, mem_ab, mem_cd, (i) + 7, -1, store_ab_state); \
299         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
300                       y6, y7, mem_ab, mem_cd, (i) + 5, -1, store_ab_state); \
301         two_roundsm32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
302                       y6, y7, mem_ab, mem_cd, (i) + 3, -1, dummy_store);
303
304 /*
305  * IN:
306  *  v0..3: byte-sliced 32-bit integers
307  * OUT:
308  *  v0..3: (IN <<< 1)
309  */
310 #define rol32_1_32(v0, v1, v2, v3, t0, t1, t2, zero) \
311         vpcmpgtb v0, zero, t0; \
312         vpaddb v0, v0, v0; \
313         vpabsb t0, t0; \
314         \
315         vpcmpgtb v1, zero, t1; \
316         vpaddb v1, v1, v1; \
317         vpabsb t1, t1; \
318         \
319         vpcmpgtb v2, zero, t2; \
320         vpaddb v2, v2, v2; \
321         vpabsb t2, t2; \
322         \
323         vpor t0, v1, v1; \
324         \
325         vpcmpgtb v3, zero, t0; \
326         vpaddb v3, v3, v3; \
327         vpabsb t0, t0; \
328         \
329         vpor t1, v2, v2; \
330         vpor t2, v3, v3; \
331         vpor t0, v0, v0;
332
333 /*
334  * IN:
335  *   r: byte-sliced AB state in memory
336  *   l: byte-sliced CD state in memory
337  * OUT:
338  *   x0..x7: new byte-sliced CD state
339  */
340 #define fls32(l, l0, l1, l2, l3, l4, l5, l6, l7, r, t0, t1, t2, t3, tt0, \
341               tt1, tt2, tt3, kll, klr, krl, krr) \
342         /* \
343          * t0 = kll; \
344          * t0 &= ll; \
345          * lr ^= rol32(t0, 1); \
346          */ \
347         vpbroadcastd kll, t0; /* only lowest 32-bit used */ \
348         vpxor tt0, tt0, tt0; \
349         vpshufb tt0, t0, t3; \
350         vpsrldq $1, t0, t0; \
351         vpshufb tt0, t0, t2; \
352         vpsrldq $1, t0, t0; \
353         vpshufb tt0, t0, t1; \
354         vpsrldq $1, t0, t0; \
355         vpshufb tt0, t0, t0; \
356         \
357         vpand l0, t0, t0; \
358         vpand l1, t1, t1; \
359         vpand l2, t2, t2; \
360         vpand l3, t3, t3; \
361         \
362         rol32_1_32(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
363         \
364         vpxor l4, t0, l4; \
365         vpbroadcastd krr, t0; /* only lowest 32-bit used */ \
366         vmovdqu l4, 4 * 32(l); \
367         vpxor l5, t1, l5; \
368         vmovdqu l5, 5 * 32(l); \
369         vpxor l6, t2, l6; \
370         vmovdqu l6, 6 * 32(l); \
371         vpxor l7, t3, l7; \
372         vmovdqu l7, 7 * 32(l); \
373         \
374         /* \
375          * t2 = krr; \
376          * t2 |= rr; \
377          * rl ^= t2; \
378          */ \
379         \
380         vpshufb tt0, t0, t3; \
381         vpsrldq $1, t0, t0; \
382         vpshufb tt0, t0, t2; \
383         vpsrldq $1, t0, t0; \
384         vpshufb tt0, t0, t1; \
385         vpsrldq $1, t0, t0; \
386         vpshufb tt0, t0, t0; \
387         \
388         vpor 4 * 32(r), t0, t0; \
389         vpor 5 * 32(r), t1, t1; \
390         vpor 6 * 32(r), t2, t2; \
391         vpor 7 * 32(r), t3, t3; \
392         \
393         vpxor 0 * 32(r), t0, t0; \
394         vpxor 1 * 32(r), t1, t1; \
395         vpxor 2 * 32(r), t2, t2; \
396         vpxor 3 * 32(r), t3, t3; \
397         vmovdqu t0, 0 * 32(r); \
398         vpbroadcastd krl, t0; /* only lowest 32-bit used */ \
399         vmovdqu t1, 1 * 32(r); \
400         vmovdqu t2, 2 * 32(r); \
401         vmovdqu t3, 3 * 32(r); \
402         \
403         /* \
404          * t2 = krl; \
405          * t2 &= rl; \
406          * rr ^= rol32(t2, 1); \
407          */ \
408         vpshufb tt0, t0, t3; \
409         vpsrldq $1, t0, t0; \
410         vpshufb tt0, t0, t2; \
411         vpsrldq $1, t0, t0; \
412         vpshufb tt0, t0, t1; \
413         vpsrldq $1, t0, t0; \
414         vpshufb tt0, t0, t0; \
415         \
416         vpand 0 * 32(r), t0, t0; \
417         vpand 1 * 32(r), t1, t1; \
418         vpand 2 * 32(r), t2, t2; \
419         vpand 3 * 32(r), t3, t3; \
420         \
421         rol32_1_32(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
422         \
423         vpxor 4 * 32(r), t0, t0; \
424         vpxor 5 * 32(r), t1, t1; \
425         vpxor 6 * 32(r), t2, t2; \
426         vpxor 7 * 32(r), t3, t3; \
427         vmovdqu t0, 4 * 32(r); \
428         vpbroadcastd klr, t0; /* only lowest 32-bit used */ \
429         vmovdqu t1, 5 * 32(r); \
430         vmovdqu t2, 6 * 32(r); \
431         vmovdqu t3, 7 * 32(r); \
432         \
433         /* \
434          * t0 = klr; \
435          * t0 |= lr; \
436          * ll ^= t0; \
437          */ \
438         \
439         vpshufb tt0, t0, t3; \
440         vpsrldq $1, t0, t0; \
441         vpshufb tt0, t0, t2; \
442         vpsrldq $1, t0, t0; \
443         vpshufb tt0, t0, t1; \
444         vpsrldq $1, t0, t0; \
445         vpshufb tt0, t0, t0; \
446         \
447         vpor l4, t0, t0; \
448         vpor l5, t1, t1; \
449         vpor l6, t2, t2; \
450         vpor l7, t3, t3; \
451         \
452         vpxor l0, t0, l0; \
453         vmovdqu l0, 0 * 32(l); \
454         vpxor l1, t1, l1; \
455         vmovdqu l1, 1 * 32(l); \
456         vpxor l2, t2, l2; \
457         vmovdqu l2, 2 * 32(l); \
458         vpxor l3, t3, l3; \
459         vmovdqu l3, 3 * 32(l);
460
461 #define transpose_4x4(x0, x1, x2, x3, t1, t2) \
462         vpunpckhdq x1, x0, t2; \
463         vpunpckldq x1, x0, x0; \
464         \
465         vpunpckldq x3, x2, t1; \
466         vpunpckhdq x3, x2, x2; \
467         \
468         vpunpckhqdq t1, x0, x1; \
469         vpunpcklqdq t1, x0, x0; \
470         \
471         vpunpckhqdq x2, t2, x3; \
472         vpunpcklqdq x2, t2, x2;
473
474 #define byteslice_16x16b_fast(a0, b0, c0, d0, a1, b1, c1, d1, a2, b2, c2, d2, \
475                               a3, b3, c3, d3, st0, st1) \
476         vmovdqu d2, st0; \
477         vmovdqu d3, st1; \
478         transpose_4x4(a0, a1, a2, a3, d2, d3); \
479         transpose_4x4(b0, b1, b2, b3, d2, d3); \
480         vmovdqu st0, d2; \
481         vmovdqu st1, d3; \
482         \
483         vmovdqu a0, st0; \
484         vmovdqu a1, st1; \
485         transpose_4x4(c0, c1, c2, c3, a0, a1); \
486         transpose_4x4(d0, d1, d2, d3, a0, a1); \
487         \
488         vbroadcasti128 .Lshufb_16x16b RIP, a0; \
489         vmovdqu st1, a1; \
490         vpshufb a0, a2, a2; \
491         vpshufb a0, a3, a3; \
492         vpshufb a0, b0, b0; \
493         vpshufb a0, b1, b1; \
494         vpshufb a0, b2, b2; \
495         vpshufb a0, b3, b3; \
496         vpshufb a0, a1, a1; \
497         vpshufb a0, c0, c0; \
498         vpshufb a0, c1, c1; \
499         vpshufb a0, c2, c2; \
500         vpshufb a0, c3, c3; \
501         vpshufb a0, d0, d0; \
502         vpshufb a0, d1, d1; \
503         vpshufb a0, d2, d2; \
504         vpshufb a0, d3, d3; \
505         vmovdqu d3, st1; \
506         vmovdqu st0, d3; \
507         vpshufb a0, d3, a0; \
508         vmovdqu d2, st0; \
509         \
510         transpose_4x4(a0, b0, c0, d0, d2, d3); \
511         transpose_4x4(a1, b1, c1, d1, d2, d3); \
512         vmovdqu st0, d2; \
513         vmovdqu st1, d3; \
514         \
515         vmovdqu b0, st0; \
516         vmovdqu b1, st1; \
517         transpose_4x4(a2, b2, c2, d2, b0, b1); \
518         transpose_4x4(a3, b3, c3, d3, b0, b1); \
519         vmovdqu st0, b0; \
520         vmovdqu st1, b1; \
521         /* does not adjust output bytes inside vectors */
522
523 /* load blocks to registers and apply pre-whitening */
524 #define inpack32_pre(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
525                      y6, y7, rio, key) \
526         vpbroadcastq key, x0; \
527         vpshufb .Lpack_bswap RIP, x0, x0; \
528         \
529         vpxor 0 * 32(rio), x0, y7; \
530         vpxor 1 * 32(rio), x0, y6; \
531         vpxor 2 * 32(rio), x0, y5; \
532         vpxor 3 * 32(rio), x0, y4; \
533         vpxor 4 * 32(rio), x0, y3; \
534         vpxor 5 * 32(rio), x0, y2; \
535         vpxor 6 * 32(rio), x0, y1; \
536         vpxor 7 * 32(rio), x0, y0; \
537         vpxor 8 * 32(rio), x0, x7; \
538         vpxor 9 * 32(rio), x0, x6; \
539         vpxor 10 * 32(rio), x0, x5; \
540         vpxor 11 * 32(rio), x0, x4; \
541         vpxor 12 * 32(rio), x0, x3; \
542         vpxor 13 * 32(rio), x0, x2; \
543         vpxor 14 * 32(rio), x0, x1; \
544         vpxor 15 * 32(rio), x0, x0;
545
546 /* byteslice pre-whitened blocks and store to temporary memory */
547 #define inpack32_post(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
548                       y6, y7, mem_ab, mem_cd) \
549         byteslice_16x16b_fast(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, \
550                               y4, y5, y6, y7, (mem_ab), (mem_cd)); \
551         \
552         vmovdqu x0, 0 * 32(mem_ab); \
553         vmovdqu x1, 1 * 32(mem_ab); \
554         vmovdqu x2, 2 * 32(mem_ab); \
555         vmovdqu x3, 3 * 32(mem_ab); \
556         vmovdqu x4, 4 * 32(mem_ab); \
557         vmovdqu x5, 5 * 32(mem_ab); \
558         vmovdqu x6, 6 * 32(mem_ab); \
559         vmovdqu x7, 7 * 32(mem_ab); \
560         vmovdqu y0, 0 * 32(mem_cd); \
561         vmovdqu y1, 1 * 32(mem_cd); \
562         vmovdqu y2, 2 * 32(mem_cd); \
563         vmovdqu y3, 3 * 32(mem_cd); \
564         vmovdqu y4, 4 * 32(mem_cd); \
565         vmovdqu y5, 5 * 32(mem_cd); \
566         vmovdqu y6, 6 * 32(mem_cd); \
567         vmovdqu y7, 7 * 32(mem_cd);
568
569 /* de-byteslice, apply post-whitening and store blocks */
570 #define outunpack32(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, \
571                     y5, y6, y7, key, stack_tmp0, stack_tmp1) \
572         byteslice_16x16b_fast(y0, y4, x0, x4, y1, y5, x1, x5, y2, y6, x2, x6, \
573                               y3, y7, x3, x7, stack_tmp0, stack_tmp1); \
574         \
575         vmovdqu x0, stack_tmp0; \
576         \
577         vpbroadcastq key, x0; \
578         vpshufb .Lpack_bswap RIP, x0, x0; \
579         \
580         vpxor x0, y7, y7; \
581         vpxor x0, y6, y6; \
582         vpxor x0, y5, y5; \
583         vpxor x0, y4, y4; \
584         vpxor x0, y3, y3; \
585         vpxor x0, y2, y2; \
586         vpxor x0, y1, y1; \
587         vpxor x0, y0, y0; \
588         vpxor x0, x7, x7; \
589         vpxor x0, x6, x6; \
590         vpxor x0, x5, x5; \
591         vpxor x0, x4, x4; \
592         vpxor x0, x3, x3; \
593         vpxor x0, x2, x2; \
594         vpxor x0, x1, x1; \
595         vpxor stack_tmp0, x0, x0;
596
597 #define write_output(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
598                      y6, y7, rio) \
599         vmovdqu x0, 0 * 32(rio); \
600         vmovdqu x1, 1 * 32(rio); \
601         vmovdqu x2, 2 * 32(rio); \
602         vmovdqu x3, 3 * 32(rio); \
603         vmovdqu x4, 4 * 32(rio); \
604         vmovdqu x5, 5 * 32(rio); \
605         vmovdqu x6, 6 * 32(rio); \
606         vmovdqu x7, 7 * 32(rio); \
607         vmovdqu y0, 8 * 32(rio); \
608         vmovdqu y1, 9 * 32(rio); \
609         vmovdqu y2, 10 * 32(rio); \
610         vmovdqu y3, 11 * 32(rio); \
611         vmovdqu y4, 12 * 32(rio); \
612         vmovdqu y5, 13 * 32(rio); \
613         vmovdqu y6, 14 * 32(rio); \
614         vmovdqu y7, 15 * 32(rio);
615
616 .text
617 .align 32
618
619 #define SHUFB_BYTES(idx) \
620         0 + (idx), 4 + (idx), 8 + (idx), 12 + (idx)
621
622 .Lshufb_16x16b:
623         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3)
624         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3)
625
626 .Lpack_bswap:
627         .long 0x00010203, 0x04050607, 0x80808080, 0x80808080
628         .long 0x00010203, 0x04050607, 0x80808080, 0x80808080
629
630 /* For CTR-mode IV byteswap */
631 .Lbswap128_mask:
632         .byte 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0
633
634 /*
635  * pre-SubByte transform
636  *
637  * pre-lookup for sbox1, sbox2, sbox3:
638  *   swap_bitendianness(
639  *       isom_map_camellia_to_aes(
640  *           camellia_f(
641  *               swap_bitendianess(in)
642  *           )
643  *       )
644  *   )
645  *
646  * (note: '⊕ 0xc5' inside camellia_f())
647  */
648 .Lpre_tf_lo_s1:
649         .byte 0x45, 0xe8, 0x40, 0xed, 0x2e, 0x83, 0x2b, 0x86
650         .byte 0x4b, 0xe6, 0x4e, 0xe3, 0x20, 0x8d, 0x25, 0x88
651 .Lpre_tf_hi_s1:
652         .byte 0x00, 0x51, 0xf1, 0xa0, 0x8a, 0xdb, 0x7b, 0x2a
653         .byte 0x09, 0x58, 0xf8, 0xa9, 0x83, 0xd2, 0x72, 0x23
654
655 /*
656  * pre-SubByte transform
657  *
658  * pre-lookup for sbox4:
659  *   swap_bitendianness(
660  *       isom_map_camellia_to_aes(
661  *           camellia_f(
662  *               swap_bitendianess(in <<< 1)
663  *           )
664  *       )
665  *   )
666  *
667  * (note: '⊕ 0xc5' inside camellia_f())
668  */
669 .Lpre_tf_lo_s4:
670         .byte 0x45, 0x40, 0x2e, 0x2b, 0x4b, 0x4e, 0x20, 0x25
671         .byte 0x14, 0x11, 0x7f, 0x7a, 0x1a, 0x1f, 0x71, 0x74
672 .Lpre_tf_hi_s4:
673         .byte 0x00, 0xf1, 0x8a, 0x7b, 0x09, 0xf8, 0x83, 0x72
674         .byte 0xad, 0x5c, 0x27, 0xd6, 0xa4, 0x55, 0x2e, 0xdf
675
676 /*
677  * post-SubByte transform
678  *
679  * post-lookup for sbox1, sbox4:
680  *  swap_bitendianness(
681  *      camellia_h(
682  *          isom_map_aes_to_camellia(
683  *              swap_bitendianness(
684  *                  aes_inverse_affine_transform(in)
685  *              )
686  *          )
687  *      )
688  *  )
689  *
690  * (note: '⊕ 0x6e' inside camellia_h())
691  */
692 .Lpost_tf_lo_s1:
693         .byte 0x3c, 0xcc, 0xcf, 0x3f, 0x32, 0xc2, 0xc1, 0x31
694         .byte 0xdc, 0x2c, 0x2f, 0xdf, 0xd2, 0x22, 0x21, 0xd1
695 .Lpost_tf_hi_s1:
696         .byte 0x00, 0xf9, 0x86, 0x7f, 0xd7, 0x2e, 0x51, 0xa8
697         .byte 0xa4, 0x5d, 0x22, 0xdb, 0x73, 0x8a, 0xf5, 0x0c
698
699 /*
700  * post-SubByte transform
701  *
702  * post-lookup for sbox2:
703  *  swap_bitendianness(
704  *      camellia_h(
705  *          isom_map_aes_to_camellia(
706  *              swap_bitendianness(
707  *                  aes_inverse_affine_transform(in)
708  *              )
709  *          )
710  *      )
711  *  ) <<< 1
712  *
713  * (note: '⊕ 0x6e' inside camellia_h())
714  */
715 .Lpost_tf_lo_s2:
716         .byte 0x78, 0x99, 0x9f, 0x7e, 0x64, 0x85, 0x83, 0x62
717         .byte 0xb9, 0x58, 0x5e, 0xbf, 0xa5, 0x44, 0x42, 0xa3
718 .Lpost_tf_hi_s2:
719         .byte 0x00, 0xf3, 0x0d, 0xfe, 0xaf, 0x5c, 0xa2, 0x51
720         .byte 0x49, 0xba, 0x44, 0xb7, 0xe6, 0x15, 0xeb, 0x18
721
722 /*
723  * post-SubByte transform
724  *
725  * post-lookup for sbox3:
726  *  swap_bitendianness(
727  *      camellia_h(
728  *          isom_map_aes_to_camellia(
729  *              swap_bitendianness(
730  *                  aes_inverse_affine_transform(in)
731  *              )
732  *          )
733  *      )
734  *  ) >>> 1
735  *
736  * (note: '⊕ 0x6e' inside camellia_h())
737  */
738 .Lpost_tf_lo_s3:
739         .byte 0x1e, 0x66, 0xe7, 0x9f, 0x19, 0x61, 0xe0, 0x98
740         .byte 0x6e, 0x16, 0x97, 0xef, 0x69, 0x11, 0x90, 0xe8
741 .Lpost_tf_hi_s3:
742         .byte 0x00, 0xfc, 0x43, 0xbf, 0xeb, 0x17, 0xa8, 0x54
743         .byte 0x52, 0xae, 0x11, 0xed, 0xb9, 0x45, 0xfa, 0x06
744
745 /* For isolating SubBytes from AESENCLAST, inverse shift row */
746 .Linv_shift_row:
747         .byte 0x00, 0x0d, 0x0a, 0x07, 0x04, 0x01, 0x0e, 0x0b
748         .byte 0x08, 0x05, 0x02, 0x0f, 0x0c, 0x09, 0x06, 0x03
749
750 .align 4
751 /* 4-bit mask */
752 .L0f0f0f0f:
753         .long 0x0f0f0f0f
754
755
756 .align 8
757 ELF(.type   __camellia_enc_blk32,@function;)
758
759 __camellia_enc_blk32:
760         /* input:
761          *      %rdi: ctx, CTX
762          *      %rax: temporary storage, 512 bytes
763          *      %ymm0..%ymm15: 32 plaintext blocks
764          * output:
765          *      %ymm0..%ymm15: 32 encrypted blocks, order swapped:
766          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
767          */
768
769         leaq 8 * 32(%rax), %rcx;
770
771         inpack32_post(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
772                       %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
773                       %ymm15, %rax, %rcx);
774
775         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
776                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
777                      %ymm15, %rax, %rcx, 0);
778
779         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
780               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
781               %ymm15,
782               ((key_table + (8) * 8) + 0)(CTX),
783               ((key_table + (8) * 8) + 4)(CTX),
784               ((key_table + (8) * 8) + 8)(CTX),
785               ((key_table + (8) * 8) + 12)(CTX));
786
787         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
788                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
789                      %ymm15, %rax, %rcx, 8);
790
791         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
792               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
793               %ymm15,
794               ((key_table + (16) * 8) + 0)(CTX),
795               ((key_table + (16) * 8) + 4)(CTX),
796               ((key_table + (16) * 8) + 8)(CTX),
797               ((key_table + (16) * 8) + 12)(CTX));
798
799         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
800                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
801                      %ymm15, %rax, %rcx, 16);
802
803         movl $24, %r8d;
804         cmpl $128, key_bitlength(CTX);
805         jne .Lenc_max32;
806
807 .Lenc_done:
808         /* load CD for output */
809         vmovdqu 0 * 32(%rcx), %ymm8;
810         vmovdqu 1 * 32(%rcx), %ymm9;
811         vmovdqu 2 * 32(%rcx), %ymm10;
812         vmovdqu 3 * 32(%rcx), %ymm11;
813         vmovdqu 4 * 32(%rcx), %ymm12;
814         vmovdqu 5 * 32(%rcx), %ymm13;
815         vmovdqu 6 * 32(%rcx), %ymm14;
816         vmovdqu 7 * 32(%rcx), %ymm15;
817
818         outunpack32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
819                     %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
820                     %ymm15, (key_table)(CTX, %r8, 8), (%rax), 1 * 32(%rax));
821
822         ret;
823
824 .align 8
825 .Lenc_max32:
826         movl $32, %r8d;
827
828         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
829               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
830               %ymm15,
831               ((key_table + (24) * 8) + 0)(CTX),
832               ((key_table + (24) * 8) + 4)(CTX),
833               ((key_table + (24) * 8) + 8)(CTX),
834               ((key_table + (24) * 8) + 12)(CTX));
835
836         enc_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
837                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
838                      %ymm15, %rax, %rcx, 24);
839
840         jmp .Lenc_done;
841 ELF(.size __camellia_enc_blk32,.-__camellia_enc_blk32;)
842
843 .align 8
844 ELF(.type   __camellia_dec_blk32,@function;)
845
846 __camellia_dec_blk32:
847         /* input:
848          *      %rdi: ctx, CTX
849          *      %rax: temporary storage, 512 bytes
850          *      %r8d: 24 for 16 byte key, 32 for larger
851          *      %ymm0..%ymm15: 16 encrypted blocks
852          * output:
853          *      %ymm0..%ymm15: 16 plaintext blocks, order swapped:
854          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
855          */
856
857         leaq 8 * 32(%rax), %rcx;
858
859         inpack32_post(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
860                       %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
861                       %ymm15, %rax, %rcx);
862
863         cmpl $32, %r8d;
864         je .Ldec_max32;
865
866 .Ldec_max24:
867         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
868                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
869                      %ymm15, %rax, %rcx, 16);
870
871         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
872               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
873               %ymm15,
874               ((key_table + (16) * 8) + 8)(CTX),
875               ((key_table + (16) * 8) + 12)(CTX),
876               ((key_table + (16) * 8) + 0)(CTX),
877               ((key_table + (16) * 8) + 4)(CTX));
878
879         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
880                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
881                      %ymm15, %rax, %rcx, 8);
882
883         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
884               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
885               %ymm15,
886               ((key_table + (8) * 8) + 8)(CTX),
887               ((key_table + (8) * 8) + 12)(CTX),
888               ((key_table + (8) * 8) + 0)(CTX),
889               ((key_table + (8) * 8) + 4)(CTX));
890
891         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
892                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
893                      %ymm15, %rax, %rcx, 0);
894
895         /* load CD for output */
896         vmovdqu 0 * 32(%rcx), %ymm8;
897         vmovdqu 1 * 32(%rcx), %ymm9;
898         vmovdqu 2 * 32(%rcx), %ymm10;
899         vmovdqu 3 * 32(%rcx), %ymm11;
900         vmovdqu 4 * 32(%rcx), %ymm12;
901         vmovdqu 5 * 32(%rcx), %ymm13;
902         vmovdqu 6 * 32(%rcx), %ymm14;
903         vmovdqu 7 * 32(%rcx), %ymm15;
904
905         outunpack32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
906                     %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
907                     %ymm15, (key_table)(CTX), (%rax), 1 * 32(%rax));
908
909         ret;
910
911 .align 8
912 .Ldec_max32:
913         dec_rounds32(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
914                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
915                      %ymm15, %rax, %rcx, 24);
916
917         fls32(%rax, %ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
918               %rcx, %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
919               %ymm15,
920               ((key_table + (24) * 8) + 8)(CTX),
921               ((key_table + (24) * 8) + 12)(CTX),
922               ((key_table + (24) * 8) + 0)(CTX),
923               ((key_table + (24) * 8) + 4)(CTX));
924
925         jmp .Ldec_max24;
926 ELF(.size __camellia_dec_blk32,.-__camellia_dec_blk32;)
927
928 #define inc_le128(x, minus_one, tmp) \
929         vpcmpeqq minus_one, x, tmp; \
930         vpsubq minus_one, x, x; \
931         vpslldq $8, tmp, tmp; \
932         vpsubq tmp, x, x;
933
934 .align 8
935 .globl _gcry_camellia_aesni_avx2_ctr_enc
936 ELF(.type   _gcry_camellia_aesni_avx2_ctr_enc,@function;)
937
938 _gcry_camellia_aesni_avx2_ctr_enc:
939         /* input:
940          *      %rdi: ctx, CTX
941          *      %rsi: dst (32 blocks)
942          *      %rdx: src (32 blocks)
943          *      %rcx: iv (big endian, 128bit)
944          */
945
946         pushq %rbp;
947         movq %rsp, %rbp;
948
949         movq 8(%rcx), %r11;
950         bswapq %r11;
951
952         vzeroupper;
953
954         subq $(16 * 32), %rsp;
955         andq $~63, %rsp;
956         movq %rsp, %rax;
957
958         vpcmpeqd %ymm15, %ymm15, %ymm15;
959         vpsrldq $8, %ymm15, %ymm15; /* ab: -1:0 ; cd: -1:0 */
960
961         /* load IV and byteswap */
962         vmovdqu (%rcx), %xmm0;
963         vpshufb .Lbswap128_mask RIP, %xmm0, %xmm0;
964         vmovdqa %xmm0, %xmm1;
965         inc_le128(%xmm0, %xmm15, %xmm14);
966         vbroadcasti128 .Lbswap128_mask RIP, %ymm14;
967         vinserti128 $1, %xmm0, %ymm1, %ymm0;
968         vpshufb %ymm14, %ymm0, %ymm13;
969         vmovdqu %ymm13, 15 * 32(%rax);
970
971         /* check need for handling 64-bit overflow and carry */
972         cmpq $(0xffffffffffffffff - 32), %r11;
973         ja .Lload_ctr_carry;
974
975         /* construct IVs */
976         vpaddq %ymm15, %ymm15, %ymm15; /* ab: -2:0 ; cd: -2:0 */
977         vpsubq %ymm15, %ymm0, %ymm0;
978         vpshufb %ymm14, %ymm0, %ymm13;
979         vmovdqu %ymm13, 14 * 32(%rax);
980         vpsubq %ymm15, %ymm0, %ymm0;
981         vpshufb %ymm14, %ymm0, %ymm13;
982         vmovdqu %ymm13, 13 * 32(%rax);
983         vpsubq %ymm15, %ymm0, %ymm0;
984         vpshufb %ymm14, %ymm0, %ymm12;
985         vpsubq %ymm15, %ymm0, %ymm0;
986         vpshufb %ymm14, %ymm0, %ymm11;
987         vpsubq %ymm15, %ymm0, %ymm0;
988         vpshufb %ymm14, %ymm0, %ymm10;
989         vpsubq %ymm15, %ymm0, %ymm0;
990         vpshufb %ymm14, %ymm0, %ymm9;
991         vpsubq %ymm15, %ymm0, %ymm0;
992         vpshufb %ymm14, %ymm0, %ymm8;
993         vpsubq %ymm15, %ymm0, %ymm0;
994         vpshufb %ymm14, %ymm0, %ymm7;
995         vpsubq %ymm15, %ymm0, %ymm0;
996         vpshufb %ymm14, %ymm0, %ymm6;
997         vpsubq %ymm15, %ymm0, %ymm0;
998         vpshufb %ymm14, %ymm0, %ymm5;
999         vpsubq %ymm15, %ymm0, %ymm0;
1000         vpshufb %ymm14, %ymm0, %ymm4;
1001         vpsubq %ymm15, %ymm0, %ymm0;
1002         vpshufb %ymm14, %ymm0, %ymm3;
1003         vpsubq %ymm15, %ymm0, %ymm0;
1004         vpshufb %ymm14, %ymm0, %ymm2;
1005         vpsubq %ymm15, %ymm0, %ymm0;
1006         vpshufb %ymm14, %ymm0, %ymm1;
1007         vpsubq %ymm15, %ymm0, %ymm0;  /* +30 ; +31 */
1008         vpsubq %xmm15, %xmm0, %xmm13; /* +32 */
1009         vpshufb %ymm14, %ymm0, %ymm0;
1010         vpshufb %xmm14, %xmm13, %xmm13;
1011         vmovdqu %xmm13, (%rcx);
1012
1013         jmp .Lload_ctr_done;
1014
1015 .align 4
1016 .Lload_ctr_carry:
1017         /* construct IVs */
1018         inc_le128(%ymm0, %ymm15, %ymm13); /* ab: le1 ; cd: le2 */
1019         inc_le128(%ymm0, %ymm15, %ymm13); /* ab: le2 ; cd: le3 */
1020         vpshufb %ymm14, %ymm0, %ymm13;
1021         vmovdqu %ymm13, 14 * 32(%rax);
1022         inc_le128(%ymm0, %ymm15, %ymm13);
1023         inc_le128(%ymm0, %ymm15, %ymm13);
1024         vpshufb %ymm14, %ymm0, %ymm13;
1025         vmovdqu %ymm13, 13 * 32(%rax);
1026         inc_le128(%ymm0, %ymm15, %ymm13);
1027         inc_le128(%ymm0, %ymm15, %ymm13);
1028         vpshufb %ymm14, %ymm0, %ymm12;
1029         inc_le128(%ymm0, %ymm15, %ymm13);
1030         inc_le128(%ymm0, %ymm15, %ymm13);
1031         vpshufb %ymm14, %ymm0, %ymm11;
1032         inc_le128(%ymm0, %ymm15, %ymm13);
1033         inc_le128(%ymm0, %ymm15, %ymm13);
1034         vpshufb %ymm14, %ymm0, %ymm10;
1035         inc_le128(%ymm0, %ymm15, %ymm13);
1036         inc_le128(%ymm0, %ymm15, %ymm13);
1037         vpshufb %ymm14, %ymm0, %ymm9;
1038         inc_le128(%ymm0, %ymm15, %ymm13);
1039         inc_le128(%ymm0, %ymm15, %ymm13);
1040         vpshufb %ymm14, %ymm0, %ymm8;
1041         inc_le128(%ymm0, %ymm15, %ymm13);
1042         inc_le128(%ymm0, %ymm15, %ymm13);
1043         vpshufb %ymm14, %ymm0, %ymm7;
1044         inc_le128(%ymm0, %ymm15, %ymm13);
1045         inc_le128(%ymm0, %ymm15, %ymm13);
1046         vpshufb %ymm14, %ymm0, %ymm6;
1047         inc_le128(%ymm0, %ymm15, %ymm13);
1048         inc_le128(%ymm0, %ymm15, %ymm13);
1049         vpshufb %ymm14, %ymm0, %ymm5;
1050         inc_le128(%ymm0, %ymm15, %ymm13);
1051         inc_le128(%ymm0, %ymm15, %ymm13);
1052         vpshufb %ymm14, %ymm0, %ymm4;
1053         inc_le128(%ymm0, %ymm15, %ymm13);
1054         inc_le128(%ymm0, %ymm15, %ymm13);
1055         vpshufb %ymm14, %ymm0, %ymm3;
1056         inc_le128(%ymm0, %ymm15, %ymm13);
1057         inc_le128(%ymm0, %ymm15, %ymm13);
1058         vpshufb %ymm14, %ymm0, %ymm2;
1059         inc_le128(%ymm0, %ymm15, %ymm13);
1060         inc_le128(%ymm0, %ymm15, %ymm13);
1061         vpshufb %ymm14, %ymm0, %ymm1;
1062         inc_le128(%ymm0, %ymm15, %ymm13);
1063         inc_le128(%ymm0, %ymm15, %ymm13);
1064         vextracti128 $1, %ymm0, %xmm13;
1065         vpshufb %ymm14, %ymm0, %ymm0;
1066         inc_le128(%xmm13, %xmm15, %xmm14);
1067         vpshufb .Lbswap128_mask RIP, %xmm13, %xmm13;
1068         vmovdqu %xmm13, (%rcx);
1069
1070 .align 4
1071 .Lload_ctr_done:
1072         /* inpack16_pre: */
1073         vpbroadcastq (key_table)(CTX), %ymm15;
1074         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1075         vpxor %ymm0, %ymm15, %ymm0;
1076         vpxor %ymm1, %ymm15, %ymm1;
1077         vpxor %ymm2, %ymm15, %ymm2;
1078         vpxor %ymm3, %ymm15, %ymm3;
1079         vpxor %ymm4, %ymm15, %ymm4;
1080         vpxor %ymm5, %ymm15, %ymm5;
1081         vpxor %ymm6, %ymm15, %ymm6;
1082         vpxor %ymm7, %ymm15, %ymm7;
1083         vpxor %ymm8, %ymm15, %ymm8;
1084         vpxor %ymm9, %ymm15, %ymm9;
1085         vpxor %ymm10, %ymm15, %ymm10;
1086         vpxor %ymm11, %ymm15, %ymm11;
1087         vpxor %ymm12, %ymm15, %ymm12;
1088         vpxor 13 * 32(%rax), %ymm15, %ymm13;
1089         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1090         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1091
1092         call __camellia_enc_blk32;
1093
1094         vpxor 0 * 32(%rdx), %ymm7, %ymm7;
1095         vpxor 1 * 32(%rdx), %ymm6, %ymm6;
1096         vpxor 2 * 32(%rdx), %ymm5, %ymm5;
1097         vpxor 3 * 32(%rdx), %ymm4, %ymm4;
1098         vpxor 4 * 32(%rdx), %ymm3, %ymm3;
1099         vpxor 5 * 32(%rdx), %ymm2, %ymm2;
1100         vpxor 6 * 32(%rdx), %ymm1, %ymm1;
1101         vpxor 7 * 32(%rdx), %ymm0, %ymm0;
1102         vpxor 8 * 32(%rdx), %ymm15, %ymm15;
1103         vpxor 9 * 32(%rdx), %ymm14, %ymm14;
1104         vpxor 10 * 32(%rdx), %ymm13, %ymm13;
1105         vpxor 11 * 32(%rdx), %ymm12, %ymm12;
1106         vpxor 12 * 32(%rdx), %ymm11, %ymm11;
1107         vpxor 13 * 32(%rdx), %ymm10, %ymm10;
1108         vpxor 14 * 32(%rdx), %ymm9, %ymm9;
1109         vpxor 15 * 32(%rdx), %ymm8, %ymm8;
1110         leaq 32 * 16(%rdx), %rdx;
1111
1112         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1113                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1114                      %ymm8, %rsi);
1115
1116         vzeroall;
1117
1118         leave;
1119         ret;
1120 ELF(.size _gcry_camellia_aesni_avx2_ctr_enc,.-_gcry_camellia_aesni_avx2_ctr_enc;)
1121
1122 .align 8
1123 .globl _gcry_camellia_aesni_avx2_cbc_dec
1124 ELF(.type   _gcry_camellia_aesni_avx2_cbc_dec,@function;)
1125
1126 _gcry_camellia_aesni_avx2_cbc_dec:
1127         /* input:
1128          *      %rdi: ctx, CTX
1129          *      %rsi: dst (32 blocks)
1130          *      %rdx: src (32 blocks)
1131          *      %rcx: iv
1132          */
1133
1134         pushq %rbp;
1135         movq %rsp, %rbp;
1136
1137         vzeroupper;
1138
1139         movq %rcx, %r9;
1140
1141         cmpl $128, key_bitlength(CTX);
1142         movl $32, %r8d;
1143         movl $24, %eax;
1144         cmovel %eax, %r8d; /* max */
1145
1146         subq $(16 * 32), %rsp;
1147         andq $~63, %rsp;
1148         movq %rsp, %rax;
1149
1150         inpack32_pre(%ymm0, %ymm1, %ymm2, %ymm3, %ymm4, %ymm5, %ymm6, %ymm7,
1151                      %ymm8, %ymm9, %ymm10, %ymm11, %ymm12, %ymm13, %ymm14,
1152                      %ymm15, %rdx, (key_table)(CTX, %r8, 8));
1153
1154         call __camellia_dec_blk32;
1155
1156         /* XOR output with IV */
1157         vmovdqu %ymm8, (%rax);
1158         vmovdqu (%r9), %xmm8;
1159         vinserti128 $1, (%rdx), %ymm8, %ymm8;
1160         vpxor %ymm8, %ymm7, %ymm7;
1161         vmovdqu (%rax), %ymm8;
1162         vpxor (0 * 32 + 16)(%rdx), %ymm6, %ymm6;
1163         vpxor (1 * 32 + 16)(%rdx), %ymm5, %ymm5;
1164         vpxor (2 * 32 + 16)(%rdx), %ymm4, %ymm4;
1165         vpxor (3 * 32 + 16)(%rdx), %ymm3, %ymm3;
1166         vpxor (4 * 32 + 16)(%rdx), %ymm2, %ymm2;
1167         vpxor (5 * 32 + 16)(%rdx), %ymm1, %ymm1;
1168         vpxor (6 * 32 + 16)(%rdx), %ymm0, %ymm0;
1169         vpxor (7 * 32 + 16)(%rdx), %ymm15, %ymm15;
1170         vpxor (8 * 32 + 16)(%rdx), %ymm14, %ymm14;
1171         vpxor (9 * 32 + 16)(%rdx), %ymm13, %ymm13;
1172         vpxor (10 * 32 + 16)(%rdx), %ymm12, %ymm12;
1173         vpxor (11 * 32 + 16)(%rdx), %ymm11, %ymm11;
1174         vpxor (12 * 32 + 16)(%rdx), %ymm10, %ymm10;
1175         vpxor (13 * 32 + 16)(%rdx), %ymm9, %ymm9;
1176         vpxor (14 * 32 + 16)(%rdx), %ymm8, %ymm8;
1177         movq (15 * 32 + 16 + 0)(%rdx), %rax;
1178         movq (15 * 32 + 16 + 8)(%rdx), %rcx;
1179
1180         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1181                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1182                      %ymm8, %rsi);
1183
1184         /* store new IV */
1185         movq %rax, (0)(%r9);
1186         movq %rcx, (8)(%r9);
1187
1188         vzeroall;
1189
1190         leave;
1191         ret;
1192 ELF(.size _gcry_camellia_aesni_avx2_cbc_dec,.-_gcry_camellia_aesni_avx2_cbc_dec;)
1193
1194 .align 8
1195 .globl _gcry_camellia_aesni_avx2_cfb_dec
1196 ELF(.type   _gcry_camellia_aesni_avx2_cfb_dec,@function;)
1197
1198 _gcry_camellia_aesni_avx2_cfb_dec:
1199         /* input:
1200          *      %rdi: ctx, CTX
1201          *      %rsi: dst (32 blocks)
1202          *      %rdx: src (32 blocks)
1203          *      %rcx: iv
1204          */
1205
1206         pushq %rbp;
1207         movq %rsp, %rbp;
1208
1209         vzeroupper;
1210
1211         subq $(16 * 32), %rsp;
1212         andq $~63, %rsp;
1213         movq %rsp, %rax;
1214
1215         /* inpack16_pre: */
1216         vpbroadcastq (key_table)(CTX), %ymm0;
1217         vpshufb .Lpack_bswap RIP, %ymm0, %ymm0;
1218         vmovdqu (%rcx), %xmm15;
1219         vinserti128 $1, (%rdx), %ymm15, %ymm15;
1220         vpxor %ymm15, %ymm0, %ymm15;
1221         vmovdqu (15 * 32 + 16)(%rdx), %xmm1;
1222         vmovdqu %xmm1, (%rcx); /* store new IV */
1223         vpxor (0 * 32 + 16)(%rdx), %ymm0, %ymm14;
1224         vpxor (1 * 32 + 16)(%rdx), %ymm0, %ymm13;
1225         vpxor (2 * 32 + 16)(%rdx), %ymm0, %ymm12;
1226         vpxor (3 * 32 + 16)(%rdx), %ymm0, %ymm11;
1227         vpxor (4 * 32 + 16)(%rdx), %ymm0, %ymm10;
1228         vpxor (5 * 32 + 16)(%rdx), %ymm0, %ymm9;
1229         vpxor (6 * 32 + 16)(%rdx), %ymm0, %ymm8;
1230         vpxor (7 * 32 + 16)(%rdx), %ymm0, %ymm7;
1231         vpxor (8 * 32 + 16)(%rdx), %ymm0, %ymm6;
1232         vpxor (9 * 32 + 16)(%rdx), %ymm0, %ymm5;
1233         vpxor (10 * 32 + 16)(%rdx), %ymm0, %ymm4;
1234         vpxor (11 * 32 + 16)(%rdx), %ymm0, %ymm3;
1235         vpxor (12 * 32 + 16)(%rdx), %ymm0, %ymm2;
1236         vpxor (13 * 32 + 16)(%rdx), %ymm0, %ymm1;
1237         vpxor (14 * 32 + 16)(%rdx), %ymm0, %ymm0;
1238
1239         call __camellia_enc_blk32;
1240
1241         vpxor 0 * 32(%rdx), %ymm7, %ymm7;
1242         vpxor 1 * 32(%rdx), %ymm6, %ymm6;
1243         vpxor 2 * 32(%rdx), %ymm5, %ymm5;
1244         vpxor 3 * 32(%rdx), %ymm4, %ymm4;
1245         vpxor 4 * 32(%rdx), %ymm3, %ymm3;
1246         vpxor 5 * 32(%rdx), %ymm2, %ymm2;
1247         vpxor 6 * 32(%rdx), %ymm1, %ymm1;
1248         vpxor 7 * 32(%rdx), %ymm0, %ymm0;
1249         vpxor 8 * 32(%rdx), %ymm15, %ymm15;
1250         vpxor 9 * 32(%rdx), %ymm14, %ymm14;
1251         vpxor 10 * 32(%rdx), %ymm13, %ymm13;
1252         vpxor 11 * 32(%rdx), %ymm12, %ymm12;
1253         vpxor 12 * 32(%rdx), %ymm11, %ymm11;
1254         vpxor 13 * 32(%rdx), %ymm10, %ymm10;
1255         vpxor 14 * 32(%rdx), %ymm9, %ymm9;
1256         vpxor 15 * 32(%rdx), %ymm8, %ymm8;
1257
1258         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1259                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1260                      %ymm8, %rsi);
1261
1262         vzeroall;
1263
1264         leave;
1265         ret;
1266 ELF(.size _gcry_camellia_aesni_avx2_cfb_dec,.-_gcry_camellia_aesni_avx2_cfb_dec;)
1267
1268 .align 8
1269 .globl _gcry_camellia_aesni_avx2_ocb_enc
1270 ELF(.type   _gcry_camellia_aesni_avx2_ocb_enc,@function;)
1271
1272 _gcry_camellia_aesni_avx2_ocb_enc:
1273         /* input:
1274          *      %rdi: ctx, CTX
1275          *      %rsi: dst (32 blocks)
1276          *      %rdx: src (32 blocks)
1277          *      %rcx: offset
1278          *      %r8 : checksum
1279          *      %r9 : L pointers (void *L[32])
1280          */
1281
1282         pushq %rbp;
1283         movq %rsp, %rbp;
1284
1285         vzeroupper;
1286
1287         subq $(16 * 32 + 4 * 8), %rsp;
1288         andq $~63, %rsp;
1289         movq %rsp, %rax;
1290
1291         movq %r10, (16 * 32 + 0 * 8)(%rax);
1292         movq %r11, (16 * 32 + 1 * 8)(%rax);
1293         movq %r12, (16 * 32 + 2 * 8)(%rax);
1294         movq %r13, (16 * 32 + 3 * 8)(%rax);
1295
1296         vmovdqu (%rcx), %xmm14;
1297         vmovdqu (%r8), %xmm13;
1298
1299         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1300         /* Checksum_i = Checksum_{i-1} xor P_i  */
1301         /* C_i = Offset_i xor ENCIPHER(K, P_i xor Offset_i)  */
1302
1303 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1304           vmovdqu (n * 32)(%rdx), yreg; \
1305           vpxor (l0reg), %xmm14, %xmm15; \
1306           vpxor (l1reg), %xmm15, %xmm14; \
1307           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1308           vpxor yreg, %ymm13, %ymm13; \
1309           vpxor yreg, %ymm15, yreg; \
1310           vmovdqu %ymm15, (n * 32)(%rsi);
1311
1312         movq (0 * 8)(%r9), %r10;
1313         movq (1 * 8)(%r9), %r11;
1314         movq (2 * 8)(%r9), %r12;
1315         movq (3 * 8)(%r9), %r13;
1316         OCB_INPUT(0, %r10, %r11, %ymm0);
1317         vmovdqu %ymm0, (15 * 32)(%rax);
1318         OCB_INPUT(1, %r12, %r13, %ymm0);
1319         vmovdqu %ymm0, (14 * 32)(%rax);
1320         movq (4 * 8)(%r9), %r10;
1321         movq (5 * 8)(%r9), %r11;
1322         movq (6 * 8)(%r9), %r12;
1323         movq (7 * 8)(%r9), %r13;
1324         OCB_INPUT(2, %r10, %r11, %ymm0);
1325         vmovdqu %ymm0, (13 * 32)(%rax);
1326         OCB_INPUT(3, %r12, %r13, %ymm12);
1327         movq (8 * 8)(%r9), %r10;
1328         movq (9 * 8)(%r9), %r11;
1329         movq (10 * 8)(%r9), %r12;
1330         movq (11 * 8)(%r9), %r13;
1331         OCB_INPUT(4, %r10, %r11, %ymm11);
1332         OCB_INPUT(5, %r12, %r13, %ymm10);
1333         movq (12 * 8)(%r9), %r10;
1334         movq (13 * 8)(%r9), %r11;
1335         movq (14 * 8)(%r9), %r12;
1336         movq (15 * 8)(%r9), %r13;
1337         OCB_INPUT(6, %r10, %r11, %ymm9);
1338         OCB_INPUT(7, %r12, %r13, %ymm8);
1339         movq (16 * 8)(%r9), %r10;
1340         movq (17 * 8)(%r9), %r11;
1341         movq (18 * 8)(%r9), %r12;
1342         movq (19 * 8)(%r9), %r13;
1343         OCB_INPUT(8, %r10, %r11, %ymm7);
1344         OCB_INPUT(9, %r12, %r13, %ymm6);
1345         movq (20 * 8)(%r9), %r10;
1346         movq (21 * 8)(%r9), %r11;
1347         movq (22 * 8)(%r9), %r12;
1348         movq (23 * 8)(%r9), %r13;
1349         OCB_INPUT(10, %r10, %r11, %ymm5);
1350         OCB_INPUT(11, %r12, %r13, %ymm4);
1351         movq (24 * 8)(%r9), %r10;
1352         movq (25 * 8)(%r9), %r11;
1353         movq (26 * 8)(%r9), %r12;
1354         movq (27 * 8)(%r9), %r13;
1355         OCB_INPUT(12, %r10, %r11, %ymm3);
1356         OCB_INPUT(13, %r12, %r13, %ymm2);
1357         movq (28 * 8)(%r9), %r10;
1358         movq (29 * 8)(%r9), %r11;
1359         movq (30 * 8)(%r9), %r12;
1360         movq (31 * 8)(%r9), %r13;
1361         OCB_INPUT(14, %r10, %r11, %ymm1);
1362         OCB_INPUT(15, %r12, %r13, %ymm0);
1363 #undef OCB_INPUT
1364
1365         vextracti128 $1, %ymm13, %xmm15;
1366         vmovdqu %xmm14, (%rcx);
1367         vpxor %xmm13, %xmm15, %xmm15;
1368         vmovdqu %xmm15, (%r8);
1369
1370         /* inpack16_pre: */
1371         vpbroadcastq (key_table)(CTX), %ymm15;
1372         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1373         vpxor %ymm0, %ymm15, %ymm0;
1374         vpxor %ymm1, %ymm15, %ymm1;
1375         vpxor %ymm2, %ymm15, %ymm2;
1376         vpxor %ymm3, %ymm15, %ymm3;
1377         vpxor %ymm4, %ymm15, %ymm4;
1378         vpxor %ymm5, %ymm15, %ymm5;
1379         vpxor %ymm6, %ymm15, %ymm6;
1380         vpxor %ymm7, %ymm15, %ymm7;
1381         vpxor %ymm8, %ymm15, %ymm8;
1382         vpxor %ymm9, %ymm15, %ymm9;
1383         vpxor %ymm10, %ymm15, %ymm10;
1384         vpxor %ymm11, %ymm15, %ymm11;
1385         vpxor %ymm12, %ymm15, %ymm12;
1386         vpxor 13 * 32(%rax), %ymm15, %ymm13;
1387         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1388         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1389
1390         call __camellia_enc_blk32;
1391
1392         vpxor 0 * 32(%rsi), %ymm7, %ymm7;
1393         vpxor 1 * 32(%rsi), %ymm6, %ymm6;
1394         vpxor 2 * 32(%rsi), %ymm5, %ymm5;
1395         vpxor 3 * 32(%rsi), %ymm4, %ymm4;
1396         vpxor 4 * 32(%rsi), %ymm3, %ymm3;
1397         vpxor 5 * 32(%rsi), %ymm2, %ymm2;
1398         vpxor 6 * 32(%rsi), %ymm1, %ymm1;
1399         vpxor 7 * 32(%rsi), %ymm0, %ymm0;
1400         vpxor 8 * 32(%rsi), %ymm15, %ymm15;
1401         vpxor 9 * 32(%rsi), %ymm14, %ymm14;
1402         vpxor 10 * 32(%rsi), %ymm13, %ymm13;
1403         vpxor 11 * 32(%rsi), %ymm12, %ymm12;
1404         vpxor 12 * 32(%rsi), %ymm11, %ymm11;
1405         vpxor 13 * 32(%rsi), %ymm10, %ymm10;
1406         vpxor 14 * 32(%rsi), %ymm9, %ymm9;
1407         vpxor 15 * 32(%rsi), %ymm8, %ymm8;
1408
1409         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1410                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1411                      %ymm8, %rsi);
1412
1413         vzeroall;
1414
1415         movq (16 * 32 + 0 * 8)(%rax), %r10;
1416         movq (16 * 32 + 1 * 8)(%rax), %r11;
1417         movq (16 * 32 + 2 * 8)(%rax), %r12;
1418         movq (16 * 32 + 3 * 8)(%rax), %r13;
1419
1420         leave;
1421         ret;
1422 ELF(.size _gcry_camellia_aesni_avx2_ocb_enc,.-_gcry_camellia_aesni_avx2_ocb_enc;)
1423
1424 .align 8
1425 .globl _gcry_camellia_aesni_avx2_ocb_dec
1426 ELF(.type   _gcry_camellia_aesni_avx2_ocb_dec,@function;)
1427
1428 _gcry_camellia_aesni_avx2_ocb_dec:
1429         /* input:
1430          *      %rdi: ctx, CTX
1431          *      %rsi: dst (32 blocks)
1432          *      %rdx: src (32 blocks)
1433          *      %rcx: offset
1434          *      %r8 : checksum
1435          *      %r9 : L pointers (void *L[32])
1436          */
1437
1438         pushq %rbp;
1439         movq %rsp, %rbp;
1440
1441         vzeroupper;
1442
1443         subq $(16 * 32 + 4 * 8), %rsp;
1444         andq $~63, %rsp;
1445         movq %rsp, %rax;
1446
1447         movq %r10, (16 * 32 + 0 * 8)(%rax);
1448         movq %r11, (16 * 32 + 1 * 8)(%rax);
1449         movq %r12, (16 * 32 + 2 * 8)(%rax);
1450         movq %r13, (16 * 32 + 3 * 8)(%rax);
1451
1452         vmovdqu (%rcx), %xmm14;
1453
1454         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1455         /* P_i = Offset_i xor DECIPHER(K, C_i xor Offset_i)  */
1456
1457 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1458           vmovdqu (n * 32)(%rdx), yreg; \
1459           vpxor (l0reg), %xmm14, %xmm15; \
1460           vpxor (l1reg), %xmm15, %xmm14; \
1461           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1462           vpxor yreg, %ymm15, yreg; \
1463           vmovdqu %ymm15, (n * 32)(%rsi);
1464
1465         movq (0 * 8)(%r9), %r10;
1466         movq (1 * 8)(%r9), %r11;
1467         movq (2 * 8)(%r9), %r12;
1468         movq (3 * 8)(%r9), %r13;
1469         OCB_INPUT(0, %r10, %r11, %ymm0);
1470         vmovdqu %ymm0, (15 * 32)(%rax);
1471         OCB_INPUT(1, %r12, %r13, %ymm0);
1472         vmovdqu %ymm0, (14 * 32)(%rax);
1473         movq (4 * 8)(%r9), %r10;
1474         movq (5 * 8)(%r9), %r11;
1475         movq (6 * 8)(%r9), %r12;
1476         movq (7 * 8)(%r9), %r13;
1477         OCB_INPUT(2, %r10, %r11, %ymm13);
1478         OCB_INPUT(3, %r12, %r13, %ymm12);
1479         movq (8 * 8)(%r9), %r10;
1480         movq (9 * 8)(%r9), %r11;
1481         movq (10 * 8)(%r9), %r12;
1482         movq (11 * 8)(%r9), %r13;
1483         OCB_INPUT(4, %r10, %r11, %ymm11);
1484         OCB_INPUT(5, %r12, %r13, %ymm10);
1485         movq (12 * 8)(%r9), %r10;
1486         movq (13 * 8)(%r9), %r11;
1487         movq (14 * 8)(%r9), %r12;
1488         movq (15 * 8)(%r9), %r13;
1489         OCB_INPUT(6, %r10, %r11, %ymm9);
1490         OCB_INPUT(7, %r12, %r13, %ymm8);
1491         movq (16 * 8)(%r9), %r10;
1492         movq (17 * 8)(%r9), %r11;
1493         movq (18 * 8)(%r9), %r12;
1494         movq (19 * 8)(%r9), %r13;
1495         OCB_INPUT(8, %r10, %r11, %ymm7);
1496         OCB_INPUT(9, %r12, %r13, %ymm6);
1497         movq (20 * 8)(%r9), %r10;
1498         movq (21 * 8)(%r9), %r11;
1499         movq (22 * 8)(%r9), %r12;
1500         movq (23 * 8)(%r9), %r13;
1501         OCB_INPUT(10, %r10, %r11, %ymm5);
1502         OCB_INPUT(11, %r12, %r13, %ymm4);
1503         movq (24 * 8)(%r9), %r10;
1504         movq (25 * 8)(%r9), %r11;
1505         movq (26 * 8)(%r9), %r12;
1506         movq (27 * 8)(%r9), %r13;
1507         OCB_INPUT(12, %r10, %r11, %ymm3);
1508         OCB_INPUT(13, %r12, %r13, %ymm2);
1509         movq (28 * 8)(%r9), %r10;
1510         movq (29 * 8)(%r9), %r11;
1511         movq (30 * 8)(%r9), %r12;
1512         movq (31 * 8)(%r9), %r13;
1513         OCB_INPUT(14, %r10, %r11, %ymm1);
1514         OCB_INPUT(15, %r12, %r13, %ymm0);
1515 #undef OCB_INPUT
1516
1517         vmovdqu %xmm14, (%rcx);
1518
1519         movq %r8, %r10;
1520
1521         cmpl $128, key_bitlength(CTX);
1522         movl $32, %r8d;
1523         movl $24, %r9d;
1524         cmovel %r9d, %r8d; /* max */
1525
1526         /* inpack16_pre: */
1527         vpbroadcastq (key_table)(CTX, %r8, 8), %ymm15;
1528         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1529         vpxor %ymm0, %ymm15, %ymm0;
1530         vpxor %ymm1, %ymm15, %ymm1;
1531         vpxor %ymm2, %ymm15, %ymm2;
1532         vpxor %ymm3, %ymm15, %ymm3;
1533         vpxor %ymm4, %ymm15, %ymm4;
1534         vpxor %ymm5, %ymm15, %ymm5;
1535         vpxor %ymm6, %ymm15, %ymm6;
1536         vpxor %ymm7, %ymm15, %ymm7;
1537         vpxor %ymm8, %ymm15, %ymm8;
1538         vpxor %ymm9, %ymm15, %ymm9;
1539         vpxor %ymm10, %ymm15, %ymm10;
1540         vpxor %ymm11, %ymm15, %ymm11;
1541         vpxor %ymm12, %ymm15, %ymm12;
1542         vpxor %ymm13, %ymm15, %ymm13;
1543         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1544         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1545
1546         call __camellia_dec_blk32;
1547
1548         vpxor 0 * 32(%rsi), %ymm7, %ymm7;
1549         vpxor 1 * 32(%rsi), %ymm6, %ymm6;
1550         vpxor 2 * 32(%rsi), %ymm5, %ymm5;
1551         vpxor 3 * 32(%rsi), %ymm4, %ymm4;
1552         vpxor 4 * 32(%rsi), %ymm3, %ymm3;
1553         vpxor 5 * 32(%rsi), %ymm2, %ymm2;
1554         vpxor 6 * 32(%rsi), %ymm1, %ymm1;
1555         vpxor 7 * 32(%rsi), %ymm0, %ymm0;
1556         vmovdqu %ymm7, (7 * 32)(%rax);
1557         vmovdqu %ymm6, (6 * 32)(%rax);
1558         vpxor 8 * 32(%rsi), %ymm15, %ymm15;
1559         vpxor 9 * 32(%rsi), %ymm14, %ymm14;
1560         vpxor 10 * 32(%rsi), %ymm13, %ymm13;
1561         vpxor 11 * 32(%rsi), %ymm12, %ymm12;
1562         vpxor 12 * 32(%rsi), %ymm11, %ymm11;
1563         vpxor 13 * 32(%rsi), %ymm10, %ymm10;
1564         vpxor 14 * 32(%rsi), %ymm9, %ymm9;
1565         vpxor 15 * 32(%rsi), %ymm8, %ymm8;
1566
1567         /* Checksum_i = Checksum_{i-1} xor P_i  */
1568
1569         vpxor %ymm5, %ymm7, %ymm7;
1570         vpxor %ymm4, %ymm6, %ymm6;
1571         vpxor %ymm3, %ymm7, %ymm7;
1572         vpxor %ymm2, %ymm6, %ymm6;
1573         vpxor %ymm1, %ymm7, %ymm7;
1574         vpxor %ymm0, %ymm6, %ymm6;
1575         vpxor %ymm15, %ymm7, %ymm7;
1576         vpxor %ymm14, %ymm6, %ymm6;
1577         vpxor %ymm13, %ymm7, %ymm7;
1578         vpxor %ymm12, %ymm6, %ymm6;
1579         vpxor %ymm11, %ymm7, %ymm7;
1580         vpxor %ymm10, %ymm6, %ymm6;
1581         vpxor %ymm9, %ymm7, %ymm7;
1582         vpxor %ymm8, %ymm6, %ymm6;
1583         vpxor %ymm7, %ymm6, %ymm7;
1584
1585         vextracti128 $1, %ymm7, %xmm6;
1586         vpxor %xmm6, %xmm7, %xmm7;
1587         vpxor (%r10), %xmm7, %xmm7;
1588         vmovdqu %xmm7, (%r10);
1589
1590         vmovdqu 7 * 32(%rax), %ymm7;
1591         vmovdqu 6 * 32(%rax), %ymm6;
1592
1593         write_output(%ymm7, %ymm6, %ymm5, %ymm4, %ymm3, %ymm2, %ymm1, %ymm0,
1594                      %ymm15, %ymm14, %ymm13, %ymm12, %ymm11, %ymm10, %ymm9,
1595                      %ymm8, %rsi);
1596
1597         vzeroall;
1598
1599         movq (16 * 32 + 0 * 8)(%rax), %r10;
1600         movq (16 * 32 + 1 * 8)(%rax), %r11;
1601         movq (16 * 32 + 2 * 8)(%rax), %r12;
1602         movq (16 * 32 + 3 * 8)(%rax), %r13;
1603
1604         leave;
1605         ret;
1606 ELF(.size _gcry_camellia_aesni_avx2_ocb_dec,.-_gcry_camellia_aesni_avx2_ocb_dec;)
1607
1608 .align 8
1609 .globl _gcry_camellia_aesni_avx2_ocb_auth
1610 ELF(.type   _gcry_camellia_aesni_avx2_ocb_auth,@function;)
1611
1612 _gcry_camellia_aesni_avx2_ocb_auth:
1613         /* input:
1614          *      %rdi: ctx, CTX
1615          *      %rsi: abuf (16 blocks)
1616          *      %rdx: offset
1617          *      %rcx: checksum
1618          *      %r8 : L pointers (void *L[16])
1619          */
1620
1621         pushq %rbp;
1622         movq %rsp, %rbp;
1623
1624         vzeroupper;
1625
1626         subq $(16 * 32 + 4 * 8), %rsp;
1627         andq $~63, %rsp;
1628         movq %rsp, %rax;
1629
1630         movq %r10, (16 * 32 + 0 * 8)(%rax);
1631         movq %r11, (16 * 32 + 1 * 8)(%rax);
1632         movq %r12, (16 * 32 + 2 * 8)(%rax);
1633         movq %r13, (16 * 32 + 3 * 8)(%rax);
1634
1635         vmovdqu (%rdx), %xmm14;
1636
1637         /* Offset_i = Offset_{i-1} xor L_{ntz(i)} */
1638         /* Checksum_i = Checksum_{i-1} xor P_i  */
1639         /* C_i = Offset_i xor ENCIPHER(K, P_i xor Offset_i)  */
1640
1641 #define OCB_INPUT(n, l0reg, l1reg, yreg) \
1642           vmovdqu (n * 32)(%rsi), yreg; \
1643           vpxor (l0reg), %xmm14, %xmm15; \
1644           vpxor (l1reg), %xmm15, %xmm14; \
1645           vinserti128 $1, %xmm14, %ymm15, %ymm15; \
1646           vpxor yreg, %ymm15, yreg;
1647
1648         movq (0 * 8)(%r8), %r10;
1649         movq (1 * 8)(%r8), %r11;
1650         movq (2 * 8)(%r8), %r12;
1651         movq (3 * 8)(%r8), %r13;
1652         OCB_INPUT(0, %r10, %r11, %ymm0);
1653         vmovdqu %ymm0, (15 * 32)(%rax);
1654         OCB_INPUT(1, %r12, %r13, %ymm0);
1655         vmovdqu %ymm0, (14 * 32)(%rax);
1656         movq (4 * 8)(%r8), %r10;
1657         movq (5 * 8)(%r8), %r11;
1658         movq (6 * 8)(%r8), %r12;
1659         movq (7 * 8)(%r8), %r13;
1660         OCB_INPUT(2, %r10, %r11, %ymm13);
1661         OCB_INPUT(3, %r12, %r13, %ymm12);
1662         movq (8 * 8)(%r8), %r10;
1663         movq (9 * 8)(%r8), %r11;
1664         movq (10 * 8)(%r8), %r12;
1665         movq (11 * 8)(%r8), %r13;
1666         OCB_INPUT(4, %r10, %r11, %ymm11);
1667         OCB_INPUT(5, %r12, %r13, %ymm10);
1668         movq (12 * 8)(%r8), %r10;
1669         movq (13 * 8)(%r8), %r11;
1670         movq (14 * 8)(%r8), %r12;
1671         movq (15 * 8)(%r8), %r13;
1672         OCB_INPUT(6, %r10, %r11, %ymm9);
1673         OCB_INPUT(7, %r12, %r13, %ymm8);
1674         movq (16 * 8)(%r8), %r10;
1675         movq (17 * 8)(%r8), %r11;
1676         movq (18 * 8)(%r8), %r12;
1677         movq (19 * 8)(%r8), %r13;
1678         OCB_INPUT(8, %r10, %r11, %ymm7);
1679         OCB_INPUT(9, %r12, %r13, %ymm6);
1680         movq (20 * 8)(%r8), %r10;
1681         movq (21 * 8)(%r8), %r11;
1682         movq (22 * 8)(%r8), %r12;
1683         movq (23 * 8)(%r8), %r13;
1684         OCB_INPUT(10, %r10, %r11, %ymm5);
1685         OCB_INPUT(11, %r12, %r13, %ymm4);
1686         movq (24 * 8)(%r8), %r10;
1687         movq (25 * 8)(%r8), %r11;
1688         movq (26 * 8)(%r8), %r12;
1689         movq (27 * 8)(%r8), %r13;
1690         OCB_INPUT(12, %r10, %r11, %ymm3);
1691         OCB_INPUT(13, %r12, %r13, %ymm2);
1692         movq (28 * 8)(%r8), %r10;
1693         movq (29 * 8)(%r8), %r11;
1694         movq (30 * 8)(%r8), %r12;
1695         movq (31 * 8)(%r8), %r13;
1696         OCB_INPUT(14, %r10, %r11, %ymm1);
1697         OCB_INPUT(15, %r12, %r13, %ymm0);
1698 #undef OCB_INPUT
1699
1700         vmovdqu %xmm14, (%rdx);
1701
1702         movq %rcx, %r10;
1703
1704         /* inpack16_pre: */
1705         vpbroadcastq (key_table)(CTX), %ymm15;
1706         vpshufb .Lpack_bswap RIP, %ymm15, %ymm15;
1707         vpxor %ymm0, %ymm15, %ymm0;
1708         vpxor %ymm1, %ymm15, %ymm1;
1709         vpxor %ymm2, %ymm15, %ymm2;
1710         vpxor %ymm3, %ymm15, %ymm3;
1711         vpxor %ymm4, %ymm15, %ymm4;
1712         vpxor %ymm5, %ymm15, %ymm5;
1713         vpxor %ymm6, %ymm15, %ymm6;
1714         vpxor %ymm7, %ymm15, %ymm7;
1715         vpxor %ymm8, %ymm15, %ymm8;
1716         vpxor %ymm9, %ymm15, %ymm9;
1717         vpxor %ymm10, %ymm15, %ymm10;
1718         vpxor %ymm11, %ymm15, %ymm11;
1719         vpxor %ymm12, %ymm15, %ymm12;
1720         vpxor %ymm13, %ymm15, %ymm13;
1721         vpxor 14 * 32(%rax), %ymm15, %ymm14;
1722         vpxor 15 * 32(%rax), %ymm15, %ymm15;
1723
1724         call __camellia_enc_blk32;
1725
1726         vpxor %ymm7, %ymm6, %ymm6;
1727         vpxor %ymm5, %ymm4, %ymm4;
1728         vpxor %ymm3, %ymm2, %ymm2;
1729         vpxor %ymm1, %ymm0, %ymm0;
1730         vpxor %ymm15, %ymm14, %ymm14;
1731         vpxor %ymm13, %ymm12, %ymm12;
1732         vpxor %ymm11, %ymm10, %ymm10;
1733         vpxor %ymm9, %ymm8, %ymm8;
1734
1735         vpxor %ymm6, %ymm4, %ymm4;
1736         vpxor %ymm2, %ymm0, %ymm0;
1737         vpxor %ymm14, %ymm12, %ymm12;
1738         vpxor %ymm10, %ymm8, %ymm8;
1739
1740         vpxor %ymm4, %ymm0, %ymm0;
1741         vpxor %ymm12, %ymm8, %ymm8;
1742
1743         vpxor %ymm0, %ymm8, %ymm0;
1744
1745         vextracti128 $1, %ymm0, %xmm1;
1746         vpxor (%r10), %xmm0, %xmm0;
1747         vpxor %xmm0, %xmm1, %xmm0;
1748         vmovdqu %xmm0, (%r10);
1749
1750         vzeroall;
1751
1752         movq (16 * 32 + 0 * 8)(%rax), %r10;
1753         movq (16 * 32 + 1 * 8)(%rax), %r11;
1754         movq (16 * 32 + 2 * 8)(%rax), %r12;
1755         movq (16 * 32 + 3 * 8)(%rax), %r13;
1756
1757         leave;
1758         ret;
1759 ELF(.size _gcry_camellia_aesni_avx2_ocb_auth,.-_gcry_camellia_aesni_avx2_ocb_auth;)
1760
1761 #endif /*defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX2_SUPPORT)*/
1762 #endif /*__x86_64*/