Some experimental support for other random gatheres
[libgcrypt.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_INIT(g10/g10.c)
11 AC_CONFIG_AUX_DIR(scripts)
12 AM_CONFIG_HEADER(config.h)
13
14
15 VERSION=`cat $srcdir/VERSION`
16 PACKAGE=gnupg
17 ALL_LINGUAS="en de it fr ru es_ES"
18 AC_SUBST(VERSION)
19 AC_SUBST(PACKAGE)
20 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
22
23 AC_MSG_CHECKING([whether use of /dev/random is requested])
24 AC_ARG_ENABLE(dev-random,
25 [  --disable-dev-random    disable the use of dev random],
26     try_dev_random=$enableval, try_dev_random=yes)
27 AC_MSG_RESULT($try_dev_random)
28
29 AC_MSG_CHECKING([whether use of extensions is requested])
30 AC_ARG_ENABLE(dynload,
31 [  --disable-dynload       disable use of extensions],
32     try_dynload=$enableval, try_dynload=yes)
33 AC_MSG_RESULT($try_dynload)
34
35 AC_MSG_CHECKING([whether assembler modules are requested])
36 AC_ARG_ENABLE(asm,
37 [  --disable-asm           do not use assembler modules],
38      try_asm_modules=$enableval, try_asm_modules=yes)
39 AC_MSG_RESULT($try_asm_modules)
40
41 AC_MSG_CHECKING([whether memory debugging is requested])
42 AC_ARG_ENABLE(m-debug,
43 [  --enable-m-debug        enable debugging of memory allocation],
44 use_m_debug=$enableval, use_m_debug=no)
45 AC_MSG_RESULT($use_m_debug)
46 if test "$use_m_debug" = yes; then
47     AC_DEFINE(M_DEBUG)
48     use_m_guard=yes
49 else
50     AC_MSG_CHECKING([whether memory guard is requested])
51     AC_ARG_ENABLE(m-guard,
52     [  --disable-m-guard       disable memory guard facility],
53     use_m_guard=$enableval, use_m_guard=yes)
54     AC_MSG_RESULT($use_m_guard)
55 fi
56 if test "$use_m_guard" = yes ; then
57     AC_DEFINE(M_GUARD)
58     CFLAGS="$CFLAGS -g -Wall"
59 else
60     CFLAGS="$CFLAGS -O2 -Wall"
61 fi
62
63
64 AC_MSG_CHECKING([whether included zlib is requested])
65 AC_ARG_WITH(included-zlib,
66     [  --with-included-zlib    use the zlib code included here],
67 [g10_force_zlib=yes], [g10_force_zlib=no] )
68 AC_MSG_RESULT($g10_force_zlib)
69
70 dnl Checks for programs.
71
72 AC_CANONICAL_SYSTEM
73 AC_ARG_PROGRAM
74 AC_PROG_MAKE_SET
75 AM_SANITY_CHECK
76 missing_dir=`cd $ac_aux_dir && pwd`
77 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
78 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
79 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
80 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
81 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
82 AC_PROG_CC
83 AC_PROG_CPP
84 AC_ISC_POSIX
85 AC_PROG_RANLIB
86 AC_PROG_INSTALL
87 AM_CYGWIN32
88
89
90
91 case "${target}" in
92     i386--mingw32)
93         # special stuff for Windoze NT
94         cross_compiling=yes
95         CC="i386--mingw32-gcc"
96         CPP="i386--mingw32-gcc -E"
97         RANLIB="i386--mingw32-ranlib"
98         ac_cv_have_dev_random=no
99         AC_DEFINE(USE_RNDW32)
100         ;;
101     *-*-hpux*)
102         if test -z "$GCC" ; then
103             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
104         fi
105         AC_DEFINE(USE_RNDUNIX)
106         ;;
107     *)
108        ;;
109 esac
110
111 case "${target}" in
112     i386--mingw32)
113         PRINTABLE_OS_NAME="MingW32"
114         ;;
115     *-linux*)
116         PRINTABLE_OS_NAME="GNU/Linux"
117         ;;
118     *)
119         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
120         ;;
121 esac
122 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
123
124 dnl  Fixme: Are these the best flags for OpenBSD????
125 case "${target}" in
126     *-openbsd*)
127         NAME_OF_DEV_RANDOM="/dev/srandom"
128         NAME_OF_DEV_URANDOM="/dev/urandom"
129         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
130         ;;
131     *)
132         NAME_OF_DEV_RANDOM="/dev/random"
133         NAME_OF_DEV_URANDOM="/dev/urandom"
134         DYNLINK_MOD_CFLAGS="-shared  -fPIC -lc"
135         ;;
136 esac
137 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
138 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
139
140
141 dnl Checks for libraries.
142
143 AM_GNU_GETTEXT
144
145 AC_CHECK_LIB(gdbm,gdbm_firstkey)
146
147 if test "$try_dynload" = yes ; then
148 AC_CHECK_LIB(dl,dlopen)
149 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
150   AC_DEFINE(USE_DYNAMIC_LINKING)
151   AC_DEFINE(HAVE_DL_DLOPEN)
152   DYNLINK_LDFLAGS=-rdynamic
153   use_gnupg_extensions=yes
154 else
155 AC_CHECK_LIB(dld,dld_link)
156 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
157   AC_DEFINE(USE_DYNAMIC_LINKING)
158   AC_DEFINE(HAVE_DLD_DLD_LINK)
159   DYNLINK_LDFLAGS=-rdynamic
160   use_gnupg_extensions=yes
161 fi
162 fi
163 else
164   AC_MSG_CHECKING(for dynamic loading)
165   DYNLINK_LDFLAGS=
166   DYNLINK_MOD_CFLAGS=
167   use_gnupg_extensions=no
168   AC_MSG_RESULT(has been disabled)
169 fi
170
171 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
172 AC_SUBST(DYNLINK_LDFLAGS)
173 AC_SUBST(DYNLINK_MOD_CFLAGS)
174
175
176 dnl Checks for header files.
177 AC_HEADER_STDC
178 AC_CHECK_HEADERS(unistd.h)
179
180
181 dnl Checks for typedefs, structures, and compiler characteristics.
182 AC_C_CONST
183 AC_C_INLINE
184 AC_TYPE_SIZE_T
185 AC_TYPE_SIGNAL
186 AC_DECL_SYS_SIGLIST
187
188 WK_CHECK_ENDIAN
189
190
191 WK_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
192 WK_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
193 WK_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
194 WK_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
195 WK_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
196
197 AC_CHECK_SIZEOF(unsigned short, 2)
198 AC_CHECK_SIZEOF(unsigned int, 4)
199 AC_CHECK_SIZEOF(unsigned long, 4)
200
201 if test "$ac_cv_sizeof_unsigned_short" = "0" \
202    || test "$ac_cv_sizeof_unsigned_int" = "0" \
203    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
204     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
205 fi
206
207
208
209 dnl Checks for library functions.
210 AC_FUNC_VPRINTF
211 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
212 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
213 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime)
214
215 WK_CHECK_MLOCK
216
217 WK_CHECK_IPC
218 if test "$ac_cv_header_sys_shm_h" = "yes"; then
219   AC_DEFINE(USE_SHM_COPROCESSING)
220 fi
221
222 dnl check whether we have a random device
223 if test "$try_dev_random" = yes ; then
224 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
225 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
226   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
227 if test "$ac_cv_have_dev_random" = yes; then
228     AC_DEFINE(HAVE_DEV_RANDOM)
229     AC_DEFINE(USE_RNDLINUX)
230 fi
231 else
232     AC_MSG_CHECKING(for random device)
233     ac_cv_have_dev_random=no
234     AC_MSG_RESULT(has been disabled)
235 fi
236
237
238 dnl setup assembler stuff
239 AC_MSG_CHECKING(for mpi assembler functions)
240 if test -f $srcdir/mpi/config.links ; then
241     . $srcdir/mpi/config.links
242     WK_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
243     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
244     ac_cv_mpi_sflags="$mpi_sflags"
245     ac_cv_mpi_config_done="yes"
246     AC_MSG_RESULT(done)
247 else
248     AC_MSG_RESULT(failed)
249     AC_MSG_ERROR([mpi/config.links missing!])
250 fi
251 MPI_EXTRA_ASM_OBJS=""
252 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
253 WK_MSG_PRINT([mpi extra asm functions:])
254 for i in $ac_cv_mpi_extra_asm_modules; do
255     WK_MSG_PRINT([$i])
256     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
257 done
258 AC_MSG_RESULT()
259 fi
260 AC_SUBST(MPI_EXTRA_ASM_OBJS)
261 MPI_SFLAGS="$ac_cv_mpi_sflags"
262 AC_SUBST(MPI_SFLAGS)
263
264 dnl Do we have zlib? Must do it here because Solaris failed
265 dnl when compiling a conftest (due to the "-lz" from LIBS).
266 if test "$g10_force_zlib" = "yes"; then
267     ZLIBS="../zlib/libzlib.a"
268     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
269     WK_LINK_FILES(zlib/zlib.h, zlib.h )
270     WK_LINK_FILES(zlib/zconf.h, zconf.h )
271 else
272 AC_CHECK_HEADERS(zlib.h)
273 if test "$ac_cv_header_zlib_h" = yes ; then
274     LIBS="$LIBS -lz"
275     ZLIBS=
276     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
277 else
278     ZLIBS="../zlib/libzlib.a"
279     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
280     WK_LINK_FILES(zlib/zlib.h, zlib.h )
281     WK_LINK_FILES(zlib/zconf.h, zconf.h )
282 fi
283 fi
284 AC_SUBST(ZLIBS)
285
286 WK_DO_LINK_FILES
287
288
289 AC_OUTPUT([
290 Makefile
291 intl/Makefile
292 po/Makefile.in
293 util/Makefile
294 mpi/Makefile
295 cipher/Makefile
296 g10/Makefile
297 doc/Makefile
298 tools/Makefile
299 zlib/Makefile
300 checks/Makefile
301 ])
302