Add AVX and AVX/BMI2 implementations for SHA-1
[libgcrypt.git] / cipher / sha1-avx-bmi2-amd64.S
1 /* sha1-avx-bmi2-amd64.S - Intel AVX/BMI2 accelerated SHA-1 transform function
2  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
33     defined(HAVE_GCC_INLINE_ASM_BMI2) && \
34     defined(HAVE_GCC_INLINE_ASM_AVX) && defined(USE_SHA1)
35
36 #ifdef __PIC__
37 #  define RIP (%rip)
38 #else
39 #  define RIP
40 #endif
41
42
43 /* Context structure */
44
45 #define state_h0 0
46 #define state_h1 4
47 #define state_h2 8
48 #define state_h3 12
49 #define state_h4 16
50
51
52 /* Constants */
53
54 .data
55 #define K1  0x5A827999
56 #define K2  0x6ED9EBA1
57 #define K3  0x8F1BBCDC
58 #define K4  0xCA62C1D6
59 .align 16
60 .LK_XMM:
61 .LK1:   .long K1, K1, K1, K1
62 .LK2:   .long K2, K2, K2, K2
63 .LK3:   .long K3, K3, K3, K3
64 .LK4:   .long K4, K4, K4, K4
65
66 .Lbswap_shufb_ctl:
67         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
68
69
70 /* Register macros */
71
72 #define RSTATE %r8
73 #define RDATA %r9
74 #define ROLDSTACK %r10
75 #define RNBLKS %r11
76
77 #define a %eax
78 #define b %ebx
79 #define c %ecx
80 #define d %edx
81 #define e %edi
82
83 #define RT0 %esi
84 #define RT1 %ebp
85
86 #define Wtmp0 %xmm0
87 #define Wtmp1 %xmm1
88
89 #define W0 %xmm2
90 #define W1 %xmm3
91 #define W2 %xmm4
92 #define W3 %xmm5
93 #define W4 %xmm6
94 #define W5 %xmm7
95 #define W6 %xmm8
96 #define W7 %xmm9
97
98 #define BSWAP_REG %xmm10
99
100
101 /* Round function macros. */
102
103 #define WK(i) (((i) & 15) * 4)(%rsp)
104
105 #define R_F1(a,b,c,d,e,i) \
106         movl c, RT0; \
107         andn d, b, RT1; \
108         addl WK(i), e; \
109         andl b, RT0; \
110         rorxl $2, b, b; \
111         addl RT1, e; \
112         leal (RT0,e), e; \
113         rorxl $27, a, RT1; \
114         addl RT1, e;
115
116 #define R_F2(a,b,c,d,e,i) \
117         movl c, RT0; \
118         addl WK(i), e; \
119         xorl b, RT0; \
120         rorxl $2, b, b; \
121         xorl d, RT0; \
122         leal (RT0,e), e; \
123         rorxl $27, a, RT1; \
124         addl RT1, e;
125
126 #define R_F3(a,b,c,d,e,i) \
127         movl c, RT0; \
128         movl b, RT1; \
129         xorl b, RT0; \
130         andl c, RT1; \
131         andl d, RT0; \
132         addl RT1, e; \
133         addl WK(i), e; \
134         rorxl $2, b, b; \
135         leal (RT0,e), e; \
136         rorxl $27, a, RT1; \
137         addl RT1, e;
138
139 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
140
141 #define R(a,b,c,d,e,f,i) \
142         R_##f(a,b,c,d,e,i)
143
144
145 /* Input expansion macros. */
146
147 #define W_PRECALC_00_15_0(i, W, tmp0) \
148         vmovdqu (4*(i))(RDATA), tmp0;
149
150 #define W_PRECALC_00_15_1(i, W, tmp0) \
151         vpshufb BSWAP_REG, tmp0, W;
152
153 #define W_PRECALC_00_15_2(i, W, tmp0) \
154         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0;
155
156 #define W_PRECALC_00_15_3(i, W, tmp0) \
157         vmovdqa tmp0, WK(i&~3);
158
159 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
160         vpalignr $8, W_m16, W_m12, W; \
161         vpsrldq $4, W_m04, tmp0; \
162         vpxor W_m08, W, W;
163
164 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
165         vpxor W_m16, tmp0, tmp0; \
166         vpxor tmp0, W, W; \
167         vpslld $1, W, tmp0; \
168         vpslldq $12, W, tmp1; \
169         vpsrld $31, W, W;
170
171 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
172         vpor W, tmp0, tmp0; \
173         vpsrld $30, tmp1, W; \
174         vpslld $2, tmp1, tmp1;
175
176 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
177         vpxor W, tmp0, tmp0; \
178         vpxor tmp1, tmp0, W; \
179         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
180         vmovdqa tmp0, WK((i)&~3);
181
182 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
183         vpxor W_m28, W, W; \
184         vpalignr $8, W_m08, W_m04, tmp0;
185
186 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
187         vpxor W_m16, W, W; \
188         vpxor tmp0, W, W;
189
190 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
191         vpsrld $30, W, tmp0; \
192         vpslld $2, W, W;
193
194 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
195         vpor W, tmp0, W; \
196         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
197         vmovdqa tmp0, WK((i)&~3);
198
199
200 /*
201  * Transform nblks*64 bytes (nblks*16 32-bit words) at DATA.
202  *
203  * unsigned int
204  * _gcry_sha1_transform_amd64_avx_bmi2 (void *ctx, const unsigned char *data,
205  *                                      size_t nblks)
206  */
207 .text
208 .globl _gcry_sha1_transform_amd64_avx_bmi2
209 .type _gcry_sha1_transform_amd64_avx_bmi2,@function
210 .align 16
211 _gcry_sha1_transform_amd64_avx_bmi2:
212   /* input:
213    *    %rdi: ctx, CTX
214    *    %rsi: data (64*nblks bytes)
215    *    %rdx: nblks
216    */
217
218   xorl %eax, %eax;
219   cmpq $0, %rdx;
220   jz .Lret;
221
222   vzeroupper;
223
224   movq %rdx, RNBLKS;
225   movq %rdi, RSTATE;
226   movq %rsi, RDATA;
227   pushq %rbx;
228   pushq %rbp;
229
230   movq %rsp, ROLDSTACK;
231
232   subq $(16*4), %rsp;
233   andq $(~31), %rsp;
234
235   /* Get the values of the chaining variables. */
236   movl state_h0(RSTATE), a;
237   movl state_h1(RSTATE), b;
238   movl state_h2(RSTATE), c;
239   movl state_h3(RSTATE), d;
240   movl state_h4(RSTATE), e;
241
242   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
243
244   /* Precalc 0-15. */
245   W_PRECALC_00_15_0(0, W0, Wtmp0);
246   W_PRECALC_00_15_1(1, W0, Wtmp0);
247   W_PRECALC_00_15_2(2, W0, Wtmp0);
248   W_PRECALC_00_15_3(3, W0, Wtmp0);
249   W_PRECALC_00_15_0(4, W7, Wtmp0);
250   W_PRECALC_00_15_1(5, W7, Wtmp0);
251   W_PRECALC_00_15_2(6, W7, Wtmp0);
252   W_PRECALC_00_15_3(7, W7, Wtmp0);
253   W_PRECALC_00_15_0(8, W6, Wtmp0);
254   W_PRECALC_00_15_1(9, W6, Wtmp0);
255   W_PRECALC_00_15_2(10, W6, Wtmp0);
256   W_PRECALC_00_15_3(11, W6, Wtmp0);
257   W_PRECALC_00_15_0(12, W5, Wtmp0);
258   W_PRECALC_00_15_1(13, W5, Wtmp0);
259   W_PRECALC_00_15_2(14, W5, Wtmp0);
260   W_PRECALC_00_15_3(15, W5, Wtmp0);
261
262 .align 8
263 .Loop:
264   addq $64, RDATA;
265
266   /* Transform 0-15 + Precalc 16-31. */
267   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
268   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
269   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
270   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
271   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
272   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
273   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
274   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
275   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
276   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
277   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
278   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
279   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
280   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
281   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
282   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
283
284   /* Transform 16-63 + Precalc 32-79. */
285   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
286   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
287   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
288   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
289   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
290   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
291   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
292   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
293   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
294   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
295   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
296   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
297   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
298   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
299   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
300   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
301   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
302   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
303   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
304   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
305   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
306   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
307   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
308   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
309   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
310   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
311   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
312   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
313   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
314   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
315   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
316   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
317   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
318   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
319   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
320   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
321   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
322   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
323   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
324   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
325   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
326   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
327   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
328   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
329   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
330   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
331   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
332   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
333
334   decq RNBLKS;
335   jz .Lend;
336
337   /* Transform 64-79 + Precalc 0-15 of next block. */
338   R( b, c, d, e, a, F4, 64 ); W_PRECALC_00_15_0(0, W0, Wtmp0);
339   R( a, b, c, d, e, F4, 65 ); W_PRECALC_00_15_1(1, W0, Wtmp0);
340   R( e, a, b, c, d, F4, 66 ); W_PRECALC_00_15_2(2, W0, Wtmp0);
341   R( d, e, a, b, c, F4, 67 ); W_PRECALC_00_15_3(3, W0, Wtmp0);
342   R( c, d, e, a, b, F4, 68 ); W_PRECALC_00_15_0(4, W7, Wtmp0);
343   R( b, c, d, e, a, F4, 69 ); W_PRECALC_00_15_1(5, W7, Wtmp0);
344   R( a, b, c, d, e, F4, 70 ); W_PRECALC_00_15_2(6, W7, Wtmp0);
345   R( e, a, b, c, d, F4, 71 ); W_PRECALC_00_15_3(7, W7, Wtmp0);
346   R( d, e, a, b, c, F4, 72 ); W_PRECALC_00_15_0(8, W6, Wtmp0);
347   R( c, d, e, a, b, F4, 73 ); W_PRECALC_00_15_1(9, W6, Wtmp0);
348   R( b, c, d, e, a, F4, 74 ); W_PRECALC_00_15_2(10, W6, Wtmp0);
349   R( a, b, c, d, e, F4, 75 ); W_PRECALC_00_15_3(11, W6, Wtmp0);
350   R( e, a, b, c, d, F4, 76 ); W_PRECALC_00_15_0(12, W5, Wtmp0);
351   R( d, e, a, b, c, F4, 77 ); W_PRECALC_00_15_1(13, W5, Wtmp0);
352   R( c, d, e, a, b, F4, 78 );
353   addl state_h0(RSTATE), a;   W_PRECALC_00_15_2(14, W5, Wtmp0);
354   R( b, c, d, e, a, F4, 79 ); W_PRECALC_00_15_3(15, W5, Wtmp0);
355
356   /* Update the chaining variables. */
357   addl state_h3(RSTATE), d;
358   addl state_h2(RSTATE), c;
359   addl state_h1(RSTATE), b;
360   addl state_h4(RSTATE), e;
361
362   movl d, state_h3(RSTATE);
363   movl c, state_h2(RSTATE);
364   movl b, state_h1(RSTATE);
365   movl a, state_h0(RSTATE);
366   movl e, state_h4(RSTATE);
367
368   jmp .Loop;
369
370 .align 16
371 .Lend:
372   vzeroall;
373
374   /* Transform 64-79. */
375   R( b, c, d, e, a, F4, 64 );
376   R( a, b, c, d, e, F4, 65 );
377   R( e, a, b, c, d, F4, 66 );
378   R( d, e, a, b, c, F4, 67 );
379   R( c, d, e, a, b, F4, 68 );
380   R( b, c, d, e, a, F4, 69 );
381   R( a, b, c, d, e, F4, 70 );
382   R( e, a, b, c, d, F4, 71 );
383   R( d, e, a, b, c, F4, 72 );
384   R( c, d, e, a, b, F4, 73 );
385   R( b, c, d, e, a, F4, 74 );
386   R( a, b, c, d, e, F4, 75 );
387   R( e, a, b, c, d, F4, 76 );
388   R( d, e, a, b, c, F4, 77 );
389   R( c, d, e, a, b, F4, 78 );
390   addl state_h0(RSTATE), a;
391   R( b, c, d, e, a, F4, 79 );
392
393   /* Update the chaining variables. */
394   addl state_h3(RSTATE), d;
395   addl state_h2(RSTATE), c;
396   addl state_h1(RSTATE), b;
397   addl state_h4(RSTATE), e;
398
399   movl d, state_h3(RSTATE);
400   movl c, state_h2(RSTATE);
401   movl b, state_h1(RSTATE);
402   movl a, state_h0(RSTATE);
403   movl e, state_h4(RSTATE);
404
405   movq ROLDSTACK, %rsp;
406
407   popq %rbp;
408   popq %rbx;
409
410   /* burn_stack */
411   movl $(16*4 + 2*8 + 31), %eax;
412
413 .Lret:
414   ret;
415
416 #endif
417 #endif