SHA-512: Add AVX and AVX2 implementations for x86-64
[libgcrypt.git] / cipher / sha512-ssse3-amd64.S
1 /*
2 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3 ; Copyright (c) 2012, Intel Corporation
4 ;
5 ; All rights reserved.
6 ;
7 ; Redistribution and use in source and binary forms, with or without
8 ; modification, are permitted provided that the following conditions are
9 ; met:
10 ;
11 ; * Redistributions of source code must retain the above copyright
12 ;   notice, this list of conditions and the following disclaimer.
13 ;
14 ; * Redistributions in binary form must reproduce the above copyright
15 ;   notice, this list of conditions and the following disclaimer in the
16 ;   documentation and/or other materials provided with the
17 ;   distribution.
18 ;
19 ; * Neither the name of the Intel Corporation nor the names of its
20 ;   contributors may be used to endorse or promote products derived from
21 ;   this software without specific prior written permission.
22 ;
23 ;
24 ; THIS SOFTWARE IS PROVIDED BY INTEL CORPORATION "AS IS" AND ANY
25 ; EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
26 ; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
27 ; PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL CORPORATION OR
28 ; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 ; EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 ; PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 ; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
32 ; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
33 ; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 ; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
36 */
37 /*
38  * Conversion to GAS assembly and integration to libgcrypt
39  *  by Jussi Kivilinna <jussi.kivilinna@iki.fi>
40  *
41  * Note: original implementation was named as SHA512-SSE4. However, only SSSE3
42  *       is required.
43  */
44
45 #ifdef __x86_64
46 #include <config.h>
47 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
48     defined(HAVE_INTEL_SYNTAX_PLATFORM_AS) && \
49     defined(HAVE_GCC_INLINE_ASM_SSSE3) && defined(USE_SHA512)
50
51 #ifdef __PIC__
52 #  define ADD_RIP +rip
53 #else
54 #  define ADD_RIP
55 #endif
56
57 .intel_syntax noprefix
58
59 .text
60
61 /* Virtual Registers */
62 msg = rdi /* ARG1 */
63 digest = rsi /* ARG2 */
64 msglen = rdx /* ARG3 */
65 T1 = rcx
66 T2 = r8
67 a_64 = r9
68 b_64 = r10
69 c_64 = r11
70 d_64 = r12
71 e_64 = r13
72 f_64 = r14
73 g_64 = r15
74 h_64 = rbx
75 tmp0 = rax
76
77 /*
78 ; Local variables (stack frame)
79 ; Note: frame_size must be an odd multiple of 8 bytes to XMM align RSP
80 */
81 frame_W      = 0 /* Message Schedule */
82 frame_W_size = (80 * 8)
83 frame_WK      = ((frame_W) + (frame_W_size)) /* W[t] + K[t] | W[t+1] + K[t+1] */
84 frame_WK_size = (2 * 8)
85 frame_GPRSAVE      = ((frame_WK) + (frame_WK_size))
86 frame_GPRSAVE_size = (5 * 8)
87 frame_size = ((frame_GPRSAVE) + (frame_GPRSAVE_size))
88
89
90 /* Useful QWORD "arrays" for simpler memory references */
91 #define MSG(i)    msg    + 8*(i)               /* Input message (arg1) */
92 #define DIGEST(i) digest + 8*(i)               /* Output Digest (arg2) */
93 #define K_t(i)    .LK512   + 8*(i) ADD_RIP     /* SHA Constants (static mem) */
94 #define W_t(i)    rsp + frame_W  + 8*(i)       /* Message Schedule (stack frame) */
95 #define WK_2(i)   rsp + frame_WK + 8*((i) % 2) /* W[t]+K[t] (stack frame) */
96 /* MSG, DIGEST, K_t, W_t are arrays */
97 /* WK_2(t) points to 1 of 2 qwords at frame.WK depdending on t being odd/even */
98
99 .macro RotateState
100         /* Rotate symbles a..h right */
101         __TMP = h_64
102         h_64 =  g_64
103         g_64 =  f_64
104         f_64 =  e_64
105         e_64 =  d_64
106         d_64 =  c_64
107         c_64 =  b_64
108         b_64 =  a_64
109         a_64 =  __TMP
110 .endm
111
112 .macro SHA512_Round t
113         /* Compute Round %%t */
114         mov     T1,   f_64        /* T1 = f */
115         mov     tmp0, e_64        /* tmp = e */
116         xor     T1,   g_64        /* T1 = f ^ g */
117         ror     tmp0, 23 /* 41     ; tmp = e ror 23 */
118         and     T1,   e_64        /* T1 = (f ^ g) & e */
119         xor     tmp0, e_64        /* tmp = (e ror 23) ^ e */
120         xor     T1,   g_64        /* T1 = ((f ^ g) & e) ^ g = CH(e,f,g) */
121         add     T1,   [WK_2(\t)] /* W[t] + K[t] from message scheduler */
122         ror     tmp0, 4 /* 18      ; tmp = ((e ror 23) ^ e) ror 4 */
123         xor     tmp0, e_64        /* tmp = (((e ror 23) ^ e) ror 4) ^ e */
124         mov     T2,   a_64        /* T2 = a */
125         add     T1,   h_64        /* T1 = CH(e,f,g) + W[t] + K[t] + h */
126         ror     tmp0, 14 /* 14     ; tmp = ((((e ror23)^e)ror4)^e)ror14 = S1(e) */
127         add     T1,   tmp0        /* T1 = CH(e,f,g) + W[t] + K[t] + S1(e) */
128         mov     tmp0, a_64        /* tmp = a */
129         xor     T2,   c_64        /* T2 = a ^ c */
130         and     tmp0, c_64        /* tmp = a & c */
131         and     T2,   b_64        /* T2 = (a ^ c) & b */
132         xor     T2,   tmp0        /* T2 = ((a ^ c) & b) ^ (a & c) = Maj(a,b,c) */
133         mov     tmp0, a_64        /* tmp = a */
134         ror     tmp0, 5 /* 39      ; tmp = a ror 5 */
135         xor     tmp0, a_64        /* tmp = (a ror 5) ^ a */
136         add     d_64, T1          /* e(next_state) = d + T1  */
137         ror     tmp0, 6 /* 34      ; tmp = ((a ror 5) ^ a) ror 6 */
138         xor     tmp0, a_64        /* tmp = (((a ror 5) ^ a) ror 6) ^ a */
139         lea     h_64, [T1 + T2]   /* a(next_state) = T1 + Maj(a,b,c) */
140         ror     tmp0, 28 /* 28     ; tmp = ((((a ror5)^a)ror6)^a)ror28 = S0(a) */
141         add     h_64, tmp0        /* a(next_state) = T1 + Maj(a,b,c) S0(a) */
142         RotateState
143 .endm
144
145 .macro SHA512_2Sched_2Round_sse t
146 /*      ; Compute rounds %%t-2 and %%t-1
147         ; Compute message schedule QWORDS %%t and %%t+1
148
149         ;   Two rounds are computed based on the values for K[t-2]+W[t-2] and
150         ; K[t-1]+W[t-1] which were previously stored at WK_2 by the message
151         ; scheduler.
152         ;   The two new schedule QWORDS are stored at [W_t(%%t)] and [W_t(%%t+1)].
153         ; They are then added to their respective SHA512 constants at
154         ; [K_t(%%t)] and [K_t(%%t+1)] and stored at dqword [WK_2(%%t)]
155         ;   For brievity, the comments following vectored instructions only refer to
156         ; the first of a pair of QWORDS.
157         ; Eg. XMM2=W[t-2] really means XMM2={W[t-2]|W[t-1]}
158         ;   The computation of the message schedule and the rounds are tightly
159         ; stitched to take advantage of instruction-level parallelism.
160         ; For clarity, integer instructions (for the rounds calculation) are indented
161         ; by one tab. Vectored instructions (for the message scheduler) are indented
162         ; by two tabs. */
163
164         mov     T1, f_64
165                 movdqa  xmm2, [W_t(\t-2)]  /* XMM2 = W[t-2] */
166         xor     T1,   g_64
167         and     T1,   e_64
168                 movdqa  xmm0, xmm2          /* XMM0 = W[t-2] */
169         xor     T1,   g_64
170         add     T1,   [WK_2(\t)]
171                 movdqu  xmm5, [W_t(\t-15)] /* XMM5 = W[t-15] */
172         mov     tmp0, e_64
173         ror     tmp0, 23 /* 41 */
174                 movdqa  xmm3, xmm5          /* XMM3 = W[t-15] */
175         xor     tmp0, e_64
176         ror     tmp0, 4 /* 18 */
177                 psrlq   xmm0, 61 - 19       /* XMM0 = W[t-2] >> 42 */
178         xor     tmp0, e_64
179         ror     tmp0, 14 /* 14 */
180                 psrlq   xmm3, (8 - 7)       /* XMM3 = W[t-15] >> 1 */
181         add     T1,   tmp0
182         add     T1,   h_64
183                 pxor    xmm0, xmm2          /* XMM0 = (W[t-2] >> 42) ^ W[t-2] */
184         mov     T2,   a_64
185         xor     T2,   c_64
186                 pxor    xmm3, xmm5          /* XMM3 = (W[t-15] >> 1) ^ W[t-15] */
187         and     T2,   b_64
188         mov     tmp0, a_64
189                 psrlq   xmm0, 19 - 6        /* XMM0 = ((W[t-2]>>42)^W[t-2])>>13 */
190         and     tmp0, c_64
191         xor     T2,   tmp0
192                 psrlq   xmm3, (7 - 1)       /* XMM3 = ((W[t-15]>>1)^W[t-15])>>6 */
193         mov     tmp0, a_64
194         ror     tmp0, 5 /* 39 */
195                 pxor    xmm0, xmm2          /* XMM0 = (((W[t-2]>>42)^W[t-2])>>13)^W[t-2] */
196         xor     tmp0, a_64
197         ror     tmp0, 6 /* 34 */
198                 pxor    xmm3, xmm5          /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15] */
199         xor     tmp0, a_64
200         ror     tmp0, 28 /* 28 */
201                 psrlq   xmm0, 6             /* XMM0 = ((((W[t-2]>>42)^W[t-2])>>13)^W[t-2])>>6 */
202         add     T2,   tmp0
203         add     d_64, T1
204                 psrlq   xmm3, 1             /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15]>>1 */
205         lea     h_64, [T1 + T2]
206         RotateState
207                 movdqa  xmm1, xmm2          /* XMM1 = W[t-2] */
208         mov     T1, f_64
209         xor     T1,   g_64
210                 movdqa  xmm4, xmm5          /* XMM4 = W[t-15] */
211         and     T1,   e_64
212         xor     T1,   g_64
213                 psllq   xmm1, (64 - 19) - (64 - 61) /* XMM1 = W[t-2] << 42 */
214         add     T1,   [WK_2(\t+1)]
215         mov     tmp0, e_64
216                 psllq   xmm4, (64 - 1) - (64 - 8) /* XMM4 = W[t-15] << 7 */
217         ror     tmp0, 23 /* 41 */
218         xor     tmp0, e_64
219                 pxor    xmm1, xmm2          /* XMM1 = (W[t-2] << 42)^W[t-2] */
220         ror     tmp0, 4 /* 18 */
221         xor     tmp0, e_64
222                 pxor    xmm4, xmm5          /* XMM4 = (W[t-15]<<7)^W[t-15] */
223         ror     tmp0, 14 /* 14 */
224         add     T1,   tmp0
225                 psllq   xmm1, (64 - 61)     /* XMM1 = ((W[t-2] << 42)^W[t-2])<<3 */
226         add     T1,   h_64
227         mov     T2,   a_64
228                 psllq   xmm4, (64 - 8)      /* XMM4 = ((W[t-15]<<7)^W[t-15])<<56 */
229         xor     T2,   c_64
230         and     T2,   b_64
231                 pxor    xmm0, xmm1          /* XMM0 = s1(W[t-2]) */
232         mov     tmp0, a_64
233         and     tmp0, c_64
234                 movdqu  xmm1, [W_t(\t- 7)] /* XMM1 = W[t-7] */
235         xor     T2,   tmp0
236                 pxor    xmm3, xmm4          /* XMM3 = s0(W[t-15]) */
237         mov     tmp0, a_64
238                 paddq   xmm0, xmm3          /* XMM0 = s1(W[t-2]) + s0(W[t-15]) */
239         ror     tmp0, 5 /* 39 */
240                 paddq   xmm0, [W_t(\t-16)] /* XMM0 = s1(W[t-2]) + s0(W[t-15]) + W[t-16] */
241         xor     tmp0, a_64
242                 paddq   xmm0, xmm1          /* XMM0 = s1(W[t-2]) + W[t-7] + s0(W[t-15]) + W[t-16] */
243         ror     tmp0, 6 /* 34 */
244                 movdqa  [W_t(\t)], xmm0     /* Store scheduled qwords */
245         xor     tmp0, a_64
246                 paddq   xmm0, [K_t(t)]      /* Compute W[t]+K[t] */
247         ror     tmp0, 28 /* 28 */
248                 movdqa  [WK_2(t)], xmm0     /* Store W[t]+K[t] for next rounds */
249         add     T2,   tmp0
250         add     d_64, T1
251         lea     h_64, [T1 + T2]
252         RotateState
253 .endm
254
255 /*
256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
257 ; void sha512_sse4(const void* M, void* D, uint64_t L);
258 ; Purpose: Updates the SHA512 digest stored at D with the message stored in M.
259 ; The size of the message pointed to by M must be an integer multiple of SHA512
260 ;   message blocks.
261 ; L is the message length in SHA512 blocks.
262 */
263 .globl _gcry_sha512_transform_amd64_ssse3
264 .type _gcry_sha512_transform_amd64_ssse3,@function;
265 .align 16
266 _gcry_sha512_transform_amd64_ssse3:
267         xor eax, eax
268
269         cmp msglen, 0
270         je .Lnowork
271
272         /* Allocate Stack Space */
273         sub     rsp, frame_size
274
275         /* Save GPRs */
276         mov     [rsp + frame_GPRSAVE + 8 * 0], rbx
277         mov     [rsp + frame_GPRSAVE + 8 * 1], r12
278         mov     [rsp + frame_GPRSAVE + 8 * 2], r13
279         mov     [rsp + frame_GPRSAVE + 8 * 3], r14
280         mov     [rsp + frame_GPRSAVE + 8 * 4], r15
281
282 .Lupdateblock:
283
284         /* Load state variables */
285         mov     a_64, [DIGEST(0)]
286         mov     b_64, [DIGEST(1)]
287         mov     c_64, [DIGEST(2)]
288         mov     d_64, [DIGEST(3)]
289         mov     e_64, [DIGEST(4)]
290         mov     f_64, [DIGEST(5)]
291         mov     g_64, [DIGEST(6)]
292         mov     h_64, [DIGEST(7)]
293
294         t = 0
295         .rept 80/2 + 1
296         /* (80 rounds) / (2 rounds/iteration) + (1 iteration) */
297         /* +1 iteration because the scheduler leads hashing by 1 iteration */
298                 .if t < 2
299                         /* BSWAP 2 QWORDS */
300                         movdqa  xmm1, [.LXMM_QWORD_BSWAP ADD_RIP]
301                         movdqu  xmm0, [MSG(t)]
302                         pshufb  xmm0, xmm1      /* BSWAP */
303                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
304                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
305                         movdqa  [WK_2(t)], xmm0 /* Store into WK for rounds */
306                 .elseif t < 16
307                         /* BSWAP 2 QWORDS; Compute 2 Rounds */
308                         movdqu  xmm0, [MSG(t)]
309                         pshufb  xmm0, xmm1      /* BSWAP */
310                         SHA512_Round (t - 2)    /* Round t-2 */
311                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
312                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
313                         SHA512_Round (t - 1)    /* Round t-1 */
314                         movdqa  [WK_2(t)], xmm0 /* Store W[t]+K[t] into WK */
315                 .elseif t < 79
316                         /* Schedule 2 QWORDS; Compute 2 Rounds */
317                         SHA512_2Sched_2Round_sse t
318                 .else
319                         /* Compute 2 Rounds */
320                         SHA512_Round (t - 2)
321                         SHA512_Round (t - 1)
322                 .endif
323                 t = (t)+2
324         .endr
325
326         /* Update digest */
327         add     [DIGEST(0)], a_64
328         add     [DIGEST(1)], b_64
329         add     [DIGEST(2)], c_64
330         add     [DIGEST(3)], d_64
331         add     [DIGEST(4)], e_64
332         add     [DIGEST(5)], f_64
333         add     [DIGEST(6)], g_64
334         add     [DIGEST(7)], h_64
335
336         /* Advance to next message block */
337         add     msg, 16*8
338         dec     msglen
339         jnz     .Lupdateblock
340
341         /* Restore GPRs */
342         mov     rbx, [rsp + frame_GPRSAVE + 8 * 0]
343         mov     r12, [rsp + frame_GPRSAVE + 8 * 1]
344         mov     r13, [rsp + frame_GPRSAVE + 8 * 2]
345         mov     r14, [rsp + frame_GPRSAVE + 8 * 3]
346         mov     r15, [rsp + frame_GPRSAVE + 8 * 4]
347
348         /* Restore Stack Pointer */
349         add     rsp, frame_size
350
351         /* Return stack burn depth */
352         mov     rax, frame_size
353
354 .Lnowork:
355         ret
356
357 /*
358 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
359 ;;; Binary Data
360 */
361
362 .data
363
364 .align 16
365
366 /* Mask for byte-swapping a couple of qwords in an XMM register using (v)pshufb. */
367 .LXMM_QWORD_BSWAP:
368         .octa 0x08090a0b0c0d0e0f0001020304050607
369
370 /* K[t] used in SHA512 hashing */
371 .LK512:
372         .quad 0x428a2f98d728ae22,0x7137449123ef65cd
373         .quad 0xb5c0fbcfec4d3b2f,0xe9b5dba58189dbbc
374         .quad 0x3956c25bf348b538,0x59f111f1b605d019
375         .quad 0x923f82a4af194f9b,0xab1c5ed5da6d8118
376         .quad 0xd807aa98a3030242,0x12835b0145706fbe
377         .quad 0x243185be4ee4b28c,0x550c7dc3d5ffb4e2
378         .quad 0x72be5d74f27b896f,0x80deb1fe3b1696b1
379         .quad 0x9bdc06a725c71235,0xc19bf174cf692694
380         .quad 0xe49b69c19ef14ad2,0xefbe4786384f25e3
381         .quad 0x0fc19dc68b8cd5b5,0x240ca1cc77ac9c65
382         .quad 0x2de92c6f592b0275,0x4a7484aa6ea6e483
383         .quad 0x5cb0a9dcbd41fbd4,0x76f988da831153b5
384         .quad 0x983e5152ee66dfab,0xa831c66d2db43210
385         .quad 0xb00327c898fb213f,0xbf597fc7beef0ee4
386         .quad 0xc6e00bf33da88fc2,0xd5a79147930aa725
387         .quad 0x06ca6351e003826f,0x142929670a0e6e70
388         .quad 0x27b70a8546d22ffc,0x2e1b21385c26c926
389         .quad 0x4d2c6dfc5ac42aed,0x53380d139d95b3df
390         .quad 0x650a73548baf63de,0x766a0abb3c77b2a8
391         .quad 0x81c2c92e47edaee6,0x92722c851482353b
392         .quad 0xa2bfe8a14cf10364,0xa81a664bbc423001
393         .quad 0xc24b8b70d0f89791,0xc76c51a30654be30
394         .quad 0xd192e819d6ef5218,0xd69906245565a910
395         .quad 0xf40e35855771202a,0x106aa07032bbd1b8
396         .quad 0x19a4c116b8d2d0c8,0x1e376c085141ab53
397         .quad 0x2748774cdf8eeb99,0x34b0bcb5e19b48a8
398         .quad 0x391c0cb3c5c95a63,0x4ed8aa4ae3418acb
399         .quad 0x5b9cca4f7763e373,0x682e6ff3d6b2b8a3
400         .quad 0x748f82ee5defb2fc,0x78a5636f43172f60
401         .quad 0x84c87814a1f0ab72,0x8cc702081a6439ec
402         .quad 0x90befffa23631e28,0xa4506cebde82bde9
403         .quad 0xbef9a3f7b2c67915,0xc67178f2e372532b
404         .quad 0xca273eceea26619c,0xd186b8c721c0c207
405         .quad 0xeada7dd6cde0eb1e,0xf57d4f7fee6ed178
406         .quad 0x06f067aa72176fba,0x0a637dc5a2c898a6
407         .quad 0x113f9804bef90dae,0x1b710b35131c471b
408         .quad 0x28db77f523047d84,0x32caab7b40c72493
409         .quad 0x3c9ebe0a15c9bebc,0x431d67c49c100d4c
410         .quad 0x4cc5d4becb3e42b6,0x597f299cfc657e2a
411         .quad 0x5fcb6fab3ad6faec,0x6c44198c4a475817
412
413 #endif
414 #endif