mac: Fix gcry_mac_close to allow for a NULL handle.
[libgcrypt.git] / cipher / sha1-ssse3-amd64.S
1 /* sha1-ssse3-amd64.S - Intel SSSE3 accelerated SHA-1 transform function
2  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
33     defined(HAVE_GCC_INLINE_ASM_SSSE3) && defined(USE_SHA1)
34
35 #ifdef __PIC__
36 #  define RIP (%rip)
37 #else
38 #  define RIP
39 #endif
40
41
42 /* Context structure */
43
44 #define state_h0 0
45 #define state_h1 4
46 #define state_h2 8
47 #define state_h3 12
48 #define state_h4 16
49
50
51 /* Constants */
52
53 .data
54 #define K1  0x5A827999
55 #define K2  0x6ED9EBA1
56 #define K3  0x8F1BBCDC
57 #define K4  0xCA62C1D6
58 .align 16
59 .LK_XMM:
60 .LK1:   .long K1, K1, K1, K1
61 .LK2:   .long K2, K2, K2, K2
62 .LK3:   .long K3, K3, K3, K3
63 .LK4:   .long K4, K4, K4, K4
64
65 .Lbswap_shufb_ctl:
66         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
67
68
69 /* Register macros */
70
71 #define RSTATE %r8
72 #define RDATA %r9
73 #define ROLDSTACK %r10
74 #define RNBLKS %r11
75
76 #define a %eax
77 #define b %ebx
78 #define c %ecx
79 #define d %edx
80 #define e %edi
81
82 #define RT0 %esi
83 #define RT1 %ebp
84
85 #define Wtmp0 %xmm0
86 #define Wtmp1 %xmm1
87
88 #define W0 %xmm2
89 #define W1 %xmm3
90 #define W2 %xmm4
91 #define W3 %xmm5
92 #define W4 %xmm6
93 #define W5 %xmm7
94 #define W6 %xmm8
95 #define W7 %xmm9
96
97 #define BSWAP_REG %xmm10
98
99
100 /* Round function macros. */
101
102 #define WK(i) (((i) & 15) * 4)(%rsp)
103
104 #define R_F1(a,b,c,d,e,i) \
105         movl c, RT0; \
106         addl WK(i), e; \
107         xorl d, RT0; \
108         movl a, RT1; \
109         andl b, RT0; \
110         roll $30, b; \
111         xorl d, RT0; \
112         leal (RT0,e), e; \
113         roll $5, RT1; \
114         addl RT1, e;
115
116 #define R_F2(a,b,c,d,e,i) \
117         movl c, RT0; \
118         addl WK(i), e; \
119         xorl b, RT0; \
120         roll $30, b; \
121         xorl d, RT0; \
122         movl a, RT1; \
123         leal (RT0,e), e; \
124         roll $5, RT1; \
125         addl RT1, e;
126
127 #define R_F3(a,b,c,d,e,i) \
128         movl c, RT0; \
129         movl b, RT1; \
130         xorl b, RT0; \
131         andl c, RT1; \
132         andl d, RT0; \
133         addl RT1, e; \
134         addl WK(i), e; \
135         roll $30, b; \
136         movl a, RT1; \
137         leal (RT0,e), e; \
138         roll $5, RT1; \
139         addl RT1, e;
140
141 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
142
143 #define R(a,b,c,d,e,f,i) \
144         R_##f(a,b,c,d,e,i)
145
146
147 /* Input expansion macros. */
148
149 #define W_PRECALC_00_15_0(i, W, tmp0) \
150         movdqu (4*(i))(RDATA), tmp0;
151
152 #define W_PRECALC_00_15_1(i, W, tmp0) \
153         pshufb BSWAP_REG, tmp0; \
154         movdqa tmp0, W;
155
156 #define W_PRECALC_00_15_2(i, W, tmp0) \
157         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0;
158
159 #define W_PRECALC_00_15_3(i, W, tmp0) \
160         movdqa tmp0, WK(i&~3);
161
162 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
163         movdqa W_m12, W; \
164         palignr $8, W_m16, W; \
165         movdqa W_m04, tmp0; \
166         psrldq $4, tmp0; \
167         pxor W_m08, W;
168
169 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
170         pxor W_m16, tmp0; \
171         pxor tmp0, W; \
172         movdqa W, tmp1; \
173         movdqa W, tmp0; \
174         pslldq $12, tmp1;
175
176 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
177         psrld $31, W; \
178         pslld $1, tmp0; \
179         por W, tmp0; \
180         movdqa tmp1, W; \
181         psrld $30, tmp1; \
182         pslld $2, W;
183
184 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
185         pxor W, tmp0; \
186         pxor tmp1, tmp0; \
187         movdqa tmp0, W; \
188         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0; \
189         movdqa tmp0, WK((i)&~3);
190
191 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
192         movdqa W_m04, tmp0; \
193         pxor W_m28, W; \
194         palignr $8, W_m08, tmp0;
195
196 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
197         pxor W_m16, W; \
198         pxor tmp0, W; \
199         movdqa W, tmp0;
200
201 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
202         psrld $30, W; \
203         pslld $2, tmp0; \
204         por W, tmp0;
205
206 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
207         movdqa tmp0, W; \
208         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0; \
209         movdqa tmp0, WK((i)&~3);
210
211 #define CLEAR_REG(reg) pxor reg, reg;
212
213
214 /*
215  * Transform nblks*64 bytes (nblks*16 32-bit words) at DATA.
216  *
217  * unsigned int
218  * _gcry_sha1_transform_amd64_ssse3 (void *ctx, const unsigned char *data,
219  *                                   size_t nblks)
220  */
221 .text
222 .globl _gcry_sha1_transform_amd64_ssse3
223 .type _gcry_sha1_transform_amd64_ssse3,@function
224 .align 16
225 _gcry_sha1_transform_amd64_ssse3:
226   /* input:
227    *    %rdi: ctx, CTX
228    *    %rsi: data (64*nblks bytes)
229    *    %rdx: nblks
230    */
231
232   xorl %eax, %eax;
233   cmpq $0, %rdx;
234   jz .Lret;
235
236   movq %rdx, RNBLKS;
237   movq %rdi, RSTATE;
238   movq %rsi, RDATA;
239   pushq %rbx;
240   pushq %rbp;
241
242   movq %rsp, ROLDSTACK;
243
244   subq $(16*4), %rsp;
245   andq $(~31), %rsp;
246
247   /* Get the values of the chaining variables. */
248   movl state_h0(RSTATE), a;
249   movl state_h1(RSTATE), b;
250   movl state_h2(RSTATE), c;
251   movl state_h3(RSTATE), d;
252   movl state_h4(RSTATE), e;
253
254   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
255
256   /* Precalc 0-15. */
257   W_PRECALC_00_15_0(0, W0, Wtmp0);
258   W_PRECALC_00_15_1(1, W0, Wtmp0);
259   W_PRECALC_00_15_2(2, W0, Wtmp0);
260   W_PRECALC_00_15_3(3, W0, Wtmp0);
261   W_PRECALC_00_15_0(4, W7, Wtmp0);
262   W_PRECALC_00_15_1(5, W7, Wtmp0);
263   W_PRECALC_00_15_2(6, W7, Wtmp0);
264   W_PRECALC_00_15_3(7, W7, Wtmp0);
265   W_PRECALC_00_15_0(8, W6, Wtmp0);
266   W_PRECALC_00_15_1(9, W6, Wtmp0);
267   W_PRECALC_00_15_2(10, W6, Wtmp0);
268   W_PRECALC_00_15_3(11, W6, Wtmp0);
269   W_PRECALC_00_15_0(12, W5, Wtmp0);
270   W_PRECALC_00_15_1(13, W5, Wtmp0);
271   W_PRECALC_00_15_2(14, W5, Wtmp0);
272   W_PRECALC_00_15_3(15, W5, Wtmp0);
273
274 .align 8
275 .Loop:
276   addq $64, RDATA;
277
278   /* Transform 0-15 + Precalc 16-31. */
279   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
280   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
281   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
282   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
283   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
284   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
285   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
286   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
287   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
288   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
289   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
290   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
291   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
292   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
293   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
294   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
295
296   /* Transform 16-63 + Precalc 32-79. */
297   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
298   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
299   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
300   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
301   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
302   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
303   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
304   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
305   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
306   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
307   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
308   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
309   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
310   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
311   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
312   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
313   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
314   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
315   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
316   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
317   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
318   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
319   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
320   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
321   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
322   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
323   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
324   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
325   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
326   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
327   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
328   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
329   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
330   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
331   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
332   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
333   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
334   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
335   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
336   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
337   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
338   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
339   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
340   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
341   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
342   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
343   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
344   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
345
346   decq RNBLKS;
347   jz .Lend;
348
349   /* Transform 64-79 + Precalc 0-15 of next block. */
350   R( b, c, d, e, a, F4, 64 ); W_PRECALC_00_15_0(0, W0, Wtmp0);
351   R( a, b, c, d, e, F4, 65 ); W_PRECALC_00_15_1(1, W0, Wtmp0);
352   R( e, a, b, c, d, F4, 66 ); W_PRECALC_00_15_2(2, W0, Wtmp0);
353   R( d, e, a, b, c, F4, 67 ); W_PRECALC_00_15_3(3, W0, Wtmp0);
354   R( c, d, e, a, b, F4, 68 ); W_PRECALC_00_15_0(4, W7, Wtmp0);
355   R( b, c, d, e, a, F4, 69 ); W_PRECALC_00_15_1(5, W7, Wtmp0);
356   R( a, b, c, d, e, F4, 70 ); W_PRECALC_00_15_2(6, W7, Wtmp0);
357   R( e, a, b, c, d, F4, 71 ); W_PRECALC_00_15_3(7, W7, Wtmp0);
358   R( d, e, a, b, c, F4, 72 ); W_PRECALC_00_15_0(8, W6, Wtmp0);
359   R( c, d, e, a, b, F4, 73 ); W_PRECALC_00_15_1(9, W6, Wtmp0);
360   R( b, c, d, e, a, F4, 74 ); W_PRECALC_00_15_2(10, W6, Wtmp0);
361   R( a, b, c, d, e, F4, 75 ); W_PRECALC_00_15_3(11, W6, Wtmp0);
362   R( e, a, b, c, d, F4, 76 ); W_PRECALC_00_15_0(12, W5, Wtmp0);
363   R( d, e, a, b, c, F4, 77 ); W_PRECALC_00_15_1(13, W5, Wtmp0);
364   R( c, d, e, a, b, F4, 78 );
365   addl state_h0(RSTATE), a;   W_PRECALC_00_15_2(14, W5, Wtmp0);
366   R( b, c, d, e, a, F4, 79 ); W_PRECALC_00_15_3(15, W5, Wtmp0);
367
368   /* Update the chaining variables. */
369   addl state_h3(RSTATE), d;
370   addl state_h2(RSTATE), c;
371   addl state_h1(RSTATE), b;
372   addl state_h4(RSTATE), e;
373
374   movl d, state_h3(RSTATE);
375   movl c, state_h2(RSTATE);
376   movl b, state_h1(RSTATE);
377   movl a, state_h0(RSTATE);
378   movl e, state_h4(RSTATE);
379
380   jmp .Loop;
381
382 .align 16
383 .Lend:
384   /* Transform 64-79 + Clear XMM registers. */
385   R( b, c, d, e, a, F4, 64 ); CLEAR_REG(BSWAP_REG);
386   R( a, b, c, d, e, F4, 65 ); CLEAR_REG(Wtmp0);
387   R( e, a, b, c, d, F4, 66 ); CLEAR_REG(Wtmp1);
388   R( d, e, a, b, c, F4, 67 ); CLEAR_REG(W0);
389   R( c, d, e, a, b, F4, 68 ); CLEAR_REG(W1);
390   R( b, c, d, e, a, F4, 69 ); CLEAR_REG(W2);
391   R( a, b, c, d, e, F4, 70 ); CLEAR_REG(W3);
392   R( e, a, b, c, d, F4, 71 ); CLEAR_REG(W4);
393   R( d, e, a, b, c, F4, 72 ); CLEAR_REG(W5);
394   R( c, d, e, a, b, F4, 73 ); CLEAR_REG(W6);
395   R( b, c, d, e, a, F4, 74 ); CLEAR_REG(W7);
396   R( a, b, c, d, e, F4, 75 );
397   R( e, a, b, c, d, F4, 76 );
398   R( d, e, a, b, c, F4, 77 );
399   R( c, d, e, a, b, F4, 78 );
400   addl state_h0(RSTATE), a;
401   R( b, c, d, e, a, F4, 79 );
402
403   /* Update the chaining variables. */
404   addl state_h3(RSTATE), d;
405   addl state_h2(RSTATE), c;
406   addl state_h1(RSTATE), b;
407   addl state_h4(RSTATE), e;
408
409   movl d, state_h3(RSTATE);
410   movl c, state_h2(RSTATE);
411   movl b, state_h1(RSTATE);
412   movl a, state_h0(RSTATE);
413   movl e, state_h4(RSTATE);
414
415   movq ROLDSTACK, %rsp;
416
417   popq %rbp;
418   popq %rbx;
419
420   /* burn_stack */
421   movl $(16*4 + 2*8 + 31), %eax;
422
423 .Lret:
424   ret;
425
426 #endif
427 #endif